qcsrc/common/weapons/weapon/vortex.qc

   1 #include "vortex.qh"
   2
   3 //REGISTER_STAT(WEP_CVAR_vortex_charge, bool, WEP_CVAR(vortex, charge))
   4 //REGISTER_STAT(WEP_CVAR_vortex_charge_animlimit, float, WEP_CVAR(vortex, charge_animlimit))
   5
   6 #if defined(GAMEQC)
   7 float autocvar_g_weapon_charge_colormod_red_full;
   8 float autocvar_g_weapon_charge_colormod_red_half;
   9 float autocvar_g_weapon_charge_colormod_green_full;
  10 float autocvar_g_weapon_charge_colormod_blue_full;
  11 float autocvar_g_weapon_charge_colormod_blue_half;
  12 float autocvar_g_weapon_charge_colormod_green_half;
  13 float autocvar_g_weapon_charge_colormod_hdrmultiplier;
  14
  15 METHOD(Vortex, wr_glow, vector(Vortex this, entity actor, entity wepent))
  16 {
  17         if (!WEP_CVAR(vortex, charge)) return '0 0 0';
  18         float charge = wepent.vortex_charge;
  19         float animlimit = WEP_CVAR(vortex, charge_animlimit);
  20         float f = autocvar_g_weapon_charge_colormod_hdrmultiplier * min(1, charge / animlimit);
  21         vector g;
  22         g.x = f * autocvar_g_weapon_charge_colormod_red_half;
  23         g.y = f * autocvar_g_weapon_charge_colormod_green_half;
  24         g.z = f * autocvar_g_weapon_charge_colormod_blue_half;
  25         if (charge > animlimit)
  26         {
  27                 f = autocvar_g_weapon_charge_colormod_hdrmultiplier * (charge - animlimit) / (1 - animlimit);
  28                 g.x += f * autocvar_g_weapon_charge_colormod_red_full;
  29                 g.y += f * autocvar_g_weapon_charge_colormod_green_full;
  30                 g.z += f * autocvar_g_weapon_charge_colormod_blue_full;
  31         }
  32         // transition color can't be '0 0 0' as it defaults to player model glow color
  33         if (g == '0 0 0')
  34                 g = '0 0 0.000001';
  35         return g;
  36 }
  37 #endif
  38
  39 REGISTER_NET_TEMP(TE_CSQC_VORTEXBEAMPARTICLE)
  40
  41 #if defined(SVQC)
  42 void SendCSQCVortexBeamParticle(float charge) {
  43         vector v;
  44         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  45         WriteHeader(MSG_BROADCAST, TE_CSQC_VORTEXBEAMPARTICLE);
  46         WriteVector(MSG_BROADCAST, w_shotorg);
  47         WriteVector(MSG_BROADCAST, v);
  48         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  49 }
  50 #elif defined(CSQC)
  51 NET_HANDLE(TE_CSQC_VORTEXBEAMPARTICLE, bool isNew)
  52 {
  53         float charge;
  54         vector shotorg = ReadVector();
  55         vector endpos = ReadVector();
  56         charge = ReadByte() / 255.0;
  57
  58         //pointparticles(EFFECT_VORTEX_MUZZLEFLASH, shotorg, normalize(endpos - shotorg) * 1000, 1);
  59
  60         //draw either the old v2.3 beam or the new beam
  61         charge = sqrt(charge); // divide evenly among trail spacing and alpha
  62         particles_alphamin = particles_alphamax = particles_fade = charge;
  63
  64         if(!MUTATOR_CALLHOOK(Particles_VortexBeam, shotorg, endpos))
  65         {
  66                 if(autocvar_cl_particles_oldvortexbeam && (STAT(ALLOW_OLDVORTEXBEAM) || isdemo()))
  67                         WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  68                 else
  69                         WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  70         }
  71         return true;
  72 }
  73 #endif
  74
  75 #ifdef SVQC
  76
  77 REGISTER_MUTATOR(vortex_charge, true);
  78
  79 MUTATOR_HOOKFUNCTION(vortex_charge, GetPressedKeys)
  80 {
  81     entity player = M_ARGV(0, entity);
  82
  83         // WEAPONTODO
  84     if(!WEP_CVAR(vortex, charge) || !WEP_CVAR(vortex, charge_velocity_rate))
  85         return;
  86
  87     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  88     {
  89         .entity weaponentity = weaponentities[slot];
  90
  91         if (player.(weaponentity).m_weapon == WEP_VORTEX && WEP_CVAR(vortex, charge) && WEP_CVAR(vortex, charge_velocity_rate) && vdist(vec2(player.velocity), >, WEP_CVAR(vortex, charge_minspeed)))
  92         {
  93             float xyspeed = vlen(vec2(player.velocity));
  94                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
  95                 xyspeed = min(xyspeed, WEP_CVAR(vortex, charge_maxspeed));
  96                 float f = (xyspeed - WEP_CVAR(vortex, charge_minspeed)) / (WEP_CVAR(vortex, charge_maxspeed) - WEP_CVAR(vortex, charge_minspeed));
  97                 // add the extra charge
  98                 player.(weaponentity).vortex_charge = min(1, player.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_velocity_rate) * f * PHYS_INPUT_TIMELENGTH);
  99         }
 100     }
 101 }
 102
 103 void W_Vortex_Attack(Weapon thiswep, entity actor, .entity weaponentity, float issecondary)
 104 {
 105         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
 106
 107         mydmg = WEP_CVAR_BOTH(vortex, !issecondary, damage);
 108         myforce = WEP_CVAR_BOTH(vortex, !issecondary, force);
 109         mymindist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_mindist);
 110         mymaxdist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_maxdist);
 111         myhalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_halflife);
 112         myforcehalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_forcehalflife);
 113         myammo = WEP_CVAR_BOTH(vortex, !issecondary, ammo);
 114
 115         float dtype = thiswep.m_id;
 116         if(WEP_CVAR_BOTH(vortex, !issecondary, armorpierce))
 117                 dtype |= HITTYPE_ARMORPIERCE;
 118
 119         float flying;
 120         flying = IsFlying(actor); // do this BEFORE to make the trace values from FireRailgunBullet last
 121
 122         if(WEP_CVAR(vortex, charge))
 123         {
 124                 charge = WEP_CVAR(vortex, charge_mindmg) / mydmg + (1 - WEP_CVAR(vortex, charge_mindmg) / mydmg) * actor.(weaponentity).vortex_charge;
 125                 actor.(weaponentity).vortex_charge *= WEP_CVAR(vortex, charge_shot_multiplier); // do this AFTER setting mydmg/myforce
 126                 // O RLY? -- divVerent
 127                 // YA RLY -- FruitieX
 128         }
 129         else
 130                 charge = 1;
 131         mydmg *= charge;
 132         myforce *= charge;
 133
 134         W_SetupShot(actor, weaponentity, true, 5, SND_NEXFIRE, CH_WEAPON_A, mydmg, dtype);
 135         if(charge > WEP_CVAR(vortex, charge_animlimit) && WEP_CVAR(vortex, charge_animlimit)) // if the Vortex is overcharged, we play an extra sound
 136         {
 137                 sound(actor, CH_WEAPON_B, SND_NEXCHARGE, VOL_BASE * (charge - 0.5 * WEP_CVAR(vortex, charge_animlimit)) / (1 - 0.5 * WEP_CVAR(vortex, charge_animlimit)), ATTN_NORM);
 138         }
 139
 140         yoda = 0;
 141         damage_goodhits = 0;
 142         FireRailgunBullet(actor, weaponentity, w_shotorg, w_shotorg + w_shotdir * max_shot_distance, mydmg, false, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, dtype);
 143
 144         if(yoda && flying)
 145                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 146         if(damage_goodhits && actor.vortex_lasthit)
 147         {
 148                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
 149                 damage_goodhits = 0; // only every second time
 150         }
 151
 152         actor.vortex_lasthit = damage_goodhits;
 153
 154         //beam done on client
 155         vector v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 156         W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, normalize(v - w_shotorg));
 157         SendCSQCVortexBeamParticle(charge);
 158
 159         W_DecreaseAmmo(thiswep, actor, myammo, weaponentity);
 160 }
 161
 162 .float vortex_chargepool_pauseregen_finished;
 163
 164 void W_Vortex_Charge(entity actor, .entity weaponentity, float dt)
 165 {
 166     if(WEP_CVAR(vortex, charge) && actor.(weaponentity).vortex_charge < WEP_CVAR(vortex, charge_limit))
 167         actor.(weaponentity).vortex_charge = min(1, actor.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_rate) * dt / W_TICSPERFRAME);
 168 }
 169
 170 METHOD(Vortex, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 171 {
 172     if(bot_aim(actor, weaponentity, 1000000, 0, 1, false))
 173         PHYS_INPUT_BUTTON_ATCK(actor) = true;
 174     else
 175     {
 176         if(WEP_CVAR(vortex, charge))
 177             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 178     }
 179 }
 180 METHOD(Vortex, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 181 {
 182     if(!WEP_CVAR(vortex, charge_always))
 183         W_Vortex_Charge(actor, weaponentity, frametime);
 184
 185     if(WEP_CVAR_SEC(vortex, chargepool))
 186         if(actor.(weaponentity).vortex_chargepool_ammo < 1)
 187         {
 188             if(actor.vortex_chargepool_pauseregen_finished < time)
 189                 actor.(weaponentity).vortex_chargepool_ammo = min(1, actor.(weaponentity).vortex_chargepool_ammo + WEP_CVAR_SEC(vortex, chargepool_regen) * frametime / W_TICSPERFRAME);
 190             actor.pauseregen_finished = max(actor.pauseregen_finished, time + WEP_CVAR_SEC(vortex, chargepool_pause_regen));
 191         }
 192
 193     if(autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo))) { // forced reload
 194         thiswep.wr_reload(thiswep, actor, weaponentity);
 195     } else
 196     {
 197         if(fire & 1)
 198         {
 199             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vortex, refire)))
 200             {
 201                 W_Vortex_Attack(thiswep, actor, weaponentity, 0);
 202                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vortex, animtime), w_ready);
 203             }
 204         }
 205         if((WEP_CVAR(vortex, charge) && !WEP_CVAR(vortex, secondary)) ? (PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) : (fire & 2))
 206         {
 207             if(WEP_CVAR(vortex, charge))
 208             {
 209                 actor.(weaponentity).vortex_charge_rottime = time + WEP_CVAR(vortex, charge_rot_pause);
 210                 float dt = frametime / W_TICSPERFRAME;
 211
 212                 if(actor.(weaponentity).vortex_charge < 1)
 213                 {
 214                     if(WEP_CVAR_SEC(vortex, chargepool))
 215                     {
 216                         if(WEP_CVAR_SEC(vortex, ammo))
 217                         {
 218                             // always deplete if secondary is held
 219                             actor.(weaponentity).vortex_chargepool_ammo = max(0, actor.(weaponentity).vortex_chargepool_ammo - WEP_CVAR_SEC(vortex, ammo) * dt);
 220
 221                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 222                             actor.vortex_chargepool_pauseregen_finished = time + WEP_CVAR_SEC(vortex, chargepool_pause_regen);
 223                             dt = min(dt, actor.(weaponentity).vortex_chargepool_ammo);
 224                             dt = max(0, dt);
 225
 226                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 227                         }
 228                     }
 229
 230                     else if(WEP_CVAR_SEC(vortex, ammo))
 231                     {
 232                         if(fire & 2) // only eat ammo when the button is pressed
 233                         {
 234                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 235                             if(!(actor.items & IT_UNLIMITED_AMMO))
 236                             {
 237                                 // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 238                                 if(autocvar_g_balance_vortex_reload_ammo)
 239                                 {
 240                                     dt = min(dt, (actor.(weaponentity).clip_load - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 241                                     dt = max(0, dt);
 242                                     if(dt > 0)
 243                                     {
 244                                         actor.(weaponentity).clip_load = max(WEP_CVAR_SEC(vortex, ammo), actor.(weaponentity).clip_load - WEP_CVAR_SEC(vortex, ammo) * dt);
 245                                     }
 246                                     actor.(weaponentity).(weapon_load[thiswep.m_id]) = actor.(weaponentity).clip_load;
 247                                 }
 248                                 else
 249                                 {
 250                                     dt = min(dt, (GetResource(actor, thiswep.ammo_type) - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 251                                     dt = max(0, dt);
 252                                     if(dt > 0)
 253                                     {
 254                                         SetResource(actor, thiswep.ammo_type, max(WEP_CVAR_SEC(vortex, ammo), GetResource(actor, thiswep.ammo_type) - WEP_CVAR_SEC(vortex, ammo) * dt));
 255                                     }
 256                                 }
 257                             }
 258                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 259                         }
 260                     }
 261
 262                     else
 263                     {
 264                         dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 265                         actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 266                     }
 267                 }
 268             }
 269             else if(WEP_CVAR(vortex, secondary))
 270             {
 271                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(vortex, refire)))
 272                 {
 273                     W_Vortex_Attack(thiswep, actor, weaponentity, 1);
 274                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(vortex, animtime), w_ready);
 275                 }
 276             }
 277         }
 278     }
 279 }
 280 METHOD(Vortex, wr_setup, void(entity thiswep, entity actor, .entity weaponentity))
 281 {
 282     actor.vortex_lasthit = 0;
 283 }
 284 METHOD(Vortex, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 285 {
 286     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(vortex, ammo);
 287     ammo_amount += (autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(vortex, ammo));
 288     return ammo_amount;
 289 }
 290 METHOD(Vortex, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 291 {
 292     if(WEP_CVAR(vortex, secondary))
 293     {
 294         // don't allow charging if we don't have enough ammo
 295         float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(vortex, ammo);
 296         ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_SEC(vortex, ammo);
 297         return ammo_amount;
 298     }
 299     else
 300     {
 301         return false; // zoom is not a fire mode
 302     }
 303 }
 304 METHOD(Vortex, wr_resetplayer, void(entity thiswep, entity actor))
 305 {
 306     if (WEP_CVAR(vortex, charge)) {
 307         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 308         {
 309             .entity weaponentity = weaponentities[slot];
 310             actor.(weaponentity).vortex_charge = WEP_CVAR(vortex, charge_start);
 311
 312             if (WEP_CVAR_SEC(vortex, chargepool))
 313                 actor.(weaponentity).vortex_chargepool_ammo = 1;
 314         }
 315     }
 316     actor.vortex_lasthit = 0;
 317 }
 318 METHOD(Vortex, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 319 {
 320     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo)), SND_RELOAD);
 321 }
 322 METHOD(Vortex, wr_suicidemessage, Notification(entity thiswep))
 323 {
 324     return WEAPON_THINKING_WITH_PORTALS;
 325 }
 326 METHOD(Vortex, wr_killmessage, Notification(entity thiswep))
 327 {
 328     return WEAPON_VORTEX_MURDER;
 329 }
 330 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
 331 {
 332     return PHYS_INPUT_BUTTON_ATCK2(actor) && !WEP_CVAR(vortex, secondary);
 333 }
 334
 335 #endif
 336 #ifdef CSQC
 337
 338 METHOD(Vortex, wr_impacteffect, void(entity thiswep, entity actor))
 339 {
 340     entity this = actor;
 341     vector org2 = w_org + w_backoff * 6;
 342     pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
 343     if(!w_issilent)
 344         sound(this, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM);
 345 }
 346 METHOD(Vortex, wr_init, void(entity thiswep))
 347 {
 348     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 349     {
 350         precache_pic("gfx/reticle_nex");
 351     }
 352 }
 353 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
 354 {
 355     if(button_zoom || zoomscript_caught || (!WEP_CVAR(vortex, secondary) && button_attack2))
 356     {
 357         return true;
 358     }
 359     else
 360     {
 361         // no weapon specific image for this weapon
 362         return false;
 363     }
 364 }
 365 METHOD(Vortex, wr_zoomdir, bool(entity thiswep))
 366 {
 367     return button_attack2 && !WEP_CVAR(vortex, secondary);
 368 }
 369
 370 #endif