qcsrc/lib/color.qh

   1 #pragma once
   2
   3 #include "string.qh"
   4
   5 #define colormapPaletteColor(c, isPants) colormapPaletteColor_(c, isPants, time)
   6 ERASEABLE
   7 vector colormapPaletteColor_(int c, bool isPants, float t)
   8 {
   9         switch (c)
  10         {
  11                 case  0: return '1.000000 1.000000 1.000000';
  12                 case  1: return '1.000000 0.333333 0.000000';
  13                 case  2: return '0.000000 1.000000 0.501961';
  14                 case  3: return '0.000000 1.000000 0.000000';
  15                 case  4: return '1.000000 0.000000 0.000000';
  16                 case  5: return '0.000000 0.666667 1.000000';
  17                 case  6: return '0.000000 1.000000 1.000000';
  18                 case  7: return '0.501961 1.000000 0.000000';
  19                 case  8: return '0.501961 0.000000 1.000000';
  20                 case  9: return '1.000000 0.000000 1.000000';
  21                 case 10: return '1.000000 0.000000 0.501961';
  22                 case 11: return '0.000000 0.000000 1.000000';
  23                 case 12: return '1.000000 1.000000 0.000000';
  24                 case 13: return '0.000000 0.333333 1.000000';
  25                 case 14: return '1.000000 0.666667 0.000000';
  26                 case 15:
  27                         if (isPants)
  28                                 return '1 0 0' * (0.502 + 0.498 * sin(t / M_E + 0))
  29                                         + '0 1 0' * (0.502 + 0.498 * sin(t / M_E + M_PI * 2 / 3))
  30                                         + '0 0 1' * (0.502 + 0.498 * sin(t / M_E + M_PI * 4 / 3));
  31                         else
  32                                 return '1 0 0' * (0.502 + 0.498 * sin(t / M_PI + M_PI * 5 / 3))
  33                                         + '0 1 0' * (0.502 + 0.498 * sin(t / M_PI + M_PI))
  34                                         + '0 0 1' * (0.502 + 0.498 * sin(t / M_PI + M_PI * 1 / 3));
  35                 default: return '0.000 0.000 0.000';
  36         }
  37 }
  38
  39 ERASEABLE
  40 float rgb_mi_ma_to_hue(vector rgb, float mi, float ma)
  41 {
  42         if (mi == ma)
  43         {
  44                 return 0;
  45         }
  46         else if (ma == rgb.x)
  47         {
  48                 if (rgb.y >= rgb.z) return (rgb.y - rgb.z) / (ma - mi);
  49                 else return (rgb.y - rgb.z) / (ma - mi) + 6;
  50         }
  51         else if (ma == rgb.y)
  52         {
  53                 return (rgb.z - rgb.x) / (ma - mi) + 2;
  54         }
  55         else  // if(ma == rgb_z)
  56         {
  57                 return (rgb.x - rgb.y) / (ma - mi) + 4;
  58         }
  59 }
  60
  61 ERASEABLE
  62 vector hue_mi_ma_to_rgb(float hue, float mi, float ma)
  63 {
  64         vector rgb;
  65
  66         hue -= 6 * floor(hue / 6);
  67
  68         // else if(ma == rgb_x)
  69         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
  70         if (hue <= 1)
  71         {
  72                 rgb.x = ma;
  73                 rgb.y = hue * (ma - mi) + mi;
  74                 rgb.z = mi;
  75         }
  76         // else if(ma == rgb_y)
  77         //      hue = 60 * (rgb_z - rgb_x) / (ma - mi) + 120;
  78         else if (hue <= 2)
  79         {
  80                 rgb.x = (2 - hue) * (ma - mi) + mi;
  81                 rgb.y = ma;
  82                 rgb.z = mi;
  83         }
  84         else if (hue <= 3)
  85         {
  86                 rgb.x = mi;
  87                 rgb.y = ma;
  88                 rgb.z = (hue - 2) * (ma - mi) + mi;
  89         }
  90         // else // if(ma == rgb_z)
  91         //      hue = 60 * (rgb_x - rgb_y) / (ma - mi) + 240;
  92         else if (hue <= 4)
  93         {
  94                 rgb.x = mi;
  95                 rgb.y = (4 - hue) * (ma - mi) + mi;
  96                 rgb.z = ma;
  97         }
  98         else if (hue <= 5)
  99         {
 100                 rgb.x = (hue - 4) * (ma - mi) + mi;
 101                 rgb.y = mi;
 102                 rgb.z = ma;
 103         }
 104         // else if(ma == rgb_x)
 105         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
 106         else  // if(hue <= 6)
 107         {
 108                 rgb.x = ma;
 109                 rgb.y = mi;
 110                 rgb.z = (6 - hue) * (ma - mi) + mi;
 111         }
 112
 113         return rgb;
 114 }
 115
 116 ERASEABLE
 117 vector rgb_to_hsv(vector rgb)
 118 {
 119         float mi, ma;
 120         vector hsv;
 121
 122         mi = min(rgb.x, rgb.y, rgb.z);
 123         ma = max(rgb.x, rgb.y, rgb.z);
 124
 125         hsv.x = rgb_mi_ma_to_hue(rgb, mi, ma);
 126         hsv.z = ma;
 127
 128         if (ma == 0) hsv.y = 0;
 129         else hsv.y = 1 - mi / ma;
 130
 131         return hsv;
 132 }
 133
 134 ERASEABLE
 135 vector hsv_to_rgb(vector hsv)
 136 {
 137         return hue_mi_ma_to_rgb(hsv.x, hsv.z * (1 - hsv.y), hsv.z);
 138 }
 139
 140 ERASEABLE
 141 vector rgb_to_hsl(vector rgb)
 142 {
 143         float mi, ma;
 144         vector hsl;
 145
 146         mi = min(rgb.x, rgb.y, rgb.z);
 147         ma = max(rgb.x, rgb.y, rgb.z);
 148
 149         hsl.x = rgb_mi_ma_to_hue(rgb, mi, ma);
 150
 151         hsl.z = 0.5 * (mi + ma);
 152         if (mi == ma) hsl.y = 0;
 153         else if (hsl.z <= 0.5) hsl.y = (ma - mi) / (2 * hsl.z);
 154         else  // if(hsl_z > 0.5)
 155                 hsl.y = (ma - mi) / (2 - 2 * hsl.z);
 156
 157         return hsl;
 158 }
 159
 160 ERASEABLE
 161 vector hsl_to_rgb(vector hsl)
 162 {
 163         float mi, ma, maminusmi;
 164
 165         if (hsl.z <= 0.5) maminusmi = hsl.y * 2 * hsl.z;
 166         else maminusmi = hsl.y * (2 - 2 * hsl.z);
 167
 168         // hsl_z     = 0.5 * mi + 0.5 * ma
 169         // maminusmi =     - mi +       ma
 170         mi = hsl.z - 0.5 * maminusmi;
 171         ma = hsl.z + 0.5 * maminusmi;
 172
 173         return hue_mi_ma_to_rgb(hsl.x, mi, ma);
 174 }
 175
 176 ERASEABLE
 177 string rgb_to_hexcolor(vector rgb)
 178 {
 179         return strcat(
 180                 "^x",
 181                 DEC_TO_HEXDIGIT(floor(rgb.x * 15 + 0.5)),
 182                 DEC_TO_HEXDIGIT(floor(rgb.y * 15 + 0.5)),
 183                 DEC_TO_HEXDIGIT(floor(rgb.z * 15 + 0.5))
 184                      );
 185 }