Remove IT_AMMO
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / rifle.qc
1 #include "rifle.qh"
2 #ifndef IMPLEMENTATION
3 CLASS(Rifle, Weapon)
4 /* ammotype  */ ATTRIB(Rifle, ammo_field, .int, ammo_nails);
5 /* impulse   */ ATTRIB(Rifle, impulse, int, 7);
6 /* flags     */ ATTRIB(Rifle, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN);
7 /* rating    */ ATTRIB(Rifle, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
8 /* color     */ ATTRIB(Rifle, wpcolor, vector, '0.5 1 0');
9 /* modelname */ ATTRIB(Rifle, mdl, string, "campingrifle");
10 #ifdef GAMEQC
11 /* model     */ ATTRIB(Rifle, m_model, Model, MDL_RIFLE_ITEM);
12 #endif
13 /* crosshair */ ATTRIB(Rifle, w_crosshair, string, "gfx/crosshairrifle");
14 /* crosshair */ ATTRIB(Rifle, w_crosshair_size, float, 0.6);
15 /* wepimg    */ ATTRIB(Rifle, model2, string, "weaponrifle");
16 /* refname   */ ATTRIB(Rifle, netname, string, "rifle");
17 /* wepname   */ ATTRIB(Rifle, m_name, string, _("Rifle"));
18
19 #define X(BEGIN, P, END, class, prefix) \
20         BEGIN(class) \
21                 P(class, prefix, ammo, float, BOTH) \
22                 P(class, prefix, animtime, float, BOTH) \
23                 P(class, prefix, bullethail, float, BOTH) \
24                 P(class, prefix, burstcost, float, BOTH) \
25                 P(class, prefix, bursttime, float, NONE) \
26                 P(class, prefix, damage, float, BOTH) \
27                 P(class, prefix, force, float, BOTH) \
28                 P(class, prefix, refire, float, BOTH) \
29                 P(class, prefix, reload, float, SEC) \
30                 P(class, prefix, reload_ammo, float, NONE) \
31         P(class, prefix, reload_time, float, NONE) \
32                 P(class, prefix, secondary, float, NONE) \
33                 P(class, prefix, shots, float, BOTH) \
34                 P(class, prefix, solidpenetration, float, BOTH) \
35                 P(class, prefix, spread, float, BOTH) \
36         P(class, prefix, switchdelay_drop, float, NONE) \
37         P(class, prefix, switchdelay_raise, float, NONE) \
38                 P(class, prefix, tracer, float, BOTH) \
39         P(class, prefix, weaponreplace, string, NONE) \
40         P(class, prefix, weaponstartoverride, float, NONE) \
41         P(class, prefix, weaponstart, float, NONE) \
42         P(class, prefix, weaponthrowable, float, NONE) \
43         END()
44     W_PROPS(X, Rifle, rifle)
45 #undef X
46 ENDCLASS(Rifle)
47 REGISTER_WEAPON(RIFLE, rifle, NEW(Rifle));
48
49
50 #ifdef SVQC
51 .float rifle_accumulator;
52 #endif
53 #endif
54 #ifdef IMPLEMENTATION
55 #ifdef SVQC
56 spawnfunc(weapon_rifle) { weapon_defaultspawnfunc(this, WEP_RIFLE); }
57 spawnfunc(weapon_campingrifle) { spawnfunc_weapon_rifle(this); }
58 spawnfunc(weapon_sniperrifle) { spawnfunc_weapon_rifle(this); }
59
60 void W_Rifle_FireBullet(Weapon thiswep, .entity weaponentity, float pSpread, float pDamage, float pForce, float pSolidPenetration, float pAmmo, int deathtype, float pTracer, float pShots, Sound pSound, entity actor)
61 {
62         float i;
63
64         W_DecreaseAmmo(thiswep, actor, pAmmo);
65
66         W_SetupShot(actor, weaponentity, true, 2, pSound, CH_WEAPON_A, pDamage * pShots);
67
68         Send_Effect(EFFECT_RIFLE_MUZZLEFLASH, w_shotorg, w_shotdir * 2000, 1);
69
70         if(PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) // if zoomed, shoot from the eye
71         {
72                 w_shotdir = v_forward;
73                 w_shotorg = actor.origin + actor.view_ofs + ((w_shotorg - actor.origin - actor.view_ofs) * v_forward) * v_forward;
74         }
75
76         for(i = 0; i < pShots; ++i)
77                 fireBullet(actor, w_shotorg, w_shotdir, pSpread, pSolidPenetration, pDamage, pForce, deathtype, (pTracer ? EF_RED : EF_BLUE));
78
79         if(autocvar_g_casings >= 2)
80     {
81         makevectors(actor.v_angle); // for some reason, this is lost
82                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor, weaponentity);
83     }
84 }
85
86 void W_Rifle_Attack(entity actor, .entity weaponentity)
87 {
88         W_Rifle_FireBullet(WEP_RIFLE, weaponentity, WEP_CVAR_PRI(rifle, spread), WEP_CVAR_PRI(rifle, damage), WEP_CVAR_PRI(rifle, force), WEP_CVAR_PRI(rifle, solidpenetration), WEP_CVAR_PRI(rifle, ammo), WEP_RIFLE.m_id, WEP_CVAR_PRI(rifle, tracer), WEP_CVAR_PRI(rifle, shots), SND_CAMPINGRIFLE_FIRE, actor);
89 }
90
91 void W_Rifle_Attack2(entity actor, .entity weaponentity)
92 {
93         W_Rifle_FireBullet(WEP_RIFLE, weaponentity, WEP_CVAR_SEC(rifle, spread), WEP_CVAR_SEC(rifle, damage), WEP_CVAR_SEC(rifle, force), WEP_CVAR_SEC(rifle, solidpenetration), WEP_CVAR_SEC(rifle, ammo), WEP_RIFLE.m_id | HITTYPE_SECONDARY, WEP_CVAR_SEC(rifle, tracer), WEP_CVAR_SEC(rifle, shots), SND_CAMPINGRIFLE_FIRE2, actor);
94 }
95
96 .void(entity actor, .entity weaponentity) rifle_bullethail_attackfunc;
97 .WFRAME rifle_bullethail_frame;
98 .float rifle_bullethail_animtime;
99 .float rifle_bullethail_refire;
100 void W_Rifle_BulletHail_Continue(Weapon thiswep, entity actor, .entity weaponentity, int fire)
101 {
102         float r, af;
103
104         Weapon sw = PS(actor).m_switchweapon; // make it not detect weapon changes as reason to abort firing
105         int slot = weaponslot(weaponentity);
106         af = ATTACK_FINISHED(actor, slot);
107         PS(actor).m_switchweapon = PS(actor).m_weapon;
108         ATTACK_FINISHED(actor, slot) = time;
109         r = weapon_prepareattack(thiswep, actor, weaponentity, actor.rifle_bullethail_frame == WFRAME_FIRE2, actor.rifle_bullethail_refire);
110         if(PS(actor).m_switchweapon == PS(actor).m_weapon)
111                 PS(actor).m_switchweapon = sw;
112         if(r)
113         {
114                 actor.rifle_bullethail_attackfunc(actor, weaponentity);
115                 weapon_thinkf(actor, weaponentity, actor.rifle_bullethail_frame, actor.rifle_bullethail_animtime, W_Rifle_BulletHail_Continue);
116         }
117         else
118         {
119                 ATTACK_FINISHED(actor, slot) = af; // reset attack_finished if we didn't fire, so the last shot enforces the refire time
120         }
121 }
122
123 void W_Rifle_BulletHail(entity actor, .entity weaponentity, float mode, void(entity actor, .entity weaponentity) AttackFunc, WFRAME fr, float animtime, float refire)
124 {
125         // if we get here, we have at least one bullet to fire
126         AttackFunc(actor, weaponentity);
127         if(mode)
128         {
129                 // continue hail
130                 actor.rifle_bullethail_attackfunc = AttackFunc;
131                 actor.rifle_bullethail_frame = fr;
132                 actor.rifle_bullethail_animtime = animtime;
133                 actor.rifle_bullethail_refire = refire;
134                 weapon_thinkf(actor, weaponentity, fr, animtime, W_Rifle_BulletHail_Continue);
135         }
136         else
137         {
138                 // just one shot
139                 weapon_thinkf(actor, weaponentity, fr, animtime, w_ready);
140         }
141 }
142
143 .float bot_secondary_riflemooth;
144
145 METHOD(Rifle, wr_aim, void(entity thiswep, entity actor))
146 {
147     PHYS_INPUT_BUTTON_ATCK(actor) = false;
148     PHYS_INPUT_BUTTON_ATCK2(actor) = false;
149     if(vdist(actor.origin - actor.enemy.origin, >, 1000))
150         actor.bot_secondary_riflemooth = 0;
151     if(actor.bot_secondary_riflemooth == 0)
152     {
153         if(bot_aim(actor, 1000000, 0, 0.001, false))
154         {
155             PHYS_INPUT_BUTTON_ATCK(actor) = true;
156             if(random() < 0.01) actor.bot_secondary_riflemooth = 1;
157         }
158     }
159     else
160     {
161         if(bot_aim(actor, 1000000, 0, 0.001, false))
162         {
163             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
164             if(random() < 0.03) actor.bot_secondary_riflemooth = 0;
165         }
166     }
167 }
168 METHOD(Rifle, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
169 {
170     if(autocvar_g_balance_rifle_reload_ammo && actor.clip_load < min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo))) { // forced reload
171         thiswep.wr_reload(thiswep, actor, weaponentity);
172     } else
173     {
174         actor.rifle_accumulator = bound(time - WEP_CVAR(rifle, bursttime), actor.rifle_accumulator, time);
175         if(fire & 1)
176         if(weapon_prepareattack_check(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire)))
177         if(time >= actor.rifle_accumulator + WEP_CVAR_PRI(rifle, burstcost))
178         {
179             weapon_prepareattack_do(actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire));
180             W_Rifle_BulletHail(actor, weaponentity, WEP_CVAR_PRI(rifle, bullethail), W_Rifle_Attack, WFRAME_FIRE1, WEP_CVAR_PRI(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
181             actor.rifle_accumulator += WEP_CVAR_PRI(rifle, burstcost);
182         }
183         if(fire & 2)
184         {
185             if(WEP_CVAR(rifle, secondary))
186             {
187                 if(WEP_CVAR_SEC(rifle, reload)) {
188                     thiswep.wr_reload(thiswep, actor, weaponentity);
189                 } else
190                 {
191                     if(weapon_prepareattack_check(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire)))
192                     if(time >= actor.rifle_accumulator + WEP_CVAR_SEC(rifle, burstcost))
193                     {
194                         weapon_prepareattack_do(actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire));
195                         W_Rifle_BulletHail(actor, weaponentity, WEP_CVAR_SEC(rifle, bullethail), W_Rifle_Attack2, WFRAME_FIRE2, WEP_CVAR_SEC(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
196                         actor.rifle_accumulator += WEP_CVAR_SEC(rifle, burstcost);
197                     }
198                 }
199             }
200         }
201     }
202 }
203 METHOD(Rifle, wr_checkammo1, bool(entity thiswep, entity actor))
204 {
205     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(rifle, ammo);
206     ammo_amount += actor.(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_PRI(rifle, ammo);
207     return ammo_amount;
208 }
209 METHOD(Rifle, wr_checkammo2, bool(entity thiswep, entity actor))
210 {
211     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(rifle, ammo);
212     ammo_amount += actor.(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_SEC(rifle, ammo);
213     return ammo_amount;
214 }
215 METHOD(Rifle, wr_resetplayer, void(entity thiswep, entity actor))
216 {
217     actor.rifle_accumulator = time - WEP_CVAR(rifle, bursttime);
218 }
219 METHOD(Rifle, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
220 {
221     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo)), SND_RELOAD);
222 }
223 METHOD(Rifle, wr_suicidemessage, Notification(entity thiswep))
224 {
225     return WEAPON_THINKING_WITH_PORTALS;
226 }
227 METHOD(Rifle, wr_killmessage, Notification(entity thiswep))
228 {
229     if(w_deathtype & HITTYPE_SECONDARY)
230     {
231         if(w_deathtype & HITTYPE_BOUNCE)
232             return WEAPON_RIFLE_MURDER_HAIL_PIERCING;
233         else
234             return WEAPON_RIFLE_MURDER_HAIL;
235     }
236     else
237     {
238         if(w_deathtype & HITTYPE_BOUNCE)
239             return WEAPON_RIFLE_MURDER_PIERCING;
240         else
241             return WEAPON_RIFLE_MURDER;
242     }
243 }
244
245 #endif
246 #ifdef CSQC
247
248 METHOD(Rifle, wr_impacteffect, void(entity thiswep, entity actor))
249 {
250     vector org2;
251     org2 = w_org + w_backoff * 2;
252     pointparticles(EFFECT_RIFLE_IMPACT, org2, w_backoff * 1000, 1);
253     if(!w_issilent)
254     {
255         sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTN_NORM);
256     }
257 }
258 METHOD(Rifle, wr_init, void(entity thiswep))
259 {
260     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
261     {
262         precache_pic("gfx/reticle_nex");
263     }
264 }
265 METHOD(Rifle, wr_zoomreticle, bool(entity thiswep))
266 {
267     if(button_zoom || zoomscript_caught)
268     {
269         reticle_image = "gfx/reticle_nex";
270         return true;
271     }
272     else
273     {
274         // no weapon specific image for this weapon
275         return false;
276     }
277 }
278
279 #endif
280 #endif