qcsrc/common/weapons/weapon/shotgun.qc

   1 #include "shotgun.qh"
   2
   3 #ifdef SVQC
   4
   5 void W_Shotgun_Attack(Weapon thiswep, entity actor, .entity weaponentity, float isprimary, float ammocount, float damage, float bullets, float spread, float solidpenetration, float force, entity bullet_trail_effect)
   6 {
   7         W_DecreaseAmmo(thiswep, actor, ammocount, weaponentity);
   8
   9         W_SetupShot(actor, weaponentity, true, 5, SND_SHOTGUN_FIRE, ((isprimary) ? CH_WEAPON_A : CH_WEAPON_SINGLE), damage * bullets, thiswep.m_id);
  10         for(int sc = 0;sc < bullets;sc = sc + 1)
  11                 fireBullet(actor, weaponentity, w_shotorg, w_shotdir, spread, solidpenetration, damage, force, thiswep.m_id, bullet_trail_effect);
  12
  13         Send_Effect(EFFECT_SHOTGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, ammocount);
  14
  15         // casing code
  16         if(autocvar_g_casings >= 1)
  17         {
  18                 makevectors(actor.v_angle); // for some reason, this is lost
  19                 //for(int sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
  20                         SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, actor, weaponentity);
  21         }
  22
  23         // muzzle flash for 1st person view
  24         entity flash = spawn();
  25         setmodel(flash, MDL_SHOTGUN_MUZZLEFLASH); // precision set below
  26         setthink(flash, SUB_Remove);
  27         flash.nextthink = time + 0.06;
  28         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  29         W_AttachToShotorg(actor, weaponentity, flash, '5 0 0');
  30 }
  31
  32 .float swing_prev;
  33 .entity swing_alreadyhit;
  34 void W_Shotgun_Melee_Think(entity this)
  35 {
  36         // declarations
  37         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  38         entity target_victim;
  39         vector targpos;
  40
  41         if(!this.cnt) // set start time of melee
  42         {
  43                 this.cnt = time;
  44                 W_PlayStrengthSound(this.realowner);
  45         }
  46
  47         makevectors(this.realowner.v_angle); // update values for v_* vectors
  48
  49         // calculate swing percentage based on time
  50         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor(this.realowner);
  51         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
  52         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
  53
  54         // check to see if we can still continue, otherwise give up now
  55         if(IS_DEAD(this.realowner) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
  56         {
  57                 delete(this);
  58                 return;
  59         }
  60
  61         // if okay, perform the traces needed for this frame
  62         for(i=this.swing_prev; i < f; ++i)
  63         {
  64                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
  65
  66                 targpos = (this.realowner.origin + this.realowner.view_ofs
  67                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
  68                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
  69                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
  70
  71                 WarpZone_traceline_antilag(this.realowner, this.realowner.origin + this.realowner.view_ofs, targpos, false, this.realowner, ((IS_CLIENT(this.realowner)) ? ANTILAG_LATENCY(this.realowner) : 0));
  72
  73                 // draw lightning beams for debugging
  74                 //te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
  75                 //te_customflash(targpos, 40,  2, '1 1 1');
  76
  77                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
  78
  79                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this
  80                         && (trace_ent.takedamage != DAMAGE_NO)
  81                         && (trace_ent != this.swing_alreadyhit)
  82                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
  83                 {
  84                         target_victim = trace_ent; // so it persists through other calls
  85
  86                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
  87                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
  88                         else
  89                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
  90
  91                         //print(strcat(this.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
  92
  93                         Damage(target_victim, this.realowner, this.realowner,
  94                                 swing_damage, WEP_SHOTGUN.m_id | HITTYPE_SECONDARY, this.weaponentity_fld,
  95                                 this.realowner.origin + this.realowner.view_ofs,
  96                                 v_forward * WEP_CVAR_SEC(shotgun, force));
  97
  98                         if(accuracy_isgooddamage(this.realowner, target_victim)) { accuracy_add(this.realowner, WEP_SHOTGUN, 0, swing_damage); }
  99
 100                         // draw large red flash for debugging
 101                         //te_customflash(targpos, 200, 2, '15 0 0');
 102
 103                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
 104                         {
 105                                 this.swing_alreadyhit = target_victim;
 106                                 continue; // move along to next trace
 107                         }
 108                         else
 109                         {
 110                                 delete(this);
 111                                 return;
 112                         }
 113                 }
 114         }
 115
 116         if(time >= this.cnt + meleetime)
 117         {
 118                 // melee is finished
 119                 delete(this);
 120                 return;
 121         }
 122         else
 123         {
 124                 // set up next frame
 125                 this.swing_prev = i;
 126                 this.nextthink = time;
 127         }
 128 }
 129
 130 void W_Shotgun_Attack2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 131 {
 132         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTEN_NORM);
 133         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
 134
 135         entity meleetemp = new_pure(meleetemp);
 136         meleetemp.realowner = actor;
 137         setthink(meleetemp, W_Shotgun_Melee_Think);
 138         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor(actor);
 139         meleetemp.weaponentity_fld = weaponentity;
 140         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range), WEP_SHOTGUN.m_id | HITTYPE_SECONDARY);
 141 }
 142
 143 // alternate secondary weapon frames
 144 void W_Shotgun_Attack3_Frame2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 145 {
 146         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 147         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 148         {
 149                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 150                 w_ready(thiswep, actor, weaponentity, fire);
 151                 return;
 152         }
 153
 154         sound(actor, CH_WEAPON_SINGLE, SND_Null, VOL_BASE, ATTN_NORM); // kill previous sound
 155         W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 156                 WEP_CVAR_PRI(shotgun, ammo),
 157                 WEP_CVAR_PRI(shotgun, damage),
 158                 WEP_CVAR_PRI(shotgun, bullets),
 159                 WEP_CVAR_PRI(shotgun, spread),
 160                 WEP_CVAR_PRI(shotgun, solidpenetration),
 161                 WEP_CVAR_PRI(shotgun, force),
 162                 EFFECT_BULLET_WEAK); // actually is secondary, but we trick the last shot into playing full reload sound
 163         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), w_ready);
 164 }
 165 void W_Shotgun_Attack3_Frame1(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 166 {
 167         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 168         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 169         {
 170                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 171                 w_ready(thiswep, actor, weaponentity, fire);
 172                 return;
 173         }
 174
 175         W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 176                 WEP_CVAR_PRI(shotgun, ammo),
 177                 WEP_CVAR_PRI(shotgun, damage),
 178                 WEP_CVAR_PRI(shotgun, bullets),
 179                 WEP_CVAR_PRI(shotgun, spread),
 180                 WEP_CVAR_PRI(shotgun, solidpenetration),
 181                 WEP_CVAR_PRI(shotgun, force),
 182                 EFFECT_BULLET_WEAK);
 183         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame2);
 184 }
 185
 186 .float shotgun_primarytime;
 187
 188 METHOD(Shotgun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 189 {
 190     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR_SEC(shotgun, melee_range)))
 191         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 192     else
 193         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 194 }
 195
 196 METHOD(Shotgun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 197 {
 198     if(WEP_CVAR(shotgun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(shotgun, ammo)) // forced reload
 199     {
 200         // don't force reload an empty shotgun if its melee attack is active
 201         if(WEP_CVAR(shotgun, secondary) < 2) {
 202             thiswep.wr_reload(thiswep, actor, weaponentity);
 203         }
 204     }
 205     else
 206     {
 207         if(fire & 1)
 208         {
 209             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 210             {
 211                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(shotgun, animtime)))
 212                 {
 213                     W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 214                                                 WEP_CVAR_PRI(shotgun, ammo),
 215                                                 WEP_CVAR_PRI(shotgun, damage),
 216                                                 WEP_CVAR_PRI(shotgun, bullets),
 217                                                 WEP_CVAR_PRI(shotgun, spread),
 218                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 219                                                 WEP_CVAR_PRI(shotgun, force),
 220                                                 EFFECT_BULLET_WEAK);
 221                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor(actor);
 222                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
 223                 }
 224             }
 225         }
 226         else if((fire & 2) && WEP_CVAR(shotgun, secondary) == 2)
 227         {
 228             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 229             {
 230                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(shotgun, alt_animtime)))
 231                 {
 232                     W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 233                                                 WEP_CVAR_PRI(shotgun, ammo),
 234                                                 WEP_CVAR_PRI(shotgun, damage),
 235                                                 WEP_CVAR_PRI(shotgun, bullets),
 236                                                 WEP_CVAR_PRI(shotgun, spread),
 237                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 238                                                 WEP_CVAR_PRI(shotgun, force),
 239                                                 EFFECT_BULLET_WEAK);
 240                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_SEC(shotgun, alt_refire) * W_WeaponRateFactor(actor);
 241                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame1);
 242                 }
 243             }
 244         }
 245     }
 246     if(actor.(weaponentity).clip_load >= 0) // we are not currently reloading
 247     if(WEP_CVAR(shotgun, secondary) == 1)
 248     if(((fire & 1) && GetResource(actor, thiswep.ammo_type) <= 0 && !(actor.items & IT_UNLIMITED_WEAPON_AMMO)) || (fire & 2))
 249     if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(shotgun, refire)))
 250     {
 251         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 252         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 253     }
 254 }
 255 METHOD(Shotgun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 256 {
 257     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 258     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 259     return ammo_amount;
 260 }
 261 METHOD(Shotgun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 262 {
 263     if(IS_BOT_CLIENT(actor))
 264     if(vdist(actor.origin - actor.enemy.origin, >, WEP_CVAR_SEC(shotgun, melee_range)))
 265         return false; // bots cannot use secondary out of range (fixes constant melee when out of ammo)
 266     switch(WEP_CVAR(shotgun, secondary))
 267     {
 268         case 1: return true; // melee does not use ammo
 269         case 2: // secondary triple shot
 270         {
 271             float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 272             ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 273             return ammo_amount;
 274         }
 275         default: return false; // secondary unavailable
 276     }
 277 }
 278 METHOD(Shotgun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 279 {
 280     W_Reload(actor, weaponentity, WEP_CVAR_PRI(shotgun, ammo), SND_RELOAD); // WEAPONTODO
 281 }
 282 METHOD(Shotgun, wr_suicidemessage, Notification(entity thiswep))
 283 {
 284     return WEAPON_THINKING_WITH_PORTALS;
 285 }
 286 METHOD(Shotgun, wr_killmessage, Notification(entity thiswep))
 287 {
 288     if(w_deathtype & HITTYPE_SECONDARY)
 289         return WEAPON_SHOTGUN_MURDER_SLAP;
 290     else
 291         return WEAPON_SHOTGUN_MURDER;
 292 }
 293
 294 #endif
 295 #ifdef CSQC
 296 .float prevric;
 297
 298 METHOD(Shotgun, wr_impacteffect, void(entity thiswep, entity actor))
 299 {
 300     vector org2 = w_org + w_backoff * 2;
 301     pointparticles(EFFECT_SHOTGUN_IMPACT, org2, w_backoff * 1000, 1);
 302     if(!w_issilent && time - actor.prevric > 0.25)
 303     {
 304         if(w_random < 0.05)
 305             sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 306         actor.prevric = time;
 307     }
 308 }
 309
 310 #endif