qcsrc/common/weapons/weapon/vortex.qc

   1 #include "vortex.qh"
   2
   3 //REGISTER_STAT(WEP_CVAR_vortex_charge, bool, WEP_CVAR(vortex, charge))
   4 //REGISTER_STAT(WEP_CVAR_vortex_charge_animlimit, float, WEP_CVAR(vortex, charge_animlimit))
   5
   6 #if defined(GAMEQC)
   7 float autocvar_g_weapon_charge_colormod_red_full;
   8 float autocvar_g_weapon_charge_colormod_red_half;
   9 float autocvar_g_weapon_charge_colormod_green_full;
  10 float autocvar_g_weapon_charge_colormod_blue_full;
  11 float autocvar_g_weapon_charge_colormod_blue_half;
  12 float autocvar_g_weapon_charge_colormod_green_half;
  13 float autocvar_g_weapon_charge_colormod_hdrmultiplier;
  14
  15 METHOD(Vortex, wr_glow, vector(Vortex this, entity actor, entity wepent))
  16 {
  17         if (!WEP_CVAR(vortex, charge)) return '0 0 0';
  18         float charge = wepent.vortex_charge;
  19         float animlimit = WEP_CVAR(vortex, charge_animlimit);
  20         float f = autocvar_g_weapon_charge_colormod_hdrmultiplier * min(1, charge / animlimit);
  21         vector g;
  22         g.x = f * autocvar_g_weapon_charge_colormod_red_half;
  23         g.y = f * autocvar_g_weapon_charge_colormod_green_half;
  24         g.z = f * autocvar_g_weapon_charge_colormod_blue_half;
  25         if (charge > animlimit)
  26         {
  27                 f = autocvar_g_weapon_charge_colormod_hdrmultiplier * (charge - animlimit) / (1 - animlimit);
  28                 g.x += f * autocvar_g_weapon_charge_colormod_red_full;
  29                 g.y += f * autocvar_g_weapon_charge_colormod_green_full;
  30                 g.z += f * autocvar_g_weapon_charge_colormod_blue_full;
  31         }
  32         // transition color can't be '0 0 0' as it defaults to player model glow color
  33         if (g == '0 0 0')
  34                 g = '0 0 0.000001';
  35         return g;
  36 }
  37 #endif
  38
  39 REGISTER_NET_TEMP(TE_CSQC_VORTEXBEAMPARTICLE)
  40
  41 #if defined(SVQC)
  42 void SendCSQCVortexBeamParticle(float charge) {
  43         vector v;
  44         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  45         WriteHeader(MSG_BROADCAST, TE_CSQC_VORTEXBEAMPARTICLE);
  46         WriteVector(MSG_BROADCAST, w_shotorg);
  47         WriteVector(MSG_BROADCAST, v);
  48         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  49 }
  50 #elif defined(CSQC)
  51 NET_HANDLE(TE_CSQC_VORTEXBEAMPARTICLE, bool isNew)
  52 {
  53         float charge;
  54     vector shotorg = ReadVector();
  55     vector endpos = ReadVector();
  56         charge = ReadByte() / 255.0;
  57
  58         //pointparticles(EFFECT_VORTEX_MUZZLEFLASH, shotorg, normalize(endpos - shotorg) * 1000, 1);
  59
  60         //draw either the old v2.3 beam or the new beam
  61         charge = sqrt(charge); // divide evenly among trail spacing and alpha
  62         particles_alphamin = particles_alphamax = particles_fade = charge;
  63
  64         if(!MUTATOR_CALLHOOK(Particles_VortexBeam, shotorg, endpos))
  65         {
  66                 if(autocvar_cl_particles_oldvortexbeam && (STAT(ALLOW_OLDVORTEXBEAM) || isdemo()))
  67                         WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  68                 else
  69                         WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  70         }
  71         return true;
  72 }
  73 #endif
  74
  75 #ifdef SVQC
  76
  77 REGISTER_MUTATOR(vortex_charge, true);
  78
  79 MUTATOR_HOOKFUNCTION(vortex_charge, GetPressedKeys)
  80 {
  81     entity player = M_ARGV(0, entity);
  82
  83         // WEAPONTODO
  84     if(!WEP_CVAR(vortex, charge) || !WEP_CVAR(vortex, charge_velocity_rate))
  85         return;
  86
  87     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  88     {
  89         .entity weaponentity = weaponentities[slot];
  90
  91         if (player.(weaponentity).m_weapon == WEP_VORTEX && WEP_CVAR(vortex, charge) && WEP_CVAR(vortex, charge_velocity_rate) && vdist(vec2(player.velocity), >, WEP_CVAR(vortex, charge_minspeed)))
  92         {
  93             float xyspeed = vlen(vec2(player.velocity));
  94                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
  95                 xyspeed = min(xyspeed, WEP_CVAR(vortex, charge_maxspeed));
  96                 float f = (xyspeed - WEP_CVAR(vortex, charge_minspeed)) / (WEP_CVAR(vortex, charge_maxspeed) - WEP_CVAR(vortex, charge_minspeed));
  97                 // add the extra charge
  98                 player.(weaponentity).vortex_charge = min(1, player.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_velocity_rate) * f * PHYS_INPUT_TIMELENGTH);
  99         }
 100     }
 101 }
 102
 103 void W_Vortex_Attack(Weapon thiswep, entity actor, .entity weaponentity, float issecondary)
 104 {
 105         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
 106
 107         mydmg = WEP_CVAR_BOTH(vortex, !issecondary, damage);
 108         myforce = WEP_CVAR_BOTH(vortex, !issecondary, force);
 109         mymindist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_mindist);
 110         mymaxdist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_maxdist);
 111         myhalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_halflife);
 112         myforcehalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_forcehalflife);
 113         myammo = WEP_CVAR_BOTH(vortex, !issecondary, ammo);
 114
 115     float dtype = thiswep.m_id;
 116     if(WEP_CVAR_BOTH(vortex, !issecondary, armorpierce))
 117         dtype |= HITTYPE_ARMORPIERCE;
 118
 119         float flying;
 120         flying = IsFlying(actor); // do this BEFORE to make the trace values from FireRailgunBullet last
 121
 122         if(WEP_CVAR(vortex, charge))
 123         {
 124                 charge = WEP_CVAR(vortex, charge_mindmg) / mydmg + (1 - WEP_CVAR(vortex, charge_mindmg) / mydmg) * actor.(weaponentity).vortex_charge;
 125                 actor.(weaponentity).vortex_charge *= WEP_CVAR(vortex, charge_shot_multiplier); // do this AFTER setting mydmg/myforce
 126                 // O RLY? -- divVerent
 127                 // YA RLY -- FruitieX
 128         }
 129         else
 130                 charge = 1;
 131         mydmg *= charge;
 132         myforce *= charge;
 133
 134         W_SetupShot(actor, weaponentity, true, 5, SND_NEXFIRE, CH_WEAPON_A, mydmg, dtype);
 135         if(charge > WEP_CVAR(vortex, charge_animlimit) && WEP_CVAR(vortex, charge_animlimit)) // if the Vortex is overcharged, we play an extra sound
 136         {
 137                 sound(actor, CH_WEAPON_B, SND_NEXCHARGE, VOL_BASE * (charge - 0.5 * WEP_CVAR(vortex, charge_animlimit)) / (1 - 0.5 * WEP_CVAR(vortex, charge_animlimit)), ATTN_NORM);
 138         }
 139
 140         yoda = 0;
 141         damage_goodhits = 0;
 142         FireRailgunBullet(actor, weaponentity, w_shotorg, w_shotorg + w_shotdir * max_shot_distance, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, dtype);
 143
 144         if(yoda && flying)
 145                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 146         if(damage_goodhits && actor.vortex_lasthit)
 147         {
 148                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
 149                 damage_goodhits = 0; // only every second time
 150         }
 151
 152         actor.vortex_lasthit = damage_goodhits;
 153
 154         //beam and muzzle flash done on client
 155     W_MuzzleFlash(actor, weaponentity, EFFECT_VORTEX_MUZZLEFLASH, w_shotorg, w_shotdir * 1000);
 156         SendCSQCVortexBeamParticle(charge);
 157
 158         W_DecreaseAmmo(thiswep, actor, myammo, weaponentity);
 159 }
 160
 161 .float vortex_chargepool_pauseregen_finished;
 162
 163 void W_Vortex_Charge(entity actor, .entity weaponentity, float dt)
 164 {
 165     if(WEP_CVAR(vortex, charge) && actor.(weaponentity).vortex_charge < WEP_CVAR(vortex, charge_limit))
 166         actor.(weaponentity).vortex_charge = min(1, actor.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_rate) * dt / W_TICSPERFRAME);
 167 }
 168
 169 METHOD(Vortex, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 170 {
 171     if(bot_aim(actor, weaponentity, 1000000, 0, 1, false))
 172         PHYS_INPUT_BUTTON_ATCK(actor) = true;
 173     else
 174     {
 175         if(WEP_CVAR(vortex, charge))
 176             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 177     }
 178 }
 179 METHOD(Vortex, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 180 {
 181     if(!WEP_CVAR(vortex, charge_always))
 182         W_Vortex_Charge(actor, weaponentity, frametime);
 183
 184     if(WEP_CVAR_SEC(vortex, chargepool))
 185         if(actor.(weaponentity).vortex_chargepool_ammo < 1)
 186         {
 187             if(actor.vortex_chargepool_pauseregen_finished < time)
 188                 actor.(weaponentity).vortex_chargepool_ammo = min(1, actor.(weaponentity).vortex_chargepool_ammo + WEP_CVAR_SEC(vortex, chargepool_regen) * frametime / W_TICSPERFRAME);
 189             actor.pauseregen_finished = max(actor.pauseregen_finished, time + WEP_CVAR_SEC(vortex, chargepool_pause_regen));
 190         }
 191
 192     if(autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo))) { // forced reload
 193         thiswep.wr_reload(thiswep, actor, weaponentity);
 194     } else
 195     {
 196         if(fire & 1)
 197         {
 198             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vortex, refire)))
 199             {
 200                 W_Vortex_Attack(thiswep, actor, weaponentity, 0);
 201                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vortex, animtime), w_ready);
 202             }
 203         }
 204         if((WEP_CVAR(vortex, charge) && !WEP_CVAR(vortex, secondary)) ? (PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) : (fire & 2))
 205         {
 206             if(WEP_CVAR(vortex, charge))
 207             {
 208                 actor.(weaponentity).vortex_charge_rottime = time + WEP_CVAR(vortex, charge_rot_pause);
 209                 float dt = frametime / W_TICSPERFRAME;
 210
 211                 if(actor.(weaponentity).vortex_charge < 1)
 212                 {
 213                     if(WEP_CVAR_SEC(vortex, chargepool))
 214                     {
 215                         if(WEP_CVAR_SEC(vortex, ammo))
 216                         {
 217                             // always deplete if secondary is held
 218                             actor.(weaponentity).vortex_chargepool_ammo = max(0, actor.(weaponentity).vortex_chargepool_ammo - WEP_CVAR_SEC(vortex, ammo) * dt);
 219
 220                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 221                             actor.vortex_chargepool_pauseregen_finished = time + WEP_CVAR_SEC(vortex, chargepool_pause_regen);
 222                             dt = min(dt, actor.(weaponentity).vortex_chargepool_ammo);
 223                             dt = max(0, dt);
 224
 225                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 226                         }
 227                     }
 228
 229                     else if(WEP_CVAR_SEC(vortex, ammo))
 230                     {
 231                         if(fire & 2) // only eat ammo when the button is pressed
 232                         {
 233                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 234                             if(!(actor.items & IT_UNLIMITED_AMMO))
 235                             {
 236                                 // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 237                                 if(autocvar_g_balance_vortex_reload_ammo)
 238                                 {
 239                                     dt = min(dt, (actor.(weaponentity).clip_load - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 240                                     dt = max(0, dt);
 241                                     if(dt > 0)
 242                                     {
 243                                         actor.(weaponentity).clip_load = max(WEP_CVAR_SEC(vortex, ammo), actor.(weaponentity).clip_load - WEP_CVAR_SEC(vortex, ammo) * dt);
 244                                     }
 245                                     actor.(weaponentity).(weapon_load[thiswep.m_id]) = actor.(weaponentity).clip_load;
 246                                 }
 247                                 else
 248                                 {
 249                                     dt = min(dt, (GetResource(actor, thiswep.ammo_type) - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 250                                     dt = max(0, dt);
 251                                     if(dt > 0)
 252                                     {
 253                                         SetResource(actor, thiswep.ammo_type, max(WEP_CVAR_SEC(vortex, ammo), GetResource(actor, thiswep.ammo_type) - WEP_CVAR_SEC(vortex, ammo) * dt));
 254                                     }
 255                                 }
 256                             }
 257                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 258                         }
 259                     }
 260
 261                     else
 262                     {
 263                         dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 264                         actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 265                     }
 266                 }
 267             }
 268             else if(WEP_CVAR(vortex, secondary))
 269             {
 270                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(vortex, refire)))
 271                 {
 272                     W_Vortex_Attack(thiswep, actor, weaponentity, 1);
 273                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(vortex, animtime), w_ready);
 274                 }
 275             }
 276         }
 277     }
 278 }
 279 METHOD(Vortex, wr_setup, void(entity thiswep, entity actor, .entity weaponentity))
 280 {
 281     actor.vortex_lasthit = 0;
 282 }
 283 METHOD(Vortex, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 284 {
 285     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(vortex, ammo);
 286     ammo_amount += (autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(vortex, ammo));
 287     return ammo_amount;
 288 }
 289 METHOD(Vortex, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 290 {
 291     if(WEP_CVAR(vortex, secondary))
 292     {
 293         // don't allow charging if we don't have enough ammo
 294         float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(vortex, ammo);
 295         ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_SEC(vortex, ammo);
 296         return ammo_amount;
 297     }
 298     else
 299     {
 300         return false; // zoom is not a fire mode
 301     }
 302 }
 303 METHOD(Vortex, wr_resetplayer, void(entity thiswep, entity actor))
 304 {
 305     if (WEP_CVAR(vortex, charge)) {
 306         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 307         {
 308             .entity weaponentity = weaponentities[slot];
 309             actor.(weaponentity).vortex_charge = WEP_CVAR(vortex, charge_start);
 310
 311             if (WEP_CVAR_SEC(vortex, chargepool))
 312                 actor.(weaponentity).vortex_chargepool_ammo = 1;
 313         }
 314     }
 315     actor.vortex_lasthit = 0;
 316 }
 317 METHOD(Vortex, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 318 {
 319     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo)), SND_RELOAD);
 320 }
 321 METHOD(Vortex, wr_suicidemessage, Notification(entity thiswep))
 322 {
 323     return WEAPON_THINKING_WITH_PORTALS;
 324 }
 325 METHOD(Vortex, wr_killmessage, Notification(entity thiswep))
 326 {
 327     return WEAPON_VORTEX_MURDER;
 328 }
 329 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
 330 {
 331     return PHYS_INPUT_BUTTON_ATCK2(actor) && !WEP_CVAR(vortex, secondary);
 332 }
 333
 334 #endif
 335 #ifdef CSQC
 336
 337 METHOD(Vortex, wr_impacteffect, void(entity thiswep, entity actor))
 338 {
 339     entity this = actor;
 340     vector org2 = w_org + w_backoff * 6;
 341     pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
 342     if(!w_issilent)
 343         sound(this, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM);
 344 }
 345 METHOD(Vortex, wr_init, void(entity thiswep))
 346 {
 347     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 348     {
 349         precache_pic("gfx/reticle_nex");
 350     }
 351 }
 352 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
 353 {
 354     if(button_zoom || zoomscript_caught || (!WEP_CVAR(vortex, secondary) && button_attack2))
 355     {
 356         return true;
 357     }
 358     else
 359     {
 360         // no weapon specific image for this weapon
 361         return false;
 362     }
 363 }
 364 METHOD(Vortex, wr_zoomdir, bool(entity thiswep))
 365 {
 366     return button_attack2 && !WEP_CVAR(vortex, secondary);
 367 }
 368
 369 #endif