qcsrc/lib/csqcmodel/cl_player.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  * Copyright (c) 2015 Micah Talkiewicz
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a copy
   6  * of this software and associated documentation files (the "Software"), to
   7  * deal in the Software without restriction, including without limitation the
   8  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   9  * sell copies of the Software, and to permit persons to whom the Software is
  10  * furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice shall be included in
  13  * all copies or substantial portions of the Software.
  14  *
  15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  20  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  21  * IN THE SOFTWARE.
  22  */
  23 #include "cl_player.qh"
  24
  25 #include "cl_model.qh"
  26 #include "common.qh"
  27 #include "interpolate.qh"
  28
  29 float autocvar_cl_movement_errorcompensation = 0;
  30 bool autocvar_cl_movement_intermissionrunning = false;
  31
  32 // engine stuff
  33 float pmove_onground; // weird engine flag we shouldn't really use but have to for now
  34
  35 vector csqcplayer_origin, csqcplayer_velocity;
  36 float csqcplayer_sequence;
  37 int player_pmflags;
  38 float csqcplayer_moveframe;
  39 vector csqcplayer_predictionerroro;
  40 vector csqcplayer_predictionerrorv;
  41 float csqcplayer_predictionerrortime;
  42 float csqcplayer_predictionerrorfactor;
  43
  44 vector CSQCPlayer_GetPredictionErrorO()
  45 {
  46         if (time >= csqcplayer_predictionerrortime) return '0 0 0';
  47         return csqcplayer_predictionerroro * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
  48 }
  49
  50 vector CSQCPlayer_GetPredictionErrorV()
  51 {
  52         if (time >= csqcplayer_predictionerrortime) return '0 0 0';
  53         return csqcplayer_predictionerrorv * (csqcplayer_predictionerrortime - time) * csqcplayer_predictionerrorfactor;
  54 }
  55
  56 void CSQCPlayer_SetPredictionError(vector o, vector v, float onground_diff)
  57 {
  58         // error too big to compensate, we LIKELY hit a teleport or a
  59         // jumppad, or it's a jump time disagreement that'll get fixed
  60         // next frame
  61
  62         // FIXME we sometimes have disagreement in order of jump velocity. Do not act on them!
  63         /*
  64         // commented out as this one did not help
  65         if(onground_diff)
  66         {
  67                 printf("ONGROUND MISMATCH: %d x=%v v=%v\n", onground_diff, o, v);
  68                 return;
  69         }
  70         */
  71         if(vdist(o, >, 32) || vdist(v, >, 192))
  72         {
  73                 //printf("TOO BIG: x=%v v=%v\n", o, v);
  74                 return;
  75         }
  76
  77         if(!autocvar_cl_movement_errorcompensation)
  78         {
  79                 csqcplayer_predictionerrorfactor = 0;
  80                 return;
  81         }
  82
  83         csqcplayer_predictionerroro = CSQCPlayer_GetPredictionErrorO() + o;
  84         csqcplayer_predictionerrorv = CSQCPlayer_GetPredictionErrorV() + v;
  85         csqcplayer_predictionerrorfactor = autocvar_cl_movement_errorcompensation / ((ticrate) ? ticrate : 1);
  86         csqcplayer_predictionerrortime = time + 1.0 / csqcplayer_predictionerrorfactor;
  87 }
  88
  89 void CSQCPlayer_Unpredict(entity this)
  90 {
  91         if (csqcplayer_status == CSQCPLAYERSTATUS_UNPREDICTED) return;
  92         if (csqcplayer_status != CSQCPLAYERSTATUS_PREDICTED) LOG_FATALF("Cannot unpredict in current status (%d)", csqcplayer_status);
  93         this.origin = csqcplayer_origin;
  94         this.velocity = csqcplayer_velocity;
  95         csqcplayer_moveframe = csqcplayer_sequence + 1; // + 1 because the recieved frame has the move already done (server side)
  96         this.flags = player_pmflags;
  97 }
  98
  99 void CSQCPlayer_SetMinsMaxs(entity this)
 100 {
 101         if (IS_DUCKED(this) || !(this.isplayermodel & ISPLAYER_PLAYER))
 102         {
 103                 this.mins = PHYS_PL_CROUCH_MIN(this);
 104                 this.maxs = PHYS_PL_CROUCH_MAX(this);
 105                 this.view_ofs = PHYS_PL_CROUCH_VIEWOFS(this);
 106         }
 107         else
 108         {
 109                 this.mins = PHYS_PL_MIN(this);
 110                 this.maxs = PHYS_PL_MAX(this);
 111                 if (IS_DEAD(this))
 112                         this.maxs.z = 5;
 113                 this.view_ofs = PHYS_PL_VIEWOFS(this);
 114         }
 115 }
 116
 117 void CSQCPlayer_SavePrediction(entity this)
 118 {
 119         player_pmflags = this.flags;
 120         csqcplayer_origin = this.origin;
 121         csqcplayer_velocity = this.velocity;
 122         csqcplayer_sequence = servercommandframe;
 123         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 124 }
 125
 126 void CSQC_ClientMovement_PlayerMove_Frame(entity this);
 127
 128 void CSQCPlayer_Physics(entity this)
 129 {
 130         if(!autocvar_cl_movement) { return; }
 131
 132         //_Movetype_CheckWater(this); // we apparently need to check water *before* physics so it can use this for water jump
 133
 134         vector oldv_angle = this.v_angle;
 135         vector oldangles = this.angles; // we need to save these, as they're abused by other code
 136         this.v_angle = PHYS_INPUT_ANGLES(this);
 137         this.angles = PHYS_WORLD_ANGLES(this);
 138
 139         CSQC_ClientMovement_PlayerMove_Frame(this);
 140
 141         Movetype_Physics_NoMatchTicrate(this, PHYS_INPUT_TIMELENGTH, true);
 142
 143         view_angles = this.v_angle;
 144         input_angles = this.angles;
 145         this.v_angle = oldv_angle;
 146         this.angles = oldangles;
 147
 148         this.pmove_flags =
 149                         ((IS_DUCKED(this)) ? PMF_DUCKED : 0) |
 150                         ((IS_JUMP_HELD(this)) ? PMF_JUMP_HELD : 0) |
 151                         ((IS_ONGROUND(this)) ? PMF_ONGROUND : 0);
 152 }
 153
 154 void CSQCPlayer_PredictTo(entity this, float endframe, bool apply_error)
 155 {
 156         CSQCPlayer_Unpredict(this);
 157         if (apply_error)
 158         {
 159                 this.origin += CSQCPlayer_GetPredictionErrorO();
 160                 this.velocity += CSQCPlayer_GetPredictionErrorV();
 161         }
 162         CSQCPlayer_SetMinsMaxs(this);
 163
 164         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 165
 166 #if 0
 167         // we don't need this
 168         // darkplaces makes servercommandframe == 0 in these cases anyway
 169         if (STAT(HEALTH) <= 0)
 170         {
 171                 csqcplayer_moveframe = clientcommandframe;
 172                 getinputstate(csqcplayer_moveframe-1);
 173                 LOG_INFO("the Weird code path got hit");
 174                 return;
 175         }
 176 #endif
 177
 178         if (csqcplayer_moveframe >= endframe)
 179         {
 180                 getinputstate(csqcplayer_moveframe - 1);
 181         }
 182         else
 183         {
 184                 do
 185                 {
 186                         if (!getinputstate(csqcplayer_moveframe)) break;
 187                         /*if (input_timelength > 0.0005)
 188                         {
 189                                 if (input_timelength > 0.05)
 190                                 {
 191                                         input_timelength /= 2;
 192                                         CSQCPlayer_Physics(this);
 193                                 }
 194                                 CSQCPlayer_Physics(this);
 195                         }*/
 196                         CSQCPlayer_Physics(this);
 197                         CSQCPlayer_SetMinsMaxs(this);
 198                         ++csqcplayer_moveframe;
 199                 }
 200                 while (csqcplayer_moveframe < endframe);
 201         }
 202
 203         // add in anything that was applied after (for low packet rate protocols)
 204         input_angles = view_angles;
 205 }
 206
 207 bool CSQCPlayer_IsLocalPlayer(entity this)
 208 {
 209         return (this == csqcplayer);
 210 }
 211
 212 float stairsmoothz;
 213 float autocvar_cl_stairsmoothspeed = 200;
 214 float autocvar_cl_smoothviewheight = 0.05;
 215 float smooth_prevtime;
 216 float viewheightavg;
 217 vector CSQCPlayer_ApplySmoothing(entity this, vector v)
 218 {
 219         float smoothtime = bound(0, time - smooth_prevtime, 0.1);
 220         smooth_prevtime = max(smooth_prevtime, drawtime); // drawtime is the previous frame's time at this point
 221
 222         if(this.csqcmodel_teleported || !(this.pmove_flags & PMF_ONGROUND) || autocvar_cl_stairsmoothspeed <= 0 || this.ground_networkentity)
 223                 stairsmoothz = v.z;
 224         else
 225         {
 226                 if(stairsmoothz < v.z)
 227                         v.z = stairsmoothz = bound(v.z - PHYS_STEPHEIGHT(this), stairsmoothz + smoothtime * autocvar_cl_stairsmoothspeed, v.z);
 228                 else if(stairsmoothz > v.z)
 229                         v.z = stairsmoothz = bound(v.z, stairsmoothz - smoothtime * autocvar_cl_stairsmoothspeed, v.z + PHYS_STEPHEIGHT(this));
 230         }
 231
 232         float viewheight = bound(0, (time - smooth_prevtime) / max(0.0001, autocvar_cl_smoothviewheight), 1);
 233         viewheightavg = viewheightavg * (1 - viewheight) + this.view_ofs.z * viewheight;
 234         v.z += viewheightavg;
 235
 236         smooth_prevtime = time;
 237
 238         return v;
 239 }
 240
 241 bool autocvar_v_deathtilt;
 242 float autocvar_v_deathtiltangle;
 243 void CSQCPlayer_ApplyDeathTilt(entity this)
 244 {
 245         if(!this.csqcmodel_isdead || !autocvar_v_deathtilt)
 246                 return;
 247         view_angles.z = autocvar_v_deathtiltangle;
 248 }
 249
 250 float autocvar_v_idlescale;
 251 float autocvar_v_ipitch_cycle;
 252 float autocvar_v_iyaw_cycle;
 253 float autocvar_v_iroll_cycle;
 254 float autocvar_v_ipitch_level;
 255 float autocvar_v_iyaw_level;
 256 float autocvar_v_iroll_level;
 257 void CSQCPlayer_ApplyIdleScaling(entity this)
 258 {
 259         if(!autocvar_v_idlescale)
 260                 return;
 261         view_angles.x += autocvar_v_idlescale * sin(time * autocvar_v_ipitch_cycle) * autocvar_v_ipitch_level;
 262         view_angles.y += autocvar_v_idlescale * sin(time * autocvar_v_iyaw_cycle) * autocvar_v_iyaw_level;
 263         view_angles.z += autocvar_v_idlescale * sin(time * autocvar_v_iroll_cycle) * autocvar_v_iroll_level;
 264         //setproperty(VF_CL_VIEWANGLES, view_angles); // update view angles as well so we can aim
 265 }
 266
 267 float autocvar_cl_bob = 0;
 268 float autocvar_cl_bobcycle = 0.5;
 269 float autocvar_cl_bob_limit = 7;
 270 float autocvar_cl_bob_limit_heightcheck = 0;
 271 float autocvar_cl_bob_velocity_limit = 400;
 272 float autocvar_cl_bobup = 0.5;
 273 float autocvar_cl_bobfall = 0.05;
 274 float autocvar_cl_bobfallcycle = 3;
 275 float autocvar_cl_bobfallminspeed = 200;
 276 float autocvar_cl_bob2 = 0;
 277 float autocvar_cl_bob2cycle = 1;
 278 float autocvar_cl_bob2smooth = 0.05;
 279 float bobfall_swing;
 280 float bobfall_speed;
 281 float bob2_smooth;
 282 vector CSQCPlayer_ApplyBobbing(entity this, vector v)
 283 {
 284         if(this.csqcmodel_isdead)
 285                 return v;
 286
 287         // bounded XY speed, used by several effects below
 288         float bob, cycle;
 289
 290         // vertical view bobbing code
 291         if(autocvar_cl_bob && autocvar_cl_bobcycle)
 292         {
 293                 float bob_limit = autocvar_cl_bob_limit;
 294
 295                 if(autocvar_cl_bob_limit_heightcheck)
 296                 {
 297                         // use traces to determine what range the view can bob in, and scale down the bob as needed
 298                         vector bob_height_check_dest = v;
 299                         bob_height_check_dest.z += autocvar_cl_bob_limit * 1.1;
 300                         traceline(v, bob_height_check_dest, MOVE_NOMONSTERS, NULL);
 301                         float trace1fraction = trace_fraction;
 302
 303                         bob_height_check_dest = v;
 304                         bob_height_check_dest.z += autocvar_cl_bob_limit * -0.5;
 305                         traceline(v, bob_height_check_dest, MOVE_NOMONSTERS, NULL);
 306                         float trace2fraction = trace_fraction;
 307
 308                         bob_limit *= min(trace1fraction, trace2fraction);
 309                 }
 310
 311                 // LordHavoc: figured out bobup: the time at which the sin is at 180
 312                 // degrees (which allows lengthening or squishing the peak or valley)
 313                 cycle = time / autocvar_cl_bobcycle;
 314                 cycle -= rint(cycle);
 315                 if(cycle < autocvar_cl_bobup)
 316                         cycle = sin(M_PI * cycle / autocvar_cl_bobup);
 317                 else
 318                         cycle = sin(M_PI + M_PI * (cycle - autocvar_cl_bobup) / (1.0 - autocvar_cl_bobup));
 319                 // bob is proportional to velocity in the xy plane
 320                 // (don't count Z, or jumping messes it up)
 321                 float xyspeed = bound(0, sqrt(this.velocity.x * this.velocity.x + this.velocity.y * this.velocity.y), autocvar_cl_bob_velocity_limit);
 322                 bob = xyspeed * autocvar_cl_bob;
 323                 bob = bound(0, bob, bob_limit);
 324                 bob = bob * 0.3 + bob * 0.7 * cycle;
 325                 v.z += bob;
 326         }
 327
 328         // horizontal view bobbing code
 329         if(autocvar_cl_bob2 && autocvar_cl_bob2cycle)
 330         {
 331                 cycle = time / autocvar_cl_bob2cycle;
 332                 cycle -= rint(cycle);
 333                 if(cycle < 0.5)
 334                         cycle = cos(M_PI * cycle / 0.5); // cos looks better here with the other view bobbing using sin
 335                 else
 336                         cycle = cos(M_PI + M_PI * (cycle - 0.5) / 0.5);
 337                 bob = autocvar_cl_bob2 * cycle;
 338
 339                 // this value slowly decreases from 1 to 0 when we stop touching the ground.
 340                 // The cycle is later multiplied with it so the view smooths back to normal
 341                 if(IS_ONGROUND(this) && !(input_buttons & BIT(1))) // also block the effect while the jump button is pressed, to avoid twitches when bunny-hopping
 342                         bob2_smooth = 1;
 343                 else
 344                 {
 345                         if(bob2_smooth > 0)
 346                                 bob2_smooth -= bound(0, autocvar_cl_bob2smooth, 1);
 347                         else
 348                                 bob2_smooth = 0;
 349                 }
 350
 351                 // calculate the front and side of the player between the X and Y axes
 352                 makevectors(view_angles);
 353                 // now get the speed based on those angles. The bounds should match the same value as xyspeed's
 354                 float side = bound(-autocvar_cl_bob_velocity_limit, (this.velocity * v_right) * bob2_smooth, autocvar_cl_bob_velocity_limit);
 355                 float front = bound(-autocvar_cl_bob_velocity_limit, (this.velocity * v_forward) * bob2_smooth, autocvar_cl_bob_velocity_limit);
 356                 v_forward = v_forward * bob;
 357                 v_right = v_right * bob;
 358                 // we use side with forward and front with right, so the bobbing goes
 359                 // to the side when we walk forward and to the front when we strafe
 360                 vector bob2vel;
 361                 bob2vel.x = side * v_forward.x + front * v_right.x + 0 * v_up.x;
 362                 bob2vel.y = side * v_forward.y + front * v_right.y + 0 * v_up.y;
 363                 bob2vel.z = side * v_forward.z + front * v_right.z + 0 * v_up.z;
 364                 v.x += bob2vel.x;
 365                 v.y += bob2vel.y;
 366         }
 367
 368         // fall bobbing code
 369         // causes the view to swing down and back up when touching the ground
 370         if(autocvar_cl_bobfall && autocvar_cl_bobfallcycle)
 371         {
 372                 if(!IS_ONGROUND(this))
 373                 {
 374                         bobfall_speed = bound(-400, this.velocity.z, 0) * bound(0, autocvar_cl_bobfall, 0.1);
 375                         if(this.velocity.z < -autocvar_cl_bobfallminspeed)
 376                                 bobfall_swing = 1;
 377                         else
 378                                 bobfall_swing = 0; // really?
 379                 }
 380                 else
 381                 {
 382                         bobfall_swing = max(0, bobfall_swing - autocvar_cl_bobfallcycle * frametime);
 383                         float bobfall = sin(M_PI * bobfall_swing) * bobfall_speed;
 384                         v.z += bobfall;
 385                 }
 386         }
 387
 388         return v;
 389 }
 390
 391 float autocvar_cl_rollangle;
 392 float autocvar_cl_rollspeed;
 393 float CSQCPlayer_CalcRoll(entity this)
 394 {
 395         makevectors(view_angles);
 396         float side = (this.velocity * v_right);
 397         float sign = (side < 0) ? -1 : 1;
 398         side = fabs(side);
 399
 400         if(side < autocvar_cl_rollspeed)
 401                 side = side * autocvar_cl_rollangle / autocvar_cl_rollspeed;
 402         else
 403                 side = autocvar_cl_rollangle;
 404
 405         return side * sign;
 406 }
 407
 408 float autocvar_chase_back;
 409 float autocvar_chase_up;
 410 bool autocvar_chase_overhead;
 411 float autocvar_chase_pitchangle;
 412 vector CSQCPlayer_ApplyChase(entity this, vector v)
 413 {
 414         vector forward;
 415         vector chase_dest;
 416
 417         if(autocvar_chase_overhead)
 418         {
 419                 view_angles.x = 0;
 420                 makevectors(view_angles);
 421                 forward = v_forward;
 422                 vector up = v_up;
 423                 // trace a little further so it hits a surface more consistently (to avoid 'snapping' on the edge of the range)
 424                 chase_dest.x = v.x - forward.x * autocvar_chase_back + up.x * autocvar_chase_up;
 425                 chase_dest.y = v.y - forward.y * autocvar_chase_back + up.y * autocvar_chase_up;
 426                 chase_dest.z = v.z - forward.z * autocvar_chase_back + up.z * autocvar_chase_up;
 427
 428                 // trace from first person view location to our chosen third person view location
 429                 traceline(v, chase_dest, MOVE_NOMONSTERS, NULL);
 430
 431                 vector bestvieworg = trace_endpos;
 432                 vector offset = '0 0 0';
 433                 for(offset.x = -16; offset.x <= 16; offset.x += 8)
 434                 {
 435                         for(offset.y = -16; offset.y <= 16; offset.y += 8)
 436                         {
 437                                 makevectors(view_angles);
 438                                 up = v_up;
 439                                 chase_dest.x = v.x - forward.x * autocvar_chase_back + up.x * autocvar_chase_up + offset.x;
 440                                 chase_dest.y = v.y - forward.y * autocvar_chase_back + up.y * autocvar_chase_up + offset.y;
 441                                 chase_dest.z = v.z - forward.z * autocvar_chase_back + up.z * autocvar_chase_up + offset.z;
 442                                 traceline(v, chase_dest, MOVE_NOMONSTERS, NULL);
 443                                 if(bestvieworg.z > trace_endpos.z)
 444                                         bestvieworg.z = trace_endpos.z;
 445                         }
 446                 }
 447                 bestvieworg.z -= 8;
 448                 v = bestvieworg;
 449
 450                 view_angles.x = autocvar_chase_pitchangle;
 451                 //setproperty(VF_CL_VIEWANGLES, view_angles); // update view angles as well so we can aim
 452         }
 453         else
 454         {
 455                 makevectors(view_angles);
 456                 forward = v_forward;
 457                 // trace a little further so it hits a surface more consistently (to avoid 'snapping' on the edge of the range)
 458                 float cdist = -autocvar_chase_back - 8;
 459                 chase_dest.x = v.x + forward.x * cdist;
 460                 chase_dest.y = v.y + forward.y * cdist;
 461                 chase_dest.z = v.z + forward.z * cdist + autocvar_chase_up;
 462                 traceline(v, chase_dest, MOVE_NOMONSTERS, NULL);
 463                 v.x = 1 * trace_endpos.x + 8 * forward.x + 4 * trace_plane_normal.x;
 464                 v.y = 1 * trace_endpos.y + 8 * forward.y + 4 * trace_plane_normal.y;
 465                 v.z = 1 * trace_endpos.z + 8 * forward.z + 4 * trace_plane_normal.z;
 466         }
 467
 468 #if 0
 469         tracebox(v, '-4 -4 -4', '4 4 4', v - v_forward * autocvar_chase_back, MOVE_NORMAL, this);
 470         v = trace_endpos;
 471         tracebox(v, '-4 -4 -4', '4 4 4', v + v_up * autocvar_chase_up, MOVE_NORMAL, this);
 472         v = trace_endpos;
 473 #endif
 474         return v;
 475 }
 476
 477 void CSQCPlayer_CalcRefdef(entity this)
 478 {
 479         vector vieworg = this.origin;
 480         if(intermission)
 481         {
 482                 // just update view offset, don't need to do anything else
 483                 vieworg.z += this.view_ofs.z;
 484         }
 485         else
 486         {
 487                 vieworg = CSQCPlayer_ApplySmoothing(this, vieworg);
 488                 if(autocvar_chase_active)
 489                         vieworg = CSQCPlayer_ApplyChase(this, vieworg);
 490                 else
 491                 {
 492                         // angles
 493                         CSQCPlayer_ApplyDeathTilt(this);
 494                         view_angles = view_angles + view_punchangle;
 495                         view_angles.z += CSQCPlayer_CalcRoll(this);
 496                         // TODO? we don't have damage time accessible here
 497                         // origin
 498                         vieworg = vieworg + view_punchvector;
 499                         vieworg = CSQCPlayer_ApplyBobbing(this, vieworg);
 500                 }
 501                 CSQCPlayer_ApplyIdleScaling(this);
 502         }
 503         setproperty(VF_ORIGIN, vieworg);
 504         setproperty(VF_ANGLES, view_angles);
 505 }
 506
 507 bool autocvar_cl_useenginerefdef = false;
 508
 509 /** Called once per CSQC_UpdateView() */
 510 void CSQCPlayer_SetCamera()
 511 {
 512         vector v0 = ((intermission && !autocvar_cl_movement_intermissionrunning) ? '0 0 0' : pmove_vel); // TRICK: pmove_vel is set by the engine when we get here. No need to network velocity
 513         float vh = PHYS_VIEWHEIGHT(NULL);
 514         vector pl_viewofs = PHYS_PL_VIEWOFS(NULL);
 515         vector pl_viewofs_crouch = PHYS_PL_CROUCH_VIEWOFS(NULL);
 516         entity e = csqcplayer;
 517         if (e)
 518         {
 519                 if (servercommandframe == 0 || clientcommandframe == 0)
 520                 {
 521                         InterpolateOrigin_Do(e);
 522                         e.view_ofs = '0 0 1' * vh;
 523
 524                         // get crouch state from the server
 525                         if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 526                         else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 527
 528                         // get onground state from the server
 529                         e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
 530
 531                         CSQCPlayer_SetMinsMaxs(e);
 532
 533                         // override it back just in case
 534                         e.view_ofs = '0 0 1' * vh;
 535
 536                         // set velocity
 537                         e.velocity = v0;
 538                 }
 539                 else
 540                 {
 541                         int flg = e.iflags; e.iflags &= ~(IFLAG_ORIGIN | IFLAG_ANGLES);
 542                         InterpolateOrigin_Do(e);
 543                         e.iflags = flg;
 544
 545                         if (csqcplayer_status == CSQCPLAYERSTATUS_FROMSERVER)
 546                         {
 547                                 vector o = e.origin;
 548                                 csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 549                                 CSQCPlayer_PredictTo(e, servercommandframe + 1, false);
 550                                 CSQCPlayer_SetPredictionError(e.origin - o, e.velocity - v0, pmove_onground - IS_ONGROUND(e));
 551                                 e.origin = o;
 552                                 e.velocity = v0;
 553
 554                                 // get crouch state from the server
 555                                 if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 556                                 else if(vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 557
 558                                 // get onground state from the server
 559                                 e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
 560
 561                                 CSQCPlayer_SavePrediction(e);
 562                         }
 563                         CSQCPlayer_PredictTo(e, clientcommandframe + 1, true);
 564
 565 #ifdef CSQCMODEL_SERVERSIDE_CROUCH
 566                         // get crouch state from the server (LAG)
 567                         if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
 568                         else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 569 #endif
 570                         CSQCPlayer_SetMinsMaxs(e);
 571
 572                         if (!IS_DEAD(e))
 573                                 e.angles.y = input_angles.y;
 574                 }
 575
 576                 // relink
 577                 setorigin(e, e.origin);
 578         }
 579
 580         const entity view = CSQCModel_server2csqc(player_localentnum - 1);
 581         if (view)
 582         {
 583                 if (view != csqcplayer)
 584                 {
 585                         InterpolateOrigin_Do(view);
 586                         view.view_ofs = '0 0 1' * vh;
 587                 }
 588                 if(autocvar_cl_useenginerefdef)
 589                 {
 590                         int refdefflags = 0;
 591                         if (view.csqcmodel_teleported) refdefflags |= REFDEFFLAG_TELEPORTED;
 592                         if (input_buttons & BIT(1)) refdefflags |= REFDEFFLAG_JUMPING;
 593                         // note: these two only work in WIP2, but are harmless in WIP1
 594                         if (PHYS_HEALTH(NULL) <= 0 && PHYS_HEALTH(NULL) != -666 && PHYS_HEALTH(NULL) != -2342) refdefflags |= REFDEFFLAG_DEAD;
 595                         if (intermission) refdefflags |= REFDEFFLAG_INTERMISSION;
 596                         V_CalcRefdef(view, refdefflags); // TODO? uses .health stat in the engine when this isn't called here, may be broken!
 597                 }
 598                 else
 599                 {
 600                         CSQCPlayer_CalcRefdef(view);
 601                 }
 602         }
 603         else
 604         {
 605                 // FIXME by CSQC spec we have to do this:
 606                 // but it breaks chase cam
 607                 /*
 608                 setproperty(VF_ORIGIN, pmove_org + '0 0 1' * vh);
 609                 setproperty(VF_ANGLES, view_angles);
 610                 */
 611         }
 612         CSQCPLAYER_HOOK_POSTCAMERASETUP();
 613 }
 614
 615 void CSQCPlayer_Remove(entity this)
 616 {
 617         csqcplayer = NULL;
 618         cvar_settemp("cl_movement_replay", "1");
 619 }
 620
 621 bool CSQCPlayer_PreUpdate(entity this)
 622 {
 623         if (this != csqcplayer) return false;
 624         if (csqcplayer_status != CSQCPLAYERSTATUS_FROMSERVER) CSQCPlayer_Unpredict(this);
 625         return true;
 626 }
 627
 628 bool CSQCPlayer_PostUpdate(entity this)
 629 {
 630         if (this.entnum != player_localnum + 1) return false;
 631         csqcplayer = this;
 632         csqcplayer_status = CSQCPLAYERSTATUS_FROMSERVER;
 633         cvar_settemp("cl_movement_replay", "0");
 634         this.entremove = CSQCPlayer_Remove;
 635         return true;
 636 }