qcsrc/common/weapons/weapon/minelayer.qc

   1 #include "minelayer.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(MineLayer, Weapon)
   4 /* ammotype  */ ATTRIB(MineLayer, ammo_field, .int, ammo_rockets);
   5 /* impulse   */ ATTRIB(MineLayer, impulse, int, 4);
   6 /* flags     */ ATTRIB(MineLayer, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH);
   7 /* rating    */ ATTRIB(MineLayer, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   8 /* color     */ ATTRIB(MineLayer, wpcolor, vector, '0.75 1 0');
   9 /* modelname */ ATTRIB(MineLayer, mdl, string, "minelayer");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(MineLayer, m_model, Model, MDL_MINELAYER_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(MineLayer, w_crosshair, string, "gfx/crosshairminelayer");
  14 /* crosshair */ ATTRIB(MineLayer, w_crosshair_size, float, 0.9);
  15 /* wepimg    */ ATTRIB(MineLayer, model2, string, "weaponminelayer");
  16 /* refname   */ ATTRIB(MineLayer, netname, string, "minelayer");
  17 /* wepname   */ ATTRIB(MineLayer, m_name, string, _("Mine Layer"));
  18
  19 #define X(BEGIN, P, END, class, prefix) \
  20         BEGIN(class) \
  21                 P(class, prefix, ammo, float, NONE) \
  22                 P(class, prefix, animtime, float, NONE) \
  23                 P(class, prefix, damageforcescale, float, NONE) \
  24                 P(class, prefix, damage, float, NONE) \
  25                 P(class, prefix, detonatedelay, float, NONE) \
  26                 P(class, prefix, edgedamage, float, NONE) \
  27                 P(class, prefix, force, float, NONE) \
  28                 P(class, prefix, health, float, NONE) \
  29                 P(class, prefix, lifetime, float, NONE) \
  30                 P(class, prefix, lifetime_countdown, float, NONE) \
  31                 P(class, prefix, limit, float, NONE) \
  32                 P(class, prefix, protection, float, NONE) \
  33                 P(class, prefix, proximityradius, float, NONE) \
  34                 P(class, prefix, radius, float, NONE) \
  35                 P(class, prefix, refire, float, NONE) \
  36                 P(class, prefix, reload_ammo, float, NONE) \
  37         P(class, prefix, reload_time, float, NONE) \
  38                 P(class, prefix, remote_damage, float, NONE) \
  39                 P(class, prefix, remote_edgedamage, float, NONE) \
  40                 P(class, prefix, remote_force, float, NONE) \
  41                 P(class, prefix, remote_radius, float, NONE) \
  42                 P(class, prefix, speed, float, NONE) \
  43         P(class, prefix, switchdelay_drop, float, NONE) \
  44         P(class, prefix, switchdelay_raise, float, NONE) \
  45                 P(class, prefix, time, float, NONE) \
  46         P(class, prefix, weaponreplace, string, NONE) \
  47         P(class, prefix, weaponstartoverride, float, NONE) \
  48         P(class, prefix, weaponstart, float, NONE) \
  49         P(class, prefix, weaponthrowable, float, NONE) \
  50         END()
  51     W_PROPS(X, MineLayer, minelayer)
  52 #undef X
  53 ENDCLASS(MineLayer)
  54 REGISTER_WEAPON(MINE_LAYER, minelayer, NEW(MineLayer));
  55
  56 #ifdef SVQC
  57 void W_MineLayer_Think(entity this);
  58 .float minelayer_detonate, mine_explodeanyway;
  59 .float mine_time;
  60 .vector mine_orientation;
  61 #endif
  62 #endif
  63 #ifdef IMPLEMENTATION
  64 #ifdef SVQC
  65 spawnfunc(weapon_minelayer) { weapon_defaultspawnfunc(this, WEP_MINE_LAYER); }
  66
  67 void W_MineLayer_Stick(entity this, entity to)
  68 {
  69         spamsound(this, CH_SHOTS, SND(MINE_STICK), VOL_BASE, ATTN_NORM);
  70
  71         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  72
  73         entity newmine = spawn();
  74         IL_PUSH(g_mines, newmine);
  75         newmine.weaponentity_fld = this.weaponentity_fld;
  76         newmine.classname = this.classname;
  77
  78         newmine.bot_dodge = this.bot_dodge;
  79         newmine.bot_dodgerating = this.bot_dodgerating;
  80
  81         newmine.owner = this.owner;
  82         newmine.realowner = this.realowner;
  83         setsize(newmine, '-4 -4 -4', '4 4 4');
  84         setorigin(newmine, this.origin);
  85         setmodel(newmine, MDL_MINELAYER_MINE);
  86         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  87
  88         newmine.mine_orientation = -trace_plane_normal;
  89
  90         newmine.takedamage = this.takedamage;
  91         newmine.damageforcescale = this.damageforcescale;
  92         newmine.health = this.health;
  93         newmine.event_damage = this.event_damage;
  94         newmine.spawnshieldtime = this.spawnshieldtime;
  95         newmine.damagedbycontents = true;
  96
  97         set_movetype(newmine, MOVETYPE_NONE); // lock the mine in place
  98         newmine.projectiledeathtype = this.projectiledeathtype;
  99
 100         newmine.mine_time = this.mine_time;
 101
 102         settouch(newmine, func_null);
 103         setthink(newmine, W_MineLayer_Think);
 104         newmine.nextthink = time;
 105         newmine.cnt = this.cnt;
 106         newmine.flags = this.flags;
 107         IL_PUSH(g_projectiles, newmine);
 108         IL_PUSH(g_bot_dodge, newmine);
 109
 110         delete(this);
 111
 112         if(to)
 113                 SetMovetypeFollow(newmine, to);
 114 }
 115
 116 void W_MineLayer_Explode(entity this, entity directhitentity)
 117 {
 118         if(directhitentity.takedamage == DAMAGE_AIM)
 119                 if(IS_PLAYER(directhitentity))
 120                         if(DIFF_TEAM(this.realowner, directhitentity))
 121                                 if(!IS_DEAD(directhitentity))
 122                                         if(IsFlying(directhitentity))
 123                                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 124
 125         this.event_damage = func_null;
 126         this.takedamage = DAMAGE_NO;
 127
 128         RadiusDamage(this, this.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), NULL, NULL, WEP_CVAR(minelayer, force), this.projectiledeathtype, directhitentity);
 129
 130         .entity weaponentity = this.weaponentity_fld;
 131         if(this.realowner.(weaponentity).m_weapon == WEP_MINE_LAYER)
 132         {
 133                 entity own = this.realowner;
 134                 Weapon w = WEP_MINE_LAYER;
 135                 if(!w.wr_checkammo1(w, own, weaponentity))
 136                 {
 137                         own.cnt = WEP_MINE_LAYER.m_id;
 138                         int slot = weaponslot(weaponentity);
 139                         ATTACK_FINISHED(own, slot) = time;
 140                         own.(weaponentity).m_switchweapon = w_getbestweapon(own, weaponentity);
 141                 }
 142         }
 143         this.realowner.minelayer_mines -= 1;
 144         delete(this);
 145 }
 146
 147 void W_MineLayer_Explode_think(entity this)
 148 {
 149         W_MineLayer_Explode(this, NULL);
 150 }
 151
 152 void W_MineLayer_DoRemoteExplode(entity this)
 153 {
 154         this.event_damage = func_null;
 155         this.takedamage = DAMAGE_NO;
 156
 157         if(this.move_movetype == MOVETYPE_NONE || this.move_movetype == MOVETYPE_FOLLOW)
 158                 this.velocity = this.mine_orientation; // particle fx and decals need .velocity
 159
 160         RadiusDamage(this, this.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), NULL, NULL, WEP_CVAR(minelayer, remote_force), this.projectiledeathtype | HITTYPE_BOUNCE, NULL);
 161
 162         .entity weaponentity = this.weaponentity_fld;
 163         if(this.realowner.(weaponentity).m_weapon == WEP_MINE_LAYER)
 164         {
 165                 entity own = this.realowner;
 166                 Weapon w = WEP_MINE_LAYER;
 167                 if(!w.wr_checkammo1(w, own, weaponentity))
 168                 {
 169                         own.cnt = WEP_MINE_LAYER.m_id;
 170                         int slot = weaponslot(weaponentity);
 171                         ATTACK_FINISHED(own, slot) = time;
 172                         own.(weaponentity).m_switchweapon = w_getbestweapon(own, weaponentity);
 173                 }
 174         }
 175         this.realowner.minelayer_mines -= 1;
 176         delete(this);
 177 }
 178
 179 void W_MineLayer_RemoteExplode(entity this)
 180 {
 181         if(!IS_DEAD(this.realowner))
 182                 if((this.spawnshieldtime >= 0)
 183                         ? (time >= this.spawnshieldtime) // timer
 184                         : (vdist(NearestPointOnBox(this.realowner, this.origin) - this.origin, >, WEP_CVAR(minelayer, remote_radius))) // safety device
 185                 )
 186                 {
 187                         W_MineLayer_DoRemoteExplode(this);
 188                 }
 189 }
 190
 191 void W_MineLayer_ProximityExplode(entity this)
 192 {
 193         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 194         if(WEP_CVAR(minelayer, protection) && this.mine_explodeanyway == 0)
 195         {
 196                 entity head;
 197                 head = findradius(this.origin, WEP_CVAR(minelayer, radius));
 198                 while(head)
 199                 {
 200                         if(head == this.realowner || SAME_TEAM(head, this.realowner))
 201                                 return;
 202                         head = head.chain;
 203                 }
 204         }
 205
 206         this.mine_time = 0;
 207         W_MineLayer_Explode(this, NULL);
 208 }
 209
 210 int W_MineLayer_Count(entity e)
 211 {
 212         int minecount = 0;
 213         IL_EACH(g_mines, it.realowner == e,
 214         {
 215                 minecount += 1;
 216         });
 217
 218         return minecount;
 219 }
 220
 221 void W_MineLayer_Think(entity this)
 222 {
 223         entity head;
 224
 225         this.nextthink = time;
 226
 227         if(this.move_movetype == MOVETYPE_FOLLOW)
 228         {
 229                 if(LostMovetypeFollow(this))
 230                 {
 231                         UnsetMovetypeFollow(this);
 232                         set_movetype(this, MOVETYPE_NONE);
 233                 }
 234         }
 235
 236         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 237         // TODO: replace this mine_trigger.wav sound with a real countdown
 238         if((time > this.cnt) && (!this.mine_time) && (this.cnt > 0))
 239         {
 240                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 241                         spamsound(this, CH_SHOTS, SND(MINE_TRIGGER), VOL_BASE, ATTN_NORM);
 242                 this.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 243                 this.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 244         }
 245
 246         // a player's mines shall explode if he disconnects or dies
 247         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 248         if(!IS_PLAYER(this.realowner) || IS_DEAD(this.realowner) || STAT(FROZEN, this.realowner))
 249         {
 250                 this.projectiledeathtype |= HITTYPE_BOUNCE;
 251                 W_MineLayer_Explode(this, NULL);
 252                 return;
 253         }
 254
 255         // set the mine for detonation when a foe gets close enough
 256         head = findradius(this.origin, WEP_CVAR(minelayer, proximityradius));
 257         while(head)
 258         {
 259                 if(IS_PLAYER(head) && !IS_DEAD(head) && !STAT(FROZEN, head))
 260                 if(head != this.realowner && DIFF_TEAM(head, this.realowner)) // don't trigger for team mates
 261                 if(!this.mine_time)
 262                 {
 263                         spamsound(this, CH_SHOTS, SND(MINE_TRIGGER), VOL_BASE, ATTN_NORM);
 264                         this.mine_time = time + WEP_CVAR(minelayer, time);
 265                 }
 266                 head = head.chain;
 267         }
 268
 269         // explode if it's time to
 270         if(this.mine_time && time >= this.mine_time)
 271         {
 272                 W_MineLayer_ProximityExplode(this);
 273                 return;
 274         }
 275
 276         // remote detonation
 277         .entity weaponentity = this.weaponentity_fld;
 278         if(this.realowner.(weaponentity).m_weapon == WEP_MINE_LAYER)
 279         if(!IS_DEAD(this.realowner))
 280         if(this.minelayer_detonate)
 281                 W_MineLayer_RemoteExplode(this);
 282 }
 283
 284 void W_MineLayer_Touch(entity this, entity toucher)
 285 {
 286         if(this.move_movetype == MOVETYPE_NONE || this.move_movetype == MOVETYPE_FOLLOW)
 287                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 288
 289         if(WarpZone_Projectile_Touch(this, toucher))
 290         {
 291                 if(wasfreed(this))
 292                         this.realowner.minelayer_mines -= 1;
 293                 return;
 294         }
 295
 296         if(toucher && IS_PLAYER(toucher) && !IS_DEAD(toucher))
 297         {
 298                 // hit a player
 299                 // don't stick
 300         }
 301         else
 302         {
 303                 W_MineLayer_Stick(this, toucher);
 304         }
 305 }
 306
 307 void W_MineLayer_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 308 {
 309         if(this.health <= 0)
 310                 return;
 311
 312         float is_from_enemy = (inflictor.realowner != this.realowner);
 313
 314         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 315                 return; // g_projectiles_damage says to halt
 316
 317         this.health = this.health - damage;
 318         this.angles = vectoangles(this.velocity);
 319
 320         if(this.health <= 0)
 321                 W_PrepareExplosionByDamage(this, attacker, W_MineLayer_Explode_think);
 322 }
 323
 324 void W_MineLayer_Attack(Weapon thiswep, entity actor, .entity weaponentity)
 325 {
 326         entity mine;
 327         entity flash;
 328
 329         // scan how many mines we placed, and return if we reached our limit
 330         if(WEP_CVAR(minelayer, limit))
 331         {
 332                 if(actor.minelayer_mines >= WEP_CVAR(minelayer, limit))
 333                 {
 334                         // the refire delay keeps this message from being spammed
 335                         Send_Notification(NOTIF_ONE, actor, MSG_MULTI, WEAPON_MINELAYER_LIMIT, WEP_CVAR(minelayer, limit));
 336                         play2(actor, SND(UNAVAILABLE));
 337                         return;
 338                 }
 339         }
 340
 341         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(minelayer, ammo), weaponentity);
 342
 343         W_SetupShot_ProjectileSize(actor, weaponentity, '-4 -4 -4', '4 4 4', false, 5, SND_MINE_FIRE, CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 344         Send_Effect(EFFECT_ROCKET_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 345
 346         mine = WarpZone_RefSys_SpawnSameRefSys(actor);
 347         mine.weaponentity_fld = weaponentity;
 348         IL_PUSH(g_mines, mine);
 349         mine.owner = mine.realowner = actor;
 350         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 351                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 352         else
 353                 mine.spawnshieldtime = -1;
 354         mine.classname = "mine";
 355         mine.bot_dodge = true;
 356         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 357
 358         mine.takedamage = DAMAGE_YES;
 359         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 360         mine.health = WEP_CVAR(minelayer, health);
 361         mine.event_damage = W_MineLayer_Damage;
 362         mine.damagedbycontents = true;
 363
 364         set_movetype(mine, MOVETYPE_TOSS);
 365         PROJECTILE_MAKETRIGGER(mine);
 366         mine.projectiledeathtype = WEP_MINE_LAYER.m_id;
 367         setsize(mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 368
 369         setorigin(mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 370         W_SetupProjVelocity_Basic(mine, WEP_CVAR(minelayer, speed), 0);
 371         mine.angles = vectoangles(mine.velocity);
 372
 373         settouch(mine, W_MineLayer_Touch);
 374         setthink(mine, W_MineLayer_Think);
 375         mine.nextthink = time;
 376         mine.cnt = (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 377         mine.flags = FL_PROJECTILE;
 378         IL_PUSH(g_projectiles, mine);
 379         IL_PUSH(g_bot_dodge, mine);
 380         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 381
 382         if(mine.cnt > 0) { mine.cnt += time; }
 383
 384         CSQCProjectile(mine, true, PROJECTILE_MINE, true);
 385
 386         // muzzle flash for 1st person view
 387         flash = spawn();
 388         setmodel(flash, MDL_MINELAYER_MUZZLEFLASH); // precision set below
 389         SUB_SetFade(flash, time, 0.1);
 390         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 391         W_AttachToShotorg(actor, weaponentity, flash, '5 0 0');
 392
 393         // common properties
 394
 395         MUTATOR_CALLHOOK(EditProjectile, actor, mine);
 396
 397         actor.minelayer_mines = W_MineLayer_Count(actor);
 398 }
 399
 400 bool W_MineLayer_PlacedMines(entity this, bool detonate)
 401 {
 402         bool minfound = false;
 403
 404         IL_EACH(g_mines, it.realowner == this,
 405         {
 406                 if(detonate)
 407                 {
 408                         if(!it.minelayer_detonate)
 409                         {
 410                                 it.minelayer_detonate = true;
 411                                 minfound = true;
 412                         }
 413                 }
 414                 else
 415                         minfound = true;
 416         });
 417         return minfound;
 418 }
 419
 420 METHOD(MineLayer, wr_aim, void(entity thiswep, entity actor))
 421 {
 422     // aim and decide to fire if appropriate
 423     if(actor.minelayer_mines >= WEP_CVAR(minelayer, limit))
 424         PHYS_INPUT_BUTTON_ATCK(actor) = false;
 425     else
 426         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), false);
 427     if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 428     {
 429         // decide whether to detonate mines
 430         float edgedamage, coredamage, edgeradius, recipricoledgeradius;
 431         float selfdamage, teamdamage, enemydamage;
 432         edgedamage = WEP_CVAR(minelayer, edgedamage);
 433         coredamage = WEP_CVAR(minelayer, damage);
 434         edgeradius = WEP_CVAR(minelayer, radius);
 435         recipricoledgeradius = 1 / edgeradius;
 436         selfdamage = 0;
 437         teamdamage = 0;
 438         enemydamage = 0;
 439
 440         IL_EACH(g_mines, it.realowner == actor,
 441         {
 442                 entity mine = it;
 443                 IL_EACH(g_bot_targets, it.bot_attack,
 444                 {
 445                         float d = vlen(it.origin + (it.mins + it.maxs) * 0.5 - mine.origin);
 446                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 447                 // count potential damage according to type of target
 448                 if(it == actor)
 449                     selfdamage = selfdamage + d;
 450                 else if(SAME_TEAM(it, actor))
 451                     teamdamage = teamdamage + d;
 452                 else if(bot_shouldattack(actor, it))
 453                     enemydamage = enemydamage + d;
 454                 });
 455         });
 456
 457         float desirabledamage;
 458         desirabledamage = enemydamage;
 459         if(time > actor.invincible_finished && time > actor.spawnshieldtime)
 460             desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 461         if(teamplay && actor.team)
 462             desirabledamage = desirabledamage - teamdamage;
 463
 464         makevectors(actor.v_angle);
 465         IL_EACH(g_mines, it.realowner == actor,
 466         {
 467             if(skill > 9) // normal players only do this for the target they are tracking
 468             {
 469                     entity mine = it;
 470                     IL_EACH(g_bot_targets, it.bot_attack,
 471                     {
 472                         if((v_forward * normalize(mine.origin - it.origin) < 0.1)
 473                             && desirabledamage > 0.1 * coredamage
 474                             ) PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 475                     });
 476                 }
 477                 else
 478                 {
 479                 //As the distance gets larger, a correct detonation gets near imposible
 480                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 481                 if((v_forward * normalize(it.origin - actor.enemy.origin) < 0.1)
 482                         && IS_PLAYER(actor.enemy)
 483                         && (desirabledamage >= 0.1 * coredamage)
 484                         )
 485                 {
 486                         float distance = bound(300, vlen(actor.origin - actor.enemy.origin), 30000);
 487                         if(random() / distance * 300 > frametime * bound(0, (10 - skill) * 0.2, 1))
 488                                 PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 489                 }
 490                 }
 491         });
 492
 493         // if we would be doing at X percent of the core damage, detonate it
 494         // but don't fire a new shot at the same time!
 495         if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 496             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 497         if((skill > 6.5) && (selfdamage > actor.health))
 498             PHYS_INPUT_BUTTON_ATCK2(actor) = false;
 499         //if(PHYS_INPUT_BUTTON_ATCK2(actor) == true)
 500         //      dprint(ftos(desirabledamage),"\n");
 501         if(PHYS_INPUT_BUTTON_ATCK2(actor)) PHYS_INPUT_BUTTON_ATCK(actor) = false;
 502     }
 503 }
 504 METHOD(MineLayer, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 505 {
 506     if(autocvar_g_balance_minelayer_reload_ammo && actor.(weaponentity).clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 507     {
 508         // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 509         if(!(W_MineLayer_PlacedMines(actor, false) && actor.(thiswep.ammo_field) < WEP_CVAR(minelayer, ammo))) {
 510             thiswep.wr_reload(thiswep, actor, weaponentity);
 511         }
 512     }
 513     else if(fire & 1)
 514     {
 515         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(minelayer, refire)))
 516         {
 517             W_MineLayer_Attack(thiswep, actor, weaponentity);
 518             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 519         }
 520     }
 521
 522     if(fire & 2)
 523     {
 524         if(W_MineLayer_PlacedMines(actor, true))
 525             sound(actor, CH_WEAPON_B, SND_MINE_DET, VOL_BASE, ATTN_NORM);
 526     }
 527 }
 528 METHOD(MineLayer, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 529 {
 530     //int slot = 0; // TODO: unhardcode
 531     // actually do // don't switch while placing a mine
 532     //if(ATTACK_FINISHED(actor, slot) <= time || PS(actor).m_weapon != WEP_MINE_LAYER)
 533     //{
 534         float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(minelayer, ammo);
 535         ammo_amount += actor.(weapon_load[WEP_MINE_LAYER.m_id]) >= WEP_CVAR(minelayer, ammo);
 536         return ammo_amount;
 537     //}
 538     //return true;
 539 }
 540 METHOD(MineLayer, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 541 {
 542     if(W_MineLayer_PlacedMines(actor, false))
 543         return true;
 544     else
 545         return false;
 546 }
 547 METHOD(MineLayer, wr_resetplayer, void(entity thiswep, entity actor))
 548 {
 549     actor.minelayer_mines = 0;
 550 }
 551 METHOD(MineLayer, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 552 {
 553     W_Reload(actor, weaponentity, WEP_CVAR(minelayer, ammo), SND_RELOAD);
 554 }
 555 METHOD(MineLayer, wr_suicidemessage, Notification(entity thiswep))
 556 {
 557     return WEAPON_MINELAYER_SUICIDE;
 558 }
 559 METHOD(MineLayer, wr_killmessage, Notification(entity thiswep))
 560 {
 561     return WEAPON_MINELAYER_MURDER;
 562 }
 563
 564 #endif
 565 #ifdef CSQC
 566
 567 METHOD(MineLayer, wr_impacteffect, void(entity thiswep, entity actor))
 568 {
 569     vector org2;
 570     org2 = w_org + w_backoff * 12;
 571     pointparticles(EFFECT_ROCKET_EXPLODE, org2, '0 0 0', 1);
 572     if(!w_issilent)
 573         sound(actor, CH_SHOTS, SND_MINE_EXP, VOL_BASE, ATTN_NORM);
 574 }
 575
 576 #endif
 577 #endif