qcsrc/lib/spawnfunc.qh

   1 #pragma once
   2
   3 // remove this ifdef when client or menu will actually make use of this stuff
   4 #ifdef SVQC
   5
   6 /** If this global exists, only functions with spawnfunc_ name prefix qualify as spawn functions */
   7 noref bool require_spawnfunc_prefix;
   8 .bool spawnfunc_checked;
   9 /** Not for production use, provides access to a dump of the entity's fields when it is parsed from map data */
  10 //noref string __fullspawndata;
  11
  12 // Optional type checking; increases compile time too much to be enabled by default
  13 #if 0
  14         bool entityfieldassignablefromeditor(int i)
  15         {
  16                 switch (entityfieldtype(i))
  17                 {
  18                         case FIELD_STRING:
  19                         case FIELD_FLOAT:
  20                         case FIELD_VECTOR:
  21                                 return true;
  22                 }
  23                 return false;
  24         }
  25
  26         #define _spawnfunc_checktypes(fld) \
  27                 if (s == #fld) \
  28                         if (!entityfieldassignablefromeditor(i)) LOG_FATALF("Entity field '%s' cannot be whitelisted", s);
  29 #else
  30         #define _spawnfunc_checktypes(fld)
  31 #endif
  32         #define _spawnfunc_check(fld) \
  33                 if (s == #fld) continue;
  34
  35         noref int __spawnfunc_expecting;
  36         noref entity __spawnfunc_expect;
  37         noref bool __spawnfunc_unreachable_workaround = true;
  38
  39     .void(entity) __spawnfunc_constructor;
  40     noref IntrusiveList g_spawn_queue;
  41
  42     #define SPAWNFUNC_INTERNAL_FIELDS(X) \
  43         X(string, classname, "spawnfunc") \
  44         X(string, target, string_null) \
  45         X(string, target2, string_null) \
  46         X(string, target3, string_null) \
  47         X(string, target4, string_null) \
  48         X(string, targetname, string_null) \
  49         /**/
  50
  51     #define X(T, fld, def) .T fld, __spawnfunc_##fld;
  52     SPAWNFUNC_INTERNAL_FIELDS(X)
  53     #undef X
  54
  55     void __spawnfunc_defer(entity prototype, void(entity) constructor)
  56     {
  57         IL_PUSH(g_spawn_queue, prototype);
  58         #define X(T, fld, def) { prototype.__spawnfunc_##fld = prototype.fld; prototype.fld = def; }
  59         SPAWNFUNC_INTERNAL_FIELDS(X);
  60         #undef X
  61         prototype.__spawnfunc_constructor = constructor;
  62     }
  63
  64     noref IntrusiveList g_map_entities;
  65     #define __spawnfunc_spawn_all() MACRO_BEGIN \
  66         g_map_entities = IL_NEW(); \
  67         IL_EACH(g_spawn_queue, true, __spawnfunc_spawn(it)); \
  68     MACRO_END
  69 #ifdef SVQC
  70     void _SV_OnEntityPreSpawnFunction(entity this);
  71 #endif
  72     void __spawnfunc_spawn(entity prototype)
  73     {
  74         entity e = new(clone);
  75         copyentity(prototype, e);
  76         IL_PUSH(g_map_entities, e);
  77         #define X(T, fld, def) { e.fld = e.__spawnfunc_##fld; e.__spawnfunc_##fld = def; }
  78         SPAWNFUNC_INTERNAL_FIELDS(X);
  79         #undef X
  80 #ifdef SVQC
  81         _SV_OnEntityPreSpawnFunction(e);
  82         if (wasfreed(e)) {
  83             return;
  84         }
  85 #endif
  86         e.__spawnfunc_constructor(e);
  87     }
  88
  89         #define FIELD_SCALAR(fld, n) \
  90                 fld(n)
  91         #define FIELD_VEC(fld, n) \
  92                 fld(n) \
  93                 fld(n##_x) \
  94                 fld(n##_y) \
  95                 fld(n##_z)
  96
  97         #define FIELDS_NONE(fld)
  98         #define FIELDS_ALL(fld) if (false)
  99
 100         #define FIELDS_COMMON(fld) \
 101                 FIELD_SCALAR(fld, classname) \
 102                 FIELD_SCALAR(fld, sourceLoc) \
 103                 FIELD_SCALAR(fld, spawnfunc_checked) \
 104                 FIELD_VEC(fld, origin) \
 105                 /**/
 106
 107         #define FIELDS_UNION(fld) \
 108                 FIELD_SCALAR(fld, Version) \
 109                 FIELD_SCALAR(fld, ammo_cells) \
 110                 FIELD_SCALAR(fld, ammo_nails) \
 111                 FIELD_SCALAR(fld, ammo_rockets) \
 112                 FIELD_SCALAR(fld, antiwall_flag) \
 113                 FIELD_SCALAR(fld, armorvalue) \
 114                 FIELD_SCALAR(fld, atten) \
 115                 FIELD_SCALAR(fld, bgmscriptdecay) \
 116                 FIELD_SCALAR(fld, bgmscriptsustain) \
 117                 FIELD_SCALAR(fld, bgmscript) \
 118                 FIELD_SCALAR(fld, button0) \
 119                 FIELD_SCALAR(fld, chmap) \
 120                 FIELD_SCALAR(fld, cnt) \
 121                 FIELD_SCALAR(fld, colormap) \
 122                 FIELD_SCALAR(fld, count) \
 123                 FIELD_SCALAR(fld, curvetarget) \
 124                 FIELD_SCALAR(fld, cvarfilter) \
 125                 FIELD_SCALAR(fld, debrisdamageforcescale) \
 126                 FIELD_SCALAR(fld, debrisfadetime) \
 127                 FIELD_SCALAR(fld, debrismovetype) \
 128                 FIELD_SCALAR(fld, debrisskin) \
 129                 FIELD_SCALAR(fld, debristimejitter) \
 130                 FIELD_SCALAR(fld, debristime) \
 131                 FIELD_SCALAR(fld, debris) \
 132                 FIELD_SCALAR(fld, delay) \
 133                 FIELD_SCALAR(fld, dmgtime) \
 134                 FIELD_SCALAR(fld, dmg) \
 135                 FIELD_SCALAR(fld, dmg_edge) \
 136                 FIELD_SCALAR(fld, dmg_force) \
 137                 FIELD_SCALAR(fld, dmg_radius) \
 138                 FIELD_SCALAR(fld, effects) \
 139                 FIELD_SCALAR(fld, falloff) \
 140                 FIELD_SCALAR(fld, flags) \
 141                 FIELD_SCALAR(fld, fog) \
 142                 FIELD_SCALAR(fld, frags) \
 143                 FIELD_SCALAR(fld, frame) \
 144                 FIELD_SCALAR(fld, gametype) \
 145                 FIELD_SCALAR(fld, gametypefilter) \
 146                 FIELD_SCALAR(fld, geomtype) \
 147                 FIELD_SCALAR(fld, gravity) \
 148                 FIELD_SCALAR(fld, health) \
 149                 FIELD_SCALAR(fld, height) \
 150                 FIELD_SCALAR(fld, impulse) \
 151                 FIELD_SCALAR(fld, invincible_finished) \
 152                 FIELD_SCALAR(fld, item_pickupsound) \
 153                 FIELD_SCALAR(fld, killtarget) \
 154                 FIELD_SCALAR(fld, lerpfrac) \
 155                 FIELD_SCALAR(fld, light_lev) \
 156                 FIELD_SCALAR(fld, lip) \
 157                 FIELD_SCALAR(fld, loddistance1) \
 158                 FIELD_SCALAR(fld, lodmodel1) \
 159                 FIELD_SCALAR(fld, lodmodel2) \
 160                 FIELD_SCALAR(fld, ltime) \
 161                 FIELD_SCALAR(fld, map) \
 162                 FIELD_SCALAR(fld, max_health) \
 163                 FIELD_SCALAR(fld, mdl) \
 164                 FIELD_SCALAR(fld, message2) \
 165                 FIELD_SCALAR(fld, message) \
 166                 FIELD_SCALAR(fld, modelindex) \
 167                 FIELD_SCALAR(fld, modelscale) \
 168                 FIELD_SCALAR(fld, model) \
 169                 FIELD_SCALAR(fld, monsterid) \
 170                 FIELD_SCALAR(fld, monster_moveflags) \
 171                 FIELD_SCALAR(fld, monster_name) \
 172                 FIELD_SCALAR(fld, movetype) \
 173                 FIELD_SCALAR(fld, move_movetype) \
 174                 FIELD_SCALAR(fld, netname) \
 175                 FIELD_SCALAR(fld, nextthink) \
 176                 FIELD_SCALAR(fld, noalign) \
 177                 FIELD_SCALAR(fld, noise1) \
 178                 FIELD_SCALAR(fld, noise2) \
 179                 FIELD_SCALAR(fld, noise3) \
 180                 FIELD_SCALAR(fld, noise) \
 181                 FIELD_SCALAR(fld, phase) \
 182                 FIELD_SCALAR(fld, platmovetype) \
 183                 FIELD_SCALAR(fld, race_place) \
 184                 FIELD_SCALAR(fld, strength_finished) \
 185                 FIELD_SCALAR(fld, radius) \
 186                 FIELD_SCALAR(fld, respawntimestart) \
 187                 FIELD_SCALAR(fld, respawntimejitter) \
 188                 FIELD_SCALAR(fld, respawntime) \
 189                 FIELD_SCALAR(fld, restriction) \
 190                 FIELD_SCALAR(fld, scale) \
 191                 FIELD_SCALAR(fld, skin) \
 192                 FIELD_SCALAR(fld, solid) \
 193                 FIELD_SCALAR(fld, sound1) \
 194                 FIELD_SCALAR(fld, sounds) \
 195                 FIELD_SCALAR(fld, spawnflags) \
 196                 FIELD_SCALAR(fld, spawnmob) \
 197                 FIELD_SCALAR(fld, speed) \
 198                 FIELD_SCALAR(fld, strength) \
 199                 FIELD_SCALAR(fld, style) \
 200                 FIELD_SCALAR(fld, target2) \
 201                 FIELD_SCALAR(fld, target3) \
 202                 FIELD_SCALAR(fld, target4) \
 203                 FIELD_SCALAR(fld, targetname) \
 204                 FIELD_SCALAR(fld, target) \
 205                 FIELD_SCALAR(fld, target_random) \
 206                 FIELD_SCALAR(fld, target_range) \
 207                 FIELD_SCALAR(fld, team) \
 208                 FIELD_SCALAR(fld, trigger_reverse) \
 209                 FIELD_SCALAR(fld, turret_scale_aim) \
 210                 FIELD_SCALAR(fld, turret_scale_ammo) \
 211                 FIELD_SCALAR(fld, turret_scale_damage) \
 212                 FIELD_SCALAR(fld, turret_scale_health) \
 213                 FIELD_SCALAR(fld, turret_scale_range) \
 214                 FIELD_SCALAR(fld, turret_scale_refire) \
 215                 FIELD_SCALAR(fld, turret_scale_respawn) \
 216                 FIELD_SCALAR(fld, volume) \
 217                 FIELD_SCALAR(fld, wait) \
 218                 FIELD_SCALAR(fld, warpzone_fadeend) \
 219                 FIELD_SCALAR(fld, warpzone_fadestart) \
 220                 FIELD_SCALAR(fld, weapon) \
 221                 FIELD_SCALAR(fld, worldtype) \
 222                 FIELD_VEC(fld, absmax) \
 223                 FIELD_VEC(fld, absmin) \
 224                 FIELD_VEC(fld, angles) \
 225                 FIELD_VEC(fld, avelocity) \
 226                 FIELD_VEC(fld, beam_color)\
 227                 FIELD_VEC(fld, debrisavelocityjitter) \
 228                 FIELD_VEC(fld, debrisvelocity) \
 229                 FIELD_VEC(fld, debrisvelocityjitter) \
 230                 FIELD_VEC(fld, color) \
 231                 FIELD_VEC(fld, mangle) \
 232                 FIELD_VEC(fld, maxs) \
 233                 FIELD_VEC(fld, mins) \
 234                 FIELD_VEC(fld, modelscale_vec) \
 235                 FIELD_VEC(fld, velocity) \
 236                 /**/
 237
 238 ERASEABLE
 239 void _checkWhitelisted(entity this, string id)
 240 {
 241         for (int i = 0, n = numentityfields(); i < n; ++i)
 242         {
 243                 string value = getentityfieldstring(i, this);
 244                 string s = entityfieldname(i);
 245                 FIELDS_UNION(_spawnfunc_checktypes)
 246                 if (value == "") continue;
 247                 if (s == "") continue;
 248                 FIELDS_COMMON(_spawnfunc_check)
 249                 FIELDS_UNION(_spawnfunc_check)
 250                 LOG_WARNF(_("Entity field %s.%s (%s) is not whitelisted. If you believe this is an error, please file an issue."), id, s, value);
 251         }
 252 }
 253
 254 // this function simply avoids expanding IL_NEW during compilation
 255 // for each spawning entity
 256 void g_spawn_queue_spawn() { g_spawn_queue = IL_NEW(); }
 257
 258 noref bool __spawnfunc_first;
 259
 260 #define spawnfunc(id) \
 261         void __spawnfunc_##id(entity this); \
 262         ACCUMULATE void spawnfunc_##id(entity this) \
 263         { \
 264                 if (!__spawnfunc_first) { \
 265                         __spawnfunc_first = true; \
 266                         static_init_early(); \
 267                 } \
 268                 bool dospawn = true; \
 269                 if (__spawnfunc_expecting > 1) { __spawnfunc_expecting = 0; } \
 270                 else if (__spawnfunc_expecting) { \
 271                         /* engine call */ \
 272                         if (!g_spawn_queue) g_spawn_queue_spawn(); \
 273                         __spawnfunc_expecting = 0; \
 274                         this = __spawnfunc_expect; \
 275                         __spawnfunc_expect = NULL; \
 276                         dospawn = false; \
 277                 } else { \
 278                         /* userland call */ \
 279                         assert(this); \
 280                 } \
 281                 if (!this.sourceLoc) { \
 282                         this.sourceLoc = __FILE__":"STR(__LINE__); \
 283                 } \
 284                 this.classname = #id; \
 285                 if (!this.spawnfunc_checked) { \
 286                         _checkWhitelisted(this, #id); \
 287                         this.spawnfunc_checked = true; \
 288                         if (this) { \
 289                                 /* not worldspawn, delay spawn */ \
 290                                 /* clear some dangerous fields (TODO: properly support these in the map!) */ \
 291                                 this.think = func_null; \
 292                                 this.nextthink = 0; \
 293                                 __spawnfunc_defer(this, __spawnfunc_##id); \
 294                         } else { \
 295                                 /* world might not be "worldspawn" */ \
 296                                 this.__spawnfunc_constructor = __spawnfunc_##id; \
 297                         } \
 298                 } \
 299                 if (dospawn) { __spawnfunc_##id(this); } \
 300                 if (__spawnfunc_unreachable_workaround) return; \
 301         } \
 302         void __spawnfunc_##id(entity this)
 303
 304 #endif