qcsrc/lib/csqcmodel/sv_model.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to
   6  * deal in the Software without restriction, including without limitation the
   7  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   8  * sell copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  19  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  20  * IN THE SOFTWARE.
  21  */
  22 #include "sv_model.qh"
  23
  24 #include "common.qh"
  25 #include <common/animdecide.qh>
  26 #include <common/constants.qh>
  27 #include <common/util.qh>
  28 #include <server/constants.qh>
  29 #include <server/defs.qh>
  30
  31 // generic CSQC model code
  32
  33 bool CSQCModel_Send(entity to, int sf)
  34 {
  35     SELFPARAM();
  36         // some nice flags for CSQCMODEL_IF
  37         noref bool isplayer = IS_CLIENT(this);
  38         noref bool islocalplayer = (this == to);
  39         noref bool isnolocalplayer = (isplayer && (this != to));
  40
  41         WriteHeader(MSG_ENTITY, ENT_CLIENT_MODEL);
  42         WriteInt24_t(MSG_ENTITY, sf);
  43         WriteByte(MSG_ENTITY, isplayer);
  44
  45 #define CSQCMODEL_IF(cond) if(cond) {
  46 #define CSQCMODEL_ENDIF }
  47 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
  48         if(sf & flag) \
  49         { \
  50                 w(MSG_ENTITY, this.csqcmodel_##f); \
  51         }
  52 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) CSQCMODEL_PROPERTY(flag,t,r,w,f)
  53         ALLPROPERTIES
  54 #undef CSQCMODEL_PROPERTY_SCALED
  55 #undef CSQCMODEL_PROPERTY
  56 #undef CSQCMODEL_ENDIF
  57 #undef CSQCMODEL_IF
  58
  59         return true;
  60 }
  61
  62 #if CSQCPLAYER_FORCE_UPDATES
  63 .float csqcmodel_nextforcedupdate;
  64 #endif
  65 void CSQCModel_CheckUpdate(entity e)
  66 {
  67         // some nice flags for CSQCMODEL_IF
  68         float isplayer = IS_CLIENT(e);
  69         float islocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
  70         float isnolocalplayer = isplayer; // we set BOTH to 1 here as we need the sendflags
  71
  72         unused_float = isplayer;
  73         unused_float = islocalplayer;
  74         unused_float = isnolocalplayer;
  75
  76 #if CSQCPLAYER_FORCE_UPDATES
  77         if(isplayer && time > e.csqcmodel_nextforcedupdate)
  78         {
  79                 e.SendFlags |= CSQCMODEL_PROPERTY_ORIGIN;
  80                 e.csqcmodel_nextforcedupdate = time + (1 / (CSQCPLAYER_FORCE_UPDATES)) * (0.5 + random()); // ensure about 4 origin sends per sec
  81         }
  82 #endif
  83
  84         if(e.effects & EF_RESTARTANIM_BIT)
  85         {
  86                 e.SendFlags |= CSQCMODEL_PROPERTY_FRAME | CSQCMODEL_PROPERTY_FRAME2; // full anim resend please
  87                 e.effects &= ~EF_RESTARTANIM_BIT;
  88         }
  89
  90         if(e.effects & EF_TELEPORT_BIT)
  91         {
  92                 e.SendFlags |= CSQCMODEL_PROPERTY_TELEPORTED; // no interpolation please
  93                 e.effects &= ~EF_TELEPORT_BIT;
  94         }
  95
  96 #define CSQCMODEL_IF(cond) if(cond) {
  97 #define CSQCMODEL_ENDIF }
  98 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
  99         { \
 100                 t tmp = e.f; \
 101                 if(tmp != e.csqcmodel_##f) \
 102                 { \
 103                         e.csqcmodel_##f = tmp; \
 104                         e.SendFlags |= flag; \
 105                 } \
 106         }
 107 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) \
 108         { \
 109                 t tmp = rint(bound(mi, s * e.f, ma) - mi); \
 110                 if(tmp != e.csqcmodel_##f) \
 111                 { \
 112                         e.csqcmodel_##f = tmp; \
 113                         e.SendFlags |= flag; \
 114                 } \
 115         }
 116         ALLPROPERTIES
 117 #undef CSQCMODEL_PROPERTY_SCALED
 118 #undef CSQCMODEL_PROPERTY
 119 #undef CSQCMODEL_ENDIF
 120 #undef CSQCMODEL_IF
 121 }
 122
 123 void CSQCModel_LinkEntity(entity e)
 124 {
 125         e.SendEntity = CSQCModel_Send;
 126         e.SendFlags = 0xFFFFFF;
 127         CSQCModel_CheckUpdate(e);
 128 }
 129
 130 void CSQCModel_UnlinkEntity(entity e)
 131 {
 132         e.SendEntity = func_null;
 133 }