qcsrc/common/weapons/weapon/arc.qc

   1 #include "arc.qh"
   2
   3 #ifdef SVQC
   4 #include <common/gamemodes/gamemode/onslaught/sv_onslaught.qh>
   5 #include <common/gamemodes/gamemode/onslaught/sv_generator.qh>
   6
   7 bool W_Arc_Beam_Send(entity this, entity to, int sf)
   8 {
   9         WriteHeader(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
  10
  11         // Truncate information when this beam is displayed to the owner client
  12         // - The owner client has no use for beam start position or directions,
  13         //    it always figures this information out for itself with csqc code.
  14         // - Spectating the owner also truncates this information.
  15         float drawlocal = ((to == this.owner) || ((to.enemy == this.owner) && IS_SPEC(to)));
  16         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
  17
  18         WriteByte(MSG_ENTITY, sf);
  19         WriteByte(MSG_ENTITY, weaponslot(this.weaponentity_fld));
  20
  21         if(sf & ARC_SF_SETTINGS) // settings information
  22         {
  23                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
  24                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
  25                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
  26                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
  27                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
  28                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
  29
  30                 WriteByte(MSG_ENTITY, drawlocal);
  31                 WriteByte(MSG_ENTITY, etof(this.owner));
  32         }
  33         if(sf & ARC_SF_START) // starting location
  34         {
  35                 WriteVector(MSG_ENTITY, this.beam_start);
  36         }
  37         if(sf & ARC_SF_WANTDIR) // want/aim direction
  38         {
  39                 WriteVector(MSG_ENTITY, this.beam_wantdir);
  40         }
  41         if(sf & ARC_SF_BEAMDIR) // beam direction
  42         {
  43                 WriteAngleVector(MSG_ENTITY, this.beam_dir);
  44         }
  45         if(sf & ARC_SF_BEAMTYPE) // beam type
  46         {
  47                 WriteByte(MSG_ENTITY, this.beam_type);
  48         }
  49
  50         return true;
  51 }
  52
  53 void Reset_ArcBeam(entity player, vector forward)
  54 {
  55         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  56         {
  57                 .entity weaponentity = weaponentities[slot];
  58                 if(!player.(weaponentity).arc_beam)
  59                         continue;
  60                 player.(weaponentity).arc_beam.beam_dir = forward;
  61                 player.(weaponentity).arc_beam.beam_teleporttime = time;
  62         }
  63 }
  64
  65 float Arc_GetHeat_Percent(entity player, .entity weaponentity)
  66 {
  67         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
  68         {
  69                 player.arc_overheat = 0;
  70                 return 0;
  71         }
  72
  73         if ( player.(weaponentity).arc_beam )
  74                 return player.(weaponentity).arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
  75
  76         if ( player.arc_overheat > time )
  77         {
  78                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
  79                         * player.arc_cooldown;
  80         }
  81
  82         return 0;
  83 }
  84 void Arc_Player_SetHeat(entity player, .entity weaponentity)
  85 {
  86         player.(weaponentity).arc_heat_percent = Arc_GetHeat_Percent(player, weaponentity);
  87         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
  88 }
  89
  90 void W_Arc_Bolt_Explode(entity this, entity directhitentity)
  91 {
  92         this.event_damage = func_null;
  93         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, this.weaponentity_fld, directhitentity);
  94
  95         delete(this);
  96 }
  97
  98 void W_Arc_Bolt_Explode_use(entity this, entity actor, entity trigger)
  99 {
 100         W_Arc_Bolt_Explode(this, trigger);
 101 }
 102
 103 void W_Arc_Bolt_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 104 {
 105         if(GetResource(this, RES_HEALTH) <= 0)
 106                 return;
 107
 108         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1))
 109                 return; // g_projectiles_damage says to halt
 110
 111         TakeResource(this, RES_HEALTH, damage);
 112         this.angles = vectoangles(this.velocity);
 113
 114         if(GetResource(this, RES_HEALTH) <= 0)
 115                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
 116 }
 117
 118 void W_Arc_Bolt_Touch(entity this, entity toucher)
 119 {
 120         PROJECTILE_TOUCH(this, toucher);
 121         this.use(this, NULL, toucher);
 122 }
 123
 124 void W_Arc_Attack_Bolt(Weapon thiswep, entity actor, .entity weaponentity)
 125 {
 126         entity missile;
 127
 128         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(arc, bolt_ammo), weaponentity);
 129
 130         W_SetupShot(actor, weaponentity, false, 2, SND_LASERGUN_FIRE, CH_WEAPON_A, WEP_CVAR(arc, bolt_damage), WEP_ARC.m_id | HITTYPE_SECONDARY);
 131
 132         W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, w_shotdir);
 133
 134         missile = new(missile);
 135         missile.owner = missile.realowner = actor;
 136         missile.bot_dodge = true;
 137         IL_PUSH(g_bot_dodge, missile);
 138         missile.bot_dodgerating = WEP_CVAR(arc, bolt_damage);
 139
 140         missile.takedamage = DAMAGE_YES;
 141         SetResourceExplicit(missile, RES_HEALTH, WEP_CVAR(arc, bolt_health));
 142         missile.damageforcescale = WEP_CVAR(arc, bolt_damageforcescale);
 143         missile.event_damage = W_Arc_Bolt_Damage;
 144         missile.damagedbycontents = true;
 145         IL_PUSH(g_damagedbycontents, missile);
 146
 147         settouch(missile, W_Arc_Bolt_Touch);
 148         missile.use = W_Arc_Bolt_Explode_use;
 149         setthink(missile, adaptor_think2use_hittype_splash);
 150         missile.nextthink = time + WEP_CVAR(arc, bolt_lifetime);
 151         PROJECTILE_MAKETRIGGER(missile);
 152         missile.projectiledeathtype = WEP_ARC.m_id | HITTYPE_SECONDARY;
 153         missile.weaponentity_fld = weaponentity;
 154         setorigin(missile, w_shotorg);
 155         setsize(missile, '0 0 0', '0 0 0');
 156
 157         set_movetype(missile, MOVETYPE_FLY);
 158         W_SetupProjVelocity_PRE(missile, arc, bolt_);
 159
 160         missile.angles = vectoangles(missile.velocity);
 161         missile.flags = FL_PROJECTILE;
 162         missile.missile_flags = MIF_SPLASH;
 163
 164         CSQCProjectile(missile, true, PROJECTILE_ARC_BOLT, true);
 165
 166         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 167 }
 168
 169 void W_Arc_Beam_Think(entity this)
 170 {
 171         .entity weaponentity = this.weaponentity_fld;
 172         entity own = this.owner;
 173         if(this != own.(weaponentity).arc_beam)
 174         {
 175                 delete(this);
 176                 return;
 177         }
 178
 179         float burst = 0;
 180         if( (PHYS_INPUT_BUTTON_ATCK2(own) && !WEP_CVAR(arc, bolt)) || this.beam_bursting)
 181         {
 182                 if(!this.beam_bursting)
 183                         this.beam_bursting = true;
 184                 burst = ARC_BT_BURSTMASK;
 185         }
 186
 187         Weapon thiswep = WEP_ARC;
 188
 189         if(
 190                 !IS_PLAYER(own)
 191                 ||
 192                 IS_DEAD(own)
 193                 ||
 194                 !weapon_prepareattack_check(thiswep, own, weaponentity, this.beam_bursting, -1)
 195                 ||
 196                 own.(weaponentity).m_switchweapon != WEP_ARC
 197                 ||
 198                 (!PHYS_INPUT_BUTTON_ATCK(own) && !burst )
 199                 ||
 200                 own.vehicle
 201                 ||
 202                 (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max))
 203         )
 204         {
 205                 if ( WEP_CVAR(arc, cooldown) > 0 )
 206                 {
 207                         float cooldown_speed = 0;
 208                         if ( this.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 209                         {
 210                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 211                         }
 212                         else if ( !burst )
 213                         {
 214                                 cooldown_speed = this.beam_heat / WEP_CVAR(arc, beam_refire);
 215                         }
 216
 217                         if ( cooldown_speed )
 218                         {
 219                                 if ( WEP_CVAR(arc, cooldown_release) || (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max)) )
 220                                         own.arc_overheat = time + this.beam_heat / cooldown_speed;
 221                                 own.arc_cooldown = cooldown_speed;
 222                         }
 223
 224                         if ( WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max) )
 225                         {
 226                                 Send_Effect(EFFECT_ARC_OVERHEAT,
 227                                         this.beam_start, this.beam_wantdir, 1 );
 228                                 sound(this, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 229                         }
 230                 }
 231
 232                 if(this == own.(weaponentity).arc_beam) { own.(weaponentity).arc_beam = NULL; }
 233                 if(!thiswep.wr_checkammo1(thiswep, own, weaponentity) && !(own.items & IT_UNLIMITED_AMMO))
 234                 {
 235                         // note: this doesn't force the switch
 236                         W_SwitchToOtherWeapon(own, weaponentity);
 237                 }
 238                 own.(weaponentity).arc_BUTTON_ATCK_prev = false; // allow switching weapons
 239                 delete(this);
 240                 return;
 241         }
 242
 243         // decrease ammo
 244         float coefficient = frametime;
 245         if(!(own.items & IT_UNLIMITED_AMMO))
 246         {
 247                 float rootammo;
 248                 if(burst)
 249                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 250                 else
 251                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 252
 253                 if(rootammo)
 254                 {
 255                         coefficient = min(coefficient, GetResource(own, thiswep.ammo_type) / rootammo);
 256                         SetResource(own, thiswep.ammo_type, max(0, GetResource(own, thiswep.ammo_type) - (rootammo * frametime)));
 257                 }
 258         }
 259         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 260         this.beam_heat = min( WEP_CVAR(arc, overheat_max), this.beam_heat + heat_speed*frametime );
 261
 262         makevectors(own.v_angle);
 263
 264         W_SetupShot_Range(
 265                 own,
 266                 weaponentity,
 267                 true,
 268                 0,
 269                 SND_Null,
 270                 0,
 271                 WEP_CVAR(arc, beam_damage) * coefficient,
 272                 WEP_CVAR(arc, beam_range),
 273                 thiswep.m_id
 274         );
 275
 276         // After teleport, "lock" the beam until the teleport is confirmed.
 277         if (time < this.beam_teleporttime + ANTILAG_LATENCY(own)) {
 278                 w_shotdir = this.beam_dir;
 279         }
 280
 281         // network information: shot origin and want/aim direction
 282         if(this.beam_start != w_shotorg)
 283         {
 284                 this.SendFlags |= ARC_SF_START;
 285                 this.beam_start = w_shotorg;
 286         }
 287         if(this.beam_wantdir != w_shotdir)
 288         {
 289                 this.SendFlags |= ARC_SF_WANTDIR;
 290                 this.beam_wantdir = w_shotdir;
 291         }
 292
 293         if(!this.beam_initialized)
 294         {
 295                 this.beam_dir = w_shotdir;
 296                 this.beam_initialized = true;
 297         }
 298
 299         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 300         // idea: blend together this.beam_dir with the inverted direction the player is moving in
 301         // might have to make some special accomodation so that it only uses view_right and view_up
 302
 303         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 304
 305         float segments;
 306         if(this.beam_dir != w_shotdir)
 307         {
 308                 // calculate how much we're going to move the end of the beam to the want position
 309                 // WEAPONTODO (server and client):
 310                 // blendfactor never actually becomes 0 in this situation, which is a problem
 311                 // regarding precision... this means that this.beam_dir and w_shotdir approach
 312                 // eachother, however they never actually become the same value with this method.
 313                 // Perhaps we should do some form of rounding/snapping?
 314                 float angle = vlen(w_shotdir - this.beam_dir) * RAD2DEG;
 315                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 316                 {
 317                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 318                         float blendfactor = bound(
 319                                 0,
 320                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 321                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 322                         );
 323                         if(vdist(this.beam_dir - w_shotdir, <, 0.01))
 324                                 this.beam_dir = w_shotdir;
 325                         else
 326                                 this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 327                 }
 328                 else
 329                 {
 330                         // the radius is not too far yet, no worries :D
 331                         float blendfactor = bound(
 332                                 0,
 333                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 334                                 1
 335                         );
 336                         if(vdist(this.beam_dir - w_shotdir, <, 0.01))
 337                                 this.beam_dir = w_shotdir;
 338                         else
 339                                 this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 340                 }
 341
 342                 // network information: beam direction
 343                 this.SendFlags |= ARC_SF_BEAMDIR;
 344
 345                 // calculate how many segments are needed
 346                 float max_allowed_segments;
 347
 348                 if(WEP_CVAR(arc, beam_distancepersegment))
 349                 {
 350                         max_allowed_segments = min(
 351                                 ARC_MAX_SEGMENTS,
 352                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 353                         );
 354                 }
 355                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 356
 357                 if(WEP_CVAR(arc, beam_degreespersegment))
 358                 {
 359                         segments = bound(
 360                                 1,
 361                                 (
 362                                         min(
 363                                                 angle,
 364                                                 WEP_CVAR(arc, beam_maxangle)
 365                                         )
 366                                         /
 367                                         WEP_CVAR(arc, beam_degreespersegment)
 368                                 ),
 369                                 max_allowed_segments
 370                         );
 371                 }
 372                 else { segments = 1; }
 373         }
 374         else { segments = 1; }
 375
 376         vector beam_endpos = (w_shotorg + (this.beam_dir * WEP_CVAR(arc, beam_range)));
 377         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 378
 379         float i;
 380         float new_beam_type = 0;
 381         vector last_origin = w_shotorg;
 382         for(i = 1; i <= segments; ++i)
 383         {
 384                 // WEAPONTODO (client):
 385                 // In order to do nice fading and pointing on the starting segment, we must always
 386                 // have that drawn as a separate triangle... However, that is difficult to do when
 387                 // keeping in mind the above problems and also optimizing the amount of segments
 388                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 389
 390                 vector new_origin = bezier_quadratic_getpoint(
 391                         w_shotorg,
 392                         beam_controlpoint,
 393                         beam_endpos,
 394                         i / segments);
 395                 vector new_dir = normalize(new_origin - last_origin);
 396
 397                 WarpZone_traceline_antilag(
 398                         own,
 399                         last_origin,
 400                         new_origin,
 401                         MOVE_NORMAL,
 402                         own,
 403                         ANTILAG_LATENCY(own)
 404                 );
 405
 406                 // Do all the transforms for warpzones right now, as we already
 407                 // "are" in the post-trace system (if we hit a player, that's
 408                 // always BEHIND the last passed wz).
 409                 last_origin = trace_endpos;
 410                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 411                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 412                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 413                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 414
 415                 bool is_player = (
 416                         IS_PLAYER(trace_ent)
 417                         ||
 418                         trace_ent.classname == "body"
 419                         ||
 420                         IS_MONSTER(trace_ent)
 421                 );
 422
 423                 if(trace_ent)
 424                 {
 425                         if(SAME_TEAM(own, trace_ent))
 426                         {
 427                                 float roothealth = ((burst) ? WEP_CVAR(arc, burst_healing_hps) : WEP_CVAR(arc, beam_healing_hps));
 428                                 float rootarmor = ((burst) ? WEP_CVAR(arc, burst_healing_aps) : WEP_CVAR(arc, beam_healing_aps));
 429                                 float hplimit = ((IS_PLAYER(trace_ent)) ? WEP_CVAR(arc, beam_healing_hmax) : RES_LIMIT_NONE);
 430                                 Heal(trace_ent, own, (roothealth * coefficient), hplimit);
 431                                 if(IS_PLAYER(trace_ent) && rootarmor)
 432                                 {
 433                                         if(GetResource(trace_ent, RES_ARMOR) <= WEP_CVAR(arc, beam_healing_amax))
 434                                         {
 435                                                 GiveResourceWithLimit(trace_ent, RES_ARMOR, (rootarmor * coefficient), WEP_CVAR(arc, beam_healing_amax));
 436                                                 trace_ent.pauserotarmor_finished = max(
 437                                                         trace_ent.pauserotarmor_finished,
 438                                                         time + autocvar_g_balance_pause_armor_rot
 439                                                 );
 440                                         }
 441                                 }
 442                                 if(roothealth || rootarmor)
 443                                         new_beam_type = ARC_BT_HEAL;
 444                         }
 445                         else if(trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 446                         {
 447                                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 448                                 // NO. trace_endpos should be just fine. If not,
 449                                 // that's an engine bug that needs proper debugging.
 450                                 vector hitorigin = trace_endpos;
 451
 452                                 float falloff = ExponentialFalloff(
 453                                         WEP_CVAR(arc, beam_falloff_mindist),
 454                                         WEP_CVAR(arc, beam_falloff_maxdist),
 455                                         WEP_CVAR(arc, beam_falloff_halflifedist),
 456                                         vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 457                                 );
 458
 459                                 float rootdamage;
 460                                 if(is_player)
 461                                 {
 462                                         if(burst)
 463                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 464                                         else
 465                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 466                                 }
 467                                 else
 468                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 469
 470                                 if(accuracy_isgooddamage(own, trace_ent))
 471                                 {
 472                                         accuracy_add(
 473                                                 own,
 474                                                 WEP_ARC,
 475                                                 0,
 476                                                 rootdamage * coefficient * falloff
 477                                         );
 478                                 }
 479
 480                                 Damage(
 481                                         trace_ent,
 482                                         own,
 483                                         own,
 484                                         rootdamage * coefficient * falloff,
 485                                         WEP_ARC.m_id,
 486                                         weaponentity,
 487                                         hitorigin,
 488                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 489                                 );
 490
 491                                 new_beam_type = ARC_BT_HIT;
 492                         }
 493                         break;
 494                 }
 495                 else if(trace_fraction != 1)
 496                 {
 497                         // we collided with geometry
 498                         new_beam_type = ARC_BT_WALL;
 499                         break;
 500                 }
 501         }
 502
 503         // te_explosion(trace_endpos);
 504
 505         // if we're bursting, use burst visual effects
 506         new_beam_type |= burst;
 507
 508         // network information: beam type
 509         if(new_beam_type != this.beam_type)
 510         {
 511                 this.SendFlags |= ARC_SF_BEAMTYPE;
 512                 this.beam_type = new_beam_type;
 513         }
 514
 515         own.(weaponentity).beam_prev = time;
 516         this.nextthink = time;
 517 }
 518
 519 void W_Arc_Beam(float burst, entity actor, .entity weaponentity)
 520 {
 521
 522         // only play fire sound if 1 sec has passed since player let go the fire button
 523         if(time - actor.(weaponentity).beam_prev > 1)
 524                 sound(actor, CH_WEAPON_A, SND_ARC_FIRE, VOL_BASE, ATTN_NORM);
 525
 526         entity beam = actor.(weaponentity).arc_beam = new(W_Arc_Beam);
 527         beam.weaponentity_fld = weaponentity;
 528         beam.solid = SOLID_NOT;
 529         setthink(beam, W_Arc_Beam_Think);
 530         beam.owner = actor;
 531         set_movetype(beam, MOVETYPE_NONE);
 532         beam.bot_dodge = true;
 533         IL_PUSH(g_bot_dodge, beam);
 534         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 535         beam.beam_bursting = burst;
 536         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 537
 538         getthink(beam)(beam);
 539 }
 540 void W_Arc_Attack(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 541 {
 542         if(!actor.(weaponentity).arc_beam || wasfreed(actor.(weaponentity).arc_beam))
 543         {
 544                 w_ready(thiswep, actor, weaponentity, fire);
 545                 return;
 546         }
 547
 548         // attack handled by the beam itself, this is just a loop to keep the attack happening!
 549
 550         // NOTE: arc doesn't use a refire
 551         //ATTACK_FINISHED(actor, weaponentity) = time + WEP_CVAR_PRI(arc, refire) * W_WeaponRateFactor(actor);
 552         actor.(weaponentity).wframe = WFRAME_FIRE1;
 553         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), W_Arc_Attack);
 554 }
 555 void Arc_Smoke(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 556 {
 557         // TODO: spamming this without checking any refires is asking for trouble!
 558         makevectors(actor.v_angle);
 559         W_SetupShot_Range(actor,weaponentity,false,0,SND_Null,0,0,0,thiswep.m_id); // TODO: probably doesn't need deathtype, since this is just a prefire effect
 560
 561         vector smoke_origin = w_shotorg + actor.velocity*frametime;
 562         if ( actor.arc_overheat > time )
 563         {
 564                 if ( random() < actor.(weaponentity).arc_heat_percent )
 565                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 566                 if ( (fire & 1) || (fire & 2) )
 567                 {
 568                         Send_Effect(EFFECT_ARC_OVERHEAT_FIRE, smoke_origin, w_shotdir, 1 );
 569                         if ( !actor.arc_smoke_sound )
 570                         {
 571                                 actor.arc_smoke_sound = 1;
 572                                 sound(actor, CH_SHOTS_SINGLE, SND_ARC_LOOP_OVERHEAT, VOL_BASE, ATTN_NORM);
 573                         }
 574                 }
 575         }
 576         else if ( actor.(weaponentity).arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 577                         actor.(weaponentity).arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 578         {
 579                 if ( random() < (actor.(weaponentity).arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 580                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 581                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 582         }
 583
 584         bool attacking = PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor);
 585         bool stop_smoke_sound = actor.arc_overheat <= time || !attacking;
 586         if ((actor.arc_smoke_sound && stop_smoke_sound) || actor.(weaponentity).m_switchweapon != thiswep)
 587         {
 588                 actor.arc_smoke_sound = 0;
 589                 sound(actor, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 590         }
 591 }
 592
 593 METHOD(Arc, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 594 {
 595     if(WEP_CVAR(arc, beam_botaimspeed))
 596     {
 597         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 598                 actor,
 599                 weaponentity,
 600             WEP_CVAR(arc, beam_botaimspeed),
 601             0,
 602             WEP_CVAR(arc, beam_botaimlifetime),
 603             false
 604         );
 605     }
 606     else
 607     {
 608         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 609                 actor,
 610                 weaponentity,
 611             1000000,
 612             0,
 613             0.001,
 614             false
 615         );
 616     }
 617 }
 618 METHOD(Arc, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 619 {
 620     Arc_Player_SetHeat(actor, weaponentity);
 621     Arc_Smoke(thiswep, actor, weaponentity, fire);
 622
 623     bool beam_fire2 = ((fire & 2) && !WEP_CVAR(arc, bolt));
 624
 625     if (time >= actor.arc_overheat)
 626     if ((fire & 1) || beam_fire2 || actor.(weaponentity).arc_beam.beam_bursting)
 627     {
 628         #if 0
 629         if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 630         {
 631             #if 0
 632             if(actor.animstate_startframe == actor.anim_shoot.x && actor.animstate_numframes == actor.anim_shoot.y)
 633                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 634             else
 635             #endif
 636                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), w_ready);
 637         }
 638         #endif
 639
 640         if((!actor.(weaponentity).arc_beam) || wasfreed(actor.(weaponentity).arc_beam))
 641         {
 642             if(weapon_prepareattack(thiswep, actor, weaponentity, boolean(beam_fire2), 0))
 643             {
 644                 W_Arc_Beam(boolean(beam_fire2), actor, weaponentity);
 645
 646                 if(!actor.(weaponentity).arc_BUTTON_ATCK_prev)
 647                 {
 648                         actor.(weaponentity).wframe = WFRAME_FIRE1;
 649                     weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), W_Arc_Attack);
 650                     actor.(weaponentity).arc_BUTTON_ATCK_prev = true;
 651                 }
 652             }
 653         }
 654
 655         return;
 656     }
 657     else if(fire & 2)
 658     {
 659         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR(arc, bolt_refire)))
 660         {
 661             W_Arc_Attack_Bolt(thiswep, actor, weaponentity);
 662             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), w_ready);
 663         }
 664     }
 665
 666     if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 667     {
 668         sound(actor, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 669         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 670         ATTACK_FINISHED(actor, weaponentity) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor(actor);
 671     }
 672     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 673
 674     #if 0
 675     if(fire & 2)
 676     if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_arc_secondary_refire))
 677     {
 678         W_Arc_Attack2();
 679         actor.arc_count = autocvar_g_balance_arc_secondary_count;
 680         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 681         actor.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor(actor);
 682     }
 683     #endif
 684 }
 685 METHOD(Arc, wr_init, void(entity thiswep))
 686 {
 687     if(!arc_shotorigin[0])
 688     {
 689         arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 690         arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 691         arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 692         arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 693     }
 694 }
 695 METHOD(Arc, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 696 {
 697     return ((!WEP_CVAR(arc, beam_ammo)) || (GetResource(actor, thiswep.ammo_type) > 0));
 698 }
 699 METHOD(Arc, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 700 {
 701     if(WEP_CVAR(arc, bolt))
 702     {
 703         float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR(arc, bolt_ammo);
 704         ammo_amount += actor.(weaponentity).(weapon_load[WEP_ARC.m_id]) >= WEP_CVAR(arc, bolt_ammo);
 705         return ammo_amount;
 706     }
 707     else
 708         return WEP_CVAR(arc, overheat_max) > 0 &&
 709             ((!WEP_CVAR(arc, burst_ammo)) || (GetResource(actor, thiswep.ammo_type) > 0));
 710 }
 711 METHOD(Arc, wr_killmessage, Notification(entity thiswep))
 712 {
 713     if(w_deathtype & HITTYPE_SECONDARY)
 714         return WEAPON_ARC_MURDER_SPRAY;
 715     else
 716         return WEAPON_ARC_MURDER;
 717 }
 718 METHOD(Arc, wr_drop, void(entity thiswep, entity actor, .entity weaponentity))
 719 {
 720     weapon_dropevent_item.arc_overheat = actor.arc_overheat;
 721     weapon_dropevent_item.arc_cooldown = actor.arc_cooldown;
 722     actor.arc_overheat = 0;
 723     actor.arc_cooldown = 0;
 724     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 725 }
 726 METHOD(Arc, wr_pickup, void(entity thiswep, entity actor, .entity weaponentity))
 727 {
 728     if ( !client_hasweapon(actor, thiswep, weaponentity, false, false) &&
 729         weapon_dropevent_item.arc_overheat > time )
 730     {
 731         actor.arc_overheat = weapon_dropevent_item.arc_overheat;
 732         actor.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 733     }
 734 }
 735 METHOD(Arc, wr_resetplayer, void(entity thiswep, entity actor))
 736 {
 737     actor.arc_overheat = 0;
 738     actor.arc_cooldown = 0;
 739     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 740     {
 741         .entity weaponentity = weaponentities[slot];
 742         actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 743     }
 744 }
 745 METHOD(Arc, wr_playerdeath, void(entity thiswep, entity actor, .entity weaponentity))
 746 {
 747     actor.arc_overheat = 0;
 748     actor.arc_cooldown = 0;
 749     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 750 }
 751 #endif
 752 #ifdef CSQC
 753 bool autocvar_cl_arcbeam_teamcolor = true;
 754 bool autocvar_cl_arcbeam_simple = true;
 755
 756 .int beam_slot;
 757
 758 METHOD(Arc, wr_impacteffect, void(entity thiswep, entity actor))
 759 {
 760     if(w_deathtype & HITTYPE_SECONDARY)
 761     {
 762         vector org2;
 763         org2 = w_org + w_backoff * 6;
 764         pointparticles(EFFECT_ARC_BOLT_EXPLODE, org2, w_backoff * 1000, 1);
 765         if(!w_issilent) { sound(actor, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 766     }
 767 }
 768
 769 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 770 {
 771         entity beam = Draw_ArcBeam_callback_entity;
 772         vector transformed_view_org;
 773         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 774
 775         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 776         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 777         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 778
 779         vector hitorigin;
 780
 781         // draw segment
 782         #if 0
 783         if(trace_fraction != 1)
 784         {
 785                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 786                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 787                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 788         }
 789         else
 790         {
 791                 hitorigin = hit;
 792         }
 793         #else
 794         hitorigin = hit;
 795         #endif
 796
 797         // decide upon thickness
 798         float thickness = beam.beam_thickness;
 799
 800         // draw primary beam render
 801         vector top    = hitorigin + (thickdir * thickness);
 802         vector bottom = hitorigin - (thickdir * thickness);
 803
 804         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 805         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 806
 807         if(autocvar_cl_arcbeam_simple)
 808                 Draw_CylindricLine(start, end, thickness, beam.beam_image, 0.25, -time * 3, beam.beam_color, beam.beam_alpha, DRAWFLAG_NORMAL, transformed_view_org);
 809         else
 810         {
 811                 R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL, false); // DRAWFLAG_ADDITIVE
 812                 R_PolygonVertex(
 813                         top,
 814                         '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 815                         beam.beam_color,
 816                         beam.beam_alpha
 817                 );
 818                 R_PolygonVertex(
 819                         last_top,
 820                         '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 821                         beam.beam_color,
 822                         beam.beam_alpha
 823                 );
 824                 R_PolygonVertex(
 825                         last_bottom,
 826                         '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 827                         beam.beam_color,
 828                         beam.beam_alpha
 829                 );
 830                 R_PolygonVertex(
 831                         bottom,
 832                         '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 833                         beam.beam_color,
 834                         beam.beam_alpha
 835                 );
 836                 R_EndPolygon();
 837         }
 838
 839         // draw trailing particles
 840         // NOTES:
 841         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 842         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 843         if(beam.beam_traileffect)
 844         {
 845                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 846         }
 847
 848         // set up for the next
 849         Draw_ArcBeam_callback_last_thickness = thickness;
 850         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 851         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 852 }
 853
 854 void Reset_ArcBeam()
 855 {
 856         entity e;
 857         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 858                 e.beam_initialized = false;
 859         }
 860         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 861                 e.beam_initialized = false;
 862         }
 863 }
 864
 865 void Draw_ArcBeam(entity this)
 866 {
 867         float dt = time - this.move_time;
 868         this.move_time = time;
 869         if(dt <= 0) { return; }
 870
 871         if(!this.beam_usevieworigin)
 872         {
 873                 InterpolateOrigin_Do(this);
 874         }
 875
 876         // origin = beam starting origin
 877         // v_angle = wanted/aim direction
 878         // angles = current direction of beam
 879
 880         vector start_pos;
 881         vector wantdir; //= view_forward;
 882         vector beamdir; //= this.beam_dir;
 883
 884         float segments;
 885         if(this.beam_usevieworigin)
 886         {
 887                 // WEAPONTODO:
 888                 // Currently we have to replicate nearly the same method of figuring
 889                 // out the shotdir that the server does... Ideally in the future we
 890                 // should be able to acquire this from a generalized function built
 891                 // into a weapon system for client code.
 892
 893                 // find where we are aiming
 894                 vector myviewangle = ((autocvar_chase_active) ? warpzone_save_view_angles : view_angles);
 895                 vector forward, right, up;
 896                 MAKE_VECTORS(myviewangle, forward, right, up);
 897                 entity wepent = viewmodels[this.beam_slot];
 898
 899                 this.beam_usevieworigin = (autocvar_chase_active) ? 1 : 2;
 900
 901                 // decide upon start position
 902                 if(this.beam_usevieworigin == 2)
 903                         { start_pos = warpzone_save_view_origin; }
 904                 else if(csqcplayer)
 905                         { start_pos = csqcplayer.origin + csqcplayer.view_ofs; }
 906                 else
 907                         { start_pos = this.origin; }
 908
 909                 // trace forward with an estimation
 910                 WarpZone_TraceLine(
 911                         start_pos,
 912                         start_pos + forward * this.beam_range,
 913                         MOVE_NOMONSTERS,
 914                         this
 915                 );
 916
 917                 int v_shot_idx;  // used later
 918                 (v_shot_idx = gettagindex(wepent, "shot")) || (v_shot_idx = gettagindex(wepent, "tag_shot"));
 919                 if(v_shot_idx && this.beam_usevieworigin == 2)
 920                         start_pos = gettaginfo(wepent, v_shot_idx) - '0 0 2';
 921
 922                 // untransform in case our trace went through a warpzone
 923                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 924
 925                 // un-adjust trueaim if shotend is too close
 926                 if(vdist(end_pos - start_pos, <, g_trueaim_minrange))
 927                         end_pos = start_pos + (forward * g_trueaim_minrange);
 928
 929                 // move shot origin to the actual gun muzzle origin
 930                 vector origin_offset = '0 0 0';
 931                 if(!v_shot_idx || this.beam_usevieworigin != 2)
 932                 {
 933                         this.beam_shotorigin = wepent.movedir;
 934                         origin_offset =
 935                                  right * -this.beam_shotorigin.y
 936                                 + up * this.beam_shotorigin.z;
 937                 }
 938                 else
 939                         this.beam_shotorigin = '0 0 0';
 940
 941                 start_pos = start_pos + origin_offset;
 942
 943                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 944                 traceline(start_pos, start_pos + forward * this.beam_shotorigin.x, MOVE_NORMAL, this);
 945                 start_pos = trace_endpos;
 946
 947                 // calculate the aim direction now
 948                 wantdir = normalize(end_pos - start_pos);
 949
 950                 if(!this.beam_initialized)
 951                 {
 952                         this.beam_dir = wantdir;
 953                         this.beam_initialized = true;
 954
 955                         this.beam_muzzleentity.drawmask = MASK_NORMAL; // NOTE: this works around the muzzle entity flashing on the middle of the screen for a frame
 956                 }
 957
 958                 if(this.beam_dir != wantdir)
 959                 {
 960                         // calculate how much we're going to move the end of the beam to the want position
 961                         // WEAPONTODO (server and client):
 962                         // blendfactor never actually becomes 0 in this situation, which is a problem
 963                         // regarding precision... this means that this.beam_dir and w_shotdir approach
 964                         // eachother, however they never actually become the same value with this method.
 965                         // Perhaps we should do some form of rounding/snapping?
 966                         float angle = vlen(wantdir - this.beam_dir) * RAD2DEG;
 967                         if(angle && (angle > this.beam_maxangle))
 968                         {
 969                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 970                                 float blendfactor = bound(
 971                                         0,
 972                                         (1 - (this.beam_returnspeed * dt)),
 973                                         min(this.beam_maxangle / angle, 1)
 974                                 );
 975                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 976                         }
 977                         else
 978                         {
 979                                 // the radius is not too far yet, no worries :D
 980                                 float blendfactor = bound(
 981                                         0,
 982                                         (1 - (this.beam_returnspeed * dt)),
 983                                         1
 984                                 );
 985                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 986                         }
 987
 988                         // calculate how many segments are needed
 989                         float max_allowed_segments;
 990
 991                         if(this.beam_distancepersegment)
 992                         {
 993                                 max_allowed_segments = min(
 994                                         ARC_MAX_SEGMENTS,
 995                                         1 + (vlen(wantdir / this.beam_distancepersegment))
 996                                 );
 997                         }
 998                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 999
1000                         if(this.beam_degreespersegment)
1001                         {
1002                                 segments = bound(
1003                                         1,
1004                                         (
1005                                                 min(
1006                                                         angle,
1007                                                         this.beam_maxangle
1008                                                 )
1009                                                 /
1010                                                 this.beam_degreespersegment
1011                                         ),
1012                                         max_allowed_segments
1013                                 );
1014                         }
1015                         else { segments = 1; }
1016                 }
1017                 else { segments = 1; }
1018
1019                 // set the beam direction which the rest of the code will refer to
1020                 beamdir = this.beam_dir;
1021
1022                 // finally, set this.angles to the proper direction so that muzzle attachment points in proper direction
1023                 this.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1024         }
1025         else
1026         {
1027                 // set the values from the provided info from the networked entity
1028                 start_pos = this.origin;
1029                 wantdir = this.v_angle;
1030                 beamdir = this.angles;
1031
1032                 if(beamdir != wantdir)
1033                 {
1034                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1035
1036                         // calculate how many segments are needed
1037                         float max_allowed_segments;
1038
1039                         if(this.beam_distancepersegment)
1040                         {
1041                                 max_allowed_segments = min(
1042                                         ARC_MAX_SEGMENTS,
1043                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1044                                 );
1045                         }
1046                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1047
1048                         if(this.beam_degreespersegment)
1049                         {
1050                                 segments = bound(
1051                                         1,
1052                                         (
1053                                                 min(
1054                                                         angle,
1055                                                         this.beam_maxangle
1056                                                 )
1057                                                 /
1058                                                 this.beam_degreespersegment
1059                                         ),
1060                                         max_allowed_segments
1061                                 );
1062                         }
1063                         else { segments = 1; }
1064                 }
1065                 else { segments = 1; }
1066         }
1067
1068         setorigin(this, start_pos);
1069         this.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1070
1071         vector beam_endpos = (start_pos + (beamdir * this.beam_range));
1072         vector beam_controlpoint = start_pos + wantdir * (this.beam_range * (1 - this.beam_tightness));
1073
1074         Draw_ArcBeam_callback_entity = this;
1075         Draw_ArcBeam_callback_last_thickness = 0;
1076         Draw_ArcBeam_callback_last_top = start_pos;
1077         Draw_ArcBeam_callback_last_bottom = start_pos;
1078
1079         vector last_origin = start_pos;
1080         vector original_start_pos = start_pos;
1081
1082         float i;
1083         for(i = 1; i <= segments; ++i)
1084         {
1085                 // WEAPONTODO (client):
1086                 // In order to do nice fading and pointing on the starting segment, we must always
1087                 // have that drawn as a separate triangle... However, that is difficult to do when
1088                 // keeping in mind the above problems and also optimizing the amount of segments
1089                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1090
1091                 vector new_origin = bezier_quadratic_getpoint(
1092                         start_pos,
1093                         beam_controlpoint,
1094                         beam_endpos,
1095                         i / segments);
1096
1097                 WarpZone_TraceBox_ThroughZone(
1098                         last_origin,
1099                         '0 0 0',
1100                         '0 0 0',
1101                         new_origin,
1102                         MOVE_NORMAL,
1103                         NULL,
1104                         NULL,
1105                         Draw_ArcBeam_callback
1106                 );
1107
1108                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1109                 // system (if we hit a player, that's always BEHIND the last passed wz).
1110                 last_origin = trace_endpos;
1111                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1112                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1113                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1114                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1115                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1116                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1117
1118                 if(trace_fraction < 1) { break; }
1119         }
1120
1121         // visual effects for startpoint and endpoint
1122         if(this.beam_hiteffect)
1123         {
1124                 // FIXME we really should do this on the server so it actually
1125                 // matches gameplay. What this client side stuff is doing is no
1126                 // more than guesswork.
1127                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1128                 pointparticles(
1129                         this.beam_hiteffect,
1130                         last_origin,
1131                         beamdir * -1,
1132                         dt * 2
1133                 );
1134         }
1135         if(this.beam_hitlight[0])
1136         {
1137                 adddynamiclight(
1138                         last_origin,
1139                         this.beam_hitlight[0],
1140                         vec3(
1141                                 this.beam_hitlight[1],
1142                                 this.beam_hitlight[2],
1143                                 this.beam_hitlight[3]
1144                         )
1145                 );
1146         }
1147         if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1148         {
1149                 pointparticles(
1150                         this.beam_muzzleeffect,
1151                         original_start_pos + wantdir * 20,
1152                         wantdir * 1000,
1153                         dt * 0.1
1154                 );
1155         }
1156         if(this.beam_muzzlelight[0])
1157         {
1158                 adddynamiclight(
1159                         original_start_pos + wantdir * 20,
1160                         this.beam_muzzlelight[0],
1161                         vec3(
1162                                 this.beam_muzzlelight[1],
1163                                 this.beam_muzzlelight[2],
1164                                 this.beam_muzzlelight[3]
1165                         )
1166                 );
1167         }
1168
1169         // cleanup
1170         Draw_ArcBeam_callback_entity = NULL;
1171         Draw_ArcBeam_callback_last_thickness = 0;
1172         Draw_ArcBeam_callback_last_top = '0 0 0';
1173         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1174 }
1175
1176 void Remove_ArcBeam(entity this)
1177 {
1178         delete(this.beam_muzzleentity);
1179         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
1180 }
1181
1182 NET_HANDLE(ENT_CLIENT_ARC_BEAM, bool isnew)
1183 {
1184         int sf = ReadByte();
1185         int slot = ReadByte();
1186         entity flash;
1187
1188         this.beam_slot = slot;
1189
1190         if(isnew)
1191         {
1192                 int gunalign = W_GunAlign(viewmodels[slot], STAT(GUNALIGN)) - 1;
1193
1194                 this.beam_shotorigin = arc_shotorigin[gunalign]; // get a starting point
1195
1196                 // set other main attributes of the beam
1197                 this.draw = Draw_ArcBeam;
1198                 IL_PUSH(g_drawables, this);
1199                 this.entremove = Remove_ArcBeam;
1200                 this.move_time = time;
1201                 loopsound(this, CH_SHOTS_SINGLE, SND_ARC_LOOP, VOL_BASE, ATTEN_NORM);
1202
1203                 flash = spawn();
1204                 flash.owner = this;
1205                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1206                 //flash.drawmask = MASK_NORMAL;
1207                 flash.solid = SOLID_NOT;
1208                 flash.avelocity_z = 5000;
1209                 setattachment(flash, this, "");
1210                 setorigin(flash, '0 0 0');
1211
1212                 this.beam_muzzleentity = flash;
1213         }
1214         else
1215         {
1216                 flash = this.beam_muzzleentity;
1217         }
1218
1219         if(sf & ARC_SF_SETTINGS) // settings information
1220         {
1221                 this.beam_degreespersegment = ReadShort();
1222                 this.beam_distancepersegment = ReadShort();
1223                 this.beam_maxangle = ReadShort();
1224                 this.beam_range = ReadCoord();
1225                 this.beam_returnspeed = ReadShort();
1226                 this.beam_tightness = (ReadByte() / 10);
1227
1228                 if(ReadByte())
1229                 {
1230                         this.beam_usevieworigin = (autocvar_chase_active) ? 1 : 2;
1231                 }
1232                 else
1233                 {
1234                         this.beam_usevieworigin = 0;
1235                 }
1236
1237                 this.sv_entnum = ReadByte();
1238         }
1239
1240         if(!this.beam_usevieworigin)
1241         {
1242                 // this.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1243                 this.iflags = IFLAG_ORIGIN;
1244
1245                 InterpolateOrigin_Undo(this);
1246         }
1247
1248         if(sf & ARC_SF_START) // starting location
1249         {
1250                 this.origin = ReadVector();
1251         }
1252         else if(this.beam_usevieworigin) // infer the location from player location
1253         {
1254                 if(this.beam_usevieworigin == 2)
1255                 {
1256                         // use view origin
1257                         this.origin = view_origin;
1258                 }
1259                 else
1260                 {
1261                         // use player origin so that third person display still works
1262                         this.origin = entcs_receiver(player_localnum).origin + ('0 0 1' * STAT(VIEWHEIGHT));
1263                 }
1264         }
1265
1266         setorigin(this, this.origin);
1267
1268         if(sf & ARC_SF_WANTDIR) // want/aim direction
1269         {
1270                 this.v_angle = ReadVector();
1271         }
1272
1273         if(sf & ARC_SF_BEAMDIR) // beam direction
1274         {
1275                 this.angles = ReadAngleVector();
1276         }
1277
1278         if(sf & ARC_SF_BEAMTYPE) // beam type
1279         {
1280                 this.beam_type = ReadByte();
1281
1282                 vector beamcolor = ((autocvar_cl_arcbeam_teamcolor) ? colormapPaletteColor(entcs_GetClientColors(this.sv_entnum - 1) & 0x0F, true) : '1 1 1');
1283                 switch(this.beam_type)
1284                 {
1285                         case ARC_BT_MISS:
1286                         {
1287                                 this.beam_color = beamcolor;
1288                                 this.beam_alpha = 0.5;
1289                                 this.beam_thickness = 8;
1290                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1291                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1292                                 this.beam_hitlight[0] = 0;
1293                                 this.beam_hitlight[1] = 1;
1294                                 this.beam_hitlight[2] = 1;
1295                                 this.beam_hitlight[3] = 1;
1296                                 this.beam_muzzleeffect = EFFECT_Null;
1297                                 this.beam_muzzlelight[0] = 0;
1298                                 this.beam_muzzlelight[1] = 1;
1299                                 this.beam_muzzlelight[2] = 1;
1300                                 this.beam_muzzlelight[3] = 1;
1301                                 this.beam_image = "particles/lgbeam";
1302                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1303                                 {
1304                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1305                                         flash.alpha = this.beam_alpha;
1306                                         flash.colormod = this.beam_color;
1307                                         flash.scale = 0.35;
1308                                 }
1309                                 break;
1310                         }
1311                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1312                         {
1313                                 this.beam_color = beamcolor;
1314                                 this.beam_alpha = 0.5;
1315                                 this.beam_thickness = 8;
1316                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1317                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1318                                 this.beam_hitlight[0] = 0;
1319                                 this.beam_hitlight[1] = 1;
1320                                 this.beam_hitlight[2] = 1;
1321                                 this.beam_hitlight[3] = 1;
1322                                 this.beam_muzzleeffect = EFFECT_Null; // (EFFECT_GRENADE_MUZZLEFLASH);
1323                                 this.beam_muzzlelight[0] = 0;
1324                                 this.beam_muzzlelight[1] = 1;
1325                                 this.beam_muzzlelight[2] = 1;
1326                                 this.beam_muzzlelight[3] = 1;
1327                                 this.beam_image = "particles/lgbeam";
1328                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1329                                 {
1330                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1331                                         flash.alpha = this.beam_alpha;
1332                                         flash.colormod = this.beam_color;
1333                                         flash.scale = 0.35;
1334                                 }
1335                                 break;
1336                         }
1337                         case ARC_BT_HEAL:
1338                         {
1339                                 this.beam_color = beamcolor;
1340                                 this.beam_alpha = 0.5;
1341                                 this.beam_thickness = 8;
1342                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1343                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT);
1344                                 this.beam_hitlight[0] = 0;
1345                                 this.beam_hitlight[1] = 1;
1346                                 this.beam_hitlight[2] = 1;
1347                                 this.beam_hitlight[3] = 1;
1348                                 this.beam_muzzleeffect = EFFECT_Null;
1349                                 this.beam_muzzlelight[0] = 0;
1350                                 this.beam_muzzlelight[1] = 1;
1351                                 this.beam_muzzlelight[2] = 1;
1352                                 this.beam_muzzlelight[3] = 1;
1353                                 this.beam_image = "particles/lgbeam";
1354                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1355                                 {
1356                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1357                                         flash.alpha = this.beam_alpha;
1358                                         flash.colormod = this.beam_color;
1359                                         flash.scale = 0.35;
1360                                 }
1361                                 break;
1362                         }
1363                         case ARC_BT_HIT:
1364                         {
1365                                 this.beam_color = beamcolor;
1366                                 this.beam_alpha = 0.5;
1367                                 this.beam_thickness = 8;
1368                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1369                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1370                                 this.beam_hitlight[0] = 20;
1371                                 this.beam_hitlight[1] = 1;
1372                                 this.beam_hitlight[2] = 0;
1373                                 this.beam_hitlight[3] = 0;
1374                                 this.beam_muzzleeffect = EFFECT_Null;
1375                                 this.beam_muzzlelight[0] = 50;
1376                                 this.beam_muzzlelight[1] = 1;
1377                                 this.beam_muzzlelight[2] = 0;
1378                                 this.beam_muzzlelight[3] = 0;
1379                                 this.beam_image = "particles/lgbeam";
1380                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1381                                 {
1382                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1383                                         flash.alpha = this.beam_alpha;
1384                                         flash.colormod = this.beam_color;
1385                                         flash.scale = 0.35;
1386                                 }
1387                                 break;
1388                         }
1389                         case ARC_BT_BURST_MISS:
1390                         {
1391                                 this.beam_color = beamcolor;
1392                                 this.beam_alpha = 0.5;
1393                                 this.beam_thickness = 14;
1394                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1395                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1396                                 this.beam_hitlight[0] = 0;
1397                                 this.beam_hitlight[1] = 1;
1398                                 this.beam_hitlight[2] = 1;
1399                                 this.beam_hitlight[3] = 1;
1400                                 this.beam_muzzleeffect = EFFECT_Null;
1401                                 this.beam_muzzlelight[0] = 0;
1402                                 this.beam_muzzlelight[1] = 1;
1403                                 this.beam_muzzlelight[2] = 1;
1404                                 this.beam_muzzlelight[3] = 1;
1405                                 this.beam_image = "particles/lgbeam";
1406                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1407                                 {
1408                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1409                                         flash.alpha = this.beam_alpha;
1410                                         flash.colormod = this.beam_color;
1411                                         flash.scale = 0.35;
1412                                 }
1413                                 break;
1414                         }
1415                         case ARC_BT_BURST_WALL:
1416                         {
1417                                 this.beam_color = beamcolor;
1418                                 this.beam_alpha = 0.5;
1419                                 this.beam_thickness = 14;
1420                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1421                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1422                                 this.beam_hitlight[0] = 0;
1423                                 this.beam_hitlight[1] = 1;
1424                                 this.beam_hitlight[2] = 1;
1425                                 this.beam_hitlight[3] = 1;
1426                                 this.beam_muzzleeffect = EFFECT_Null;
1427                                 this.beam_muzzlelight[0] = 0;
1428                                 this.beam_muzzlelight[1] = 1;
1429                                 this.beam_muzzlelight[2] = 1;
1430                                 this.beam_muzzlelight[3] = 1;
1431                                 this.beam_image = "particles/lgbeam";
1432                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1433                                 {
1434                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1435                                         flash.alpha = this.beam_alpha;
1436                                         flash.colormod = this.beam_color;
1437                                         flash.scale = 0.35;
1438                                 }
1439                                 break;
1440                         }
1441                         case ARC_BT_BURST_HEAL:
1442                         {
1443                                 this.beam_color = beamcolor;
1444                                 this.beam_alpha = 0.5;
1445                                 this.beam_thickness = 14;
1446                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1447                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT2);
1448                                 this.beam_hitlight[0] = 0;
1449                                 this.beam_hitlight[1] = 1;
1450                                 this.beam_hitlight[2] = 1;
1451                                 this.beam_hitlight[3] = 1;
1452                                 this.beam_muzzleeffect = EFFECT_Null;
1453                                 this.beam_muzzlelight[0] = 0;
1454                                 this.beam_muzzlelight[1] = 1;
1455                                 this.beam_muzzlelight[2] = 1;
1456                                 this.beam_muzzlelight[3] = 1;
1457                                 this.beam_image = "particles/lgbeam";
1458                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1459                                 {
1460                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1461                                         flash.alpha = this.beam_alpha;
1462                                         flash.colormod = this.beam_color;
1463                                         flash.scale = 0.35;
1464                                 }
1465                                 break;
1466                         }
1467                         case ARC_BT_BURST_HIT:
1468                         {
1469                                 this.beam_color = beamcolor;
1470                                 this.beam_alpha = 0.5;
1471                                 this.beam_thickness = 14;
1472                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1473                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1474                                 this.beam_hitlight[0] = 0;
1475                                 this.beam_hitlight[1] = 1;
1476                                 this.beam_hitlight[2] = 1;
1477                                 this.beam_hitlight[3] = 1;
1478                                 this.beam_muzzleeffect = EFFECT_Null;
1479                                 this.beam_muzzlelight[0] = 0;
1480                                 this.beam_muzzlelight[1] = 1;
1481                                 this.beam_muzzlelight[2] = 1;
1482                                 this.beam_muzzlelight[3] = 1;
1483                                 this.beam_image = "particles/lgbeam";
1484                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1485                                 {
1486                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1487                                         flash.alpha = this.beam_alpha;
1488                                         flash.colormod = this.beam_color;
1489                                         flash.scale = 0.35;
1490                                 }
1491                                 break;
1492                         }
1493
1494                         // shouldn't be possible, but lets make it colorful if it does :D
1495                         default:
1496                         {
1497                                 this.beam_color = randomvec();
1498                                 this.beam_alpha = 1;
1499                                 this.beam_thickness = 8;
1500                                 this.beam_traileffect = NULL;
1501                                 this.beam_hiteffect = NULL;
1502                                 this.beam_hitlight[0] = 0;
1503                                 this.beam_hitlight[1] = 1;
1504                                 this.beam_hitlight[2] = 1;
1505                                 this.beam_hitlight[3] = 1;
1506                                 this.beam_muzzleeffect = EFFECT_Null;
1507                                 this.beam_muzzlelight[0] = 0;
1508                                 this.beam_muzzlelight[1] = 1;
1509                                 this.beam_muzzlelight[2] = 1;
1510                                 this.beam_muzzlelight[3] = 1;
1511                                 this.beam_image = "particles/lgbeam";
1512                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1513                                 {
1514                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1515                                         flash.alpha = this.beam_alpha;
1516                                         flash.colormod = this.beam_color;
1517                                         flash.scale = 0.35;
1518                                 }
1519                                 break;
1520                         }
1521                 }
1522         }
1523
1524         if(!this.beam_usevieworigin)
1525         {
1526                 InterpolateOrigin_Note(this);
1527         }
1528         return true;
1529 }
1530
1531 #endif