qcsrc/common/weapons/weapon/devastator.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Devastator, Weapon)
   3 /* ammotype  */ ATTRIB(Devastator, ammo_field, .int, ammo_rockets)
   4 /* impulse   */ ATTRIB(Devastator, impulse, int, 9)
   5 /* flags     */ ATTRIB(Devastator, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(Devastator, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Devastator, wpcolor, vector, '1 1 0');
   8 /* modelname */ ATTRIB(Devastator, mdl, string, "rl");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Devastator, m_model, Model, MDL_DEVASTATOR_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Devastator, w_crosshair, string, "gfx/crosshairrocketlauncher");
  13 /* crosshair */ ATTRIB(Devastator, w_crosshair_size, float, 0.7);
  14 /* wepimg    */ ATTRIB(Devastator, model2, string, "weaponrocketlauncher");
  15 /* refname   */ ATTRIB(Devastator, netname, string, "devastator");
  16 /* wepname   */ ATTRIB(Devastator, m_name, string, _("Devastator"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20                 P(class, prefix, ammo, float, NONE) \
  21         P(class, prefix, animtime, float, NONE) \
  22         P(class, prefix, damageforcescale, float, NONE) \
  23         P(class, prefix, damage, float, NONE) \
  24         P(class, prefix, detonatedelay, float, NONE) \
  25         P(class, prefix, edgedamage, float, NONE) \
  26         P(class, prefix, force, float, NONE) \
  27         P(class, prefix, guidedelay, float, NONE) \
  28         P(class, prefix, guidegoal, float, NONE) \
  29         P(class, prefix, guideratedelay, float, NONE) \
  30         P(class, prefix, guiderate, float, NONE) \
  31         P(class, prefix, guidestop, float, NONE) \
  32         P(class, prefix, health, float, NONE) \
  33         P(class, prefix, lifetime, float, NONE) \
  34         P(class, prefix, radius, float, NONE) \
  35         P(class, prefix, refire, float, NONE) \
  36                 P(class, prefix, reload_ammo, float, NONE) \
  37                 P(class, prefix, reload_time, float, NONE) \
  38         P(class, prefix, remote_damage, float, NONE) \
  39         P(class, prefix, remote_edgedamage, float, NONE) \
  40         P(class, prefix, remote_force, float, NONE) \
  41         P(class, prefix, remote_jump_damage, float, NONE) \
  42         P(class, prefix, remote_jump_radius, float, NONE) \
  43         P(class, prefix, remote_jump_velocity_z_add, float, NONE) \
  44         P(class, prefix, remote_jump_velocity_z_max, float, NONE) \
  45         P(class, prefix, remote_jump_velocity_z_min, float, NONE) \
  46         P(class, prefix, remote_radius, float, NONE) \
  47         P(class, prefix, speedaccel, float, NONE) \
  48         P(class, prefix, speedstart, float, NONE) \
  49         P(class, prefix, speed, float, NONE) \
  50                 P(class, prefix, switchdelay_drop, float, NONE) \
  51                 P(class, prefix, switchdelay_raise, float, NONE) \
  52                 P(class, prefix, weaponreplace, string,NONE) \
  53                 P(class, prefix, weaponstartoverride, float, NONE) \
  54                 P(class, prefix, weaponstart, float, NONE) \
  55                 P(class, prefix, weaponthrowable, float, NONE) \
  56         END()
  57         W_PROPS(X, Devastator, devastator)
  58 #undef X
  59
  60 ENDCLASS(Devastator)
  61 REGISTER_WEAPON(DEVASTATOR, devastator, NEW(Devastator));
  62
  63 #ifdef SVQC
  64 .float rl_release;
  65 .float rl_detonate_later;
  66 #endif
  67 #endif
  68 #ifdef IMPLEMENTATION
  69 #ifdef SVQC
  70 spawnfunc(weapon_devastator) { weapon_defaultspawnfunc(this, WEP_DEVASTATOR); }
  71 spawnfunc(weapon_rocketlauncher) { spawnfunc_weapon_devastator(this); }
  72
  73 .entity lastrocket;
  74
  75 void W_Devastator_Unregister(entity this)
  76 {
  77         if(this.realowner && this.realowner.lastrocket == this)
  78         {
  79                 this.realowner.lastrocket = NULL;
  80                 // this.realowner.rl_release = 1;
  81         }
  82 }
  83
  84 void W_Devastator_Explode(entity this)
  85 {
  86         W_Devastator_Unregister(this);
  87
  88         if(other.takedamage == DAMAGE_AIM)
  89                 if(IS_PLAYER(other))
  90                         if(DIFF_TEAM(this.realowner, other))
  91                                 if(!IS_DEAD(other))
  92                                         if(IsFlying(other))
  93                                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  94
  95         this.event_damage = func_null;
  96         this.takedamage = DAMAGE_NO;
  97
  98         RadiusDamage(
  99                 this,
 100                 this.realowner,
 101                 WEP_CVAR(devastator, damage),
 102                 WEP_CVAR(devastator, edgedamage),
 103                 WEP_CVAR(devastator, radius),
 104                 NULL,
 105                 NULL,
 106                 WEP_CVAR(devastator, force),
 107                 this.projectiledeathtype,
 108                 other
 109         );
 110
 111         Weapon thiswep = WEP_DEVASTATOR;
 112         if(PS(this.realowner).m_weapon == thiswep)
 113         {
 114                 if(this.realowner.(thiswep.ammo_field) < WEP_CVAR(devastator, ammo))
 115                 if(!(this.realowner.items & IT_UNLIMITED_WEAPON_AMMO))
 116                 {
 117                         this.realowner.cnt = WEP_DEVASTATOR.m_id;
 118                         int slot = 0; // TODO: unhardcode
 119                         ATTACK_FINISHED(this.realowner, slot) = time;
 120                         PS(this.realowner).m_switchweapon = w_getbestweapon(this.realowner);
 121                 }
 122         }
 123         remove(this);
 124 }
 125
 126 void W_Devastator_DoRemoteExplode(entity this, .entity weaponentity)
 127 {
 128         W_Devastator_Unregister(this);
 129
 130         this.event_damage = func_null;
 131         this.takedamage = DAMAGE_NO;
 132
 133         float handled_as_rocketjump = false;
 134
 135         entity head = WarpZone_FindRadius(
 136                 this.origin,
 137                 WEP_CVAR(devastator, remote_jump_radius),
 138                 false
 139         );
 140
 141         while(head)
 142         {
 143                 if(head.takedamage && (head == this.realowner))
 144                 {
 145                         float distance_to_head = vlen(this.origin - head.WarpZone_findradius_nearest);
 146                         if(distance_to_head <= WEP_CVAR(devastator, remote_jump_radius))
 147                         {
 148                                 // we handled this as a rocketjump :)
 149                                 handled_as_rocketjump = true;
 150
 151                                 // modify velocity
 152                                 head.velocity_x *= 0.9;
 153                                 head.velocity_y *= 0.9;
 154                                 head.velocity_z = bound(
 155                                         WEP_CVAR(devastator, remote_jump_velocity_z_min),
 156                                         head.velocity.z + WEP_CVAR(devastator, remote_jump_velocity_z_add),
 157                                         WEP_CVAR(devastator, remote_jump_velocity_z_max)
 158                                 );
 159
 160                                 // now do the damage
 161                                 RadiusDamage(
 162                                         this,
 163                                         head,
 164                                         WEP_CVAR(devastator, remote_jump_damage),
 165                                         WEP_CVAR(devastator, remote_jump_damage),
 166                                         WEP_CVAR(devastator, remote_jump_radius),
 167                                         NULL,
 168                                         head,
 169                                         0,
 170                                         this.projectiledeathtype | HITTYPE_BOUNCE,
 171                                         NULL
 172                                 );
 173                                 break;
 174                         }
 175                 }
 176                 head = head.chain;
 177         }
 178
 179         RadiusDamage(
 180                 this,
 181                 this.realowner,
 182                 WEP_CVAR(devastator, remote_damage),
 183                 WEP_CVAR(devastator, remote_edgedamage),
 184                 WEP_CVAR(devastator, remote_radius),
 185                 (handled_as_rocketjump ? head : NULL),
 186                 NULL,
 187                 WEP_CVAR(devastator, remote_force),
 188                 this.projectiledeathtype | HITTYPE_BOUNCE,
 189                 NULL
 190         );
 191
 192         Weapon thiswep = WEP_DEVASTATOR;
 193         if(PS(this.realowner).m_weapon == thiswep)
 194         {
 195                 if(this.realowner.(thiswep.ammo_field) < WEP_CVAR(devastator, ammo))
 196                 if(!(this.realowner.items & IT_UNLIMITED_WEAPON_AMMO))
 197                 {
 198                         this.realowner.cnt = WEP_DEVASTATOR.m_id;
 199                         int slot = weaponslot(weaponentity);
 200                         ATTACK_FINISHED(this.realowner, slot) = time;
 201                         PS(this.realowner).m_switchweapon = w_getbestweapon(this.realowner);
 202                 }
 203         }
 204         remove(this);
 205 }
 206
 207 void W_Devastator_RemoteExplode(entity this, .entity weaponentity)
 208 {
 209         if(!IS_DEAD(this.realowner))
 210         if(this.realowner.lastrocket)
 211         {
 212                 if((this.spawnshieldtime >= 0)
 213                         ? (time >= this.spawnshieldtime) // timer
 214                         : (vdist(NearestPointOnBox(this.realowner, this.origin) - this.origin, >, WEP_CVAR(devastator, remote_radius))) // safety device
 215                 )
 216                 {
 217                         W_Devastator_DoRemoteExplode(this, weaponentity);
 218                 }
 219         }
 220 }
 221
 222 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 223 {
 224         if(thisdir * goaldir > maxturn_cos)
 225                 return goaldir;
 226         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 227                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 228         float f, m2;
 229         vector v;
 230         // solve:
 231         //   g = normalize(thisdir + goaldir * X)
 232         //   thisdir * g = maxturn
 233         //
 234         //   gg = thisdir + goaldir * X
 235         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 236         //
 237         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 238         f = thisdir * goaldir;
 239         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 240         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 241         m2 = maxturn_cos * maxturn_cos;
 242         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 243         return normalize(thisdir + goaldir * v.y); // the larger solution!
 244 }
 245 // assume thisdir == -goaldir:
 246 //   f == -1
 247 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 248 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 249 //   x^2 - 2 * x + 1 = 0
 250 //   (x - 1)^2 = 0
 251 //   x = 1
 252 //   normalize(thisdir + goaldir)
 253 //   normalize(0)
 254
 255 void W_Devastator_Think(entity this)
 256 {
 257         vector desireddir, olddir, newdir, desiredorigin, goal;
 258         float velspeed, f;
 259         this.nextthink = time;
 260         if(time > this.cnt)
 261         {
 262                 other = NULL;
 263                 this.projectiledeathtype |= HITTYPE_BOUNCE;
 264                 W_Devastator_Explode(this);
 265                 return;
 266         }
 267
 268         // accelerate
 269         makevectors(this.angles.x * '-1 0 0' + this.angles.y * '0 1 0');
 270         velspeed = WEP_CVAR(devastator, speed) * W_WeaponSpeedFactor(this.realowner) - (this.velocity * v_forward);
 271         if(velspeed > 0)
 272                 this.velocity = this.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * W_WeaponSpeedFactor(this.realowner) * frametime, velspeed);
 273
 274         // laser guided, or remote detonation
 275         if(PS(this.realowner).m_weapon == WEP_DEVASTATOR)
 276         {
 277                 if(this == this.realowner.lastrocket)
 278                 if(!this.realowner.rl_release)
 279                 if(!PHYS_INPUT_BUTTON_ATCK2(this))
 280                 if(WEP_CVAR(devastator, guiderate))
 281                 if(time > this.pushltime)
 282                 if(!IS_DEAD(this.realowner))
 283                 {
 284                         f = WEP_CVAR(devastator, guideratedelay);
 285                         if(f)
 286                                 f = bound(0, (time - this.pushltime) / f, 1);
 287                         else
 288                                 f = 1;
 289
 290                         velspeed = vlen(this.velocity);
 291
 292                         makevectors(this.realowner.v_angle);
 293                         desireddir = WarpZone_RefSys_TransformVelocity(this.realowner, this, v_forward);
 294                         desiredorigin = WarpZone_RefSys_TransformOrigin(this.realowner, this, this.realowner.origin + this.realowner.view_ofs);
 295                         olddir = normalize(this.velocity);
 296
 297                         // now it gets tricky... we want to move like some curve to approximate the target direction
 298                         // but we are limiting the rate at which we can turn!
 299                         goal = desiredorigin + ((this.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 300                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - this.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 301
 302                         this.velocity = newdir * velspeed;
 303                         this.angles = vectoangles(this.velocity);
 304
 305                         if(!this.count)
 306                         {
 307                                 Send_Effect(EFFECT_ROCKET_GUIDE, this.origin, this.velocity, 1);
 308                                 // TODO add a better sound here
 309                                 sound(this.realowner, CH_WEAPON_B, SND_ROCKET_MODE, VOL_BASE, ATTN_NORM);
 310                                 this.count = 1;
 311                         }
 312                 }
 313
 314                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 315                 if(this.rl_detonate_later)
 316                         W_Devastator_RemoteExplode(this, weaponentity);
 317         }
 318
 319         if(this.csqcprojectile_clientanimate == 0)
 320                 UpdateCSQCProjectile(this);
 321 }
 322
 323 void W_Devastator_Touch(entity this)
 324 {
 325         if(WarpZone_Projectile_Touch(this))
 326         {
 327                 if(wasfreed(this))
 328                         W_Devastator_Unregister(this);
 329                 return;
 330         }
 331         W_Devastator_Unregister(this);
 332         W_Devastator_Explode(this);
 333 }
 334
 335 void W_Devastator_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 336 {
 337         if(this.health <= 0)
 338                 return;
 339
 340         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 341                 return; // g_projectiles_damage says to halt
 342
 343         this.health = this.health - damage;
 344         this.angles = vectoangles(this.velocity);
 345
 346         if(this.health <= 0)
 347                 W_PrepareExplosionByDamage(this, attacker, W_Devastator_Explode);
 348 }
 349
 350 void W_Devastator_Attack(Weapon thiswep, entity actor)
 351 {
 352         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(devastator, ammo));
 353
 354         W_SetupShot_ProjectileSize(actor, '-3 -3 -3', '3 3 3', false, 5, SND_ROCKET_FIRE, CH_WEAPON_A, WEP_CVAR(devastator, damage));
 355         Send_Effect(EFFECT_ROCKET_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 356
 357         entity missile = WarpZone_RefSys_SpawnSameRefSys(actor);
 358         missile.owner = missile.realowner = actor;
 359         actor.lastrocket = missile;
 360         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 361                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 362         else
 363                 missile.spawnshieldtime = -1;
 364         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 365         missile.classname = "rocket";
 366         missile.bot_dodge = true;
 367         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 368
 369         missile.takedamage = DAMAGE_YES;
 370         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 371         missile.health = WEP_CVAR(devastator, health);
 372         missile.event_damage = W_Devastator_Damage;
 373         missile.damagedbycontents = true;
 374
 375         missile.movetype = MOVETYPE_FLY;
 376         PROJECTILE_MAKETRIGGER(missile);
 377         missile.projectiledeathtype = WEP_DEVASTATOR.m_id;
 378         setsize(missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 379
 380         setorigin(missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 381         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 382         missile.angles = vectoangles(missile.velocity);
 383
 384         settouch(missile, W_Devastator_Touch);
 385         setthink(missile, W_Devastator_Think);
 386         missile.nextthink = time;
 387         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 388         missile.flags = FL_PROJECTILE;
 389         missile.missile_flags = MIF_SPLASH;
 390
 391         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, false); // because of fly sound
 392
 393         // muzzle flash for 1st person view
 394         entity flash = spawn();
 395         setmodel(flash, MDL_DEVASTATOR_MUZZLEFLASH); // precision set below
 396         SUB_SetFade(flash, time, 0.1);
 397         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 398         W_AttachToShotorg(actor, flash, '5 0 0');
 399
 400         // common properties
 401         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 402 }
 403
 404 #if 0
 405 METHOD(Devastator, wr_aim, void(entity thiswep, entity actor))
 406 {
 407     entity this = actor;
 408     // aim and decide to fire if appropriate
 409     PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), false);
 410     if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 411     {
 412         // decide whether to detonate rockets
 413         entity missile, targetlist, targ;
 414         targetlist = findchainfloat(bot_attack, true);
 415         for(missile = NULL; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == actor)
 416         {
 417             targ = targetlist;
 418             while(targ)
 419             {
 420                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 421                 {
 422                     PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 423                     break;
 424                 }
 425                 targ = targ.chain;
 426             }
 427         }
 428
 429         if(PHYS_INPUT_BUTTON_ATCK2(actor)) PHYS_INPUT_BUTTON_ATCK(actor) = false;
 430     }
 431 }
 432 #else
 433 METHOD(Devastator, wr_aim, void(entity thiswep, entity actor))
 434 {
 435     // aim and decide to fire if appropriate
 436     PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), false);
 437     if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 438     {
 439         // decide whether to detonate rockets
 440         entity targetlist, targ;
 441         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 442         float selfdamage, teamdamage, enemydamage;
 443         edgedamage = WEP_CVAR(devastator, edgedamage);
 444         coredamage = WEP_CVAR(devastator, damage);
 445         edgeradius = WEP_CVAR(devastator, radius);
 446         recipricoledgeradius = 1 / edgeradius;
 447         selfdamage = 0;
 448         teamdamage = 0;
 449         enemydamage = 0;
 450         targetlist = findchainfloat(bot_attack, true);
 451         FOREACH_ENTITY_ENT(realowner, actor,
 452         {
 453             if(it.classname != "rocket") continue;
 454
 455             targ = targetlist;
 456             while(targ)
 457             {
 458                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - it.origin);
 459                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 460                 // count potential damage according to type of target
 461                 if(targ == actor)
 462                     selfdamage = selfdamage + d;
 463                 else if(targ.team == actor.team && teamplay)
 464                     teamdamage = teamdamage + d;
 465                 else if(bot_shouldattack(actor, targ))
 466                     enemydamage = enemydamage + d;
 467                 targ = targ.chain;
 468             }
 469         });
 470         float desirabledamage;
 471         desirabledamage = enemydamage;
 472         if(time > actor.invincible_finished && time > actor.spawnshieldtime)
 473             desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 474         if(teamplay && actor.team)
 475             desirabledamage = desirabledamage - teamdamage;
 476
 477         FOREACH_ENTITY_ENT(realowner, actor,
 478         {
 479             if(it.classname != "rocket") continue;
 480
 481             makevectors(it.v_angle);
 482             targ = targetlist;
 483             if(skill > 9) // normal players only do this for the target they are tracking
 484             {
 485                 targ = targetlist;
 486                 while(targ)
 487                 {
 488                     if(
 489                         (v_forward * normalize(it.origin - targ.origin)< 0.1)
 490                         && desirabledamage > 0.1*coredamage
 491                     ) PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 492                     targ = targ.chain;
 493                 }
 494             }
 495             else
 496             {
 497                 float distance; distance= bound(300,vlen(actor.origin-actor.enemy.origin),30000);
 498                 //As the distance gets larger, a correct detonation gets near imposible
 499                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 500                 if(v_forward * normalize(it.origin - actor.enemy.origin)< 0.1)
 501                     if(IS_PLAYER(actor.enemy))
 502                         if(desirabledamage >= 0.1*coredamage)
 503                             if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 504                                 PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 505             //  dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 506             }
 507         });
 508         // if we would be doing at X percent of the core damage, detonate it
 509         // but don't fire a new shot at the same time!
 510         if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 511             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 512         if((skill > 6.5) && (selfdamage > actor.health))
 513             PHYS_INPUT_BUTTON_ATCK2(actor) = false;
 514         //if(PHYS_INPUT_BUTTON_ATCK2(actor) == true)
 515         //      dprint(ftos(desirabledamage),"\n");
 516         if(PHYS_INPUT_BUTTON_ATCK2(actor)) PHYS_INPUT_BUTTON_ATCK(actor) = false;
 517     }
 518 }
 519 #endif
 520 METHOD(Devastator, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 521 {
 522     if(WEP_CVAR(devastator, reload_ammo) && actor.clip_load < WEP_CVAR(devastator, ammo)) { // forced reload
 523         thiswep.wr_reload(thiswep, actor, weaponentity);
 524     } else {
 525         if(fire & 1)
 526         {
 527             if(actor.rl_release || WEP_CVAR(devastator, guidestop))
 528             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(devastator, refire)))
 529             {
 530                 W_Devastator_Attack(thiswep, actor);
 531                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 532                 actor.rl_release = 0;
 533             }
 534         }
 535         else
 536             actor.rl_release = 1;
 537
 538         if(fire & 2)
 539         if(PS(actor).m_switchweapon == WEP_DEVASTATOR)
 540         {
 541             entity rock;
 542             bool rockfound = false;
 543             for(rock = NULL; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == actor)
 544             {
 545                 if(!rock.rl_detonate_later)
 546                 {
 547                     rock.rl_detonate_later = true;
 548                     rockfound = true;
 549                 }
 550             }
 551             if(rockfound)
 552                 sound(actor, CH_WEAPON_B, SND_ROCKET_DET, VOL_BASE, ATTN_NORM);
 553         }
 554     }
 555 }
 556 METHOD(Devastator, wr_setup, void(entity thiswep, entity actor))
 557 {
 558     actor.rl_release = 1;
 559 }
 560 METHOD(Devastator, wr_checkammo1, bool(entity thiswep, entity actor))
 561 {
 562     #if 0
 563     // don't switch while guiding a missile
 564     if(ATTACK_FINISHED(actor, slot) <= time || PS(actor).m_weapon != WEP_DEVASTATOR)
 565     {
 566         ammo_amount = false;
 567         if(WEP_CVAR(devastator, reload_ammo))
 568         {
 569             if(actor.(thiswep.ammo_field) < WEP_CVAR(devastator, ammo) && actor.(weapon_load[WEP_DEVASTATOR.m_id]) < WEP_CVAR(devastator, ammo))
 570                 ammo_amount = true;
 571         }
 572         else if(actor.(thiswep.ammo_field) < WEP_CVAR(devastator, ammo))
 573             ammo_amount = true;
 574         return !ammo_amount;
 575     }
 576     #endif
 577     #if 0
 578     if(actor.rl_release == 0)
 579     {
 580         LOG_INFOF("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: TRUE\n", actor.rl_release, actor.(thiswep.ammo_field), WEP_CVAR(devastator, ammo));
 581         return true;
 582     }
 583     else
 584     {
 585         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(devastator, ammo);
 586         ammo_amount += actor.(weapon_load[WEP_DEVASTATOR.m_id]) >= WEP_CVAR(devastator, ammo);
 587         LOG_INFOF("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: %s\n", actor.rl_release, actor.(thiswep.ammo_field), WEP_CVAR(devastator, ammo), (ammo_amount ? "TRUE" : "FALSE"));
 588         return ammo_amount;
 589     }
 590     #else
 591     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(devastator, ammo);
 592     ammo_amount += actor.(weapon_load[WEP_DEVASTATOR.m_id]) >= WEP_CVAR(devastator, ammo);
 593     return ammo_amount;
 594     #endif
 595 }
 596 METHOD(Devastator, wr_checkammo2, bool(entity thiswep, entity actor))
 597 {
 598     return false;
 599 }
 600 METHOD(Devastator, wr_resetplayer, void(entity thiswep, entity actor))
 601 {
 602     actor.lastrocket = NULL; // stop rocket guiding, no revenge from the grave!
 603     actor.rl_release = 0;
 604 }
 605 METHOD(Devastator, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 606 {
 607     W_Reload(actor, WEP_CVAR(devastator, ammo), SND_RELOAD);
 608 }
 609 METHOD(Devastator, wr_suicidemessage, Notification(entity thiswep))
 610 {
 611     return WEAPON_DEVASTATOR_SUICIDE;
 612 }
 613 METHOD(Devastator, wr_killmessage, Notification(entity thiswep))
 614 {
 615     if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 616         return WEAPON_DEVASTATOR_MURDER_SPLASH;
 617     else
 618         return WEAPON_DEVASTATOR_MURDER_DIRECT;
 619 }
 620
 621 #endif
 622 #ifdef CSQC
 623
 624 METHOD(Devastator, wr_impacteffect, void(entity thiswep, entity actor))
 625 {
 626     vector org2;
 627     org2 = w_org + w_backoff * 12;
 628     pointparticles(EFFECT_ROCKET_EXPLODE, org2, '0 0 0', 1);
 629     if(!w_issilent)
 630         sound(actor, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTN_NORM);
 631 }
 632
 633 #endif
 634 #endif