qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include <client/defs.qh>
   7         #include "../constants.qh"
   8         #include "../stats.qh"
   9         #include <lib/warpzone/anglestransform.qh>
  10         #include <lib/warpzone/common.qh>
  11         #include <lib/warpzone/client.qh>
  12         #include "../util.qh"
  13         #include <client/autocvars.qh>
  14         #include "../deathtypes/all.qh"
  15         #include <lib/csqcmodel/interpolate.qh>
  16         #include "../physics/movetypes/movetypes.qh"
  17         #include <client/main.qh>
  18         #include <lib/csqcmodel/cl_model.qh>
  19 #elif defined(MENUQC)
  20 #elif defined(SVQC)
  21         #include <common/items/_mod.qh>
  22     #include <lib/warpzone/anglestransform.qh>
  23     #include <lib/warpzone/common.qh>
  24     #include <lib/warpzone/util_server.qh>
  25     #include <lib/warpzone/server.qh>
  26     #include "../constants.qh"
  27     #include "../stats.qh"
  28     #include "../teams.qh"
  29     #include <common/util.qh>
  30     #include "../monsters/_mod.qh"
  31     #include "config.qh"
  32     #include <server/weapons/csqcprojectile.qh>
  33     #include <server/weapons/tracing.qh>
  34     #include "../t_items.qh"
  35     #include <server/autocvars.qh>
  36     #include <server/constants.qh>
  37     #include <server/defs.qh>
  38     #include "../notifications/all.qh"
  39     #include "../deathtypes/all.qh"
  40     #include <server/mutators/_mod.qh>
  41     #include "../mapinfo.qh"
  42     #include <server/command/_mod.qh>
  43     #include <lib/csqcmodel/sv_model.qh>
  44     #include <server/portals.qh>
  45     #include <server/g_hook.qh>
  46 #endif
  47 #ifdef GAMEQC
  48         #include "calculations.qc"
  49 #endif
  50 #ifdef SVQC
  51         #include "config.qc"
  52 #endif
  53
  54 #include "weapon/_mod.inc"
  55
  56
  57 // WEAPON PLUGIN SYSTEM
  58
  59 WepSet _WepSet_FromWeapon(int a)
  60 {
  61         a -= WEP_FIRST;
  62         if (Weapons_MAX > 24)
  63                 if (a >= 24)
  64                 {
  65                         a -= 24;
  66                         if (Weapons_MAX > 48)
  67                                 if (a >= 24)
  68                                 {
  69                                         a -= 24;
  70                                         return '0 0 1' * (2 ** a);
  71                                 }
  72                         return '0 1 0' * (2 ** a);
  73                 }
  74         return '1 0 0' * (2 ** a);
  75 }
  76 #ifdef SVQC
  77         void WriteWepSet(float dst, WepSet w)
  78         {
  79                 if (Weapons_MAX > 48) WriteInt72_t(dst, w);
  80                 else if (Weapons_MAX > 24) WriteInt48_t(dst, w);
  81                 else WriteInt24_t(dst, w.x);
  82         }
  83 #endif
  84 #ifdef CSQC
  85         WepSet WepSet_GetFromStat()
  86         {
  87                 return STAT(WEAPONS);
  88         }
  89         WepSet WepSet_GetFromStat_InMap()
  90         {
  91                 return STAT(WEAPONSINMAP);
  92         }
  93         WepSet ReadWepSet()
  94         {
  95                 if (Weapons_MAX > 48) return ReadInt72_t();
  96                 if (Weapons_MAX > 24) return ReadInt48_t();
  97                 return ReadInt24_t() * '1 0 0';
  98         }
  99 #endif
 100
 101 string W_FixWeaponOrder(string order, float complete)
 102 {
 103         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 104 }
 105 string W_NameWeaponOrder_MapFunc(string s)
 106 {
 107         int i = stof(s);
 108         if (s == "0" || i)
 109         {
 110                 entity wi = Weapons_from(i);
 111                 if (wi != WEP_Null) return wi.netname;
 112         }
 113         return s;
 114 }
 115
 116 string W_UndeprecateName(string s)
 117 {
 118         switch (s)
 119         {
 120                 case "nex": return "vortex";
 121                 case "rocketlauncher": return "devastator";
 122                 case "laser": return "blaster";
 123                 case "minstanex": return "vaporizer";
 124                 case "grenadelauncher": return "mortar";
 125                 case "uzi": return "machinegun";
 126                 default: return s;
 127         }
 128 }
 129 string W_NameWeaponOrder(string order)
 130 {
 131         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 132 }
 133 string W_NumberWeaponOrder_MapFunc(string s)
 134 {
 135         if (s == "0" || stof(s)) return s;
 136         s = W_UndeprecateName(s);
 137         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 138         return s;
 139 }
 140 string W_NumberWeaponOrder(string order)
 141 {
 142         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 143 }
 144
 145 float W_FixWeaponOrder_BuildImpulseList_buf[Weapons_MAX];
 146 string W_FixWeaponOrder_BuildImpulseList_order;
 147 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 148 {
 149         float h;
 150         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 151         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 152         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 153 }
 154 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 155 {
 156         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 157         Weapon e1 = Weapons_from(si);
 158         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 159         Weapon e2 = Weapons_from(sj);
 160         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 161         if (d != 0) return -d;  // high impulse first!
 162         return strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 163                 sprintf(" %d ", si), 0)
 164                -
 165                strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 166                 sprintf(" %d ", sj), 0)
 167         ;  // low char index first!
 168 }
 169 string W_FixWeaponOrder_BuildImpulseList(string o)
 170 {
 171         int i;
 172         W_FixWeaponOrder_BuildImpulseList_order = o;
 173         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 174                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 175         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 176                 NULL);
 177         o = "";
 178         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 179                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 180         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 181         return substring(o, 1, -1);
 182 }
 183
 184 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 185 {
 186         return W_FixWeaponOrder(order, 0);
 187 }
 188
 189 string W_FixWeaponOrder_ForceComplete(string order)
 190 {
 191         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 192         return W_FixWeaponOrder(order, 1);
 193 }
 194
 195 void W_RandomWeapons(entity e, int n)
 196 {
 197         WepSet remaining = e.weapons;
 198         WepSet result = '0 0 0';
 199         for (int j = 0; j < n; ++j)
 200         {
 201                 RandomSelection_Init();
 202                 FOREACH(Weapons, it != WEP_Null, {
 203                         if (remaining & (it.m_wepset))
 204                                 RandomSelection_AddEnt(it, 1, 1);
 205                 });
 206                 Weapon w = RandomSelection_chosen_ent;
 207                 result |= WepSet_FromWeapon(w);
 208                 remaining &= ~WepSet_FromWeapon(w);
 209         }
 210         e.weapons = result;
 211 }
 212
 213 string GetAmmoPicture(int ammotype)
 214 {
 215         switch (ammotype)
 216         {
 217                 case RESOURCE_SHELLS:  return ITEM_Shells.m_icon;
 218                 case RESOURCE_BULLETS: return ITEM_Bullets.m_icon;
 219                 case RESOURCE_ROCKETS: return ITEM_Rockets.m_icon;
 220                 case RESOURCE_CELLS:   return ITEM_Cells.m_icon;
 221                 case RESOURCE_PLASMA:  return ITEM_Plasma.m_icon;
 222                 case RESOURCE_FUEL:    return ITEM_JetpackFuel.m_icon;
 223                 default: return "";  // wtf, no ammo type?
 224         }
 225 }
 226
 227 #ifdef CSQC
 228 int GetAmmoTypeFromNum(int i)
 229 {
 230         switch (i)
 231         {
 232                 case 0: return RESOURCE_SHELLS;
 233                 case 1: return RESOURCE_BULLETS;
 234                 case 2: return RESOURCE_ROCKETS;
 235                 case 3: return RESOURCE_CELLS;
 236                 case 4: return RESOURCE_PLASMA;
 237                 case 5: return RESOURCE_FUEL;
 238                 default: return RESOURCE_NONE;
 239         }
 240 }
 241
 242 int GetAmmoStat(int ammotype)
 243 {
 244         switch (ammotype)
 245         {
 246                 case RESOURCE_SHELLS: return STAT_SHELLS;
 247                 case RESOURCE_BULLETS: return STAT_NAILS;
 248                 case RESOURCE_ROCKETS: return STAT_ROCKETS;
 249                 case RESOURCE_CELLS: return STAT_CELLS;
 250                 case RESOURCE_PLASMA: return STAT_PLASMA.m_id;
 251                 case RESOURCE_FUEL: return STAT_FUEL.m_id;
 252                 default: return -1;
 253         }
 254 }
 255 #endif
 256
 257 string W_Sound(string w_snd)
 258 {
 259         string output = strcat("weapons/", w_snd);
 260         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 261         return M_ARGV(1, string);
 262 }
 263
 264 string W_Model(string w_mdl)
 265 {
 266         string output = strcat("models/weapons/", w_mdl);
 267         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 268         return M_ARGV(1, string);
 269 }
 270
 271 #ifdef GAMEQC
 272 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 273 {
 274         switch (algn)
 275         {
 276                 default:
 277                 case 3:
 278                         // right alignment
 279                         break;
 280                 case 4:
 281                         // left
 282                         vecs.y = -vecs.y;
 283                         break;
 284                 case 1:
 285                 case 2:
 286                         // center
 287                         vecs.y = 0;
 288                         vecs.z -= 2;
 289                         break;
 290         }
 291         return vecs;
 292 }
 293
 294 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 295 {
 296         string s;
 297         if (visual)
 298         {
 299                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 300         }
 301         else if (STAT(SHOOTFROMEYE))
 302         {
 303                 vecs.y = vecs.z = 0;
 304         }
 305         else if (STAT(SHOOTFROMCENTER))
 306         {
 307                 vecs.y = 0;
 308                 vecs.z -= 2;
 309         }
 310         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 311         {
 312                 vector v = stov(s);
 313                 if (y_is_right) v.y = -v.y;
 314                 if (v.x != 0) vecs.x = v.x;
 315                 vecs.y = v.y;
 316                 vecs.z = v.z;
 317         }
 318         else  // just do the same as top
 319         {
 320                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 321         }
 322
 323         return vecs;
 324 }
 325
 326 #define shotorg_adjust shotorg_adjust_values
 327
 328 /**
 329  * supported formats:
 330  *
 331  * 1. simple animated model, muzzle flash handling on h_ model:
 332  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 333  *      tags:
 334  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 335  *        shell = casings ejection point (must be on the right hand side of the gun)
 336  *        weapon = attachment for v_tuba.md3
 337  *    v_tuba.md3 - first and third person model
 338  *    g_tuba.md3 - pickup model
 339  *
 340  * 2. simple animated model, muzzle flash handling on v_ model:
 341  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 342  *      tags:
 343  *        weapon = attachment for v_tuba.md3
 344  *    v_tuba.md3 - first and third person model
 345  *      tags:
 346  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 347  *        shell = casings ejection point (must be on the right hand side of the gun)
 348  *    g_tuba.md3 - pickup model
 349  *
 350  * 3. fully animated model, muzzle flash handling on h_ model:
 351  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 352  *      tags:
 353  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 354  *        shell = casings ejection point (must be on the right hand side of the gun)
 355  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 356  *    v_tuba.md3 - third person model
 357  *    g_tuba.md3 - pickup model
 358  *
 359  * 4. fully animated model, muzzle flash handling on v_ model:
 360  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 361  *      tags:
 362  *        shot = muzzle end (shot origin)
 363  *        shell = casings ejection point (must be on the right hand side of the gun)
 364  *    v_tuba.md3 - third person model
 365  *      tags:
 366  *        shot = muzzle end (for muzzle flashes)
 367  *    g_tuba.md3 - pickup model
 368  *
 369  * writes:
 370  *   this.origin, this.angles
 371  *   this.weaponchild
 372  *   this.movedir, this.view_ofs
 373  *   attachment stuff
 374  *   anim stuff
 375  * to free:
 376  *   call again with ""
 377  *   remove the ent
 378  */
 379 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 380 {
 381         if (name == "")
 382         {
 383                 vector oldmin = this.mins, oldmax = this.maxs;
 384                 setmodel(this, MDL_Null);
 385                 setsize(this, oldmin, oldmax);
 386                 if (this.weaponchild) delete(this.weaponchild);
 387                 this.weaponchild = NULL;
 388                 this.movedir = '0 0 0';
 389                 this.spawnorigin = '0 0 0';
 390                 this.oldorigin = '0 0 0';
 391                 this.anim_fire1  = '0 1 0.01';
 392                 this.anim_fire2  = '0 1 0.01';
 393                 this.anim_idle   = '0 1 0.01';
 394                 this.anim_reload = '0 1 0.01';
 395         }
 396         else
 397         {
 398                 // if there is a child entity, hide it until we're sure we use it
 399                 if (this.weaponchild) this.weaponchild.model = "";
 400                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 401                 int v_shot_idx;  // used later
 402                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 403
 404                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 405                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 406                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 407                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 408                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 409                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 410
 411                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 412                 // if we don't, this is a "real" animated model
 413                 string t;
 414                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 415                 {
 416                         if (!this.weaponchild)
 417                         {
 418                                 this.weaponchild = new(weaponchild);
 419 #ifdef CSQC
 420                                 this.weaponchild.drawmask = MASK_NORMAL;
 421                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 422 #endif
 423                         }
 424                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 425                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 426                         setattachment(this.weaponchild, this, t);
 427                 }
 428                 else
 429                 {
 430                         if (this.weaponchild) delete(this.weaponchild);
 431                         this.weaponchild = NULL;
 432                 }
 433
 434                 setsize(this, '0 0 0', '0 0 0');
 435                 setorigin(this, '0 0 0');
 436                 this.angles = '0 0 0';
 437                 this.frame = 0;
 438 #ifdef SVQC
 439                 this.viewmodelforclient = NULL;
 440 #else
 441                 this.renderflags &= ~RF_VIEWMODEL;
 442 #endif
 443                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 444                 {
 445                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 446                 }
 447                 else
 448                 {
 449                         int idx;
 450                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 451                         {
 452                                 this.movedir = gettaginfo(this, idx);
 453                         }
 454                         else
 455                         {
 456                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 457                                         this.model);
 458                                 this.movedir = '0 0 0';
 459                         }
 460                 }
 461                 {
 462                         int idx = 0;
 463                         // v_ model attached to invisible h_ model
 464                         if (this.weaponchild
 465                             && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 466                         {
 467                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 468                         }
 469                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 470                         {
 471                                 this.spawnorigin = gettaginfo(this, idx);
 472                         }
 473                         else
 474                         {
 475                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 476                                         this.model);
 477                                 this.spawnorigin = this.movedir;
 478                         }
 479                 }
 480                 if (v_shot_idx)
 481                 {
 482                         this.oldorigin = '0 0 0';  // use regular attachment
 483                 }
 484                 else
 485                 {
 486                         int idx;
 487                         if (this.weaponchild)
 488                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 489                         else
 490                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 491                         if (idx)
 492                         {
 493                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 494                         }
 495                         else
 496                         {
 497                                 LOG_WARNF(
 498                                         "weapon model %s does not support the 'handle' tag "
 499                                         "and neither does the v_ model support the 'shot' tag, "
 500                                         "will display muzzle flashes TOTALLY wrong\n",
 501                                         this.model);
 502                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 503                         }
 504                 }
 505
 506 #ifdef SVQC
 507                 this.viewmodelforclient = this.owner;
 508 #else
 509                 this.renderflags |= RF_VIEWMODEL;
 510 #endif
 511         }
 512
 513         this.view_ofs = '0 0 0';
 514
 515         if (this.movedir.x >= 0)
 516         {
 517                 //int algn = STAT(GUNALIGN, this.owner);
 518                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 519         #ifdef SVQC
 520                 this.m_gunalign = algn;
 521         #endif
 522                 vector v = this.movedir;
 523                 this.movedir = shotorg_adjust(v, false, false, algn);
 524                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 525         }
 526         int compressed_shotorg = compressShotOrigin(this.movedir);
 527         // make them match perfectly
 528 #ifdef SVQC
 529     // null during init
 530     if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 531         this.movedir = decompressShotOrigin(compressed_shotorg);
 532 #else
 533         this.movedir = decompressShotOrigin(compressed_shotorg);
 534 #endif
 535
 536         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 537
 538         // check if an instant weapon switch occurred
 539         setorigin(this, this.view_ofs);
 540         if (!_anim) return;
 541         // reset animstate now
 542         this.wframe = WFRAME_IDLE;
 543         setanim(this, this.anim_idle, true, false, true);
 544 }
 545 #endif
 546
 547 #ifdef GAMEQC
 548
 549 REGISTER_NET_TEMP(wframe)
 550 #ifdef CSQC
 551 NET_HANDLE(wframe, bool isNew)
 552 {
 553         vector a = ReadVector();
 554     int slot = ReadByte();
 555         bool restartanim = ReadByte();
 556         entity wepent = viewmodels[slot];
 557         if(a.x == wepent.anim_idle_x) // we don't need to enforce idle animation
 558                 wepent.animstate_looping = false;
 559         else
 560                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 561         wepent.state = ReadByte();
 562         wepent.weapon_nextthink = ReadFloat();
 563         switch (wepent.state)
 564         {
 565                 case WS_RAISE:
 566                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 567                         break;
 568                 case WS_DROP:
 569                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 570                         break;
 571         default:
 572             wepent.weapon_switchdelay = 0;
 573             break;
 574         }
 575         return true;
 576 }
 577 #endif
 578
 579 #ifdef SVQC
 580 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim)
 581 {
 582         if (!IS_REAL_CLIENT(actor)) return;
 583         int channel = MSG_ONE;
 584         msg_entity = actor;
 585         WriteHeader(channel, wframe);
 586         WriteVector(channel, a);
 587         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 588         WriteByte(channel, restartanim);
 589         WriteByte(channel, weaponentity.state);
 590         WriteFloat(channel, weaponentity.weapon_nextthink);
 591 }
 592 #endif
 593
 594 REGISTER_NET_C2S(w_whereis)
 595 #ifdef SVQC
 596 void Weapon_whereis(Weapon this, entity cl);
 597 NET_HANDLE(w_whereis, bool)
 598 {
 599         Weapon wpn = ReadRegistered(Weapons);
 600         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 601         return true;
 602 }
 603 #else
 604 void w_whereis(Weapon this)
 605 {
 606         int channel = MSG_C2S;
 607         WriteHeader(channel, w_whereis);
 608         WriteRegistered(Weapons, channel, this);
 609 }
 610 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 611 {
 612         switch (request)
 613         {
 614                 case CMD_REQUEST_COMMAND:
 615                 {
 616                         string s = argv(1);
 617                         if (s == "all")
 618                         {
 619                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 620                                 return;
 621                         }
 622                         if (s == "unowned")
 623                         {
 624                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 625                                 return;
 626                         }
 627                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 628                         {
 629                                 w_whereis(it);
 630                                 return;
 631                         });
 632                 }
 633                 default:
 634                 {
 635                         LOG_INFOF("Incorrect parameters for ^2%s^7", "weapon_find");
 636                 }
 637                 case CMD_REQUEST_USAGE:
 638                 {
 639                         LOG_INFO("Usage:^3 cl_cmd weapon_find weapon");
 640                         LOG_INFO("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.");
 641                         return;
 642                 }
 643         }
 644 }
 645 #endif
 646
 647
 648 #endif
 649
 650 #endif