qcsrc/common/weapons/weapon/electro.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Electro, Weapon)
   3 /* ammotype  */ ATTRIB(Electro, ammo_field, .int, ammo_cells)
   4 /* impulse   */ ATTRIB(Electro, impulse, int, 5)
   5 /* flags     */ ATTRIB(Electro, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(Electro, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
   7 /* color     */ ATTRIB(Electro, wpcolor, vector, '0 0.5 1');
   8 /* modelname */ ATTRIB(Electro, mdl, string, "electro");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Electro, m_model, Model, MDL_ELECTRO_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Electro, w_crosshair, string, "gfx/crosshairelectro");
  13 /* crosshair */ ATTRIB(Electro, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(Electro, model2, string, "weaponelectro");
  15 /* refname   */ ATTRIB(Electro, netname, string, "electro");
  16 /* wepname   */ ATTRIB(Electro, m_name, string, _("Electro"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20                 P(class, prefix, ammo, float, BOTH) \
  21                 P(class, prefix, animtime, float, BOTH) \
  22                 P(class, prefix, bouncefactor, float, SEC) \
  23                 P(class, prefix, bouncestop, float, SEC) \
  24                 P(class, prefix, comboradius, float, PRI) \
  25                 P(class, prefix, combo_comboradius, float, NONE) \
  26                 P(class, prefix, combo_comboradius_thruwall, float, NONE) \
  27                 P(class, prefix, combo_damage, float, NONE) \
  28                 P(class, prefix, combo_edgedamage, float, NONE) \
  29                 P(class, prefix, combo_force, float, NONE) \
  30                 P(class, prefix, combo_radius, float, NONE) \
  31                 P(class, prefix, combo_safeammocheck, float, NONE) \
  32                 P(class, prefix, combo_speed, float, NONE) \
  33                 P(class, prefix, count, float, SEC) \
  34                 P(class, prefix, damagedbycontents, float, SEC) \
  35                 P(class, prefix, damageforcescale, float, SEC) \
  36                 P(class, prefix, damage, float, BOTH) \
  37                 P(class, prefix, edgedamage, float, BOTH) \
  38                 P(class, prefix, force, float, BOTH) \
  39                 P(class, prefix, health, float, SEC) \
  40                 P(class, prefix, lifetime, float, BOTH) \
  41                 P(class, prefix, midaircombo_explode, float, PRI) \
  42                 P(class, prefix, midaircombo_interval, float, PRI) \
  43                 P(class, prefix, midaircombo_radius, float, PRI) \
  44                 P(class, prefix, radius, float, BOTH) \
  45                 P(class, prefix, refire2, float, SEC) \
  46                 P(class, prefix, refire, float, BOTH) \
  47                 P(class, prefix, reload_ammo, float, NONE) \
  48                 P(class, prefix, reload_time, float, NONE) \
  49                 P(class, prefix, speed, float, BOTH) \
  50                 P(class, prefix, speed_up, float, SEC) \
  51                 P(class, prefix, speed_z, float, SEC) \
  52                 P(class, prefix, spread, float, BOTH) \
  53                 P(class, prefix, stick, float, SEC) \
  54                 P(class, prefix, switchdelay_drop, float, NONE) \
  55                 P(class, prefix, switchdelay_raise, float, NONE) \
  56                 P(class, prefix, touchexplode, float, SEC) \
  57                 P(class, prefix, weaponreplace, string,NONE) \
  58                 P(class, prefix, weaponstartoverride, float, NONE) \
  59                 P(class, prefix, weaponstart, float, NONE) \
  60                 P(class, prefix, weaponthrowable, float, NONE) \
  61         END()
  62         W_PROPS(X, Electro, electro)
  63 #undef X
  64
  65 ENDCLASS(Electro)
  66 REGISTER_WEAPON(ELECTRO, electro, NEW(Electro));
  67
  68
  69 #ifdef SVQC
  70 .float electro_count;
  71 .float electro_secondarytime;
  72 void W_Electro_ExplodeCombo(entity this);
  73 #endif
  74 #endif
  75 #ifdef IMPLEMENTATION
  76 #ifdef SVQC
  77 spawnfunc(weapon_electro) { weapon_defaultspawnfunc(this, WEP_ELECTRO); }
  78
  79 void W_Electro_TriggerCombo(vector org, float rad, entity own)
  80 {
  81         entity e = WarpZone_FindRadius(org, rad, !WEP_CVAR(electro, combo_comboradius_thruwall));
  82         while(e)
  83         {
  84                 if(e.classname == "electro_orb")
  85                 {
  86                         // do we allow thruwall triggering?
  87                         if(WEP_CVAR(electro, combo_comboradius_thruwall))
  88                         {
  89                                 // if distance is greater than thruwall distance, check to make sure it's not through a wall
  90                                 if(vdist(e.WarpZone_findradius_dist, >, WEP_CVAR(electro, combo_comboradius_thruwall)))
  91                                 {
  92                                         WarpZone_TraceLine(org, e.origin, MOVE_NOMONSTERS, e);
  93                                         if(trace_fraction != 1)
  94                                         {
  95                                                 // trigger is through a wall and outside of thruwall range, abort
  96                                                 e = e.chain;
  97                                                 continue;
  98                                         }
  99                                 }
 100                         }
 101
 102                         // change owner to whoever caused the combo explosion
 103                         e.realowner = own;
 104                         e.takedamage = DAMAGE_NO;
 105                         e.classname = "electro_orb_chain";
 106
 107                         // now set the next one to trigger as well
 108                         setthink(e, W_Electro_ExplodeCombo);
 109
 110                         // delay combo chains, looks cooler
 111                         e.nextthink =
 112                                 (
 113                                         time
 114                                         +
 115                                         (WEP_CVAR(electro, combo_speed) ?
 116                                                 (vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed))
 117                                                 :
 118                                                 0
 119                                         )
 120                                 );
 121                 }
 122                 e = e.chain;
 123         }
 124 }
 125
 126 void W_Electro_ExplodeCombo(entity this)
 127 {
 128         W_Electro_TriggerCombo(this.origin, WEP_CVAR(electro, combo_comboradius), this.realowner);
 129
 130         this.event_damage = func_null;
 131
 132         RadiusDamage(
 133                 this,
 134                 this.realowner,
 135                 WEP_CVAR(electro, combo_damage),
 136                 WEP_CVAR(electro, combo_edgedamage),
 137                 WEP_CVAR(electro, combo_radius),
 138                 NULL,
 139                 NULL,
 140                 WEP_CVAR(electro, combo_force),
 141                 WEP_ELECTRO.m_id | HITTYPE_BOUNCE, // use THIS type for a combo because primary can't bounce
 142                 NULL
 143         );
 144
 145         delete(this);
 146 }
 147
 148 void W_Electro_Explode(entity this, entity directhitentity)
 149 {
 150         if(directhitentity.takedamage == DAMAGE_AIM)
 151                 if(IS_PLAYER(directhitentity))
 152                         if(DIFF_TEAM(this.realowner, directhitentity))
 153                                 if(!IS_DEAD(directhitentity))
 154                                         if(IsFlying(directhitentity))
 155                                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
 156
 157         this.event_damage = func_null;
 158         this.takedamage = DAMAGE_NO;
 159
 160         if(this.move_movetype == MOVETYPE_BOUNCE || this.classname == "electro_orb") // TODO: classname is more reliable anyway?
 161         {
 162                 RadiusDamage(
 163                         this,
 164                         this.realowner,
 165                         WEP_CVAR_SEC(electro, damage),
 166                         WEP_CVAR_SEC(electro, edgedamage),
 167                         WEP_CVAR_SEC(electro, radius),
 168                         NULL,
 169                         NULL,
 170                         WEP_CVAR_SEC(electro, force),
 171                         this.projectiledeathtype,
 172                         directhitentity
 173                 );
 174         }
 175         else
 176         {
 177                 W_Electro_TriggerCombo(this.origin, WEP_CVAR_PRI(electro, comboradius), this.realowner);
 178                 RadiusDamage(
 179                         this,
 180                         this.realowner,
 181                         WEP_CVAR_PRI(electro, damage),
 182                         WEP_CVAR_PRI(electro, edgedamage),
 183                         WEP_CVAR_PRI(electro, radius),
 184                         NULL,
 185                         NULL,
 186                         WEP_CVAR_PRI(electro, force),
 187                         this.projectiledeathtype,
 188                         directhitentity
 189                 );
 190         }
 191
 192         delete(this);
 193 }
 194
 195 void W_Electro_Explode_use(entity this, entity actor, entity trigger)
 196 {
 197         W_Electro_Explode(this, trigger);
 198 }
 199
 200 void W_Electro_TouchExplode(entity this, entity toucher)
 201 {
 202         PROJECTILE_TOUCH(this, toucher);
 203         W_Electro_Explode(this, toucher);
 204 }
 205
 206
 207 void sys_phys_update_single(entity this);
 208
 209 void W_Electro_Bolt_Think(entity this)
 210 {
 211         // sys_phys_update_single(this);
 212         if(time >= this.ltime)
 213         {
 214                 this.use(this, NULL, NULL);
 215                 return;
 216         }
 217
 218         if(WEP_CVAR_PRI(electro, midaircombo_radius))
 219         {
 220                 float found = 0;
 221                 entity e = WarpZone_FindRadius(this.origin, WEP_CVAR_PRI(electro, midaircombo_radius), true);
 222
 223                 // loop through nearby orbs and trigger them
 224                 while(e)
 225                 {
 226                         if(e.classname == "electro_orb")
 227                         {
 228                                 // change owner to whoever caused the combo explosion
 229                                 e.realowner = this.realowner;
 230                                 e.takedamage = DAMAGE_NO;
 231                                 e.classname = "electro_orb_chain";
 232
 233                                 // now set the next one to trigger as well
 234                                 setthink(e, W_Electro_ExplodeCombo);
 235
 236                                 // delay combo chains, looks cooler
 237                                 e.nextthink =
 238                                         (
 239                                                 time
 240                                                 +
 241                                                 (WEP_CVAR(electro, combo_speed) ?
 242                                                         (vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed))
 243                                                         :
 244                                                         0
 245                                                 )
 246                                         );
 247
 248                                 ++found;
 249                         }
 250                         e = e.chain;
 251                 }
 252
 253                 // if we triggered an orb, should we explode? if not, lets try again next time
 254                 if(found && WEP_CVAR_PRI(electro, midaircombo_explode))
 255                         { this.use(this, NULL, NULL); }
 256                 else
 257                         { this.nextthink = min(time + WEP_CVAR_PRI(electro, midaircombo_interval), this.ltime); }
 258         }
 259         else { this.nextthink = this.ltime; }
 260         // this.nextthink = time;
 261 }
 262
 263 void W_Electro_Attack_Bolt(Weapon thiswep, entity actor)
 264 {
 265         entity proj;
 266
 267         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_PRI(electro, ammo));
 268
 269         W_SetupShot_ProjectileSize(
 270                 actor,
 271                 '0 0 -3',
 272                 '0 0 -3',
 273                 false,
 274                 2,
 275                 SND_ELECTRO_FIRE,
 276                 CH_WEAPON_A,
 277                 WEP_CVAR_PRI(electro, damage)
 278         );
 279
 280         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 281
 282         proj = new(electro_bolt);
 283         proj.owner = proj.realowner = actor;
 284         proj.bot_dodge = true;
 285         proj.bot_dodgerating = WEP_CVAR_PRI(electro, damage);
 286         proj.use = W_Electro_Explode_use;
 287         setthink(proj, W_Electro_Bolt_Think);
 288         proj.nextthink = time;
 289         proj.ltime = time + WEP_CVAR_PRI(electro, lifetime);
 290         PROJECTILE_MAKETRIGGER(proj);
 291         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 292         setorigin(proj, w_shotorg);
 293
 294         // if (IS_CSQC)
 295         set_movetype(proj, MOVETYPE_FLY);
 296         W_SetupProjVelocity_PRI(proj, electro);
 297         proj.angles = vectoangles(proj.velocity);
 298         settouch(proj, W_Electro_TouchExplode);
 299         setsize(proj, '0 0 -3', '0 0 -3');
 300         proj.flags = FL_PROJECTILE;
 301         IL_PUSH(g_projectiles, proj);
 302         proj.missile_flags = MIF_SPLASH;
 303
 304         CSQCProjectile(proj, true, PROJECTILE_ELECTRO_BEAM, true);
 305
 306         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 307         // proj.com_phys_pos = proj.origin;
 308         // proj.com_phys_vel = proj.velocity;
 309 }
 310
 311 void W_Electro_Orb_Stick(entity this, entity to)
 312 {
 313         entity newproj = spawn();
 314         newproj.classname = this.classname;
 315
 316         newproj.bot_dodge = this.bot_dodge;
 317         newproj.bot_dodgerating = this.bot_dodgerating;
 318
 319         newproj.owner = this.owner;
 320         newproj.realowner = this.realowner;
 321         setsize(newproj, this.mins, this.maxs);
 322         setorigin(newproj, this.origin);
 323         setmodel(newproj, MDL_PROJECTILE_ELECTRO);
 324         newproj.angles = vectoangles(-trace_plane_normal); // face against the surface
 325
 326         newproj.takedamage = this.takedamage;
 327         newproj.damageforcescale = this.damageforcescale;
 328         newproj.health = this.health;
 329         newproj.event_damage = this.event_damage;
 330         newproj.spawnshieldtime = this.spawnshieldtime;
 331         newproj.damagedbycontents = true;
 332
 333         set_movetype(newproj, MOVETYPE_NONE); // lock the orb in place
 334         newproj.projectiledeathtype = this.projectiledeathtype;
 335
 336         settouch(newproj, func_null);
 337         setthink(newproj, getthink(this));
 338         newproj.nextthink = this.nextthink;
 339         newproj.use = this.use;
 340         newproj.flags = this.flags;
 341
 342         delete(this);
 343
 344         if(to)
 345                 SetMovetypeFollow(this, to);
 346 }
 347
 348 void W_Electro_Orb_Touch(entity this, entity toucher)
 349 {
 350         PROJECTILE_TOUCH(this, toucher);
 351         if(toucher.takedamage == DAMAGE_AIM)
 352                 { if(WEP_CVAR_SEC(electro, touchexplode)) { W_Electro_Explode(this, toucher); } }
 353         else
 354         {
 355                 //UpdateCSQCProjectile(this);
 356                 spamsound(this, CH_SHOTS, SND(ELECTRO_BOUNCE), VOL_BASE, ATTEN_NORM);
 357                 this.projectiledeathtype |= HITTYPE_BOUNCE;
 358
 359                 if(WEP_CVAR_SEC(electro, stick))
 360                         W_Electro_Orb_Stick(this, toucher);
 361         }
 362 }
 363
 364 void W_Electro_Orb_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 365 {
 366         if(this.health <= 0)
 367                 return;
 368
 369         // note: combos are usually triggered by W_Electro_TriggerCombo, not damage
 370         float is_combo = (inflictor.classname == "electro_orb_chain" || inflictor.classname == "electro_bolt");
 371
 372         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, (is_combo ? 1 : -1)))
 373                 return; // g_projectiles_damage says to halt
 374
 375         this.health = this.health - damage;
 376         if(this.health <= 0)
 377         {
 378                 this.takedamage = DAMAGE_NO;
 379                 this.nextthink = time;
 380                 if(is_combo)
 381                 {
 382                         // change owner to whoever caused the combo explosion
 383                         this.realowner = inflictor.realowner;
 384                         this.classname = "electro_orb_chain";
 385                         setthink(this, W_Electro_ExplodeCombo);
 386                         this.nextthink = time +
 387                                 (
 388                                         // bound the length, inflictor may be in a galaxy far far away (warpzones)
 389                                         min(
 390                                                 WEP_CVAR(electro, combo_radius),
 391                                                 vlen(this.origin - inflictor.origin)
 392                                         )
 393                                         /
 394                                         // delay combo chains, looks cooler
 395                                         WEP_CVAR(electro, combo_speed)
 396                                 );
 397                 }
 398                 else
 399                 {
 400                         this.use = W_Electro_Explode_use;
 401                         setthink(this, adaptor_think2use); // not _hittype_splash, as this runs "immediately"
 402                 }
 403         }
 404 }
 405
 406 void W_Electro_Attack_Orb(Weapon thiswep, entity actor)
 407 {
 408         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(electro, ammo));
 409
 410         W_SetupShot_ProjectileSize(
 411                 actor,
 412                 '-4 -4 -4',
 413                 '4 4 4',
 414                 false,
 415                 2,
 416                 SND_ELECTRO_FIRE2,
 417                 CH_WEAPON_A,
 418                 WEP_CVAR_SEC(electro, damage)
 419         );
 420
 421         w_shotdir = v_forward; // no TrueAim for grenades please
 422
 423         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 424
 425         entity proj = new(electro_orb);
 426         proj.owner = proj.realowner = actor;
 427         proj.use = W_Electro_Explode_use;
 428         setthink(proj, adaptor_think2use_hittype_splash);
 429         proj.bot_dodge = true;
 430         proj.bot_dodgerating = WEP_CVAR_SEC(electro, damage);
 431         proj.nextthink = time + WEP_CVAR_SEC(electro, lifetime);
 432         PROJECTILE_MAKETRIGGER(proj);
 433         proj.projectiledeathtype = WEP_ELECTRO.m_id | HITTYPE_SECONDARY;
 434         setorigin(proj, w_shotorg);
 435
 436         //proj.glow_size = 50;
 437         //proj.glow_color = 45;
 438         set_movetype(proj, MOVETYPE_BOUNCE);
 439         W_SetupProjVelocity_UP_SEC(proj, electro);
 440         settouch(proj, W_Electro_Orb_Touch);
 441         setsize(proj, '-4 -4 -4', '4 4 4');
 442         proj.takedamage = DAMAGE_YES;
 443         proj.damageforcescale = WEP_CVAR_SEC(electro, damageforcescale);
 444         proj.health = WEP_CVAR_SEC(electro, health);
 445         proj.event_damage = W_Electro_Orb_Damage;
 446         proj.flags = FL_PROJECTILE;
 447         IL_PUSH(g_projectiles, proj);
 448         proj.damagedbycontents = (WEP_CVAR_SEC(electro, damagedbycontents));
 449
 450         proj.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
 451         proj.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
 452         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 453
 454 #if 0
 455         entity p2;
 456         p2 = spawn();
 457         copyentity(proj, p2);
 458         setmodel(p2, MDL_PROJECTILE_ELECTRO);
 459         setsize(p2, proj.mins, proj.maxs);
 460 #endif
 461
 462         CSQCProjectile(proj, true, PROJECTILE_ELECTRO, false); // no culling, it has sound
 463
 464         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 465 }
 466
 467 void W_Electro_CheckAttack(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 468 {
 469         if(actor.electro_count > 1)
 470         if(PHYS_INPUT_BUTTON_ATCK2(actor))
 471         if(weapon_prepareattack(thiswep, actor, weaponentity, true, -1))
 472         {
 473                 W_Electro_Attack_Orb(WEP_ELECTRO, actor);
 474                 actor.electro_count -= 1;
 475                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 476                 return;
 477         }
 478         // WEAPONTODO: when the player releases the button, cut down the length of refire2?
 479         w_ready(thiswep, actor, weaponentity, fire);
 480 }
 481
 482 .float bot_secondary_electromooth;
 483
 484 METHOD(Electro, wr_aim, void(entity thiswep, entity actor))
 485 {
 486     PHYS_INPUT_BUTTON_ATCK(actor) = PHYS_INPUT_BUTTON_ATCK2(actor) = false;
 487     if(vdist(actor.origin - actor.enemy.origin, >, 1000)) { actor.bot_secondary_electromooth = 0; }
 488     if(actor.bot_secondary_electromooth == 0)
 489     {
 490         float shoot;
 491
 492         if(WEP_CVAR_PRI(electro, speed))
 493             shoot = bot_aim(actor, WEP_CVAR_PRI(electro, speed), 0, WEP_CVAR_PRI(electro, lifetime), false);
 494         else
 495             shoot = bot_aim(actor, 1000000, 0, 0.001, false);
 496
 497         if(shoot)
 498         {
 499             PHYS_INPUT_BUTTON_ATCK(actor) = true;
 500             if(random() < 0.01) actor.bot_secondary_electromooth = 1;
 501         }
 502     }
 503     else
 504     {
 505         if(bot_aim(actor, WEP_CVAR_SEC(electro, speed), WEP_CVAR_SEC(electro, speed_up), WEP_CVAR_SEC(electro, lifetime), true))
 506         {
 507             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 508             if(random() < 0.03) actor.bot_secondary_electromooth = 0;
 509         }
 510     }
 511 }
 512 METHOD(Electro, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 513 {
 514     if(autocvar_g_balance_electro_reload_ammo) // forced reload // WEAPONTODO
 515     {
 516         float ammo_amount = 0;
 517         if(actor.clip_load >= WEP_CVAR_PRI(electro, ammo))
 518             ammo_amount = 1;
 519         if(actor.clip_load >= WEP_CVAR_SEC(electro, ammo))
 520             ammo_amount += 1;
 521
 522         if(!ammo_amount)
 523         {
 524             thiswep.wr_reload(thiswep, actor, weaponentity);
 525             return;
 526         }
 527     }
 528
 529     if(fire & 1)
 530     {
 531         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(electro, refire)))
 532         {
 533                 W_Electro_Attack_Bolt(thiswep, actor);
 534                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(electro, animtime), w_ready);
 535         }
 536     }
 537     else if(fire & 2)
 538     {
 539         if(time >= actor.electro_secondarytime)
 540         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(electro, refire)))
 541         {
 542             W_Electro_Attack_Orb(thiswep, actor);
 543             actor.electro_count = WEP_CVAR_SEC(electro, count);
 544             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 545             actor.electro_secondarytime = time + WEP_CVAR_SEC(electro, refire2) * W_WeaponRateFactor(actor);
 546         }
 547     }
 548 }
 549 METHOD(Electro, wr_checkammo1, bool(entity thiswep, entity actor))
 550 {
 551     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(electro, ammo);
 552     ammo_amount += actor.(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_PRI(electro, ammo);
 553     return ammo_amount;
 554 }
 555 METHOD(Electro, wr_checkammo2, bool(entity thiswep, entity actor))
 556 {
 557     float ammo_amount;
 558     if(WEP_CVAR(electro, combo_safeammocheck)) // true if you can fire at least one secondary blob AND one primary shot after it, otherwise false.
 559     {
 560         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 561         ammo_amount += actor.(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 562     }
 563     else
 564     {
 565         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(electro, ammo);
 566         ammo_amount += actor.(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_SEC(electro, ammo);
 567     }
 568     return ammo_amount;
 569 }
 570 METHOD(Electro, wr_resetplayer, void(entity thiswep, entity actor))
 571 {
 572     actor.electro_secondarytime = time;
 573 }
 574 METHOD(Electro, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 575 {
 576     W_Reload(actor, min(WEP_CVAR_PRI(electro, ammo), WEP_CVAR_SEC(electro, ammo)), SND_RELOAD);
 577 }
 578 METHOD(Electro, wr_suicidemessage, Notification(entity thiswep))
 579 {
 580     if(w_deathtype & HITTYPE_SECONDARY)
 581         return WEAPON_ELECTRO_SUICIDE_ORBS;
 582     else
 583         return WEAPON_ELECTRO_SUICIDE_BOLT;
 584 }
 585 METHOD(Electro, wr_killmessage, Notification(entity thiswep))
 586 {
 587     if(w_deathtype & HITTYPE_SECONDARY)
 588     {
 589         return WEAPON_ELECTRO_MURDER_ORBS;
 590     }
 591     else
 592     {
 593         if(w_deathtype & HITTYPE_BOUNCE)
 594             return WEAPON_ELECTRO_MURDER_COMBO;
 595         else
 596             return WEAPON_ELECTRO_MURDER_BOLT;
 597     }
 598 }
 599
 600 #endif
 601 #ifdef CSQC
 602
 603 METHOD(Electro, wr_impacteffect, void(entity thiswep, entity actor))
 604 {
 605     vector org2;
 606     org2 = w_org + w_backoff * 6;
 607     if(w_deathtype & HITTYPE_SECONDARY)
 608     {
 609         pointparticles(EFFECT_ELECTRO_BALLEXPLODE, org2, '0 0 0', 1);
 610         if(!w_issilent)
 611             sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_NORM);
 612     }
 613     else
 614     {
 615         if(w_deathtype & HITTYPE_BOUNCE)
 616         {
 617             // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 618             pointparticles(EFFECT_ELECTRO_COMBO, org2, '0 0 0', 1);
 619             if(!w_issilent)
 620                 sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT_COMBO, VOL_BASE, ATTEN_NORM);
 621         }
 622         else
 623         {
 624             pointparticles(EFFECT_ELECTRO_IMPACT, org2, '0 0 0', 1);
 625             if(!w_issilent)
 626                 sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_NORM);
 627         }
 628     }
 629 }
 630
 631 #endif
 632 #endif