qcsrc/common/weapons/weapon/vortex.qc

   1 #include "vortex.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(Vortex, Weapon)
   4 /* ammotype  */ ATTRIB(Vortex, ammo_field, .int, ammo_cells);
   5 /* impulse   */ ATTRIB(Vortex, impulse, int, 7);
   6 /* flags     */ ATTRIB(Vortex, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN);
   7 /* rating    */ ATTRIB(Vortex, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   8 /* color     */ ATTRIB(Vortex, wpcolor, vector, '0.5 1 1');
   9 /* modelname */ ATTRIB(Vortex, mdl, string, "nex");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(Vortex, m_model, Model, MDL_VORTEX_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(Vortex, w_crosshair, string, "gfx/crosshairnex");
  14 /* crosshair */ ATTRIB(Vortex, w_crosshair_size, float, 0.65);
  15 /* wepimg    */ ATTRIB(Vortex, model2, string, "weaponnex");
  16 /* refname   */ ATTRIB(Vortex, netname, string, "vortex");
  17 /* wepname   */ ATTRIB(Vortex, m_name, string, _("Vortex"));
  18
  19 #define X(BEGIN, P, END, class, prefix) \
  20         BEGIN(class) \
  21                 P(class, prefix, ammo, float, BOTH) \
  22                 P(class, prefix, animtime, float, BOTH) \
  23                 P(class, prefix, chargepool, float, SEC) \
  24                 P(class, prefix, chargepool_pause_regen, float, SEC) \
  25                 P(class, prefix, chargepool_regen, float, SEC) \
  26                 P(class, prefix, charge, float, NONE) \
  27                 P(class, prefix, charge_animlimit, float, NONE) \
  28                 P(class, prefix, charge_limit, float, NONE) \
  29                 P(class, prefix, charge_maxspeed, float, NONE) \
  30                 P(class, prefix, charge_mindmg, float, NONE) \
  31                 P(class, prefix, charge_minspeed, float, NONE) \
  32                 P(class, prefix, charge_rate, float, NONE) \
  33                 P(class, prefix, charge_rot_pause, float, NONE) \
  34                 P(class, prefix, charge_rot_rate, float, NONE) \
  35                 P(class, prefix, charge_shot_multiplier, float, NONE) \
  36                 P(class, prefix, charge_start, float, NONE) \
  37                 P(class, prefix, charge_velocity_rate, float, NONE) \
  38                 P(class, prefix, damagefalloff_forcehalflife, float, BOTH) \
  39                 P(class, prefix, damagefalloff_halflife, float, BOTH) \
  40                 P(class, prefix, damagefalloff_maxdist, float, BOTH) \
  41                 P(class, prefix, damagefalloff_mindist, float, BOTH) \
  42                 P(class, prefix, damage, float, BOTH) \
  43                 P(class, prefix, force, float, BOTH) \
  44                 P(class, prefix, refire, float, BOTH) \
  45                 P(class, prefix, secondary, float, NONE) \
  46                 P(class, prefix, reload_ammo, float, NONE) \
  47         P(class, prefix, reload_time, float, NONE) \
  48         P(class, prefix, switchdelay_raise, float, NONE) \
  49         P(class, prefix, switchdelay_drop, float, NONE) \
  50         P(class, prefix, weaponreplace, string, NONE) \
  51         P(class, prefix, weaponstart, float, NONE) \
  52         P(class, prefix, weaponstartoverride, float, NONE) \
  53         P(class, prefix, weaponthrowable, float, NONE) \
  54         END()
  55     W_PROPS(X, Vortex, vortex)
  56 #undef X
  57
  58 ENDCLASS(Vortex)
  59 REGISTER_WEAPON(VORTEX, vortex, NEW(Vortex));
  60
  61
  62 #ifdef SVQC
  63
  64 .float vortex_lasthit;
  65 #endif
  66 #endif
  67 #ifdef IMPLEMENTATION
  68
  69 REGISTER_STAT(WEP_CVAR_vortex_charge, bool, WEP_CVAR(vortex, charge))
  70 REGISTER_STAT(WEP_CVAR_vortex_charge_animlimit, float, WEP_CVAR(vortex, charge_animlimit))
  71
  72 #if defined(GAMEQC)
  73 float autocvar_g_weapon_charge_colormod_red_full;
  74 float autocvar_g_weapon_charge_colormod_red_half;
  75 float autocvar_g_weapon_charge_colormod_green_full;
  76 float autocvar_g_weapon_charge_colormod_blue_full;
  77 float autocvar_g_weapon_charge_colormod_blue_half;
  78 float autocvar_g_weapon_charge_colormod_green_half;
  79 float autocvar_g_weapon_charge_colormod_hdrmultiplier;
  80
  81 METHOD(Vortex, wr_glow, vector(Vortex this, entity actor))
  82 {
  83         if (!STAT(WEP_CVAR_vortex_charge, actor)) return '0 0 0';
  84         float charge = STAT(VORTEX_CHARGE, actor);
  85         float animlimit = STAT(WEP_CVAR_vortex_charge_animlimit, actor);
  86         vector g;
  87         g.x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, charge / animlimit);
  88         g.y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, charge / animlimit);
  89         g.z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, charge / animlimit);
  90         if (charge > animlimit)
  91         {
  92                 g.x += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (charge - animlimit) / (1 - animlimit);
  93                 g.y += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (charge - animlimit) / (1 - animlimit);
  94                 g.z += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (charge - animlimit) / (1 - animlimit);
  95         }
  96         return g;
  97 }
  98 #endif
  99
 100 REGISTER_NET_TEMP(TE_CSQC_VORTEXBEAMPARTICLE)
 101
 102 #if defined(SVQC)
 103 void SendCSQCVortexBeamParticle(float charge) {
 104         vector v;
 105         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 106         WriteHeader(MSG_BROADCAST, TE_CSQC_VORTEXBEAMPARTICLE);
 107         WriteCoord(MSG_BROADCAST, w_shotorg.x);
 108         WriteCoord(MSG_BROADCAST, w_shotorg.y);
 109         WriteCoord(MSG_BROADCAST, w_shotorg.z);
 110         WriteCoord(MSG_BROADCAST, v.x);
 111         WriteCoord(MSG_BROADCAST, v.y);
 112         WriteCoord(MSG_BROADCAST, v.z);
 113         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
 114 }
 115 #elif defined(CSQC)
 116 NET_HANDLE(TE_CSQC_VORTEXBEAMPARTICLE, bool isNew)
 117 {
 118         vector shotorg, endpos;
 119         float charge;
 120         shotorg.x = ReadCoord(); shotorg.y = ReadCoord(); shotorg.z = ReadCoord();
 121         endpos.x = ReadCoord(); endpos.y = ReadCoord(); endpos.z = ReadCoord();
 122         charge = ReadByte() / 255.0;
 123
 124         pointparticles(EFFECT_VORTEX_MUZZLEFLASH, shotorg, normalize(endpos - shotorg) * 1000, 1);
 125
 126         //draw either the old v2.3 beam or the new beam
 127         charge = sqrt(charge); // divide evenly among trail spacing and alpha
 128         particles_alphamin = particles_alphamax = particles_fade = charge;
 129
 130         if(!MUTATOR_CALLHOOK(Particles_VortexBeam, shotorg, endpos))
 131         if(autocvar_cl_particles_oldvortexbeam && (STAT(ALLOW_OLDVORTEXBEAM) || isdemo()))
 132                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
 133         else
 134                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
 135         return true;
 136 }
 137 #endif
 138
 139 #ifdef SVQC
 140 spawnfunc(weapon_vortex) { weapon_defaultspawnfunc(this, WEP_VORTEX); }
 141 spawnfunc(weapon_nex) { spawnfunc_weapon_vortex(this); }
 142
 143 REGISTER_MUTATOR(vortex_charge, true);
 144
 145 MUTATOR_HOOKFUNCTION(vortex_charge, GetPressedKeys)
 146 {
 147     entity player = M_ARGV(0, entity);
 148
 149         // WEAPONTODO
 150         float xyspeed = vlen(vec2(player.velocity));
 151         if (PS(player).m_weapon == WEP_VORTEX && WEP_CVAR(vortex, charge) && WEP_CVAR(vortex, charge_velocity_rate) && xyspeed > WEP_CVAR(vortex, charge_minspeed))
 152         {
 153                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
 154                 xyspeed = min(xyspeed, WEP_CVAR(vortex, charge_maxspeed));
 155                 float f = (xyspeed - WEP_CVAR(vortex, charge_minspeed)) / (WEP_CVAR(vortex, charge_maxspeed) - WEP_CVAR(vortex, charge_minspeed));
 156                 // add the extra charge
 157                 player.vortex_charge = min(1, player.vortex_charge + WEP_CVAR(vortex, charge_velocity_rate) * f * PHYS_INPUT_TIMELENGTH);
 158         }
 159 }
 160
 161 void W_Vortex_Attack(Weapon thiswep, entity actor, .entity weaponentity, float issecondary)
 162 {
 163         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
 164
 165         mydmg = WEP_CVAR_BOTH(vortex, !issecondary, damage);
 166         myforce = WEP_CVAR_BOTH(vortex, !issecondary, force);
 167         mymindist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_mindist);
 168         mymaxdist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_maxdist);
 169         myhalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_halflife);
 170         myforcehalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_forcehalflife);
 171         myammo = WEP_CVAR_BOTH(vortex, !issecondary, ammo);
 172
 173         float flying;
 174         flying = IsFlying(actor); // do this BEFORE to make the trace values from FireRailgunBullet last
 175
 176         if(WEP_CVAR(vortex, charge))
 177         {
 178                 charge = WEP_CVAR(vortex, charge_mindmg) / mydmg + (1 - WEP_CVAR(vortex, charge_mindmg) / mydmg) * actor.vortex_charge;
 179                 actor.vortex_charge *= WEP_CVAR(vortex, charge_shot_multiplier); // do this AFTER setting mydmg/myforce
 180                 // O RLY? -- divVerent
 181                 // YA RLY -- FruitieX
 182         }
 183         else
 184                 charge = 1;
 185         mydmg *= charge;
 186         myforce *= charge;
 187
 188         W_SetupShot(actor, weaponentity, true, 5, SND_NEXFIRE, CH_WEAPON_A, mydmg);
 189         if(charge > WEP_CVAR(vortex, charge_animlimit) && WEP_CVAR(vortex, charge_animlimit)) // if the Vortex is overcharged, we play an extra sound
 190         {
 191                 sound(actor, CH_WEAPON_B, SND_NEXCHARGE, VOL_BASE * (charge - 0.5 * WEP_CVAR(vortex, charge_animlimit)) / (1 - 0.5 * WEP_CVAR(vortex, charge_animlimit)), ATTN_NORM);
 192         }
 193
 194         yoda = 0;
 195         damage_goodhits = 0;
 196         FireRailgunBullet(actor, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_VORTEX.m_id);
 197
 198         if(yoda && flying)
 199                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 200         if(damage_goodhits && actor.vortex_lasthit)
 201         {
 202                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
 203                 damage_goodhits = 0; // only every second time
 204         }
 205
 206         actor.vortex_lasthit = damage_goodhits;
 207
 208         //beam and muzzle flash done on client
 209         SendCSQCVortexBeamParticle(charge);
 210
 211         W_DecreaseAmmo(thiswep, actor, myammo);
 212 }
 213
 214 .float vortex_chargepool_pauseregen_finished;
 215
 216 METHOD(Vortex, wr_aim, void(entity thiswep, entity actor))
 217 {
 218     if(bot_aim(actor, 1000000, 0, 1, false))
 219         PHYS_INPUT_BUTTON_ATCK(actor) = true;
 220     else
 221     {
 222         if(WEP_CVAR(vortex, charge))
 223             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 224     }
 225 }
 226 METHOD(Vortex, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 227 {
 228     if(WEP_CVAR(vortex, charge) && actor.vortex_charge < WEP_CVAR(vortex, charge_limit))
 229         actor.vortex_charge = min(1, actor.vortex_charge + WEP_CVAR(vortex, charge_rate) * frametime / W_TICSPERFRAME);
 230
 231     if(WEP_CVAR_SEC(vortex, chargepool))
 232         if(actor.vortex_chargepool_ammo < 1)
 233         {
 234             if(actor.vortex_chargepool_pauseregen_finished < time)
 235                 actor.vortex_chargepool_ammo = min(1, actor.vortex_chargepool_ammo + WEP_CVAR_SEC(vortex, chargepool_regen) * frametime / W_TICSPERFRAME);
 236             actor.pauseregen_finished = max(actor.pauseregen_finished, time + WEP_CVAR_SEC(vortex, chargepool_pause_regen));
 237         }
 238
 239     if(autocvar_g_balance_vortex_reload_ammo && actor.clip_load < min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo))) { // forced reload
 240         thiswep.wr_reload(thiswep, actor, weaponentity);
 241     } else
 242     {
 243         if(fire & 1)
 244         {
 245             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vortex, refire)))
 246             {
 247                 W_Vortex_Attack(thiswep, actor, weaponentity, 0);
 248                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vortex, animtime), w_ready);
 249             }
 250         }
 251         if((WEP_CVAR(vortex, charge) && !WEP_CVAR(vortex, secondary)) ? (PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) : (fire & 2))
 252         {
 253             if(WEP_CVAR(vortex, charge))
 254             {
 255                 actor.vortex_charge_rottime = time + WEP_CVAR(vortex, charge_rot_pause);
 256                 float dt = frametime / W_TICSPERFRAME;
 257
 258                 if(actor.vortex_charge < 1)
 259                 {
 260                     if(WEP_CVAR_SEC(vortex, chargepool))
 261                     {
 262                         if(WEP_CVAR_SEC(vortex, ammo))
 263                         {
 264                             // always deplete if secondary is held
 265                             actor.vortex_chargepool_ammo = max(0, actor.vortex_chargepool_ammo - WEP_CVAR_SEC(vortex, ammo) * dt);
 266
 267                             dt = min(dt, (1 - actor.vortex_charge) / WEP_CVAR(vortex, charge_rate));
 268                             actor.vortex_chargepool_pauseregen_finished = time + WEP_CVAR_SEC(vortex, chargepool_pause_regen);
 269                             dt = min(dt, actor.vortex_chargepool_ammo);
 270                             dt = max(0, dt);
 271
 272                             actor.vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 273                         }
 274                     }
 275
 276                     else if(WEP_CVAR_SEC(vortex, ammo))
 277                     {
 278                         if(fire & 2) // only eat ammo when the button is pressed
 279                         {
 280                             dt = min(dt, (1 - actor.vortex_charge) / WEP_CVAR(vortex, charge_rate));
 281                             if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 282                             {
 283                                 // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 284                                 if(autocvar_g_balance_vortex_reload_ammo)
 285                                 {
 286                                     dt = min(dt, (actor.clip_load - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 287                                     dt = max(0, dt);
 288                                     if(dt > 0)
 289                                     {
 290                                         actor.clip_load = max(WEP_CVAR_SEC(vortex, ammo), actor.clip_load - WEP_CVAR_SEC(vortex, ammo) * dt);
 291                                     }
 292                                     actor.(weapon_load[WEP_VORTEX.m_id]) = actor.clip_load;
 293                                 }
 294                                 else
 295                                 {
 296                                     dt = min(dt, (actor.(thiswep.ammo_field) - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 297                                     dt = max(0, dt);
 298                                     if(dt > 0)
 299                                     {
 300                                         actor.(thiswep.ammo_field) = max(WEP_CVAR_SEC(vortex, ammo), actor.(thiswep.ammo_field) - WEP_CVAR_SEC(vortex, ammo) * dt);
 301                                     }
 302                                 }
 303                             }
 304                             actor.vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 305                         }
 306                     }
 307
 308                     else
 309                     {
 310                         dt = min(dt, (1 - actor.vortex_charge) / WEP_CVAR(vortex, charge_rate));
 311                         actor.vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 312                     }
 313                 }
 314             }
 315             else if(WEP_CVAR(vortex, secondary))
 316             {
 317                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(vortex, refire)))
 318                 {
 319                     W_Vortex_Attack(thiswep, actor, weaponentity, 1);
 320                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(vortex, animtime), w_ready);
 321                 }
 322             }
 323         }
 324     }
 325 }
 326 METHOD(Vortex, wr_setup, void(entity thiswep, entity actor))
 327 {
 328     actor.vortex_lasthit = 0;
 329 }
 330 METHOD(Vortex, wr_checkammo1, bool(entity thiswep, entity actor))
 331 {
 332     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(vortex, ammo);
 333     ammo_amount += (autocvar_g_balance_vortex_reload_ammo && actor.(weapon_load[WEP_VORTEX.m_id]) >= WEP_CVAR_PRI(vortex, ammo));
 334     return ammo_amount;
 335 }
 336 METHOD(Vortex, wr_checkammo2, bool(entity thiswep, entity actor))
 337 {
 338     if(WEP_CVAR(vortex, secondary))
 339     {
 340         // don't allow charging if we don't have enough ammo
 341         float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(vortex, ammo);
 342         ammo_amount += actor.(weapon_load[WEP_VORTEX.m_id]) >= WEP_CVAR_SEC(vortex, ammo);
 343         return ammo_amount;
 344     }
 345     else
 346     {
 347         return false; // zoom is not a fire mode
 348     }
 349 }
 350 METHOD(Vortex, wr_resetplayer, void(entity thiswep, entity actor))
 351 {
 352     if (WEP_CVAR(vortex, charge)) {
 353         if (WEP_CVAR_SEC(vortex, chargepool)) {
 354             actor.vortex_chargepool_ammo = 1;
 355         }
 356         actor.vortex_charge = WEP_CVAR(vortex, charge_start);
 357     }
 358     actor.vortex_lasthit = 0;
 359 }
 360 METHOD(Vortex, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 361 {
 362     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo)), SND_RELOAD);
 363 }
 364 METHOD(Vortex, wr_suicidemessage, Notification(entity thiswep))
 365 {
 366     return WEAPON_THINKING_WITH_PORTALS;
 367 }
 368 METHOD(Vortex, wr_killmessage, Notification(entity thiswep))
 369 {
 370     return WEAPON_VORTEX_MURDER;
 371 }
 372
 373 #endif
 374 #ifdef CSQC
 375
 376 METHOD(Vortex, wr_impacteffect, void(entity thiswep, entity actor))
 377 {
 378     entity this = actor;
 379     vector org2 = w_org + w_backoff * 6;
 380     pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
 381     if(!w_issilent)
 382         sound(this, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM);
 383 }
 384 METHOD(Vortex, wr_init, void(entity thiswep))
 385 {
 386     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 387     {
 388         precache_pic("gfx/reticle_nex");
 389     }
 390 }
 391 METHOD(Vortex, wr_zoomreticle, bool(entity thiswep))
 392 {
 393     if(button_zoom || zoomscript_caught || (!WEP_CVAR(vortex, secondary) && button_attack2))
 394     {
 395         reticle_image = "gfx/reticle_nex";
 396         return true;
 397     }
 398     else
 399     {
 400         // no weapon specific image for this weapon
 401         return false;
 402     }
 403 }
 404
 405 #endif
 406 #endif