qcsrc/common/weapons/weapon/hagar.qc

   1 #include "hagar.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(Hagar, Weapon)
   4 /* ammotype  */ ATTRIB(Hagar, ammo_field, .int, ammo_rockets);
   5 /* impulse   */ ATTRIB(Hagar, impulse, int, 8);
   6 /* flags     */ ATTRIB(Hagar, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   7 /* rating    */ ATTRIB(Hagar, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
   8 /* color     */ ATTRIB(Hagar, wpcolor, vector, '1 1 0.5');
   9 /* modelname */ ATTRIB(Hagar, mdl, string, "hagar");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(Hagar, m_model, Model, MDL_HAGAR_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(Hagar, w_crosshair, string, "gfx/crosshairhagar");
  14 /* crosshair */ ATTRIB(Hagar, w_crosshair_size, float, 0.8);
  15 /* wepimg    */ ATTRIB(Hagar, model2, string, "weaponhagar");
  16 /* refname   */ ATTRIB(Hagar, netname, string, "hagar");
  17 /* wepname   */ ATTRIB(Hagar, m_name, string, _("Hagar"));
  18
  19 #define X(BEGIN, P, END, class, prefix) \
  20         BEGIN(class) \
  21                 P(class, prefix, ammo, float, BOTH) \
  22         P(class, prefix, damageforcescale, float, BOTH) \
  23         P(class, prefix, damage, float, BOTH) \
  24         P(class, prefix, edgedamage, float, BOTH) \
  25         P(class, prefix, force, float, BOTH) \
  26         P(class, prefix, health, float, BOTH) \
  27         P(class, prefix, lifetime, float, PRI) \
  28         P(class, prefix, lifetime_min, float, SEC) \
  29         P(class, prefix, lifetime_rand, float, SEC) \
  30         P(class, prefix, load, float, SEC) \
  31         P(class, prefix, load_abort, float, SEC) \
  32         P(class, prefix, load_animtime, float, SEC) \
  33         P(class, prefix, load_hold, float, SEC) \
  34         P(class, prefix, load_linkexplode, float, SEC) \
  35         P(class, prefix, load_max, float, SEC) \
  36         P(class, prefix, load_releasedeath, float, SEC) \
  37         P(class, prefix, load_speed, float, SEC) \
  38         P(class, prefix, load_spread, float, SEC) \
  39         P(class, prefix, load_spread_bias, float, SEC) \
  40         P(class, prefix, radius, float, BOTH) \
  41         P(class, prefix, refire, float, BOTH) \
  42         P(class, prefix, reload_ammo, float, NONE) \
  43         P(class, prefix, reload_time, float, NONE) \
  44         P(class, prefix, secondary, float, NONE) \
  45         P(class, prefix, speed, float, BOTH) \
  46         P(class, prefix, spread, float, BOTH) \
  47         P(class, prefix, switchdelay_drop, float, NONE) \
  48         P(class, prefix, switchdelay_raise, float, NONE) \
  49         P(class, prefix, weaponreplace, string,NONE) \
  50         P(class, prefix, weaponstartoverride, float, NONE) \
  51         P(class, prefix, weaponstart, float, NONE) \
  52         P(class, prefix, weaponthrowable, float, NONE) \
  53         END()
  54     W_PROPS(X, Hagar, hagar)
  55 #undef X
  56
  57 ENDCLASS(Hagar)
  58 REGISTER_WEAPON(HAGAR, hagar, NEW(Hagar));
  59
  60 #endif
  61 #ifdef IMPLEMENTATION
  62 #ifdef SVQC
  63 spawnfunc(weapon_hagar) { weapon_defaultspawnfunc(this, WEP_HAGAR); }
  64
  65 // NO bounce protection, as bounces are limited!
  66
  67 void W_Hagar_Explode(entity this, entity directhitentity)
  68 {
  69         this.event_damage = func_null;
  70         RadiusDamage(this, this.realowner, WEP_CVAR_PRI(hagar, damage), WEP_CVAR_PRI(hagar, edgedamage), WEP_CVAR_PRI(hagar, radius), NULL, NULL, WEP_CVAR_PRI(hagar, force), this.projectiledeathtype, directhitentity);
  71
  72         delete(this);
  73 }
  74
  75 void W_Hagar_Explode_use(entity this, entity actor, entity trigger)
  76 {
  77         W_Hagar_Explode(this, trigger);
  78 }
  79
  80 void W_Hagar_Explode2(entity this, entity directhitentity)
  81 {
  82         this.event_damage = func_null;
  83         RadiusDamage(this, this.realowner, WEP_CVAR_SEC(hagar, damage), WEP_CVAR_SEC(hagar, edgedamage), WEP_CVAR_SEC(hagar, radius), NULL, NULL, WEP_CVAR_SEC(hagar, force), this.projectiledeathtype, directhitentity);
  84
  85         delete(this);
  86 }
  87
  88 void W_Hagar_Explode2_use(entity this, entity actor, entity trigger)
  89 {
  90         W_Hagar_Explode2(this, trigger);
  91 }
  92
  93 void W_Hagar_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
  94 {
  95         if(this.health <= 0)
  96                 return;
  97
  98         float is_linkexplode = ( ((inflictor.owner != NULL) ? (inflictor.owner == this.owner) : true)
  99                 && (inflictor.projectiledeathtype & HITTYPE_SECONDARY)
 100                 && (this.projectiledeathtype & HITTYPE_SECONDARY));
 101
 102         if(is_linkexplode)
 103                 is_linkexplode = (is_linkexplode && WEP_CVAR_SEC(hagar, load_linkexplode));
 104         else
 105                 is_linkexplode = -1; // not secondary load, so continue as normal without exception.
 106
 107         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, is_linkexplode))
 108                 return; // g_projectiles_damage says to halt
 109
 110         this.health = this.health - damage;
 111         this.angles = vectoangles(this.velocity);
 112
 113         if(this.health <= 0)
 114                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
 115 }
 116
 117 void W_Hagar_Touch(entity this, entity toucher)
 118 {
 119         PROJECTILE_TOUCH(this, toucher);
 120         this.use(this, NULL, toucher);
 121 }
 122
 123 void W_Hagar_Touch2(entity this, entity toucher)
 124 {
 125         PROJECTILE_TOUCH(this, toucher);
 126
 127         if(this.cnt > 0 || toucher.takedamage == DAMAGE_AIM) {
 128                 this.use(this, NULL, toucher);
 129         } else {
 130                 this.cnt++;
 131                 Send_Effect(EFFECT_HAGAR_BOUNCE, this.origin, this.velocity, 1);
 132                 this.angles = vectoangles(this.velocity);
 133                 this.owner = NULL;
 134                 this.projectiledeathtype |= HITTYPE_BOUNCE;
 135         }
 136 }
 137
 138 void W_Hagar_Attack(Weapon thiswep, entity actor, .entity weaponentity)
 139 {
 140         entity missile;
 141
 142         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_PRI(hagar, ammo));
 143
 144         W_SetupShot(actor, weaponentity, false, 2, SND_HAGAR_FIRE, CH_WEAPON_A, WEP_CVAR_PRI(hagar, damage));
 145
 146         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 147
 148         missile = new(missile);
 149         missile.owner = missile.realowner = actor;
 150         missile.bot_dodge = true;
 151         missile.bot_dodgerating = WEP_CVAR_PRI(hagar, damage);
 152
 153         missile.takedamage = DAMAGE_YES;
 154         missile.health = WEP_CVAR_PRI(hagar, health);
 155         missile.damageforcescale = WEP_CVAR_PRI(hagar, damageforcescale);
 156         missile.event_damage = W_Hagar_Damage;
 157         missile.damagedbycontents = true;
 158
 159         settouch(missile, W_Hagar_Touch);
 160         missile.use = W_Hagar_Explode_use;
 161         setthink(missile, adaptor_think2use_hittype_splash);
 162         missile.nextthink = time + WEP_CVAR_PRI(hagar, lifetime);
 163         PROJECTILE_MAKETRIGGER(missile);
 164         missile.projectiledeathtype = WEP_HAGAR.m_id;
 165         setorigin(missile, w_shotorg);
 166         setsize(missile, '0 0 0', '0 0 0');
 167
 168         set_movetype(missile, MOVETYPE_FLY);
 169         W_SetupProjVelocity_PRI(missile, hagar);
 170
 171         missile.angles = vectoangles(missile.velocity);
 172         missile.flags = FL_PROJECTILE;
 173         IL_PUSH(g_projectiles, missile);
 174         missile.missile_flags = MIF_SPLASH;
 175
 176         CSQCProjectile(missile, true, PROJECTILE_HAGAR, true);
 177
 178         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 179 }
 180
 181 void W_Hagar_Attack2(Weapon thiswep, entity actor, .entity weaponentity)
 182 {
 183         entity missile;
 184
 185         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hagar, ammo));
 186
 187         W_SetupShot(actor, weaponentity, false, 2, SND_HAGAR_FIRE, CH_WEAPON_A, WEP_CVAR_SEC(hagar, damage));
 188
 189         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 190
 191         missile = new(missile);
 192         missile.owner = missile.realowner = actor;
 193         missile.bot_dodge = true;
 194         missile.bot_dodgerating = WEP_CVAR_SEC(hagar, damage);
 195
 196         missile.takedamage = DAMAGE_YES;
 197         missile.health = WEP_CVAR_SEC(hagar, health);
 198         missile.damageforcescale = WEP_CVAR_SEC(hagar, damageforcescale);
 199         missile.event_damage = W_Hagar_Damage;
 200         missile.damagedbycontents = true;
 201
 202         settouch(missile, W_Hagar_Touch2);
 203         missile.cnt = 0;
 204         missile.use = W_Hagar_Explode2_use;
 205         setthink(missile, adaptor_think2use_hittype_splash);
 206         missile.nextthink = time + WEP_CVAR_SEC(hagar, lifetime_min) + random() * WEP_CVAR_SEC(hagar, lifetime_rand);
 207         PROJECTILE_MAKETRIGGER(missile);
 208         missile.projectiledeathtype = WEP_HAGAR.m_id | HITTYPE_SECONDARY;
 209         setorigin(missile, w_shotorg);
 210         setsize(missile, '0 0 0', '0 0 0');
 211
 212         set_movetype(missile, MOVETYPE_BOUNCEMISSILE);
 213         W_SetupProjVelocity_SEC(missile, hagar);
 214
 215         missile.angles = vectoangles(missile.velocity);
 216         missile.flags = FL_PROJECTILE;
 217         IL_PUSH(g_projectiles, missile);
 218         missile.missile_flags = MIF_SPLASH;
 219
 220         CSQCProjectile(missile, true, PROJECTILE_HAGAR_BOUNCING, true);
 221
 222         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 223 }
 224
 225 .float hagar_loadstep, hagar_loadblock, hagar_loadbeep, hagar_warning;
 226 void W_Hagar_Attack2_Load_Release(entity actor, .entity weaponentity)
 227 {
 228         // time to release the rockets we've loaded
 229
 230         entity missile;
 231         float counter, shots, spread_pershot;
 232         vector s;
 233         vector forward, right, up;
 234
 235         if(!actor.hagar_load)
 236                 return;
 237
 238         weapon_prepareattack_do(actor, weaponentity, true, WEP_CVAR_SEC(hagar, refire));
 239
 240         W_SetupShot(actor, weaponentity, false, 2, SND_HAGAR_FIRE, CH_WEAPON_A, WEP_CVAR_SEC(hagar, damage));
 241         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 242
 243         forward = v_forward;
 244         right = v_right;
 245         up = v_up;
 246
 247         shots = actor.hagar_load;
 248         missile = NULL;
 249         for(counter = 0; counter < shots; ++counter)
 250         {
 251                 missile = new(missile);
 252                 missile.owner = missile.realowner = actor;
 253                 missile.bot_dodge = true;
 254                 missile.bot_dodgerating = WEP_CVAR_SEC(hagar, damage);
 255
 256                 missile.takedamage = DAMAGE_YES;
 257                 missile.health = WEP_CVAR_SEC(hagar, health);
 258                 missile.damageforcescale = WEP_CVAR_SEC(hagar, damageforcescale);
 259                 missile.event_damage = W_Hagar_Damage;
 260                 missile.damagedbycontents = true;
 261
 262                 settouch(missile, W_Hagar_Touch); // not bouncy
 263                 missile.use = W_Hagar_Explode2_use;
 264                 setthink(missile, adaptor_think2use_hittype_splash);
 265                 missile.nextthink = time + WEP_CVAR_SEC(hagar, lifetime_min) + random() * WEP_CVAR_SEC(hagar, lifetime_rand);
 266                 PROJECTILE_MAKETRIGGER(missile);
 267                 missile.projectiledeathtype = WEP_HAGAR.m_id | HITTYPE_SECONDARY;
 268                 setorigin(missile, w_shotorg);
 269                 setsize(missile, '0 0 0', '0 0 0');
 270                 set_movetype(missile, MOVETYPE_FLY);
 271                 missile.missile_flags = MIF_SPLASH;
 272
 273                 // per-shot spread calculation: the more shots there are, the less spread is applied (based on the bias cvar)
 274                 spread_pershot = ((shots - 1) / (WEP_CVAR_SEC(hagar, load_max) - 1));
 275                 spread_pershot = (1 - (spread_pershot * WEP_CVAR_SEC(hagar, load_spread_bias)));
 276                 spread_pershot = (WEP_CVAR_SEC(hagar, spread) * spread_pershot * g_weaponspreadfactor);
 277
 278                 // pattern spread calculation
 279                 s = '0 0 0';
 280                 if(counter == 0)
 281                         s = '0 0 0';
 282                 else
 283                 {
 284                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 285                         s.y = v_forward.x;
 286                         s.z = v_forward.y;
 287                 }
 288                 s = s * WEP_CVAR_SEC(hagar, load_spread) * g_weaponspreadfactor;
 289
 290                 W_SetupProjVelocity_Explicit(missile, w_shotdir + right * s.y + up * s.z, v_up, WEP_CVAR_SEC(hagar, speed), 0, 0, spread_pershot, false);
 291
 292                 missile.angles = vectoangles(missile.velocity);
 293                 missile.flags = FL_PROJECTILE;
 294                 IL_PUSH(g_projectiles, missile);
 295
 296                 CSQCProjectile(missile, true, PROJECTILE_HAGAR, true);
 297
 298                 MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 299         }
 300
 301         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(hagar, load_animtime), w_ready);
 302         actor.hagar_loadstep = time + WEP_CVAR_SEC(hagar, refire) * W_WeaponRateFactor(actor);
 303         actor.hagar_load = 0;
 304 }
 305
 306 void W_Hagar_Attack2_Load(Weapon thiswep, entity actor, .entity weaponentity)
 307 {
 308         // loadable hagar secondary attack, must always run each frame
 309
 310         if(time < game_starttime)
 311                 return;
 312
 313         bool loaded = actor.hagar_load >= WEP_CVAR_SEC(hagar, load_max);
 314
 315         // this is different than WR_CHECKAMMO when it comes to reloading
 316         bool enough_ammo;
 317         if(actor.items & IT_UNLIMITED_WEAPON_AMMO)
 318                 enough_ammo = true;
 319         else if(autocvar_g_balance_hagar_reload_ammo)
 320                 enough_ammo = actor.(weapon_load[WEP_HAGAR.m_id]) >= WEP_CVAR_SEC(hagar, ammo);
 321         else
 322                 enough_ammo = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(hagar, ammo);
 323
 324         bool stopped = loaded || !enough_ammo;
 325
 326         if(PHYS_INPUT_BUTTON_ATCK2(actor))
 327         {
 328                 if(PHYS_INPUT_BUTTON_ATCK(actor) && WEP_CVAR_SEC(hagar, load_abort))
 329                 {
 330                         if(actor.hagar_load)
 331                         {
 332                                 // if we pressed primary fire while loading, unload all rockets and abort
 333                                 actor.(weaponentity).state = WS_READY;
 334                                 W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hagar, ammo) * actor.hagar_load * -1); // give back ammo
 335                                 actor.hagar_load = 0;
 336                                 sound(actor, CH_WEAPON_A, SND_HAGAR_BEEP, VOL_BASE, ATTN_NORM);
 337
 338                                 // pause until we can load rockets again, once we re-press the alt fire button
 339                                 actor.hagar_loadstep = time + WEP_CVAR_SEC(hagar, load_speed) * W_WeaponRateFactor(actor);
 340
 341                                 // require letting go of the alt fire button before we can load again
 342                                 actor.hagar_loadblock = true;
 343                         }
 344                 }
 345                 else
 346                 {
 347                         // check if we can attempt to load another rocket
 348                         if(!stopped)
 349                         {
 350                                 if(!actor.hagar_loadblock && actor.hagar_loadstep < time)
 351                                 {
 352                                         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hagar, ammo));
 353                                         actor.(weaponentity).state = WS_INUSE;
 354                                         actor.hagar_load += 1;
 355                                         sound(actor, CH_WEAPON_B, SND_HAGAR_LOAD, VOL_BASE * 0.8, ATTN_NORM); // sound is too loud according to most
 356
 357                                         if(actor.hagar_load >= WEP_CVAR_SEC(hagar, load_max))
 358                                                 stopped = true;
 359                                         else
 360                                                 actor.hagar_loadstep = time + WEP_CVAR_SEC(hagar, load_speed) * W_WeaponRateFactor(actor);
 361                                 }
 362                         }
 363                         if(stopped && !actor.hagar_loadbeep && actor.hagar_load) // prevents the beep from playing each frame
 364                         {
 365                                 // if this is the last rocket we can load, play a beep sound to notify the player
 366                                 sound(actor, CH_WEAPON_A, SND_HAGAR_BEEP, VOL_BASE, ATTN_NORM);
 367                                 actor.hagar_loadbeep = true;
 368                                 actor.hagar_loadstep = time + WEP_CVAR_SEC(hagar, load_hold) * W_WeaponRateFactor(actor);
 369                         }
 370                 }
 371         }
 372         else if(actor.hagar_loadblock)
 373         {
 374                 // the alt fire button has been released, so re-enable loading if blocked
 375                 actor.hagar_loadblock = false;
 376         }
 377
 378         if(actor.hagar_load)
 379         {
 380                 // play warning sound if we're about to release
 381                 if(stopped && actor.hagar_loadstep - 0.5 < time && WEP_CVAR_SEC(hagar, load_hold) >= 0)
 382                 {
 383                         if(!actor.hagar_warning) // prevents the beep from playing each frame
 384                         {
 385                                 // we're about to automatically release after holding time, play a beep sound to notify the player
 386                                 sound(actor, CH_WEAPON_A, SND_HAGAR_BEEP, VOL_BASE, ATTN_NORM);
 387                                 actor.hagar_warning = true;
 388                         }
 389                 }
 390
 391                 // release if player let go of button or if they've held it in too long
 392                 if(!PHYS_INPUT_BUTTON_ATCK2(actor) || (stopped && actor.hagar_loadstep < time && WEP_CVAR_SEC(hagar, load_hold) >= 0))
 393                 {
 394                         actor.(weaponentity).state = WS_READY;
 395                         W_Hagar_Attack2_Load_Release(actor, weaponentity);
 396                 }
 397         }
 398         else
 399         {
 400                 actor.hagar_loadbeep = false;
 401                 actor.hagar_warning = false;
 402
 403                 // we aren't checking ammo during an attack, so we must do it here
 404                 if(!(thiswep.wr_checkammo1(thiswep, actor) + thiswep.wr_checkammo2(thiswep, actor)))
 405                 if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 406                 {
 407                         // note: this doesn't force the switch
 408                         W_SwitchToOtherWeapon(actor);
 409                         return;
 410                 }
 411         }
 412 }
 413
 414 void W_Hagar_Attack_Auto(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 415 {
 416         if(!(fire & 1) || actor.hagar_load || actor.hagar_loadblock)
 417         {
 418                 w_ready(thiswep, actor, weaponentity, fire);
 419                 return;
 420         }
 421
 422         if(!thiswep.wr_checkammo1(thiswep, actor))
 423         if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 424         {
 425                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
 426                 w_ready(thiswep, actor, weaponentity, fire);
 427                 return;
 428         }
 429
 430         W_Hagar_Attack(thiswep, actor, weaponentity);
 431
 432         int slot = weaponslot(weaponentity);
 433         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR_PRI(hagar, refire) * W_WeaponRateFactor(actor);
 434         int theframe = WFRAME_FIRE1;
 435         entity this = actor.(weaponentity);
 436         if(this)
 437         {
 438                 if(this.wframe == WFRAME_FIRE1)
 439                         theframe = WFRAME_DONTCHANGE;
 440         }
 441         weapon_thinkf(actor, weaponentity, theframe, WEP_CVAR_PRI(hagar, refire), W_Hagar_Attack_Auto);
 442 }
 443
 444 METHOD(Hagar, wr_aim, void(entity thiswep, entity actor))
 445 {
 446     if(random()>0.15)
 447         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, WEP_CVAR_PRI(hagar, speed), 0, WEP_CVAR_PRI(hagar, lifetime), false);
 448     else // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 449         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, WEP_CVAR_PRI(hagar, speed), 0, WEP_CVAR_PRI(hagar, lifetime), false);
 450 }
 451 METHOD(Hagar, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 452 {
 453     float loadable_secondary;
 454     loadable_secondary = (WEP_CVAR_SEC(hagar, load) && WEP_CVAR(hagar, secondary));
 455
 456     if(loadable_secondary)
 457         W_Hagar_Attack2_Load(thiswep, actor, weaponentity); // must always run each frame
 458     if(autocvar_g_balance_hagar_reload_ammo && actor.clip_load < min(WEP_CVAR_PRI(hagar, ammo), WEP_CVAR_SEC(hagar, ammo))) { // forced reload
 459         thiswep.wr_reload(thiswep, actor, weaponentity);
 460     }
 461     else if((fire & 1) && !actor.hagar_load && !actor.hagar_loadblock) // not while secondary is loaded or awaiting reset
 462         {
 463                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, 0))
 464                         W_Hagar_Attack_Auto(thiswep, actor, weaponentity, fire);
 465         }
 466     else if((fire & 2) && !loadable_secondary && WEP_CVAR(hagar, secondary))
 467     {
 468         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(hagar, refire)))
 469         {
 470             W_Hagar_Attack2(thiswep, actor, weaponentity);
 471             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(hagar, refire), w_ready);
 472         }
 473     }
 474 }
 475 METHOD(Hagar, wr_gonethink, void(entity thiswep, entity actor, .entity weaponentity))
 476 {
 477     // we lost the weapon and want to prepare switching away
 478     if(actor.hagar_load)
 479     {
 480         actor.(weaponentity).state = WS_READY;
 481         W_Hagar_Attack2_Load_Release(actor, weaponentity);
 482     }
 483 }
 484 METHOD(Hagar, wr_setup, void(entity thiswep, entity actor))
 485 {
 486     actor.hagar_loadblock = false;
 487
 488     if(actor.hagar_load)
 489     {
 490         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hagar, ammo) * actor.hagar_load * -1); // give back ammo if necessary
 491         actor.hagar_load = 0;
 492     }
 493 }
 494 METHOD(Hagar, wr_checkammo1, bool(entity thiswep, entity actor))
 495 {
 496     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(hagar, ammo);
 497     ammo_amount += actor.(weapon_load[WEP_HAGAR.m_id]) >= WEP_CVAR_PRI(hagar, ammo);
 498     return ammo_amount;
 499 }
 500 METHOD(Hagar, wr_checkammo2, bool(entity thiswep, entity actor))
 501 {
 502     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(hagar, ammo);
 503     ammo_amount += actor.(weapon_load[WEP_HAGAR.m_id]) >= WEP_CVAR_SEC(hagar, ammo);
 504     return ammo_amount;
 505 }
 506 METHOD(Hagar, wr_resetplayer, void(entity thiswep, entity actor))
 507 {
 508     actor.hagar_load = 0;
 509 }
 510 METHOD(Hagar, wr_playerdeath, void(entity thiswep, entity actor, .entity weaponentity))
 511 {
 512     // if we have any rockets loaded when we die, release them
 513     if(actor.hagar_load && WEP_CVAR_SEC(hagar, load_releasedeath))
 514         W_Hagar_Attack2_Load_Release(actor, weaponentity);
 515 }
 516 METHOD(Hagar, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 517 {
 518     if(!actor.hagar_load) // require releasing loaded rockets first
 519         W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(hagar, ammo), WEP_CVAR_SEC(hagar, ammo)), SND_RELOAD);
 520 }
 521 METHOD(Hagar, wr_suicidemessage, Notification(entity thiswep))
 522 {
 523     return WEAPON_HAGAR_SUICIDE;
 524 }
 525 METHOD(Hagar, wr_killmessage, Notification(entity thiswep))
 526 {
 527     if(w_deathtype & HITTYPE_SECONDARY)
 528         return WEAPON_HAGAR_MURDER_BURST;
 529     else
 530         return WEAPON_HAGAR_MURDER_SPRAY;
 531 }
 532
 533 #endif
 534 #ifdef CSQC
 535
 536 METHOD(Hagar, wr_impacteffect, void(entity thiswep, entity actor))
 537 {
 538     vector org2;
 539     org2 = w_org + w_backoff * 6;
 540     pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 541     if(!w_issilent)
 542     {
 543         if(w_random<0.15)
 544             sound(actor, CH_SHOTS, SND_HAGEXP1, VOL_BASE, ATTN_NORM);
 545         else if(w_random<0.7)
 546             sound(actor, CH_SHOTS, SND_HAGEXP2, VOL_BASE, ATTN_NORM);
 547         else
 548             sound(actor, CH_SHOTS, SND_HAGEXP3, VOL_BASE, ATTN_NORM);
 549     }
 550 }
 551
 552 #endif
 553 #endif