qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include <client/defs.qh>
   7         #include "../constants.qh"
   8         #include "../stats.qh"
   9         #include <lib/warpzone/anglestransform.qh>
  10         #include <lib/warpzone/common.qh>
  11         #include <lib/warpzone/client.qh>
  12         #include "../util.qh"
  13         #include <client/autocvars.qh>
  14         #include "../deathtypes/all.qh"
  15         #include <lib/csqcmodel/interpolate.qh>
  16         #include "../physics/movetypes/movetypes.qh"
  17         #include <client/main.qh>
  18         #include <lib/csqcmodel/cl_model.qh>
  19 #elif defined(MENUQC)
  20 #elif defined(SVQC)
  21         #include <common/items/_mod.qh>
  22     #include <lib/warpzone/anglestransform.qh>
  23     #include <lib/warpzone/common.qh>
  24     #include <lib/warpzone/util_server.qh>
  25     #include <lib/warpzone/server.qh>
  26     #include "../constants.qh"
  27     #include "../stats.qh"
  28     #include "../teams.qh"
  29     #include <common/util.qh>
  30     #include "../monsters/_mod.qh"
  31     #include "config.qh"
  32     #include <server/weapons/csqcprojectile.qh>
  33     #include <server/weapons/tracing.qh>
  34     #include "../t_items.qh"
  35     #include <server/autocvars.qh>
  36     #include <server/constants.qh>
  37     #include <server/defs.qh>
  38     #include "../notifications/all.qh"
  39     #include "../deathtypes/all.qh"
  40     #include <server/mutators/_mod.qh>
  41     #include "../mapinfo.qh"
  42     #include <server/command/_mod.qh>
  43     #include <lib/csqcmodel/sv_model.qh>
  44     #include <server/portals.qh>
  45     #include <server/g_hook.qh>
  46 #endif
  47 #ifdef GAMEQC
  48         #include "calculations.qc"
  49 #endif
  50 #ifdef SVQC
  51         #include "config.qc"
  52 #endif
  53
  54 #include "weapon/_mod.inc"
  55
  56
  57 // WEAPON PLUGIN SYSTEM
  58
  59 WepSet _WepSet_FromWeapon(int a)
  60 {
  61         a -= WEP_FIRST;
  62         if (Weapons_MAX > 24)
  63                 if (a >= 24)
  64                 {
  65                         a -= 24;
  66                         if (Weapons_MAX > 48)
  67                                 if (a >= 24)
  68                                 {
  69                                         a -= 24;
  70                                         return '0 0 1' * (2 ** a);
  71                                 }
  72                         return '0 1 0' * (2 ** a);
  73                 }
  74         return '1 0 0' * (2 ** a);
  75 }
  76 #ifdef SVQC
  77         void WriteWepSet(float dst, WepSet w)
  78         {
  79                 if (Weapons_MAX > 48) WriteInt72_t(dst, w);
  80                 else if (Weapons_MAX > 24) WriteInt48_t(dst, w);
  81                 else WriteInt24_t(dst, w.x);
  82         }
  83 #endif
  84 #ifdef CSQC
  85         WepSet WepSet_GetFromStat()
  86         {
  87                 return STAT(WEAPONS);
  88         }
  89         WepSet WepSet_GetFromStat_InMap()
  90         {
  91                 return STAT(WEAPONSINMAP);
  92         }
  93         WepSet ReadWepSet()
  94         {
  95                 if (Weapons_MAX > 48) return ReadInt72_t();
  96                 if (Weapons_MAX > 24) return ReadInt48_t();
  97                 return ReadInt24_t() * '1 0 0';
  98         }
  99 #endif
 100
 101 string W_FixWeaponOrder(string order, float complete)
 102 {
 103         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 104 }
 105 string W_NameWeaponOrder_MapFunc(string s)
 106 {
 107         int i = stof(s);
 108         if (s == "0" || i)
 109         {
 110                 entity wi = Weapons_from(i);
 111                 if (wi != WEP_Null) return wi.netname;
 112         }
 113         return s;
 114 }
 115
 116 string W_UndeprecateName(string s)
 117 {
 118         switch (s)
 119         {
 120                 case "nex": return "vortex";
 121                 case "rocketlauncher": return "devastator";
 122                 case "laser": return "blaster";
 123                 case "minstanex": return "vaporizer";
 124                 case "grenadelauncher": return "mortar";
 125                 case "uzi": return "machinegun";
 126                 default: return s;
 127         }
 128 }
 129 string W_NameWeaponOrder(string order)
 130 {
 131         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 132 }
 133 string W_NumberWeaponOrder_MapFunc(string s)
 134 {
 135         if (s == "0" || stof(s)) return s;
 136         s = W_UndeprecateName(s);
 137         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 138         return s;
 139 }
 140 string W_NumberWeaponOrder(string order)
 141 {
 142         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 143 }
 144
 145 float W_FixWeaponOrder_BuildImpulseList_buf[Weapons_MAX];
 146 string W_FixWeaponOrder_BuildImpulseList_order;
 147 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 148 {
 149         float h;
 150         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 151         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 152         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 153 }
 154 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 155 {
 156         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 157         Weapon e1 = Weapons_from(si);
 158         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 159         Weapon e2 = Weapons_from(sj);
 160         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 161         if (d != 0) return -d;  // high impulse first!
 162         return strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 163                 sprintf(" %d ", si), 0)
 164                -
 165                strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 166                 sprintf(" %d ", sj), 0)
 167         ;  // low char index first!
 168 }
 169 string W_FixWeaponOrder_BuildImpulseList(string o)
 170 {
 171         int i;
 172         W_FixWeaponOrder_BuildImpulseList_order = o;
 173         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 174                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 175         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 176                 NULL);
 177         o = "";
 178         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 179                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 180         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 181         return substring(o, 1, -1);
 182 }
 183
 184 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 185 {
 186         return W_FixWeaponOrder(order, 0);
 187 }
 188
 189 string W_FixWeaponOrder_ForceComplete(string order)
 190 {
 191         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 192         return W_FixWeaponOrder(order, 1);
 193 }
 194
 195 void W_RandomWeapons(entity e, int n)
 196 {
 197         WepSet remaining = e.weapons;
 198         WepSet result = '0 0 0';
 199         for (int j = 0; j < n; ++j)
 200         {
 201                 RandomSelection_Init();
 202                 FOREACH(Weapons, it != WEP_Null, {
 203                         if (remaining & (it.m_wepset))
 204                                 RandomSelection_AddEnt(it, 1, 1);
 205                 });
 206                 Weapon w = RandomSelection_chosen_ent;
 207                 result |= WepSet_FromWeapon(w);
 208                 remaining &= ~WepSet_FromWeapon(w);
 209         }
 210         e.weapons = result;
 211 }
 212
 213 string GetAmmoPicture(int ammotype)
 214 {
 215         switch (ammotype)
 216         {
 217                 case RESOURCE_SHELLS:  return ITEM_Shells.m_icon;
 218                 case RESOURCE_BULLETS: return ITEM_Bullets.m_icon;
 219                 case RESOURCE_ROCKETS: return ITEM_Rockets.m_icon;
 220                 case RESOURCE_CELLS:   return ITEM_Cells.m_icon;
 221                 case RESOURCE_PLASMA:  return ITEM_Plasma.m_icon;
 222                 case RESOURCE_FUEL:    return ITEM_JetpackFuel.m_icon;
 223                 default: return "";  // wtf, no ammo type?
 224         }
 225 }
 226
 227 #ifdef CSQC
 228 int GetAmmoTypeFromNum(int i)
 229 {
 230         switch (i)
 231         {
 232                 case 0: return RESOURCE_SHELLS;
 233                 case 1: return RESOURCE_BULLETS;
 234                 case 2: return RESOURCE_ROCKETS;
 235                 case 3: return RESOURCE_CELLS;
 236                 case 4: return RESOURCE_PLASMA;
 237                 case 5: return RESOURCE_FUEL;
 238                 default: return RESOURCE_NONE;
 239         }
 240 }
 241
 242 int GetAmmoStat(int ammotype)
 243 {
 244         switch (ammotype)
 245         {
 246                 case RESOURCE_SHELLS: return STAT_SHELLS;
 247                 case RESOURCE_BULLETS: return STAT_NAILS;
 248                 case RESOURCE_ROCKETS: return STAT_ROCKETS;
 249                 case RESOURCE_CELLS: return STAT_CELLS;
 250                 case RESOURCE_PLASMA: return STAT_PLASMA.m_id;
 251                 case RESOURCE_FUEL: return STAT_FUEL.m_id;
 252                 default: return -1;
 253         }
 254 }
 255 #endif
 256
 257 string W_Sound(string w_snd)
 258 {
 259         string output = strcat("weapons/", w_snd);
 260         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 261         return M_ARGV(1, string);
 262 }
 263
 264 string W_Model(string w_mdl)
 265 {
 266         string output = strcat("models/weapons/", w_mdl);
 267         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 268         return M_ARGV(1, string);
 269 }
 270
 271 #ifdef GAMEQC
 272 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 273 {
 274         switch (algn)
 275         {
 276                 default:
 277                 case 3:
 278                         // right alignment
 279                         break;
 280                 case 4:
 281                         // left
 282                         vecs.y = -vecs.y;
 283                         break;
 284                 case 1:
 285                 case 2:
 286                         // center
 287                         vecs.y = 0;
 288                         vecs.z -= 2;
 289                         break;
 290         }
 291         return vecs;
 292 }
 293
 294 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 295 {
 296 #ifdef SVQC
 297         string s;
 298 #endif
 299         if (visual)
 300         {
 301                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 302         }
 303 #ifdef SVQC
 304         else if (autocvar_g_shootfromeye)
 305         {
 306                 vecs.y = vecs.z = 0;
 307         }
 308         else if (autocvar_g_shootfromcenter)
 309         {
 310                 vecs.y = 0;
 311                 vecs.z -= 2;
 312         }
 313         else if ((s = autocvar_g_shootfromfixedorigin) != "")
 314         {
 315                 vector v = stov(s);
 316                 if (y_is_right) v.y = -v.y;
 317                 if (v.x != 0) vecs.x = v.x;
 318                 vecs.y = v.y;
 319                 vecs.z = v.z;
 320         }
 321 #endif
 322         else  // just do the same as top
 323         {
 324                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 325         }
 326
 327         return vecs;
 328 }
 329
 330 #define shotorg_adjust shotorg_adjust_values
 331
 332 /**
 333  * supported formats:
 334  *
 335  * 1. simple animated model, muzzle flash handling on h_ model:
 336  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 337  *      tags:
 338  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 339  *        shell = casings ejection point (must be on the right hand side of the gun)
 340  *        weapon = attachment for v_tuba.md3
 341  *    v_tuba.md3 - first and third person model
 342  *    g_tuba.md3 - pickup model
 343  *
 344  * 2. simple animated model, muzzle flash handling on v_ model:
 345  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 346  *      tags:
 347  *        weapon = attachment for v_tuba.md3
 348  *    v_tuba.md3 - first and third person model
 349  *      tags:
 350  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 351  *        shell = casings ejection point (must be on the right hand side of the gun)
 352  *    g_tuba.md3 - pickup model
 353  *
 354  * 3. fully animated model, muzzle flash handling on h_ model:
 355  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 356  *      tags:
 357  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 358  *        shell = casings ejection point (must be on the right hand side of the gun)
 359  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 360  *    v_tuba.md3 - third person model
 361  *    g_tuba.md3 - pickup model
 362  *
 363  * 4. fully animated model, muzzle flash handling on v_ model:
 364  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 365  *      tags:
 366  *        shot = muzzle end (shot origin)
 367  *        shell = casings ejection point (must be on the right hand side of the gun)
 368  *    v_tuba.md3 - third person model
 369  *      tags:
 370  *        shot = muzzle end (for muzzle flashes)
 371  *    g_tuba.md3 - pickup model
 372  *
 373  * writes:
 374  *   this.origin, this.angles
 375  *   this.weaponchild
 376  *   this.movedir, this.view_ofs
 377  *   attachment stuff
 378  *   anim stuff
 379  * to free:
 380  *   call again with ""
 381  *   remove the ent
 382  */
 383 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 384 {
 385         if (name == "")
 386         {
 387                 vector oldmin = this.mins, oldmax = this.maxs;
 388                 setmodel(this, MDL_Null);
 389                 setsize(this, oldmin, oldmax);
 390                 if (this.weaponchild) delete(this.weaponchild);
 391                 this.weaponchild = NULL;
 392                 this.movedir = '0 0 0';
 393                 this.spawnorigin = '0 0 0';
 394                 this.oldorigin = '0 0 0';
 395                 this.anim_fire1  = '0 1 0.01';
 396                 this.anim_fire2  = '0 1 0.01';
 397                 this.anim_idle   = '0 1 0.01';
 398                 this.anim_reload = '0 1 0.01';
 399         }
 400         else
 401         {
 402                 // if there is a child entity, hide it until we're sure we use it
 403                 if (this.weaponchild) this.weaponchild.model = "";
 404                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 405                 int v_shot_idx;  // used later
 406                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 407
 408                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 409                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 410                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 411                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 412                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 413                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 414
 415                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 416                 // if we don't, this is a "real" animated model
 417                 string t;
 418                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 419                 {
 420                         if (!this.weaponchild)
 421                         {
 422                                 this.weaponchild = new(weaponchild);
 423 #ifdef CSQC
 424                                 this.weaponchild.drawmask = MASK_NORMAL;
 425                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 426 #endif
 427                         }
 428                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 429                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 430                         setattachment(this.weaponchild, this, t);
 431                 }
 432                 else
 433                 {
 434                         if (this.weaponchild) delete(this.weaponchild);
 435                         this.weaponchild = NULL;
 436                 }
 437
 438                 setsize(this, '0 0 0', '0 0 0');
 439                 setorigin(this, '0 0 0');
 440                 this.angles = '0 0 0';
 441                 this.frame = 0;
 442 #ifdef SVQC
 443                 this.viewmodelforclient = NULL;
 444 #else
 445                 this.renderflags &= ~RF_VIEWMODEL;
 446 #endif
 447                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 448                 {
 449                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 450                 }
 451                 else
 452                 {
 453                         int idx;
 454                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 455                         {
 456                                 this.movedir = gettaginfo(this, idx);
 457                         }
 458                         else
 459                         {
 460                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 461                                         this.model);
 462                                 this.movedir = '0 0 0';
 463                         }
 464                 }
 465                 {
 466                         int idx = 0;
 467                         // v_ model attached to invisible h_ model
 468                         if (this.weaponchild
 469                             && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 470                         {
 471                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 472                         }
 473                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 474                         {
 475                                 this.spawnorigin = gettaginfo(this, idx);
 476                         }
 477                         else
 478                         {
 479                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 480                                         this.model);
 481                                 this.spawnorigin = this.movedir;
 482                         }
 483                 }
 484                 if (v_shot_idx)
 485                 {
 486                         this.oldorigin = '0 0 0';  // use regular attachment
 487                 }
 488                 else
 489                 {
 490                         int idx;
 491                         if (this.weaponchild)
 492                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 493                         else
 494                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 495                         if (idx)
 496                         {
 497                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 498                         }
 499                         else
 500                         {
 501                                 LOG_WARNF(
 502                                         "weapon model %s does not support the 'handle' tag "
 503                                         "and neither does the v_ model support the 'shot' tag, "
 504                                         "will display muzzle flashes TOTALLY wrong\n",
 505                                         this.model);
 506                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 507                         }
 508                 }
 509
 510 #ifdef SVQC
 511                 this.viewmodelforclient = this.owner;
 512 #else
 513                 this.renderflags |= RF_VIEWMODEL;
 514 #endif
 515         }
 516
 517         this.view_ofs = '0 0 0';
 518
 519         if (this.movedir.x >= 0)
 520         {
 521                 //int algn = STAT(GUNALIGN, this.owner);
 522                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 523         #ifdef SVQC
 524                 this.m_gunalign = algn;
 525         #endif
 526                 vector v = this.movedir;
 527                 this.movedir = shotorg_adjust(v, false, false, algn);
 528                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 529         }
 530         int compressed_shotorg = compressShotOrigin(this.movedir);
 531         // make them match perfectly
 532 #ifdef SVQC
 533     // null during init
 534     if (this.owner) this.owner.stat_shotorg = compressed_shotorg;
 535         this.movedir = decompressShotOrigin(compressed_shotorg);
 536 #else
 537         this.movedir = decompressShotOrigin(compressed_shotorg);
 538 #endif
 539
 540         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 541
 542         // check if an instant weapon switch occurred
 543         setorigin(this, this.view_ofs);
 544         if (!_anim) return;
 545         // reset animstate now
 546         this.wframe = WFRAME_IDLE;
 547         setanim(this, this.anim_idle, true, false, true);
 548 }
 549 #endif
 550
 551 #ifdef GAMEQC
 552
 553 REGISTER_NET_TEMP(wframe)
 554 #ifdef CSQC
 555 NET_HANDLE(wframe, bool isNew)
 556 {
 557         vector a;
 558         a.x = ReadCoord();
 559     a.y = ReadCoord();
 560     a.z = ReadCoord();
 561     int slot = ReadByte();
 562         bool restartanim = ReadByte();
 563         entity wepent = viewmodels[slot];
 564         if(a.x == wepent.anim_idle_x) // we don't need to enforce idle animation
 565                 wepent.animstate_looping = false;
 566         else
 567                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 568         wepent.state = ReadByte();
 569         wepent.weapon_nextthink = ReadFloat();
 570         switch (wepent.state)
 571         {
 572                 case WS_RAISE:
 573                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 574                         break;
 575                 case WS_DROP:
 576                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 577                         break;
 578         default:
 579             wepent.weapon_switchdelay = 0;
 580             break;
 581         }
 582         return true;
 583 }
 584 #endif
 585
 586 #ifdef SVQC
 587 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim)
 588 {
 589         if (!IS_REAL_CLIENT(actor)) return;
 590         int channel = MSG_ONE;
 591         msg_entity = actor;
 592         WriteHeader(channel, wframe);
 593         WriteCoord(channel, a.x);
 594         WriteCoord(channel, a.y);
 595         WriteCoord(channel, a.z);
 596         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 597         WriteByte(channel, restartanim);
 598         WriteByte(channel, weaponentity.state);
 599         WriteFloat(channel, weaponentity.weapon_nextthink);
 600 }
 601 #endif
 602
 603 REGISTER_NET_C2S(w_whereis)
 604 #ifdef SVQC
 605 void Weapon_whereis(Weapon this, entity cl);
 606 NET_HANDLE(w_whereis, bool)
 607 {
 608         Weapon wpn = ReadRegistered(Weapons);
 609         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 610         return true;
 611 }
 612 #else
 613 void w_whereis(Weapon this)
 614 {
 615         int channel = MSG_C2S;
 616         WriteHeader(channel, w_whereis);
 617         WriteRegistered(Weapons, channel, this);
 618 }
 619 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 620 {
 621         switch (request)
 622         {
 623                 case CMD_REQUEST_COMMAND:
 624                 {
 625                         string s = argv(1);
 626                         if (s == "all")
 627                         {
 628                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 629                                 return;
 630                         }
 631                         if (s == "unowned")
 632                         {
 633                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 634                                 return;
 635                         }
 636                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 637                         {
 638                                 w_whereis(it);
 639                                 return;
 640                         });
 641                 }
 642                 default:
 643                 {
 644                         LOG_INFOF("Incorrect parameters for ^2%s^7", "weapon_find");
 645                 }
 646                 case CMD_REQUEST_USAGE:
 647                 {
 648                         LOG_INFO("Usage:^3 cl_cmd weapon_find weapon");
 649                         LOG_INFO("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.");
 650                         return;
 651                 }
 652         }
 653 }
 654 #endif
 655
 656
 657 #endif
 658
 659 #endif