qcsrc/csqcmodellib/cl_player.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to
   6  * deal in the Software without restriction, including without limitation the
   7  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   8  * sell copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  19  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  20  * IN THE SOFTWARE.
  21  */
  22
  23 var float autocvar_cl_predictionerrorcompensation = 0;
  24
  25 // engine stuff
  26 .float pmove_flags;
  27 float pmove_onground; // weird engine flag we shouldn't really use but have to for now
  28 #define PMF_JUMP_HELD 1
  29 #define PMF_DUCKED 4
  30 #define PMF_ONGROUND 8
  31 #define REFDEFFLAG_TELEPORTED 1
  32 #define REFDEFFLAG_JUMPING 2
  33
  34 entity csqcplayer;
  35 vector csqcplayer_origin, csqcplayer_velocity;
  36 float csqcplayer_sequence, player_pmflags;
  37 float csqcplayer_moveframe;
  38 vector csqcplayer_predictionerror;
  39 float csqcplayer_predictionerrortime;
  40
  41 vector CSQCPlayer_GetPredictionError()
  42 {
  43         if(!autocvar_cl_predictionerrorcompensation)
  44                 return '0 0 0';
  45         if(time < csqcplayer_predictionerrortime)
  46                 return csqcplayer_predictionerror * (csqcplayer_predictionerrortime - time) * autocvar_cl_predictionerrorcompensation;
  47         return '0 0 0';
  48 }
  49
  50 void CSQCPlayer_SetPredictionError(vector v)
  51 {
  52         if(!autocvar_cl_predictionerrorcompensation)
  53                 return;
  54         csqcplayer_predictionerror = (csqcplayer_predictionerrortime - time) * autocvar_cl_predictionerrorcompensation * csqcplayer_predictionerror + v;
  55         csqcplayer_predictionerrortime = time + 1.0 / autocvar_cl_predictionerrorcompensation;
  56 }
  57
  58 void CSQCPlayer_Unpredict()
  59 {
  60         if(csqcplayer_status == CSQCPLAYERSTATUS_UNPREDICTED)
  61                 return;
  62         if(csqcplayer_status != CSQCPLAYERSTATUS_PREDICTED)
  63                 error("Cannot unpredict in current status");
  64         self.origin = csqcplayer_origin;
  65         self.velocity = csqcplayer_velocity;
  66         csqcplayer_moveframe = csqcplayer_sequence+1; //+1 because the recieved frame has the move already done (server side)
  67         self.pmove_flags = player_pmflags;
  68 }
  69
  70 void CSQCPlayer_SetMinsMaxs()
  71 {
  72         if(self.pmove_flags & PMF_DUCKED)
  73         {
  74                 self.mins = PL_CROUCH_MIN;
  75                 self.maxs = PL_CROUCH_MAX;
  76                 self.view_ofs = PL_CROUCH_VIEW_OFS;
  77         }
  78         else
  79         {
  80                 self.mins = PL_MIN;
  81                 self.maxs = PL_MAX;
  82                 self.view_ofs = PL_VIEW_OFS;
  83         }
  84 }
  85
  86 void CSQCPlayer_SavePrediction()
  87 {
  88         player_pmflags = self.pmove_flags;
  89         csqcplayer_origin = self.origin;
  90         csqcplayer_velocity = self.velocity;
  91         csqcplayer_sequence = servercommandframe;
  92         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
  93 }
  94
  95 void CSQCPlayer_PredictTo(float endframe)
  96 {
  97         CSQCPlayer_Unpredict();
  98         CSQCPlayer_SetMinsMaxs();
  99
 100         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 101
 102         if (getstatf(STAT_HEALTH) <= 0)
 103         {
 104                 csqcplayer_moveframe = clientcommandframe;
 105                 getinputstate(csqcplayer_moveframe-1);
 106                 return;
 107         }
 108
 109         while(csqcplayer_moveframe < endframe)
 110         {
 111                 if (!getinputstate(csqcplayer_moveframe))
 112                 {
 113                         break;
 114                 }
 115                 if(input_timelength <= 0.0005) // too short move
 116                 {
 117                         dprint("CSQC physics hack: too short frame skipped\n");
 118                         // even if not running physics, handle releasing the jump key
 119                         if(!(input_buttons & 4))
 120                                 self.pmove_flags &~= PMF_JUMP_HELD;
 121                 }
 122                 else if(input_timelength > 0.05) // too long move
 123                 {
 124                         dprint("CSQC physics hack: too long frame split in two\n");
 125                         input_timelength *= 0.5;
 126                         runstandardplayerphysics(self);
 127                         CSQCPlayer_SetMinsMaxs();
 128                         runstandardplayerphysics(self);
 129                         CSQCPlayer_SetMinsMaxs();
 130                 }
 131                 else
 132                 {
 133                         runstandardplayerphysics(self);
 134                         CSQCPlayer_SetMinsMaxs();
 135                 }
 136                 csqcplayer_moveframe++;
 137         }
 138
 139         //add in anything that was applied after (for low packet rate protocols)
 140         input_angles = view_angles;
 141 }
 142
 143 float CSQCPlayer_IsLocalPlayer()
 144 {
 145         return (self == csqcplayer);
 146 }
 147
 148 void(entity e, float fl) V_CalcRefdef = #640; // DP_CSQC_V_CALCREFDEF
 149
 150 void CSQCPlayer_SetCamera()
 151 {
 152         if(csqcplayer)
 153         {
 154                 entity oldself;
 155                 oldself = self;
 156                 self = csqcplayer;
 157
 158 #ifdef COMPAT_XON050_ENGINE
 159                 if(servercommandframe == 0 || clientcommandframe == 0 || !(checkextension("DP_CSQC_V_CALCREFDEF") || checkextension("DP_CSQC_V_CALCREFDEF_WIP1")))
 160 #else
 161                 if(servercommandframe == 0 || clientcommandframe == 0)
 162 #endif
 163                 {
 164                         InterpolateOrigin_Do();
 165                         self.view_ofs = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 166
 167                         // get crouch state from the server
 168                         if(getstati(STAT_VIEWHEIGHT) == PL_VIEW_OFS_z)
 169                                 self.pmove_flags &~= PMF_DUCKED;
 170                         else if(getstati(STAT_VIEWHEIGHT) == PL_CROUCH_VIEW_OFS_z)
 171                                 self.pmove_flags |= PMF_DUCKED;
 172
 173                         // get onground state from the server
 174                         if(pmove_onground)
 175                                 self.pmove_flags |= PMF_ONGROUND;
 176                         else
 177                                 self.pmove_flags &~= PMF_ONGROUND;
 178
 179                         CSQCPlayer_SetMinsMaxs();
 180
 181                         // override it back just in case
 182                         self.view_ofs = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 183                 }
 184                 else
 185                 {
 186                         if(csqcplayer_status == CSQCPLAYERSTATUS_FROMSERVER)
 187                         {
 188                                 vector o, v;
 189                                 o = self.origin;
 190                                 v = pmove_vel; // TRICK: pmove_vel is set by the engine when we get here. No need to network velocity
 191                                 csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 192                                 CSQCPlayer_PredictTo(servercommandframe + 1);
 193                                 CSQCPlayer_SetPredictionError(o - self.origin);
 194                                 self.origin = o;
 195                                 self.velocity = v;
 196
 197                                 // get crouch state from the server
 198                                 if(getstati(STAT_VIEWHEIGHT) == PL_VIEW_OFS_z)
 199                                         self.pmove_flags &~= PMF_DUCKED;
 200                                 else if(getstati(STAT_VIEWHEIGHT) == PL_CROUCH_VIEW_OFS_z)
 201                                         self.pmove_flags |= PMF_DUCKED;
 202
 203                                 // get onground state from the server
 204                                 if(pmove_onground)
 205                                         self.pmove_flags |= PMF_ONGROUND;
 206                                 else
 207                                         self.pmove_flags &~= PMF_ONGROUND;
 208
 209                                 CSQCPlayer_SavePrediction();
 210                         }
 211                         CSQCPlayer_PredictTo(clientcommandframe + 1);
 212
 213                         CSQCPlayer_SetMinsMaxs();
 214
 215                         self.angles_y = input_angles_y;
 216                 }
 217
 218                 // relink
 219                 setorigin(self, self.origin);
 220
 221                 self = oldself;
 222         }
 223
 224         entity view;
 225 #ifdef COMPAT_XON050_ENGINE
 226         view = CSQCModel_server2csqc((spectatee_status > 0) ? spectatee_status : player_localentnum);
 227 #else
 228         view = CSQCModel_server2csqc(player_localentnum);
 229 #endif
 230
 231 #ifdef COMPAT_XON050_ENGINE
 232         if(view && !(checkextension("DP_CSQC_V_CALCREFDEF") || checkextension("DP_CSQC_V_CALCREFDEF_WIP1")))
 233         {
 234                 // legacy code, not totally correct, but good enough for not having V_CalcRefdef
 235                 setproperty(VF_ORIGIN, view.origin + '0 0 1' * getstati(STAT_VIEWHEIGHT));
 236                 setproperty(VF_ANGLES, view_angles);
 237         }
 238         else
 239 #endif
 240         if(view)
 241         {
 242                 var float refdefflags = 0;
 243
 244                 if(view.csqcmodel_teleported)
 245                         refdefflags |= REFDEFFLAG_TELEPORTED;
 246
 247                 if(input_buttons & 4)
 248                         refdefflags |= REFDEFFLAG_JUMPING;
 249
 250                 V_CalcRefdef(view, refdefflags);
 251         }
 252         else
 253         {
 254                 setproperty(VF_ORIGIN, pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT));
 255                 setproperty(VF_ANGLES, view_angles);
 256         }
 257
 258         { CSQCPLAYER_HOOK_POSTCAMERASETUP }
 259 }
 260
 261 void CSQCPlayer_Remove()
 262 {
 263         if(self.entnum != player_localnum + 1)
 264                 return;
 265         csqcplayer = world;
 266         cvar_clientsettemp("cl_movement_replay", "1");
 267 }
 268
 269 float CSQCPlayer_PreUpdate()
 270 {
 271         if(self.entnum != player_localnum + 1)
 272                 return 0;
 273         cvar_clientsettemp("cl_movement_replay", "0");
 274         if(csqcplayer_status != CSQCPLAYERSTATUS_FROMSERVER)
 275                 CSQCPlayer_Unpredict();
 276         return 1;
 277 }
 278
 279 float CSQCPlayer_PostUpdate()
 280 {
 281         if(self.entnum != player_localentnum)
 282                 return 0;
 283         csqcplayer_status = CSQCPLAYERSTATUS_FROMSERVER;
 284         csqcplayer = self;
 285         self.entremove = CSQCPlayer_Remove;
 286         return 1;
 287 }