qcsrc/ecs/systems/physics.qc

   1 #include "physics.qh"
   2 #include "input.qh"
   3
   4 .int disableclientprediction;
   5
   6 void sys_phys_simulate(entity this, float dt);
   7 void sys_phys_simulate_simple(entity this, float dt);
   8
   9 void sys_phys_postupdate(entity this);
  10
  11 void sys_phys_update(entity this, float dt)
  12 {
  13         if (!IS_CLIENT(this)) {
  14                 sys_phys_simulate_simple(this, dt);
  15                 return;
  16         }
  17         sys_in_update(this, dt);
  18
  19         sys_phys_fix(this, dt);
  20         if (sys_phys_override(this, dt))
  21                 return;
  22
  23         sys_phys_monitor(this, dt);
  24
  25         PHYS_CS(this).movement_old = PHYS_CS(this).movement;
  26         PHYS_CS(this).v_angle_old = this.v_angle;
  27         PHYS_CS(this).buttons_old = PHYS_INPUT_BUTTON_MASK(this);
  28
  29         sys_phys_ai(this);
  30
  31         sys_phys_pregame_hold(this);
  32
  33         if (IS_SVQC) {
  34                 if (this.move_movetype == MOVETYPE_NONE) { return; }
  35                 // when we get here, disableclientprediction cannot be 2
  36                 this.disableclientprediction = (this.move_qcphysics) ? -1 : 0;
  37         }
  38
  39         viewloc_PlayerPhysics(this);
  40
  41         PM_check_frozen(this);
  42
  43         PM_check_blocked(this);
  44
  45         float maxspeed_mod = (!this.in_swamp) ? 1 : this.swamp_slowdown;  // cvar("g_balance_swamp_moverate");
  46
  47 // conveyors: first fix velocity
  48         if (this.conveyor.active) { this.velocity -= this.conveyor.movedir; }
  49         MUTATOR_CALLHOOK(PlayerPhysics, this, dt);
  50
  51         if (!IS_PLAYER(this)) {
  52                 sys_phys_spectator_control(this);
  53                 maxspeed_mod = STAT(SPECTATORSPEED, this);
  54         }
  55         sys_phys_fixspeed(this, maxspeed_mod);
  56
  57         if (IS_DEAD(this)) {
  58                 // handle water here
  59                 vector midpoint = ((this.absmin + this.absmax) * 0.5);
  60                 int cont = pointcontents(midpoint);
  61                 if (cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME) {
  62                         this.velocity = this.velocity * 0.5;
  63
  64                         // do we want this?
  65                         // if(pointcontents(midpoint + '0 0 2') == CONTENT_WATER)
  66                         // { this.velocity_z = 70; }
  67                 }
  68                 sys_phys_postupdate(this);
  69                 return;
  70         }
  71
  72         PM_check_slick(this);
  73
  74         if (IS_SVQC && !PHYS_FIXANGLE(this)) { this.angles = '0 1 0' * this.v_angle.y; }
  75         if (IS_PLAYER(this)) {
  76                 if (IS_ONGROUND(this)) {
  77                         PM_check_hitground(this);
  78                         PM_Footsteps(this);
  79                 } else if (IsFlying(this)) {
  80                         this.wasFlying = true;
  81                 }
  82                 CheckPlayerJump(this);
  83         }
  84
  85         if (this.flags & FL_WATERJUMP) {
  86                 this.velocity_x = this.movedir.x;
  87                 this.velocity_y = this.movedir.y;
  88                 if (this.waterlevel == WATERLEVEL_NONE
  89                     || time > PHYS_TELEPORT_TIME(this)
  90                     || PHYS_WATERJUMP_TIME(this) <= 0
  91                    ) {
  92                         this.flags &= ~FL_WATERJUMP;
  93                         PHYS_TELEPORT_TIME(this) = 0;
  94                         PHYS_WATERJUMP_TIME(this) = 0;
  95                 }
  96         } else if (MUTATOR_CALLHOOK(PM_Physics, this, maxspeed_mod, dt)) {
  97                 // handled
  98         } else if (this.move_movetype == MOVETYPE_NOCLIP
  99             || this.move_movetype == MOVETYPE_FLY
 100             || this.move_movetype == MOVETYPE_FLY_WORLDONLY
 101             || MUTATOR_CALLHOOK(IsFlying, this)) {
 102                 this.com_phys_friction = PHYS_FRICTION(this);
 103                 this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
 104                 this.com_phys_acc_rate = PHYS_ACCELERATE(this) * maxspeed_mod;
 105                 this.com_phys_friction_air = true;
 106                 sys_phys_simulate(this, dt);
 107                 this.com_phys_friction_air = false;
 108         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
 109                 this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
 110                 this.com_phys_acc_rate = PHYS_ACCELERATE(this) * maxspeed_mod;
 111                 this.com_phys_water = true;
 112                 sys_phys_simulate(this, dt);
 113                 this.com_phys_water = false;
 114                 this.jumppadcount = 0;
 115         } else if (time < this.ladder_time) {
 116                 this.com_phys_friction = PHYS_FRICTION(this);
 117                 this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
 118                 this.com_phys_acc_rate = PHYS_ACCELERATE(this) * maxspeed_mod;
 119                 this.com_phys_gravity = '0 0 -1' * PHYS_GRAVITY(this) * dt;
 120                 if (PHYS_ENTGRAVITY(this)) { this.com_phys_gravity *= PHYS_ENTGRAVITY(this); }
 121                 this.com_phys_ladder = true;
 122                 this.com_phys_friction_air = true;
 123                 sys_phys_simulate(this, dt);
 124                 this.com_phys_friction_air = false;
 125                 this.com_phys_ladder = false;
 126                 this.com_phys_gravity = '0 0 0';
 127         } else if (ITEMS_STAT(this) & IT_USING_JETPACK) {
 128                 PM_jetpack(this, maxspeed_mod, dt);
 129         } else if (IS_ONGROUND(this)) {
 130                 if (!WAS_ONGROUND(this)) {
 131                         emit(phys_land, this);
 132                         if (this.lastground < time - 0.3) {
 133                                 this.velocity *= (1 - PHYS_FRICTION_ONLAND(this));
 134                         }
 135                 }
 136                 this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
 137                 this.com_phys_gravity = '0 0 -1' * PHYS_GRAVITY(this) * dt;
 138                 if (PHYS_ENTGRAVITY(this)) { this.com_phys_gravity *= PHYS_ENTGRAVITY(this); }
 139                 this.com_phys_ground = true;
 140                 this.com_phys_vel_2d = true;
 141                 sys_phys_simulate(this, dt);
 142                 this.com_phys_vel_2d = false;
 143                 this.com_phys_ground = false;
 144                 this.com_phys_gravity = '0 0 0';
 145         } else {
 146                 this.com_phys_acc_rate_air = PHYS_AIRACCELERATE(this) * min(maxspeed_mod, 1);
 147                 this.com_phys_acc_rate_air_stop = PHYS_AIRSTOPACCELERATE(this) * maxspeed_mod;
 148                 this.com_phys_acc_rate_air_strafe = PHYS_AIRSTRAFEACCELERATE(this) * maxspeed_mod;
 149                 this.com_phys_vel_max_air_strafe = PHYS_MAXAIRSTRAFESPEED(this) * maxspeed_mod;
 150                 this.com_phys_vel_max_air = PHYS_MAXAIRSPEED(this) * maxspeed_mod;
 151                 this.com_phys_vel_max = PHYS_MAXAIRSPEED(this) * min(maxspeed_mod, 1);
 152                 this.com_phys_air = true;
 153                 this.com_phys_vel_2d = true;
 154                 sys_phys_simulate(this, dt);
 155                 this.com_phys_vel_2d = false;
 156                 this.com_phys_air = false;
 157         }
 158
 159         sys_phys_postupdate(this);
 160 }
 161
 162 void sys_phys_postupdate(entity this)
 163 {
 164         if (IS_ONGROUND(this)) { this.lastground = time; }
 165 // conveyors: then break velocity again
 166         if (this.conveyor.active) { this.velocity += this.conveyor.movedir; }
 167         this.lastflags = this.flags;
 168
 169         this.lastclassname = this.classname;
 170 }
 171
 172 /** for players */
 173 void sys_phys_simulate(entity this, float dt)
 174 {
 175         if (!this.com_phys_ground && !this.com_phys_air) {
 176                 // noclipping
 177                 // flying
 178                 // on a spawnfunc_func_ladder
 179                 // swimming in spawnfunc_func_water
 180                 // swimming
 181                 UNSET_ONGROUND(this);
 182
 183                 if (this.com_phys_friction_air) {
 184                         const vector g = -this.com_phys_gravity;
 185                         this.velocity_z += g.z / 2;
 186                         this.velocity = this.velocity * (1 - dt * this.com_phys_friction);
 187                         this.velocity_z += g.z / 2;
 188                 }
 189         }
 190
 191         if (this.com_phys_water) {
 192                 // water jump only in certain situations
 193                 // this mimics quakeworld code
 194                 if (this.com_in_jump && this.waterlevel == WATERLEVEL_SWIMMING && this.velocity_z >= -180 && !this.viewloc) {
 195                         vector yawangles = '0 1 0' * this.v_angle.y;
 196                         vector forward, right, up;
 197                         MAKE_VECTORS(yawangles, forward, right, up);
 198                         vector spot = this.origin + 24 * forward;
 199                         spot_z += 8;
 200                         traceline(spot, spot, MOVE_NOMONSTERS, this);
 201                         if (trace_startsolid) {
 202                                 spot_z += 24;
 203                                 traceline(spot, spot, MOVE_NOMONSTERS, this);
 204                                 if (!trace_startsolid) {
 205                                         this.velocity = forward * 50;
 206                                         this.velocity_z = 310;
 207                                         UNSET_ONGROUND(this);
 208                                         SET_JUMP_HELD(this);
 209                                 }
 210                         }
 211                 }
 212         }
 213
 214         vector forward, right, up;
 215         MAKE_VECTORS(vmul(this.v_angle, (this.com_phys_vel_2d ? '0 1 0' : '1 1 1')), forward, right, up);
 216         // wishvel = forward * PHYS_CS(this).movement.x + right * PHYS_CS(this).movement.y + up * PHYS_CS(this).movement.z;
 217         vector wishvel = forward * PHYS_CS(this).movement.x
 218             + right * PHYS_CS(this).movement.y
 219             + '0 0 1' * PHYS_CS(this).movement.z * (this.com_phys_vel_2d ? 0 : 1);
 220         if (this.com_phys_water) {
 221                 if (PHYS_INPUT_BUTTON_CROUCH(this)) {
 222                         wishvel.z = -PHYS_MAXSPEED(this);
 223                 }
 224                 if (this.viewloc) {
 225                         wishvel.z = -160;    // drift anyway
 226                 } else if (wishvel == '0 0 0') {
 227                         wishvel = '0 0 -60'; // drift towards bottom
 228                 }
 229         }
 230         if (this.com_phys_ladder) {
 231                 if (this.viewloc) {
 232                         wishvel.z = PHYS_CS(this).movement_old.x;
 233                 }
 234                 if (this.ladder_entity.classname == "func_water") {
 235                         float f = vlen(wishvel);
 236                         if (f > this.ladder_entity.speed) {
 237                                 wishvel *= (this.ladder_entity.speed / f);
 238                         }
 239
 240                         this.watertype = this.ladder_entity.skin;
 241                         f = this.ladder_entity.origin_z + this.ladder_entity.maxs_z;
 242                         if ((this.origin_z + this.view_ofs_z) < f) {
 243                                 this.waterlevel = WATERLEVEL_SUBMERGED;
 244                         } else if ((this.origin_z + (this.mins_z + this.maxs_z) * 0.5) < f) {
 245                                 this.waterlevel = WATERLEVEL_SWIMMING;
 246                         } else if ((this.origin_z + this.mins_z + 1) < f) {
 247                                 this.waterlevel = WATERLEVEL_WETFEET;
 248                         } else {
 249                                 this.waterlevel = WATERLEVEL_NONE;
 250                                 this.watertype = CONTENT_EMPTY;
 251                         }
 252                 }
 253         }
 254         // acceleration
 255         const vector wishdir = normalize(wishvel);
 256         float wishspeed = min(vlen(wishvel), this.com_phys_vel_max);
 257
 258         if (this.com_phys_air) {
 259                 if ((IS_SVQC && time >= PHYS_TELEPORT_TIME(this))
 260                     ||  (IS_CSQC && PHYS_WATERJUMP_TIME(this) <= 0)) {
 261                         // apply air speed limit
 262                         float airaccelqw = PHYS_AIRACCEL_QW(this);
 263                         float wishspeed0 = wishspeed;
 264                         const float maxairspd = this.com_phys_vel_max;
 265                         wishspeed = min(wishspeed, maxairspd);
 266                         if (IS_DUCKED(this)) {
 267                                 wishspeed *= 0.5;
 268                         }
 269                         float airaccel = this.com_phys_acc_rate_air;
 270
 271                         float accelerating = (this.velocity * wishdir > 0);
 272                         float wishspeed2 = wishspeed;
 273
 274                         // CPM: air control
 275                         if (PHYS_AIRSTOPACCELERATE(this)) {
 276                                 vector curdir = normalize(vec2(this.velocity));
 277                                 airaccel += (this.com_phys_acc_rate_air_stop - airaccel) * max(0, -(curdir * wishdir));
 278                         }
 279                         // note that for straight forward jumping:
 280                         // step = accel * dt * wishspeed0;
 281                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 282                         // -->
 283                         // dv/dt = accel * maxspeed (when slow)
 284                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
 285                         // log dv/dt = logaccel + logmaxspeed (when slow)
 286                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
 287                         float strafity = IsMoveInDirection(PHYS_CS(this).movement, -90) + IsMoveInDirection(PHYS_CS(this).movement, +90);  // if one is nonzero, other is always zero
 288                         if (PHYS_MAXAIRSTRAFESPEED(this)) {
 289                                 wishspeed =
 290                                     min(wishspeed,
 291                                         GeomLerp(this.com_phys_vel_max_air, strafity, this.com_phys_vel_max_air_strafe));
 292                         }
 293                         if (PHYS_AIRSTRAFEACCELERATE(this)) {
 294                                 airaccel = GeomLerp(airaccel, strafity, this.com_phys_acc_rate_air_strafe);
 295                         }
 296                         if (PHYS_AIRSTRAFEACCEL_QW(this)) {
 297                                 airaccelqw =
 298                                     (((strafity > 0.5 ? PHYS_AIRSTRAFEACCEL_QW(this) : PHYS_AIRACCEL_QW(this)) >= 0) ? +1 : -1)
 299                                     *
 300                                     (1 - GeomLerp(1 - fabs(PHYS_AIRACCEL_QW(this)), strafity, 1 - fabs(PHYS_AIRSTRAFEACCEL_QW(this))));
 301                         }
 302                         // !CPM
 303
 304                         if (PHYS_WARSOWBUNNY_TURNACCEL(this) && accelerating && PHYS_CS(this).movement.y == 0 && PHYS_CS(this).movement.x != 0) {
 305                                 PM_AirAccelerate(this, dt, wishdir, wishspeed2);
 306                         } else {
 307                                 float sidefric = maxairspd ? (PHYS_AIRACCEL_SIDEWAYS_FRICTION(this) / maxairspd) : 0;
 308                                 PM_Accelerate(this, dt, wishdir, wishspeed, wishspeed0, airaccel, airaccelqw,
 309                                         PHYS_AIRACCEL_QW_STRETCHFACTOR(this), sidefric, PHYS_AIRSPEEDLIMIT_NONQW(this));
 310                         }
 311
 312                         if (PHYS_AIRCONTROL(this)) {
 313                                 CPM_PM_Aircontrol(this, dt, wishdir, wishspeed2);
 314                         }
 315                 }
 316         } else {
 317                 if (this.com_phys_ground && IS_DUCKED(this)) { wishspeed *= 0.5; }
 318                 if (this.com_phys_water) {
 319                         wishspeed *= 0.7;
 320
 321                         //      if (PHYS_WATERJUMP_TIME(this) <= 0) // TODO: use
 322                         {
 323                                 // water friction
 324                                 float f = 1 - dt * PHYS_FRICTION(this);
 325                                 f = min(max(0, f), 1);
 326                                 this.velocity *= f;
 327
 328                                 f = wishspeed - this.velocity * wishdir;
 329                                 if (f > 0) {
 330                                         float accelspeed = min(PHYS_ACCELERATE(this) * dt * wishspeed, f);
 331                                         this.velocity += accelspeed * wishdir;
 332                                 }
 333
 334                                 // holding jump button swims upward slowly
 335                                 if (this.com_in_jump && !this.viewloc) {
 336                                         // was:
 337                                         // lava: 50
 338                                         // slime: 80
 339                                         // water: 100
 340                                         // idea: double those
 341                                         this.velocity_z = 200;
 342                                         if (this.waterlevel >= WATERLEVEL_SUBMERGED) {
 343                                                 this.velocity_z = PHYS_MAXSPEED(this) * 0.7;
 344                                         }
 345                                 }
 346                         }
 347                         if (this.viewloc) {
 348                                 const float addspeed = wishspeed - this.velocity * wishdir;
 349                                 if (addspeed > 0) {
 350                                         const float accelspeed = min(PHYS_ACCELERATE(this) * dt * wishspeed, addspeed);
 351                                         this.velocity += accelspeed * wishdir;
 352                                 }
 353                         } else {
 354                                 // water acceleration
 355                                 PM_Accelerate(this, dt, wishdir, wishspeed, wishspeed, this.com_phys_acc_rate, 1, 0, 0, 0);
 356                         }
 357                         return;
 358                 }
 359                 if (this.com_phys_ground) {
 360                         // apply edge friction
 361                         const float f2 = vlen2(vec2(this.velocity));
 362                         if (f2 > 0) {
 363                                 trace_dphitq3surfaceflags = 0;
 364                                 tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 365                                 // TODO: apply edge friction
 366                                 // apply ground friction
 367                                 const int realfriction = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
 368                                     ? PHYS_FRICTION_SLICK(this)
 369                                         : PHYS_FRICTION(this);
 370
 371                                 float f = sqrt(f2);
 372                                 f = 1 - dt * realfriction
 373                                     * ((f < PHYS_STOPSPEED(this)) ? (PHYS_STOPSPEED(this) / f) : 1);
 374                                 f = max(0, f);
 375                                 this.velocity *= f;
 376                                 /*
 377                                    Mathematical analysis time!
 378
 379                                    Our goal is to invert this mess.
 380
 381                                    For the two cases we get:
 382                                     v = v0 * (1 - dt * (PHYS_STOPSPEED(this) / v0) * PHYS_FRICTION(this))
 383                                       = v0 - dt * PHYS_STOPSPEED(this) * PHYS_FRICTION(this)
 384                                     v0 = v + dt * PHYS_STOPSPEED(this) * PHYS_FRICTION(this)
 385                                    and
 386                                     v = v0 * (1 - dt * PHYS_FRICTION(this))
 387                                     v0 = v / (1 - dt * PHYS_FRICTION(this))
 388
 389                                    These cases would be chosen ONLY if:
 390                                     v0 < PHYS_STOPSPEED(this)
 391                                     v + dt * PHYS_STOPSPEED(this) * PHYS_FRICTION(this) < PHYS_STOPSPEED(this)
 392                                     v < PHYS_STOPSPEED(this) * (1 - dt * PHYS_FRICTION(this))
 393                                    and, respectively:
 394                                     v0 >= PHYS_STOPSPEED(this)
 395                                     v / (1 - dt * PHYS_FRICTION(this)) >= PHYS_STOPSPEED(this)
 396                                     v >= PHYS_STOPSPEED(this) * (1 - dt * PHYS_FRICTION(this))
 397                                  */
 398                         }
 399                         const float addspeed = wishspeed - this.velocity * wishdir;
 400                         if (addspeed > 0) {
 401                                 const float accelspeed = min(PHYS_ACCELERATE(this) * dt * wishspeed, addspeed);
 402                                 this.velocity += accelspeed * wishdir;
 403                         }
 404                         return;
 405                 }
 406
 407                 if (IS_CSQC ? PHYS_WATERJUMP_TIME(this) <= 0 : time >= PHYS_TELEPORT_TIME(this)) {
 408                         PM_Accelerate(this, dt, wishdir, wishspeed, wishspeed, this.com_phys_acc_rate, 1, 0, 0, 0);
 409                 }
 410         }
 411 }
 412
 413 .entity groundentity;
 414 /** for other entities */
 415 void sys_phys_simulate_simple(entity this, float dt)
 416 {
 417         vector mn = this.mins;
 418         vector mx = this.maxs;
 419
 420         vector g = '0 0 0';
 421         if (this.com_phys_gravity_factor && !g) g = '0 0 -1' * PHYS_GRAVITY(NULL);
 422
 423         vector acc = this.com_phys_acc;
 424         vector vel = this.com_phys_vel;
 425         vector pos = this.com_phys_pos;
 426
 427         // SV_Physics_Toss
 428
 429         vel += g * dt;
 430
 431         this.angles += dt * this.avelocity;
 432         float movetime = dt;
 433         for (int i = 0; i < MAX_CLIP_PLANES && movetime > 0; i++) {
 434                 vector push = vel * movetime;
 435                 vector p0 = pos;
 436                 vector p1 = p0 + push;
 437                 // SV_PushEntity
 438                 tracebox(p0, mn, mx, p1, MOVE_NORMAL, this);
 439                 if (!trace_startsolid) {
 440                         bool hit = trace_fraction < 1;
 441                         pos = trace_endpos;
 442                         entity ent = trace_ent;
 443                         // SV_LinkEdict_TouchAreaGrid
 444                         if (this.solid != SOLID_NOT) {
 445                                 FOREACH_ENTITY_RADIUS_ORDERED(0.5 * (this.absmin + this.absmax), 0.5 * vlen(this.absmax - this.absmin), true, {
 446                                         if (it.solid != SOLID_TRIGGER || it == this) continue;
 447                                         if (gettouch(it) && boxesoverlap(it.absmin, it.absmax, this.absmin, this.absmax)) {
 448                                             // SV_LinkEdict_TouchAreaGrid_Call
 449                                             trace_allsolid = false;
 450                                             trace_startsolid = false;
 451                                             trace_fraction = 1;
 452                                             trace_inwater = false;
 453                                             trace_inopen = true;
 454                                             trace_endpos = it.origin;
 455                                             trace_plane_normal = '0 0 1';
 456                                             trace_plane_dist = 0;
 457                                             trace_ent = this;
 458                                             trace_dpstartcontents = 0;
 459                                             trace_dphitcontents = 0;
 460                                             trace_dphitq3surfaceflags = 0;
 461                                             trace_dphittexturename = string_null;
 462                                             gettouch(it)(this, it);
 463                                             vel = this.velocity;
 464                                         }
 465                                 });
 466                         }
 467                         if (hit && this.solid >= SOLID_TRIGGER && (!IS_ONGROUND(this) || this.groundentity != ent)) {
 468                                 // SV_Impact (ent, trace);
 469                                 tracebox(p0, mn, mx, p1, MOVE_NORMAL, this);
 470                                 void(entity, entity) touched = gettouch(this);
 471                                 if (touched && this.solid != SOLID_NOT) {
 472                                         touched(ent, this);
 473                                 }
 474                                 void(entity, entity) touched2 = gettouch(ent);
 475                                 if (this && ent && touched2 && ent.solid != SOLID_NOT) {
 476                                         trace_endpos = ent.origin;
 477                                         trace_plane_normal *= -1;
 478                                         trace_plane_dist *= -1;
 479                                         trace_ent = this;
 480                                         trace_dpstartcontents = 0;
 481                                         trace_dphitcontents = 0;
 482                                         trace_dphitq3surfaceflags = 0;
 483                                         trace_dphittexturename = string_null;
 484                                         touched2(this, ent);
 485                                 }
 486                         }
 487                 }
 488                 // end SV_PushEntity
 489                 if (wasfreed(this)) { return; }
 490                 tracebox(p0, mn, mx, p1, MOVE_NORMAL, this);
 491                 if (trace_fraction == 1) { break; }
 492                 movetime *= 1 - min(1, trace_fraction);
 493                 ClipVelocity(vel, trace_plane_normal, vel, 1);
 494         }
 495
 496         this.com_phys_acc = acc;
 497         this.com_phys_vel = vel;
 498         this.com_phys_pos = pos;
 499         setorigin(this, this.com_phys_pos);
 500 }
 501
 502 void sys_phys_update_single(entity this)
 503 {
 504         sys_phys_simulate_simple(this, frametime);
 505 }