Use a trick to prevent handling of items that aren't registered with .itemdef (should...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / hagar.qc
1 #include "hagar.qh"
2 #ifndef IMPLEMENTATION
3 CLASS(Hagar, Weapon)
4 /* ammotype  */ ATTRIB(Hagar, ammo_field, .int, ammo_rockets);
5 /* impulse   */ ATTRIB(Hagar, impulse, int, 8);
6 /* flags     */ ATTRIB(Hagar, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
7 /* rating    */ ATTRIB(Hagar, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
8 /* color     */ ATTRIB(Hagar, wpcolor, vector, '1 1 0.5');
9 /* modelname */ ATTRIB(Hagar, mdl, string, "hagar");
10 #ifdef GAMEQC
11 /* model     */ ATTRIB(Hagar, m_model, Model, MDL_HAGAR_ITEM);
12 #endif
13 /* crosshair */ ATTRIB(Hagar, w_crosshair, string, "gfx/crosshairhagar");
14 /* crosshair */ ATTRIB(Hagar, w_crosshair_size, float, 0.8);
15 /* wepimg    */ ATTRIB(Hagar, model2, string, "weaponhagar");
16 /* refname   */ ATTRIB(Hagar, netname, string, "hagar");
17 /* wepname   */ ATTRIB(Hagar, m_name, string, _("Hagar"));
18
19 #define X(BEGIN, P, END, class, prefix) \
20         BEGIN(class) \
21                 P(class, prefix, ammo, float, BOTH) \
22         P(class, prefix, damageforcescale, float, BOTH) \
23         P(class, prefix, damage, float, BOTH) \
24         P(class, prefix, edgedamage, float, BOTH) \
25         P(class, prefix, force, float, BOTH) \
26         P(class, prefix, health, float, BOTH) \
27         P(class, prefix, lifetime, float, PRI) \
28         P(class, prefix, lifetime_min, float, SEC) \
29         P(class, prefix, lifetime_rand, float, SEC) \
30         P(class, prefix, load, float, SEC) \
31         P(class, prefix, load_abort, float, SEC) \
32         P(class, prefix, load_animtime, float, SEC) \
33         P(class, prefix, load_hold, float, SEC) \
34         P(class, prefix, load_linkexplode, float, SEC) \
35         P(class, prefix, load_max, float, SEC) \
36         P(class, prefix, load_releasedeath, float, SEC) \
37         P(class, prefix, load_speed, float, SEC) \
38         P(class, prefix, load_spread, float, SEC) \
39         P(class, prefix, load_spread_bias, float, SEC) \
40         P(class, prefix, radius, float, BOTH) \
41         P(class, prefix, refire, float, BOTH) \
42         P(class, prefix, reload_ammo, float, NONE) \
43         P(class, prefix, reload_time, float, NONE) \
44         P(class, prefix, secondary, float, NONE) \
45         P(class, prefix, speed, float, BOTH) \
46         P(class, prefix, spread, float, BOTH) \
47         P(class, prefix, switchdelay_drop, float, NONE) \
48         P(class, prefix, switchdelay_raise, float, NONE) \
49         P(class, prefix, weaponreplace, string,NONE) \
50         P(class, prefix, weaponstartoverride, float, NONE) \
51         P(class, prefix, weaponstart, float, NONE) \
52         P(class, prefix, weaponthrowable, float, NONE) \
53         END()
54     W_PROPS(X, Hagar, hagar)
55 #undef X
56
57 ENDCLASS(Hagar)
58 REGISTER_WEAPON(HAGAR, hagar, NEW(Hagar));
59
60 #endif
61 #ifdef IMPLEMENTATION
62 #ifdef SVQC
63 spawnfunc(weapon_hagar) { weapon_defaultspawnfunc(this, WEP_HAGAR); }
64
65 // NO bounce protection, as bounces are limited!
66
67 void W_Hagar_Explode(entity this, entity directhitentity)
68 {
69         this.event_damage = func_null;
70         RadiusDamage(this, this.realowner, WEP_CVAR_PRI(hagar, damage), WEP_CVAR_PRI(hagar, edgedamage), WEP_CVAR_PRI(hagar, radius), NULL, NULL, WEP_CVAR_PRI(hagar, force), this.projectiledeathtype, directhitentity);
71
72         delete(this);
73 }
74
75 void W_Hagar_Explode_use(entity this, entity actor, entity trigger)
76 {
77         W_Hagar_Explode(this, trigger);
78 }
79
80 void W_Hagar_Explode2(entity this, entity directhitentity)
81 {
82         this.event_damage = func_null;
83         RadiusDamage(this, this.realowner, WEP_CVAR_SEC(hagar, damage), WEP_CVAR_SEC(hagar, edgedamage), WEP_CVAR_SEC(hagar, radius), NULL, NULL, WEP_CVAR_SEC(hagar, force), this.projectiledeathtype, directhitentity);
84
85         delete(this);
86 }
87
88 void W_Hagar_Explode2_use(entity this, entity actor, entity trigger)
89 {
90         W_Hagar_Explode2(this, trigger);
91 }
92
93 void W_Hagar_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
94 {
95         if(this.health <= 0)
96                 return;
97
98         float is_linkexplode = ( ((inflictor.owner != NULL) ? (inflictor.owner == this.owner) : true)
99                 && (inflictor.projectiledeathtype & HITTYPE_SECONDARY)
100                 && (this.projectiledeathtype & HITTYPE_SECONDARY));
101
102         if(is_linkexplode)
103                 is_linkexplode = (is_linkexplode && WEP_CVAR_SEC(hagar, load_linkexplode));
104         else
105                 is_linkexplode = -1; // not secondary load, so continue as normal without exception.
106
107         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, is_linkexplode))
108                 return; // g_projectiles_damage says to halt
109
110         this.health = this.health - damage;
111         this.angles = vectoangles(this.velocity);
112
113         if(this.health <= 0)
114                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
115 }
116
117 void W_Hagar_Touch(entity this, entity toucher)
118 {
119         PROJECTILE_TOUCH(this, toucher);
120         this.use(this, NULL, toucher);
121 }
122
123 void W_Hagar_Touch2(entity this, entity toucher)
124 {
125         PROJECTILE_TOUCH(this, toucher);
126
127         if(this.cnt > 0 || toucher.takedamage == DAMAGE_AIM) {
128                 this.use(this, NULL, toucher);
129         } else {
130                 this.cnt++;
131                 Send_Effect(EFFECT_HAGAR_BOUNCE, this.origin, this.velocity, 1);
132                 this.angles = vectoangles(this.velocity);
133                 this.owner = NULL;
134                 this.projectiledeathtype |= HITTYPE_BOUNCE;
135         }
136 }
137
138 void W_Hagar_Attack(Weapon thiswep, entity actor, .entity weaponentity)
139 {
140         entity missile;
141
142         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_PRI(hagar, ammo));
143
144         W_SetupShot(actor, weaponentity, false, 2, SND_HAGAR_FIRE, CH_WEAPON_A, WEP_CVAR_PRI(hagar, damage));
145
146         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
147
148         missile = new(missile);
149         missile.owner = missile.realowner = actor;
150         missile.bot_dodge = true;
151         missile.bot_dodgerating = WEP_CVAR_PRI(hagar, damage);
152
153         missile.takedamage = DAMAGE_YES;
154         missile.health = WEP_CVAR_PRI(hagar, health);
155         missile.damageforcescale = WEP_CVAR_PRI(hagar, damageforcescale);
156         missile.event_damage = W_Hagar_Damage;
157         missile.damagedbycontents = true;
158         IL_PUSH(g_damagedbycontents, missile);
159
160         settouch(missile, W_Hagar_Touch);
161         missile.use = W_Hagar_Explode_use;
162         setthink(missile, adaptor_think2use_hittype_splash);
163         missile.nextthink = time + WEP_CVAR_PRI(hagar, lifetime);
164         PROJECTILE_MAKETRIGGER(missile);
165         missile.projectiledeathtype = WEP_HAGAR.m_id;
166         setorigin(missile, w_shotorg);
167         setsize(missile, '0 0 0', '0 0 0');
168
169         set_movetype(missile, MOVETYPE_FLY);
170         W_SetupProjVelocity_PRI(missile, hagar);
171
172         missile.angles = vectoangles(missile.velocity);
173         missile.flags = FL_PROJECTILE;
174         IL_PUSH(g_projectiles, missile);
175         IL_PUSH(g_bot_dodge, missile);
176         missile.missile_flags = MIF_SPLASH;
177
178         CSQCProjectile(missile, true, PROJECTILE_HAGAR, true);
179
180         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
181 }
182
183 void W_Hagar_Attack2(Weapon thiswep, entity actor, .entity weaponentity)
184 {
185         entity missile;
186
187         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hagar, ammo));
188
189         W_SetupShot(actor, weaponentity, false, 2, SND_HAGAR_FIRE, CH_WEAPON_A, WEP_CVAR_SEC(hagar, damage));
190
191         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
192
193         missile = new(missile);
194         missile.owner = missile.realowner = actor;
195         missile.bot_dodge = true;
196         missile.bot_dodgerating = WEP_CVAR_SEC(hagar, damage);
197
198         missile.takedamage = DAMAGE_YES;
199         missile.health = WEP_CVAR_SEC(hagar, health);
200         missile.damageforcescale = WEP_CVAR_SEC(hagar, damageforcescale);
201         missile.event_damage = W_Hagar_Damage;
202         missile.damagedbycontents = true;
203         IL_PUSH(g_damagedbycontents, missile);
204
205         settouch(missile, W_Hagar_Touch2);
206         missile.cnt = 0;
207         missile.use = W_Hagar_Explode2_use;
208         setthink(missile, adaptor_think2use_hittype_splash);
209         missile.nextthink = time + WEP_CVAR_SEC(hagar, lifetime_min) + random() * WEP_CVAR_SEC(hagar, lifetime_rand);
210         PROJECTILE_MAKETRIGGER(missile);
211         missile.projectiledeathtype = WEP_HAGAR.m_id | HITTYPE_SECONDARY;
212         setorigin(missile, w_shotorg);
213         setsize(missile, '0 0 0', '0 0 0');
214
215         set_movetype(missile, MOVETYPE_BOUNCEMISSILE);
216         W_SetupProjVelocity_SEC(missile, hagar);
217
218         missile.angles = vectoangles(missile.velocity);
219         missile.flags = FL_PROJECTILE;
220         IL_PUSH(g_projectiles, missile);
221         IL_PUSH(g_bot_dodge, missile);
222         missile.missile_flags = MIF_SPLASH;
223
224         CSQCProjectile(missile, true, PROJECTILE_HAGAR_BOUNCING, true);
225
226         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
227 }
228
229 .float hagar_loadstep, hagar_loadblock, hagar_loadbeep, hagar_warning;
230 void W_Hagar_Attack2_Load_Release(entity actor, .entity weaponentity)
231 {
232         // time to release the rockets we've loaded
233
234         entity missile;
235         float counter, shots, spread_pershot;
236         vector s;
237         vector forward, right, up;
238
239         if(!actor.hagar_load)
240                 return;
241
242         weapon_prepareattack_do(actor, weaponentity, true, WEP_CVAR_SEC(hagar, refire));
243
244         W_SetupShot(actor, weaponentity, false, 2, SND_HAGAR_FIRE, CH_WEAPON_A, WEP_CVAR_SEC(hagar, damage));
245         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
246
247         forward = v_forward;
248         right = v_right;
249         up = v_up;
250
251         shots = actor.hagar_load;
252         missile = NULL;
253         for(counter = 0; counter < shots; ++counter)
254         {
255                 missile = new(missile);
256                 missile.owner = missile.realowner = actor;
257                 missile.bot_dodge = true;
258                 missile.bot_dodgerating = WEP_CVAR_SEC(hagar, damage);
259
260                 missile.takedamage = DAMAGE_YES;
261                 missile.health = WEP_CVAR_SEC(hagar, health);
262                 missile.damageforcescale = WEP_CVAR_SEC(hagar, damageforcescale);
263                 missile.event_damage = W_Hagar_Damage;
264                 missile.damagedbycontents = true;
265                 IL_PUSH(g_damagedbycontents, missile);
266
267                 settouch(missile, W_Hagar_Touch); // not bouncy
268                 missile.use = W_Hagar_Explode2_use;
269                 setthink(missile, adaptor_think2use_hittype_splash);
270                 missile.nextthink = time + WEP_CVAR_SEC(hagar, lifetime_min) + random() * WEP_CVAR_SEC(hagar, lifetime_rand);
271                 PROJECTILE_MAKETRIGGER(missile);
272                 missile.projectiledeathtype = WEP_HAGAR.m_id | HITTYPE_SECONDARY;
273                 setorigin(missile, w_shotorg);
274                 setsize(missile, '0 0 0', '0 0 0');
275                 set_movetype(missile, MOVETYPE_FLY);
276                 missile.missile_flags = MIF_SPLASH;
277
278                 // per-shot spread calculation: the more shots there are, the less spread is applied (based on the bias cvar)
279                 spread_pershot = ((shots - 1) / (WEP_CVAR_SEC(hagar, load_max) - 1));
280                 spread_pershot = (1 - (spread_pershot * WEP_CVAR_SEC(hagar, load_spread_bias)));
281                 spread_pershot = (WEP_CVAR_SEC(hagar, spread) * spread_pershot * g_weaponspreadfactor);
282
283                 // pattern spread calculation
284                 s = '0 0 0';
285                 if(counter == 0)
286                         s = '0 0 0';
287                 else
288                 {
289                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
290                         s.y = v_forward.x;
291                         s.z = v_forward.y;
292                 }
293                 s = s * WEP_CVAR_SEC(hagar, load_spread) * g_weaponspreadfactor;
294
295                 W_SetupProjVelocity_Explicit(missile, w_shotdir + right * s.y + up * s.z, v_up, WEP_CVAR_SEC(hagar, speed), 0, 0, spread_pershot, false);
296
297                 missile.angles = vectoangles(missile.velocity);
298                 missile.flags = FL_PROJECTILE;
299                 IL_PUSH(g_projectiles, missile);
300                 IL_PUSH(g_bot_dodge, missile);
301
302                 CSQCProjectile(missile, true, PROJECTILE_HAGAR, true);
303
304                 MUTATOR_CALLHOOK(EditProjectile, actor, missile);
305         }
306
307         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(hagar, load_animtime), w_ready);
308         actor.hagar_loadstep = time + WEP_CVAR_SEC(hagar, refire) * W_WeaponRateFactor(actor);
309         actor.hagar_load = 0;
310 }
311
312 void W_Hagar_Attack2_Load(Weapon thiswep, entity actor, .entity weaponentity)
313 {
314         // loadable hagar secondary attack, must always run each frame
315
316         if(time < game_starttime)
317                 return;
318
319         bool loaded = actor.hagar_load >= WEP_CVAR_SEC(hagar, load_max);
320
321         // this is different than WR_CHECKAMMO when it comes to reloading
322         bool enough_ammo;
323         if(actor.items & IT_UNLIMITED_WEAPON_AMMO)
324                 enough_ammo = true;
325         else if(autocvar_g_balance_hagar_reload_ammo)
326                 enough_ammo = actor.(weapon_load[WEP_HAGAR.m_id]) >= WEP_CVAR_SEC(hagar, ammo);
327         else
328                 enough_ammo = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(hagar, ammo);
329
330         bool stopped = loaded || !enough_ammo;
331
332         if(PHYS_INPUT_BUTTON_ATCK2(actor))
333         {
334                 if(PHYS_INPUT_BUTTON_ATCK(actor) && WEP_CVAR_SEC(hagar, load_abort))
335                 {
336                         if(actor.hagar_load)
337                         {
338                                 // if we pressed primary fire while loading, unload all rockets and abort
339                                 actor.(weaponentity).state = WS_READY;
340                                 W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hagar, ammo) * actor.hagar_load * -1); // give back ammo
341                                 actor.hagar_load = 0;
342                                 sound(actor, CH_WEAPON_A, SND_HAGAR_BEEP, VOL_BASE, ATTN_NORM);
343
344                                 // pause until we can load rockets again, once we re-press the alt fire button
345                                 actor.hagar_loadstep = time + WEP_CVAR_SEC(hagar, load_speed) * W_WeaponRateFactor(actor);
346
347                                 // require letting go of the alt fire button before we can load again
348                                 actor.hagar_loadblock = true;
349                         }
350                 }
351                 else
352                 {
353                         // check if we can attempt to load another rocket
354                         if(!stopped)
355                         {
356                                 if(!actor.hagar_loadblock && actor.hagar_loadstep < time)
357                                 {
358                                         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hagar, ammo));
359                                         actor.(weaponentity).state = WS_INUSE;
360                                         actor.hagar_load += 1;
361                                         sound(actor, CH_WEAPON_B, SND_HAGAR_LOAD, VOL_BASE * 0.8, ATTN_NORM); // sound is too loud according to most
362
363                                         if(actor.hagar_load >= WEP_CVAR_SEC(hagar, load_max))
364                                                 stopped = true;
365                                         else
366                                                 actor.hagar_loadstep = time + WEP_CVAR_SEC(hagar, load_speed) * W_WeaponRateFactor(actor);
367                                 }
368                         }
369                         if(stopped && !actor.hagar_loadbeep && actor.hagar_load) // prevents the beep from playing each frame
370                         {
371                                 // if this is the last rocket we can load, play a beep sound to notify the player
372                                 sound(actor, CH_WEAPON_A, SND_HAGAR_BEEP, VOL_BASE, ATTN_NORM);
373                                 actor.hagar_loadbeep = true;
374                                 actor.hagar_loadstep = time + WEP_CVAR_SEC(hagar, load_hold) * W_WeaponRateFactor(actor);
375                         }
376                 }
377         }
378         else if(actor.hagar_loadblock)
379         {
380                 // the alt fire button has been released, so re-enable loading if blocked
381                 actor.hagar_loadblock = false;
382         }
383
384         if(actor.hagar_load)
385         {
386                 // play warning sound if we're about to release
387                 if(stopped && actor.hagar_loadstep - 0.5 < time && WEP_CVAR_SEC(hagar, load_hold) >= 0)
388                 {
389                         if(!actor.hagar_warning) // prevents the beep from playing each frame
390                         {
391                                 // we're about to automatically release after holding time, play a beep sound to notify the player
392                                 sound(actor, CH_WEAPON_A, SND_HAGAR_BEEP, VOL_BASE, ATTN_NORM);
393                                 actor.hagar_warning = true;
394                         }
395                 }
396
397                 // release if player let go of button or if they've held it in too long
398                 if(!PHYS_INPUT_BUTTON_ATCK2(actor) || (stopped && actor.hagar_loadstep < time && WEP_CVAR_SEC(hagar, load_hold) >= 0))
399                 {
400                         actor.(weaponentity).state = WS_READY;
401                         W_Hagar_Attack2_Load_Release(actor, weaponentity);
402                 }
403         }
404         else
405         {
406                 actor.hagar_loadbeep = false;
407                 actor.hagar_warning = false;
408
409                 // we aren't checking ammo during an attack, so we must do it here
410                 if(!(thiswep.wr_checkammo1(thiswep, actor) + thiswep.wr_checkammo2(thiswep, actor)))
411                 if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
412                 {
413                         // note: this doesn't force the switch
414                         W_SwitchToOtherWeapon(actor);
415                         return;
416                 }
417         }
418 }
419
420 void W_Hagar_Attack_Auto(Weapon thiswep, entity actor, .entity weaponentity, int fire)
421 {
422         if(!(fire & 1) || actor.hagar_load || actor.hagar_loadblock || PS(actor).m_switchweapon != WEP_HAGAR)
423         {
424                 w_ready(thiswep, actor, weaponentity, fire);
425                 return;
426         }
427
428         if(!thiswep.wr_checkammo1(thiswep, actor))
429         if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
430         {
431                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
432                 w_ready(thiswep, actor, weaponentity, fire);
433                 return;
434         }
435
436         W_Hagar_Attack(thiswep, actor, weaponentity);
437
438         int slot = weaponslot(weaponentity);
439         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR_PRI(hagar, refire) * W_WeaponRateFactor(actor);
440         int theframe = WFRAME_FIRE1;
441         entity this = actor.(weaponentity);
442         if(this)
443         {
444                 if(this.wframe == WFRAME_FIRE1)
445                         theframe = WFRAME_DONTCHANGE;
446         }
447         weapon_thinkf(actor, weaponentity, theframe, WEP_CVAR_PRI(hagar, refire), W_Hagar_Attack_Auto);
448 }
449
450 METHOD(Hagar, wr_aim, void(entity thiswep, entity actor))
451 {
452     if(random()>0.15)
453         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, WEP_CVAR_PRI(hagar, speed), 0, WEP_CVAR_PRI(hagar, lifetime), false);
454     else // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
455         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, WEP_CVAR_PRI(hagar, speed), 0, WEP_CVAR_PRI(hagar, lifetime), false);
456 }
457 METHOD(Hagar, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
458 {
459     float loadable_secondary;
460     loadable_secondary = (WEP_CVAR_SEC(hagar, load) && WEP_CVAR(hagar, secondary));
461
462     if(loadable_secondary)
463         W_Hagar_Attack2_Load(thiswep, actor, weaponentity); // must always run each frame
464     if(autocvar_g_balance_hagar_reload_ammo && actor.clip_load < min(WEP_CVAR_PRI(hagar, ammo), WEP_CVAR_SEC(hagar, ammo))) { // forced reload
465         thiswep.wr_reload(thiswep, actor, weaponentity);
466     }
467     else if((fire & 1) && !actor.hagar_load && !actor.hagar_loadblock) // not while secondary is loaded or awaiting reset
468         {
469                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, 0))
470                         W_Hagar_Attack_Auto(thiswep, actor, weaponentity, fire);
471         }
472     else if((fire & 2) && !loadable_secondary && WEP_CVAR(hagar, secondary))
473     {
474         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(hagar, refire)))
475         {
476             W_Hagar_Attack2(thiswep, actor, weaponentity);
477             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(hagar, refire), w_ready);
478         }
479     }
480 }
481 METHOD(Hagar, wr_gonethink, void(entity thiswep, entity actor, .entity weaponentity))
482 {
483     // we lost the weapon and want to prepare switching away
484     if(actor.hagar_load)
485     {
486         actor.(weaponentity).state = WS_READY;
487         W_Hagar_Attack2_Load_Release(actor, weaponentity);
488     }
489 }
490 METHOD(Hagar, wr_setup, void(entity thiswep, entity actor))
491 {
492     actor.hagar_loadblock = false;
493
494     if(actor.hagar_load)
495     {
496         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hagar, ammo) * actor.hagar_load * -1); // give back ammo if necessary
497         actor.hagar_load = 0;
498     }
499 }
500 METHOD(Hagar, wr_checkammo1, bool(entity thiswep, entity actor))
501 {
502     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(hagar, ammo);
503     ammo_amount += actor.(weapon_load[WEP_HAGAR.m_id]) >= WEP_CVAR_PRI(hagar, ammo);
504     return ammo_amount;
505 }
506 METHOD(Hagar, wr_checkammo2, bool(entity thiswep, entity actor))
507 {
508     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(hagar, ammo);
509     ammo_amount += actor.(weapon_load[WEP_HAGAR.m_id]) >= WEP_CVAR_SEC(hagar, ammo);
510     return ammo_amount;
511 }
512 METHOD(Hagar, wr_resetplayer, void(entity thiswep, entity actor))
513 {
514     actor.hagar_load = 0;
515 }
516 METHOD(Hagar, wr_playerdeath, void(entity thiswep, entity actor, .entity weaponentity))
517 {
518     // if we have any rockets loaded when we die, release them
519     if(actor.hagar_load && WEP_CVAR_SEC(hagar, load_releasedeath))
520         W_Hagar_Attack2_Load_Release(actor, weaponentity);
521 }
522 METHOD(Hagar, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
523 {
524     if(!actor.hagar_load) // require releasing loaded rockets first
525         W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(hagar, ammo), WEP_CVAR_SEC(hagar, ammo)), SND_RELOAD);
526 }
527 METHOD(Hagar, wr_suicidemessage, Notification(entity thiswep))
528 {
529     return WEAPON_HAGAR_SUICIDE;
530 }
531 METHOD(Hagar, wr_killmessage, Notification(entity thiswep))
532 {
533     if(w_deathtype & HITTYPE_SECONDARY)
534         return WEAPON_HAGAR_MURDER_BURST;
535     else
536         return WEAPON_HAGAR_MURDER_SPRAY;
537 }
538
539 #endif
540 #ifdef CSQC
541
542 METHOD(Hagar, wr_impacteffect, void(entity thiswep, entity actor))
543 {
544     vector org2;
545     org2 = w_org + w_backoff * 6;
546     pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
547     if(!w_issilent)
548     {
549         if(w_random<0.15)
550             sound(actor, CH_SHOTS, SND_HAGEXP1, VOL_BASE, ATTN_NORM);
551         else if(w_random<0.7)
552             sound(actor, CH_SHOTS, SND_HAGEXP2, VOL_BASE, ATTN_NORM);
553         else
554             sound(actor, CH_SHOTS, SND_HAGEXP3, VOL_BASE, ATTN_NORM);
555     }
556 }
557
558 #endif
559 #endif