qcsrc/lib/csqcmodel/sv_model.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to
   6  * deal in the Software without restriction, including without limitation the
   7  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   8  * sell copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  19  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  20  * IN THE SOFTWARE.
  21  */
  22 #include "sv_model.qh"
  23
  24 #include "common.qh"
  25 #include <common/animdecide.qh>
  26 #include <common/constants.qh>
  27 #include <common/util.qh>
  28 #include <server/constants.qh>
  29 #include <server/defs.qh>
  30
  31 // generic CSQC model code
  32
  33 bool CSQCModel_Send(entity this, entity to, int sf)
  34 {
  35         // some nice flags for CSQCMODEL_IF
  36         noref bool isplayer = IS_CLIENT(this);
  37         noref bool islocalplayer = (this == to);
  38         noref bool isnolocalplayer = (isplayer && (this != to));
  39
  40         WriteHeader(MSG_ENTITY, ENT_CLIENT_MODEL);
  41         WriteInt24_t(MSG_ENTITY, sf);
  42         WriteByte(MSG_ENTITY, isplayer);
  43
  44 #define CSQCMODEL_IF(cond) if(cond) {
  45 #define CSQCMODEL_ENDIF }
  46 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
  47         if(sf & flag) \
  48         { \
  49                 w(MSG_ENTITY, this.csqcmodel_##f); \
  50         }
  51 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) CSQCMODEL_PROPERTY(flag,t,r,w,f)
  52         ALLPROPERTIES
  53 #undef CSQCMODEL_PROPERTY_SCALED
  54 #undef CSQCMODEL_PROPERTY
  55 #undef CSQCMODEL_ENDIF
  56 #undef CSQCMODEL_IF
  57
  58         return true;
  59 }
  60
  61 #if CSQCPLAYER_FORCE_UPDATES
  62 .float csqcmodel_nextforcedupdate;
  63 #endif
  64 void CSQCModel_CheckUpdate(entity e)
  65 {
  66         // some nice flags for CSQCMODEL_IF
  67         float isplayer = IS_CLIENT(e);
  68         float islocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
  69         float isnolocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
  70
  71         unused_float = isplayer;
  72         unused_float = islocalplayer;
  73         unused_float = isnolocalplayer;
  74
  75 #if CSQCPLAYER_FORCE_UPDATES
  76         if(isplayer && time > e.csqcmodel_nextforcedupdate)
  77         {
  78                 e.SendFlags |= CSQCMODEL_PROPERTY_ORIGIN;
  79                 e.csqcmodel_nextforcedupdate = time + (1 / (CSQCPLAYER_FORCE_UPDATES)) * (0.5 + random()); // ensure about 4 origin sends per sec
  80         }
  81 #endif
  82
  83         if(e.effects & EF_RESTARTANIM_BIT)
  84         {
  85                 e.SendFlags |= CSQCMODEL_PROPERTY_FRAME | CSQCMODEL_PROPERTY_FRAME2; // full anim resend please
  86                 e.effects &= ~EF_RESTARTANIM_BIT;
  87         }
  88
  89         if(e.effects & EF_TELEPORT_BIT)
  90         {
  91                 e.SendFlags |= CSQCMODEL_PROPERTY_TELEPORTED; // no interpolation please
  92                 e.effects &= ~EF_TELEPORT_BIT;
  93         }
  94
  95 #define CSQCMODEL_IF(cond) if(cond) {
  96 #define CSQCMODEL_ENDIF }
  97 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
  98         { \
  99                 t tmp = e.f; \
 100                 if(tmp != e.csqcmodel_##f) \
 101                 { \
 102                         e.csqcmodel_##f = tmp; \
 103                         e.SendFlags |= flag; \
 104                 } \
 105         }
 106 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) \
 107         { \
 108                 t tmp = rint(bound(mi, s * e.f, ma) - mi); \
 109                 if(tmp != e.csqcmodel_##f) \
 110                 { \
 111                         e.csqcmodel_##f = tmp; \
 112                         e.SendFlags |= flag; \
 113                 } \
 114         }
 115         ALLPROPERTIES
 116 #undef CSQCMODEL_PROPERTY_SCALED
 117 #undef CSQCMODEL_PROPERTY
 118 #undef CSQCMODEL_ENDIF
 119 #undef CSQCMODEL_IF
 120 }
 121
 122 void CSQCModel_LinkEntity(entity e)
 123 {
 124         setSendEntity(e, CSQCModel_Send);
 125         e.SendFlags = 0xFFFFFF;
 126         CSQCModel_CheckUpdate(e);
 127 }
 128
 129 void CSQCModel_UnlinkEntity(entity e)
 130 {
 131         setSendEntity(e, func_null);
 132 }