qcsrc/common/weapons/weapon/mortar.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ MORTAR,
   4 /* function  */ W_Mortar,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 4,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* color     */ '1 0 0',
  10 /* modelname */ "gl",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairgrenadelauncher 0.7",
  13 /* wepimg    */ "weapongrenadelauncher",
  14 /* refname   */ "mortar",
  15 /* wepname   */ _("Mortar")
  16 );
  17
  18 #define MORTAR_SETTINGS(w_cvar,w_prop) MORTAR_SETTINGS_LIST(w_cvar, w_prop, MORTAR, mortar)
  19 #define MORTAR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, BOTH, ammo) \
  21         w_cvar(id, sn, BOTH, animtime) \
  22         w_cvar(id, sn, NONE, bouncefactor) \
  23         w_cvar(id, sn, NONE, bouncestop) \
  24         w_cvar(id, sn, BOTH, damage) \
  25         w_cvar(id, sn, BOTH, damageforcescale) \
  26         w_cvar(id, sn, BOTH, edgedamage) \
  27         w_cvar(id, sn, BOTH, force) \
  28         w_cvar(id, sn, BOTH, health) \
  29         w_cvar(id, sn, BOTH, lifetime) \
  30         w_cvar(id, sn, SEC,  lifetime_bounce) \
  31         w_cvar(id, sn, BOTH, lifetime_stick) \
  32         w_cvar(id, sn, BOTH, radius) \
  33         w_cvar(id, sn, BOTH, refire) \
  34         w_cvar(id, sn, SEC,  remote_detonateprimary) \
  35         w_cvar(id, sn, PRI,  remote_minbouncecnt) \
  36         w_cvar(id, sn, BOTH, speed) \
  37         w_cvar(id, sn, BOTH, speed_up) \
  38         w_cvar(id, sn, BOTH, speed_z) \
  39         w_cvar(id, sn, BOTH, spread) \
  40         w_cvar(id, sn, BOTH, type) \
  41         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  42         w_prop(id, sn, float,  reloading_time, reload_time) \
  43         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  44         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  45         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  46         w_prop(id, sn, float,  weaponstart, weaponstart) \
  47         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  48         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  49
  50 #ifdef SVQC
  51 MORTAR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  52 .float gl_detonate_later;
  53 .float gl_bouncecnt;
  54 #endif
  55 #endif
  56 #ifdef IMPLEMENTATION
  57 #ifdef SVQC
  58
  59 void spawnfunc_weapon_mortar(void) { weapon_defaultspawnfunc(WEP_MORTAR.m_id); }
  60 void spawnfunc_weapon_grenadelauncher(void) { spawnfunc_weapon_mortar(); }
  61
  62 void W_Mortar_Grenade_Explode(void)
  63 {SELFPARAM();
  64         if(other.takedamage == DAMAGE_AIM)
  65                 if(IS_PLAYER(other))
  66                         if(DIFF_TEAM(self.realowner, other))
  67                                 if(other.deadflag == DEAD_NO)
  68                                         if(IsFlying(other))
  69                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  70
  71         self.event_damage = func_null;
  72         self.takedamage = DAMAGE_NO;
  73
  74         if(self.movetype == MOVETYPE_NONE)
  75                 self.velocity = self.oldvelocity;
  76
  77         RadiusDamage(self, self.realowner, WEP_CVAR_PRI(mortar, damage), WEP_CVAR_PRI(mortar, edgedamage), WEP_CVAR_PRI(mortar, radius), world, world, WEP_CVAR_PRI(mortar, force), self.projectiledeathtype, other);
  78
  79         remove(self);
  80 }
  81
  82 void W_Mortar_Grenade_Explode2(void)
  83 {SELFPARAM();
  84         if(other.takedamage == DAMAGE_AIM)
  85                 if(IS_PLAYER(other))
  86                         if(DIFF_TEAM(self.realowner, other))
  87                                 if(other.deadflag == DEAD_NO)
  88                                         if(IsFlying(other))
  89                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  90
  91         self.event_damage = func_null;
  92         self.takedamage = DAMAGE_NO;
  93
  94         if(self.movetype == MOVETYPE_NONE)
  95                 self.velocity = self.oldvelocity;
  96
  97         RadiusDamage(self, self.realowner, WEP_CVAR_SEC(mortar, damage), WEP_CVAR_SEC(mortar, edgedamage), WEP_CVAR_SEC(mortar, radius), world, world, WEP_CVAR_SEC(mortar, force), self.projectiledeathtype, other);
  98
  99         remove(self);
 100 }
 101
 102
 103 void W_Mortar_Grenade_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 104 {SELFPARAM();
 105         if(self.health <= 0)
 106                 return;
 107
 108         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 109                 return; // g_projectiles_damage says to halt
 110
 111         self.health = self.health - damage;
 112
 113         if(self.health <= 0)
 114                 W_PrepareExplosionByDamage(attacker, self.use);
 115 }
 116
 117 void W_Mortar_Grenade_Think1(void)
 118 {SELFPARAM();
 119         self.nextthink = time;
 120         if(time > self.cnt)
 121         {
 122                 other = world;
 123                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 124                 W_Mortar_Grenade_Explode();
 125                 return;
 126         }
 127         if(self.gl_detonate_later && self.gl_bouncecnt >= WEP_CVAR_PRI(mortar, remote_minbouncecnt))
 128                 W_Mortar_Grenade_Explode();
 129 }
 130
 131 void W_Mortar_Grenade_Touch1(void)
 132 {SELFPARAM();
 133         PROJECTILE_TOUCH;
 134         if(other.takedamage == DAMAGE_AIM || WEP_CVAR_PRI(mortar, type) == 0) // always explode when hitting a player, or if normal mortar projectile
 135         {
 136                 self.use();
 137         }
 138         else if(WEP_CVAR_PRI(mortar, type) == 1) // bounce
 139         {
 140                 spamsound(self, CH_SHOTS, SND(GRENADE_BOUNCE_RANDOM()), VOL_BASE, ATTN_NORM);
 141                 Send_Effect(EFFECT_HAGAR_BOUNCE, self.origin, self.velocity, 1);
 142                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 143                 self.gl_bouncecnt += 1;
 144         }
 145         else if(WEP_CVAR_PRI(mortar, type) == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 146         {
 147                 spamsound(self, CH_SHOTS, SND(GRENADE_STICK), VOL_BASE, ATTN_NORM);
 148
 149                 // let it stick whereever it is
 150                 self.oldvelocity = self.velocity;
 151                 self.velocity = '0 0 0';
 152                 self.movetype = MOVETYPE_NONE; // also disables gravity
 153                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 154                 UpdateCSQCProjectile(self);
 155
 156                 // do not respond to any more touches
 157                 self.solid = SOLID_NOT;
 158
 159                 self.nextthink = min(self.nextthink, time + WEP_CVAR_PRI(mortar, lifetime_stick));
 160         }
 161 }
 162
 163 void W_Mortar_Grenade_Touch2(void)
 164 {SELFPARAM();
 165         PROJECTILE_TOUCH;
 166         if(other.takedamage == DAMAGE_AIM || WEP_CVAR_SEC(mortar, type) == 0) // always explode when hitting a player, or if normal mortar projectile
 167         {
 168                 self.use();
 169         }
 170         else if(WEP_CVAR_SEC(mortar, type) == 1) // bounce
 171         {
 172                 spamsound(self, CH_SHOTS, SND(GRENADE_BOUNCE_RANDOM()), VOL_BASE, ATTN_NORM);
 173                 Send_Effect(EFFECT_HAGAR_BOUNCE, self.origin, self.velocity, 1);
 174                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 175                 self.gl_bouncecnt += 1;
 176
 177                 if(WEP_CVAR_SEC(mortar, lifetime_bounce) && self.gl_bouncecnt == 1)
 178                         self.nextthink = time + WEP_CVAR_SEC(mortar, lifetime_bounce);
 179
 180         }
 181         else if(WEP_CVAR_SEC(mortar, type) == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 182         {
 183                 spamsound(self, CH_SHOTS, SND(GRENADE_STICK), VOL_BASE, ATTN_NORM);
 184
 185                 // let it stick whereever it is
 186                 self.oldvelocity = self.velocity;
 187                 self.velocity = '0 0 0';
 188                 self.movetype = MOVETYPE_NONE; // also disables gravity
 189                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 190                 UpdateCSQCProjectile(self);
 191
 192                 // do not respond to any more touches
 193                 self.solid = SOLID_NOT;
 194
 195                 self.nextthink = min(self.nextthink, time + WEP_CVAR_SEC(mortar, lifetime_stick));
 196         }
 197 }
 198
 199 void W_Mortar_Attack(void)
 200 {SELFPARAM();
 201         entity gren;
 202
 203         W_DecreaseAmmo(WEP_CVAR_PRI(mortar, ammo));
 204
 205         W_SetupShot_ProjectileSize(self, '-3 -3 -3', '3 3 3', false, 4, SND(GRENADE_FIRE), CH_WEAPON_A, WEP_CVAR_PRI(mortar, damage));
 206         w_shotdir = v_forward; // no TrueAim for grenades please
 207
 208         Send_Effect(EFFECT_GRENADE_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 209
 210         gren = spawn();
 211         gren.owner = gren.realowner = self;
 212         gren.classname = "grenade";
 213         gren.bot_dodge = true;
 214         gren.bot_dodgerating = WEP_CVAR_PRI(mortar, damage);
 215         gren.movetype = MOVETYPE_BOUNCE;
 216         gren.bouncefactor = WEP_CVAR(mortar, bouncefactor);
 217         gren.bouncestop = WEP_CVAR(mortar, bouncestop);
 218         PROJECTILE_MAKETRIGGER(gren);
 219         gren.projectiledeathtype = WEP_MORTAR.m_id;
 220         setorigin(gren, w_shotorg);
 221         setsize(gren, '-3 -3 -3', '3 3 3');
 222
 223         gren.cnt = time + WEP_CVAR_PRI(mortar, lifetime);
 224         gren.nextthink = time;
 225         gren.think = W_Mortar_Grenade_Think1;
 226         gren.use = W_Mortar_Grenade_Explode;
 227         gren.touch = W_Mortar_Grenade_Touch1;
 228
 229         gren.takedamage = DAMAGE_YES;
 230         gren.health = WEP_CVAR_PRI(mortar, health);
 231         gren.damageforcescale = WEP_CVAR_PRI(mortar, damageforcescale);
 232         gren.event_damage = W_Mortar_Grenade_Damage;
 233         gren.damagedbycontents = true;
 234         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 235         W_SetupProjVelocity_UP_PRI(gren, mortar);
 236
 237         gren.angles = vectoangles(gren.velocity);
 238         gren.flags = FL_PROJECTILE;
 239
 240         if(WEP_CVAR_PRI(mortar, type) == 0 || WEP_CVAR_PRI(mortar, type) == 2)
 241                 CSQCProjectile(gren, true, PROJECTILE_GRENADE, true);
 242         else
 243                 CSQCProjectile(gren, true, PROJECTILE_GRENADE_BOUNCING, true);
 244
 245         MUTATOR_CALLHOOK(EditProjectile, self, gren);
 246 }
 247
 248 void W_Mortar_Attack2(void)
 249 {SELFPARAM();
 250         entity gren;
 251
 252         W_DecreaseAmmo(WEP_CVAR_SEC(mortar, ammo));
 253
 254         W_SetupShot_ProjectileSize(self, '-3 -3 -3', '3 3 3', false, 4, SND(GRENADE_FIRE), CH_WEAPON_A, WEP_CVAR_SEC(mortar, damage));
 255         w_shotdir = v_forward; // no TrueAim for grenades please
 256
 257         Send_Effect(EFFECT_GRENADE_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 258
 259         gren = spawn();
 260         gren.owner = gren.realowner = self;
 261         gren.classname = "grenade";
 262         gren.bot_dodge = true;
 263         gren.bot_dodgerating = WEP_CVAR_SEC(mortar, damage);
 264         gren.movetype = MOVETYPE_BOUNCE;
 265         gren.bouncefactor = WEP_CVAR(mortar, bouncefactor);
 266         gren.bouncestop = WEP_CVAR(mortar, bouncestop);
 267         PROJECTILE_MAKETRIGGER(gren);
 268         gren.projectiledeathtype = WEP_MORTAR.m_id | HITTYPE_SECONDARY;
 269         setorigin(gren, w_shotorg);
 270         setsize(gren, '-3 -3 -3', '3 3 3');
 271
 272         gren.nextthink = time + WEP_CVAR_SEC(mortar, lifetime);
 273         gren.think = adaptor_think2use_hittype_splash;
 274         gren.use = W_Mortar_Grenade_Explode2;
 275         gren.touch = W_Mortar_Grenade_Touch2;
 276
 277         gren.takedamage = DAMAGE_YES;
 278         gren.health = WEP_CVAR_SEC(mortar, health);
 279         gren.damageforcescale = WEP_CVAR_SEC(mortar, damageforcescale);
 280         gren.event_damage = W_Mortar_Grenade_Damage;
 281         gren.damagedbycontents = true;
 282         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 283         W_SetupProjVelocity_UP_SEC(gren, mortar);
 284
 285         gren.angles = vectoangles(gren.velocity);
 286         gren.flags = FL_PROJECTILE;
 287
 288         if(WEP_CVAR_SEC(mortar, type) == 0 || WEP_CVAR_SEC(mortar, type) == 2)
 289                 CSQCProjectile(gren, true, PROJECTILE_GRENADE, true);
 290         else
 291                 CSQCProjectile(gren, true, PROJECTILE_GRENADE_BOUNCING, true);
 292
 293         MUTATOR_CALLHOOK(EditProjectile, self, gren);
 294 }
 295
 296 .float bot_secondary_grenademooth;
 297 bool W_Mortar(int req)
 298 {SELFPARAM();
 299         entity nade;
 300         float nadefound;
 301         float ammo_amount;
 302         switch(req)
 303         {
 304                 case WR_AIM:
 305                 {
 306                         self.BUTTON_ATCK = false;
 307                         self.BUTTON_ATCK2 = false;
 308                         if(self.bot_secondary_grenademooth == 0) // WEAPONTODO: merge this into using WEP_CVAR_BOTH
 309                         {
 310                                 if(bot_aim(WEP_CVAR_PRI(mortar, speed), WEP_CVAR_PRI(mortar, speed_up), WEP_CVAR_PRI(mortar, lifetime), true))
 311                                 {
 312                                         self.BUTTON_ATCK = true;
 313                                         if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 314                                 }
 315                         }
 316                         else
 317                         {
 318                                 if(bot_aim(WEP_CVAR_SEC(mortar, speed), WEP_CVAR_SEC(mortar, speed_up), WEP_CVAR_SEC(mortar, lifetime), true))
 319                                 {
 320                                         self.BUTTON_ATCK2 = true;
 321                                         if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 322                                 }
 323                         }
 324
 325                         return true;
 326                 }
 327                 /*case WR_CALCINFO:
 328                 {
 329                         wepinfo_pri_refire = max3(sys_frametime, WEP_CVAR_PRI(mortar, refire), WEP_CVAR_PRI(mortar, animtime));
 330                         wepinfo_pri_dps = (WEP_CVAR_PRI(mortar, damage) * (1 / wepinfo_pri_refire));
 331                         wepinfo_pri_speed = (1 / max(1, (10000 / max(1, WEP_CVAR_PRI(mortar, speed)))));
 332
 333                         // for the range calculation, closer to 1 is better
 334                         wepinfo_pri_range_max = 2000 * wepinfo_pri_speed;
 335                         wepinfo_pri_range = wepinfo_pri_speed * WEP_CVAR_PRI(mortar,
 336
 337                         wepinfo_sec_refire = max3(sys_frametime, WEP_CVAR_SEC(mortar, refire), WEP_CVAR_SEC(mortar, animtime));
 338                         wepinfo_sec_dps = (WEP_CVAR_SEC(mortar, damage) * (1 / wepinfo_sec_refire));
 339
 340                         wepinfo_sec_dps = (WEP_CVAR_SEC(mortar, damage) * (1 / max3(sys_frametime, WEP_CVAR_SEC(mortar, refire), WEP_CVAR_SEC(mortar, animtime))));
 341                         wepinfo_ter_dps = 0;
 342                         */
 343                 case WR_THINK:
 344                 {
 345                         if(autocvar_g_balance_mortar_reload_ammo && self.clip_load < min(WEP_CVAR_PRI(mortar, ammo), WEP_CVAR_SEC(mortar, ammo))) // forced reload
 346                                 WEP_ACTION(self.weapon, WR_RELOAD);
 347                         else if(self.BUTTON_ATCK)
 348                         {
 349                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(mortar, refire)))
 350                                 {
 351                                         W_Mortar_Attack();
 352                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(mortar, animtime), w_ready);
 353                                 }
 354                         }
 355                         else if(self.BUTTON_ATCK2)
 356                         {
 357                                 if(WEP_CVAR_SEC(mortar, remote_detonateprimary))
 358                                 {
 359                                         nadefound = 0;
 360                                         for(nade = world; (nade = find(nade, classname, "grenade")); ) if(nade.realowner == self)
 361                                         {
 362                                                 if(!nade.gl_detonate_later)
 363                                                 {
 364                                                         nade.gl_detonate_later = true;
 365                                                         nadefound = 1;
 366                                                 }
 367                                         }
 368                                         if(nadefound)
 369                                                 sound(self, CH_WEAPON_B, SND_ROCKET_DET, VOL_BASE, ATTN_NORM);
 370                                 }
 371                                 else if(weapon_prepareattack(1, WEP_CVAR_SEC(mortar, refire)))
 372                                 {
 373                                         W_Mortar_Attack2();
 374                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(mortar, animtime), w_ready);
 375                                 }
 376                         }
 377
 378                         return true;
 379                 }
 380                 case WR_INIT:
 381                 {
 382                         MORTAR_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 383                         return true;
 384                 }
 385                 case WR_CHECKAMMO1:
 386                 {
 387                         ammo_amount = self.WEP_AMMO(MORTAR) >= WEP_CVAR_PRI(mortar, ammo);
 388                         ammo_amount += self.(weapon_load[WEP_MORTAR.m_id]) >= WEP_CVAR_PRI(mortar, ammo);
 389                         return ammo_amount;
 390                 }
 391                 case WR_CHECKAMMO2:
 392                 {
 393                         ammo_amount = self.WEP_AMMO(MORTAR) >= WEP_CVAR_SEC(mortar, ammo);
 394                         ammo_amount += self.(weapon_load[WEP_MORTAR.m_id]) >= WEP_CVAR_SEC(mortar, ammo);
 395                         return ammo_amount;
 396                 }
 397                 case WR_CONFIG:
 398                 {
 399                         MORTAR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 400                         return true;
 401                 }
 402                 case WR_RELOAD:
 403                 {
 404                         W_Reload(min(WEP_CVAR_PRI(mortar, ammo), WEP_CVAR_SEC(mortar, ammo)), SND(RELOAD)); // WEAPONTODO
 405                         return true;
 406                 }
 407                 case WR_SUICIDEMESSAGE:
 408                 {
 409                         if(w_deathtype & HITTYPE_SECONDARY)
 410                                 return WEAPON_MORTAR_SUICIDE_BOUNCE;
 411                         else
 412                                 return WEAPON_MORTAR_SUICIDE_EXPLODE;
 413                 }
 414                 case WR_KILLMESSAGE:
 415                 {
 416                         if(w_deathtype & HITTYPE_SECONDARY)
 417                                 return WEAPON_MORTAR_MURDER_BOUNCE;
 418                         else
 419                                 return WEAPON_MORTAR_MURDER_EXPLODE;
 420                 }
 421         }
 422         return false;
 423 }
 424 #endif
 425 #ifdef CSQC
 426 bool W_Mortar(int req)
 427 {SELFPARAM();
 428         switch(req)
 429         {
 430                 case WR_IMPACTEFFECT:
 431                 {
 432                         vector org2;
 433                         org2 = w_org + w_backoff * 12;
 434                         pointparticles(particleeffectnum(EFFECT_GRENADE_EXPLODE), org2, '0 0 0', 1);
 435                         if(!w_issilent)
 436                                 sound(self, CH_SHOTS, SND_GRENADE_IMPACT, VOL_BASE, ATTN_NORM);
 437
 438                         return true;
 439                 }
 440                 case WR_INIT:
 441                 {
 442                         return true;
 443                 }
 444                 case WR_ZOOMRETICLE:
 445                 {
 446                         // no weapon specific image for this weapon
 447                         return false;
 448                 }
 449         }
 450         return false;
 451 }
 452 #endif
 453 #endif