qcsrc/lib/warpzone/server.qc

   1 #include "server.qh"
   2
   3 #include "common.qh"
   4 #if defined(CSQC)
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7         #include "../../common/constants.qh"
   8         #include "../../common/triggers/subs.qh"
   9         #include "../../common/util.qh"
  10         #include "../../server/command/common.qh"
  11         #include "../../server/constants.qh"
  12         #include "../../server/defs.qh"
  13 #endif
  14
  15 #ifdef WARPZONELIB_KEEPDEBUG
  16 #define WARPZONELIB_REMOVEHACK
  17 #endif
  18
  19 // for think function
  20 .vector warpzone_save_origin;
  21 .vector warpzone_save_angles;
  22 .vector warpzone_save_eorigin;
  23 .vector warpzone_save_eangles;
  24
  25 // for all entities
  26 .vector warpzone_oldorigin, warpzone_oldvelocity, warpzone_oldangles;
  27 .float warpzone_teleport_time;
  28 .float warpzone_teleport_finishtime;
  29 .entity warpzone_teleport_zone;
  30
  31 void WarpZone_StoreProjectileData(entity e)
  32 {
  33         e.warpzone_oldorigin = e.origin;
  34         e.warpzone_oldvelocity = e.velocity;
  35         e.warpzone_oldangles = e.angles;
  36 }
  37
  38 void WarpZone_TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity)
  39 {
  40         setorigin (player, to); // NOTE: this also aborts the move, when this is called by touch
  41         player.oldorigin = to; // for DP's unsticking
  42         player.angles = to_angles;
  43         player.fixangle = true;
  44         player.velocity = to_velocity;
  45
  46         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
  47
  48         if(IS_PLAYER(player))
  49                 BITCLR_ASSIGN(player.flags, FL_ONGROUND);
  50
  51         WarpZone_PostTeleportPlayer_Callback(player);
  52 }
  53
  54 bool WarpZone_Teleported_Send(entity to, int sf)
  55 {SELFPARAM();
  56         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE_TELEPORTED);
  57         WriteCoord(MSG_ENTITY, self.angles.x);
  58         WriteCoord(MSG_ENTITY, self.angles.y);
  59         WriteCoord(MSG_ENTITY, self.angles.z);
  60         return true;
  61 }
  62
  63 float WarpZone_Teleport(entity wz, entity player, float f0, float f1)
  64 {
  65         vector o0, a0, v0, o1, a1, v1, o10;
  66
  67         o0 = player.origin + player.view_ofs;
  68         v0 = player.velocity;
  69         a0 = player.angles;
  70
  71         o10 = o1 = WarpZone_TransformOrigin(wz, o0);
  72         v1 = WarpZone_TransformVelocity(wz, v0);
  73         if (!IS_NOT_A_CLIENT(player))
  74                 a1 = WarpZone_TransformVAngles(wz, player.v_angle);
  75         else
  76                 a1 = WarpZone_TransformAngles(wz, a0);
  77
  78         if(f0 != 0 || f1 != 0)
  79         {
  80                 // retry last move but behind the warpzone!
  81                 // we must first go back as far as we can, then forward again, to not cause double touch events!
  82
  83                 tracebox(o1 - player.view_ofs + v1 * frametime * f1, player.mins, player.maxs, o1 - player.view_ofs + v1 * frametime * f0, MOVE_WORLDONLY, player);
  84                 {
  85                         entity own;
  86                         own = player.owner;
  87                         player.owner = world;
  88                         tracebox(trace_endpos, player.mins, player.maxs, o1 - player.view_ofs + v1 * frametime * f1, MOVE_NORMAL, player); // this should get us through the warpzone
  89                         player.owner = own;
  90                 }
  91                 o1 = trace_endpos + player.view_ofs;
  92
  93                 float d, dv, md;
  94                 md = max(vlen(player.mins), vlen(player.maxs));
  95                 d = WarpZone_TargetPlaneDist(wz, o1);
  96                 dv = WarpZone_TargetPlaneDist(wz, v1);
  97                 if(d < 0)
  98                         o1 = o1 - v1 * (d / dv);
  99         }
 100
 101         // put him out of solid
 102         tracebox(o1 - player.view_ofs, player.mins, player.maxs, o1 - player.view_ofs, MOVE_NOMONSTERS, player);
 103         if(trace_startsolid)
 104         {
 105                 setorigin(player, o1 - player.view_ofs);
 106                 if(WarpZoneLib_MoveOutOfSolid(player))
 107                 {
 108                         o1 = player.origin + player.view_ofs;
 109                         setorigin(player, o0 - player.view_ofs);
 110                 }
 111                 else
 112                 {
 113                         LOG_INFO("would have to put player in solid, won't do that\n");
 114                         setorigin(player, o0 - player.view_ofs);
 115                         return 0;
 116                 }
 117         }
 118
 119         // do the teleport
 120         WarpZone_RefSys_Add(player, wz);
 121         WarpZone_TeleportPlayer(wz, player, o1 - player.view_ofs, a1, v1);
 122         WarpZone_StoreProjectileData(player);
 123         player.warpzone_teleport_time = time;
 124         player.warpzone_teleport_finishtime = time;
 125         player.warpzone_teleport_zone = wz;
 126
 127         // prevent further teleports back
 128         float dt = (o1 - o10) * v1 * (1 / (v1 * v1));
 129         if(dt < sys_frametime)
 130                 player.warpzone_teleport_finishtime += sys_frametime - dt;
 131
 132 #ifndef WARPZONE_USE_FIXANGLE
 133         if(IS_VEHICLE(player) && player.owner)
 134                 player = player.owner; // hax
 135         if(IS_PLAYER(player))
 136         {
 137                 // instead of fixangle, send the transform to the client for smoother operation
 138                 player.fixangle = false;
 139
 140                 entity ts = spawn();
 141                 setmodel(ts, MDL_Null);
 142                 ts.SendEntity = WarpZone_Teleported_Send;
 143                 ts.SendFlags = 0xFFFFFF;
 144                 ts.drawonlytoclient = player;
 145                 ts.think = SUB_Remove;
 146                 ts.nextthink = time + 1;
 147                 ts.owner = player;
 148                 ts.enemy = wz;
 149                 ts.effects = EF_NODEPTHTEST;
 150                 ts.classname = "warpzone_teleported";
 151                 ts.angles = wz.warpzone_transform;
 152         }
 153 #endif
 154
 155         return 1;
 156 }
 157
 158 void WarpZone_Touch (void)
 159 {SELFPARAM();
 160         if(other.classname == "trigger_warpzone")
 161                 return;
 162
 163         if(time <= other.warpzone_teleport_finishtime) // already teleported this frame
 164                 return;
 165
 166         // FIXME needs a better check to know what is safe to teleport and what not
 167         if(other.movetype == MOVETYPE_NONE || other.movetype == MOVETYPE_FOLLOW || other.tag_entity)
 168                 return;
 169
 170         if(WarpZoneLib_ExactTrigger_Touch())
 171                 return;
 172
 173         if(WarpZone_PlaneDist(self, other.origin + other.view_ofs) >= 0) // wrong side of the trigger_warpzone (don't teleport yet)
 174                 return;
 175
 176         float f;
 177         // number of frames we need to go back:
 178         //   dist = 16*sqrt(2) qu
 179         //   dist ~ 24 qu
 180         //   24 qu = v*t
 181         //   24 qu = v*frametime*n
 182         //       n = 24 qu/(v*frametime)
 183         // for clients go only one frame though, may be too irritating otherwise
 184         // but max 0.25 sec = 0.25/frametime frames
 185         //       24/(0.25/frametime)
 186         //       96*frametime
 187         float d;
 188         d = 24 + max(vlen(other.mins), vlen(other.maxs));
 189         if(IS_NOT_A_CLIENT(other))
 190                 f = -d / bound(frametime * d * 1, frametime * vlen(other.velocity), d);
 191         else
 192                 f = -1;
 193         if(WarpZone_Teleport(self, other, f, 0))
 194         {
 195                 string save1, save2;
 196                 activator = other;
 197
 198                 save1 = self.target; self.target = string_null;
 199                 save2 = self.target3; self.target3 = string_null;
 200                 SUB_UseTargets();
 201                 if (!self.target) self.target = save1;
 202                 if (!self.target3) self.target3 = save2;
 203
 204                 setself(self.enemy);
 205                 save1 = self.target; self.target = string_null;
 206                 save2 = self.target2; self.target2 = string_null;
 207                 SUB_UseTargets();
 208                 if (!self.target) self.target = save1;
 209                 if (!self.target2) self.target2 = save2;
 210                 setself(this);
 211         }
 212         else
 213         {
 214                 LOG_TRACE("WARPZONE FAIL AHAHAHAHAH))\n");
 215         }
 216 }
 217
 218 bool WarpZone_Send(entity to, int sendflags)
 219 {SELFPARAM();
 220         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE);
 221
 222         // we must send this flag for clientside to match properly too
 223         int f = 0;
 224         if(self.warpzone_isboxy)
 225                 BITSET_ASSIGN(f, 1);
 226         if(self.warpzone_fadestart)
 227                 BITSET_ASSIGN(f, 2);
 228         if(self.origin != '0 0 0')
 229                 BITSET_ASSIGN(f, 4);
 230         WriteByte(MSG_ENTITY, f);
 231
 232         // we need THESE to render the warpzone (and cull properly)...
 233         if(f & 4)
 234         {
 235                 WriteCoord(MSG_ENTITY, self.origin.x);
 236                 WriteCoord(MSG_ENTITY, self.origin.y);
 237                 WriteCoord(MSG_ENTITY, self.origin.z);
 238         }
 239
 240         WriteShort(MSG_ENTITY, self.modelindex);
 241         WriteCoord(MSG_ENTITY, self.mins.x);
 242         WriteCoord(MSG_ENTITY, self.mins.y);
 243         WriteCoord(MSG_ENTITY, self.mins.z);
 244         WriteCoord(MSG_ENTITY, self.maxs.x);
 245         WriteCoord(MSG_ENTITY, self.maxs.y);
 246         WriteCoord(MSG_ENTITY, self.maxs.z);
 247         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 248
 249         // we need THESE to calculate the proper transform
 250         WriteCoord(MSG_ENTITY, self.warpzone_origin.x);
 251         WriteCoord(MSG_ENTITY, self.warpzone_origin.y);
 252         WriteCoord(MSG_ENTITY, self.warpzone_origin.z);
 253         WriteCoord(MSG_ENTITY, self.warpzone_angles.x);
 254         WriteCoord(MSG_ENTITY, self.warpzone_angles.y);
 255         WriteCoord(MSG_ENTITY, self.warpzone_angles.z);
 256         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin.x);
 257         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin.y);
 258         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin.z);
 259         WriteCoord(MSG_ENTITY, self.warpzone_targetangles.x);
 260         WriteCoord(MSG_ENTITY, self.warpzone_targetangles.y);
 261         WriteCoord(MSG_ENTITY, self.warpzone_targetangles.z);
 262
 263         if(f & 2)
 264         {
 265                 WriteShort(MSG_ENTITY, self.warpzone_fadestart);
 266                 WriteShort(MSG_ENTITY, self.warpzone_fadeend);
 267         }
 268
 269         return true;
 270 }
 271
 272 bool WarpZone_Camera_Send(entity to, int sendflags)
 273 {SELFPARAM();
 274         int f = 0;
 275         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE_CAMERA);
 276
 277         if(self.warpzone_fadestart)
 278                 BITSET_ASSIGN(f, 2);
 279         if(self.origin != '0 0 0')
 280                 BITSET_ASSIGN(f, 4);
 281         WriteByte(MSG_ENTITY, f);
 282
 283         // we need THESE to render the warpzone (and cull properly)...
 284         if(f & 4)
 285         {
 286                 WriteCoord(MSG_ENTITY, self.origin.x);
 287                 WriteCoord(MSG_ENTITY, self.origin.y);
 288                 WriteCoord(MSG_ENTITY, self.origin.z);
 289         }
 290
 291         WriteShort(MSG_ENTITY, self.modelindex);
 292         WriteCoord(MSG_ENTITY, self.mins.x);
 293         WriteCoord(MSG_ENTITY, self.mins.y);
 294         WriteCoord(MSG_ENTITY, self.mins.z);
 295         WriteCoord(MSG_ENTITY, self.maxs.x);
 296         WriteCoord(MSG_ENTITY, self.maxs.y);
 297         WriteCoord(MSG_ENTITY, self.maxs.z);
 298         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 299
 300         // we need THESE to calculate the proper transform
 301         WriteCoord(MSG_ENTITY, self.enemy.origin.x);
 302         WriteCoord(MSG_ENTITY, self.enemy.origin.y);
 303         WriteCoord(MSG_ENTITY, self.enemy.origin.z);
 304         WriteCoord(MSG_ENTITY, self.enemy.angles.x);
 305         WriteCoord(MSG_ENTITY, self.enemy.angles.y);
 306         WriteCoord(MSG_ENTITY, self.enemy.angles.z);
 307
 308         if(f & 2)
 309         {
 310                 WriteShort(MSG_ENTITY, self.warpzone_fadestart);
 311                 WriteShort(MSG_ENTITY, self.warpzone_fadeend);
 312         }
 313
 314         return true;
 315 }
 316
 317 #ifdef WARPZONELIB_KEEPDEBUG
 318 float WarpZone_CheckProjectileImpact(entity player)
 319 {SELFPARAM();
 320         vector o0, v0;
 321
 322         o0 = player.origin + player.view_ofs;
 323         v0 = player.velocity;
 324
 325         // if we teleported shortly before, abort
 326         if(time <= player.warpzone_teleport_finishtime + 0.1)
 327                 return 0;
 328
 329         // if player hit a warpzone, abort
 330         entity wz;
 331         wz = WarpZone_Find(o0 + player.mins, o0 + player.maxs);
 332         if(!wz)
 333                 return 0;
 334
 335 #ifdef WARPZONELIB_REMOVEHACK
 336         LOG_INFO("impactfilter found something - and it no longer gets handled correctly - please tell divVerent whether anything behaves broken now\n");
 337 #else
 338         LOG_INFO("impactfilter found something - and it even gets handled correctly - please tell divVerent that this code apparently gets triggered again\n");
 339 #endif
 340         LOG_INFO("Entity type: ", player.classname, "\n");
 341         LOG_INFO("Origin: ", vtos(player.origin), "\n");
 342         LOG_INFO("Velocity: ", vtos(player.velocity), "\n");
 343
 344 #ifdef WARPZONELIB_REMOVEHACK
 345         return 0;
 346 #else
 347         // retry previous move
 348         setorigin(player, player.warpzone_oldorigin);
 349         player.velocity = player.warpzone_oldvelocity;
 350         if(WarpZone_Teleport(wz, player, 0, 1))
 351         {
 352                 entity oldself;
 353                 string save1, save2;
 354
 355                 oldself = self;
 356                 self = wz;
 357                 other = player;
 358                 activator = player;
 359
 360                 save1 = self.target; self.target = string_null;
 361                 save2 = self.target3; self.target3 = string_null;
 362                 SUB_UseTargets();
 363                 if (!self.target) self.target = save1;
 364                 if (!self.target3) self.target3 = save2;
 365
 366                 self = self.enemy;
 367                 save1 = self.target; self.target = string_null;
 368                 save2 = self.target2; self.target2 = string_null;
 369                 SUB_UseTargets();
 370                 if (!self.target) self.target = save1;
 371                 if (!self.target2) self.target2 = save2;
 372                 self = oldself;
 373         }
 374         else
 375         {
 376                 setorigin(player, o0 - player.view_ofs);
 377                 player.velocity = v0;
 378         }
 379
 380         return +1;
 381 #endif
 382 }
 383 #endif
 384
 385 float WarpZone_Projectile_Touch()
 386 {SELFPARAM();
 387         if(other.classname == "trigger_warpzone")
 388                 return true;
 389
 390         // no further impacts if we teleported this frame!
 391         // this is because even if we did teleport, the engine still may raise
 392         // touch events for the previous location
 393         // engine now aborts moves on teleport, so this SHOULD not happen any more
 394         // but if this is called from TouchAreaGrid of the projectile moving,
 395         // then this won't do
 396         if(time == self.warpzone_teleport_time)
 397                 return true;
 398
 399 #ifdef WARPZONELIB_KEEPDEBUG
 400         // this SEEMS to not happen at the moment, but if it did, it would be more reliable
 401         {
 402                 float save_dpstartcontents;
 403                 float save_dphitcontents;
 404                 float save_dphitq3surfaceflags;
 405                 string save_dphittexturename;
 406                 float save_allsolid;
 407                 float save_startsolid;
 408                 float save_fraction;
 409                 vector save_endpos;
 410                 vector save_plane_normal;
 411                 float save_plane_dist;
 412                 entity save_ent;
 413                 float save_inopen;
 414                 float save_inwater;
 415                 save_dpstartcontents = trace_dpstartcontents;
 416                 save_dphitcontents = trace_dphitcontents;
 417                 save_dphitq3surfaceflags = trace_dphitq3surfaceflags;
 418                 save_dphittexturename = trace_dphittexturename;
 419                 save_allsolid = trace_allsolid;
 420                 save_startsolid = trace_startsolid;
 421                 save_fraction = trace_fraction;
 422                 save_endpos = trace_endpos;
 423                 save_plane_normal = trace_plane_normal;
 424                 save_plane_dist = trace_plane_dist;
 425                 save_ent = trace_ent;
 426                 save_inopen = trace_inopen;
 427                 save_inwater = trace_inwater;
 428                 float f;
 429                 if((f = WarpZone_CheckProjectileImpact(self)) != 0)
 430                         return (f > 0);
 431                 trace_dpstartcontents = save_dpstartcontents;
 432                 trace_dphitcontents = save_dphitcontents;
 433                 trace_dphitq3surfaceflags = save_dphitq3surfaceflags;
 434                 trace_dphittexturename = save_dphittexturename;
 435                 trace_allsolid = save_allsolid;
 436                 trace_startsolid = save_startsolid;
 437                 trace_fraction = save_fraction;
 438                 trace_endpos = save_endpos;
 439                 trace_plane_normal = save_plane_normal;
 440                 trace_plane_dist = save_plane_dist;
 441                 trace_ent = save_ent;
 442                 trace_inopen = save_inopen;
 443                 trace_inwater = save_inwater;
 444         }
 445 #endif
 446
 447         if(WarpZone_Projectile_Touch_ImpactFilter_Callback())
 448                 return true;
 449
 450         return false;
 451 }
 452
 453 void WarpZone_InitStep_FindOriginTarget()
 454 {SELFPARAM();
 455         if(self.killtarget != "")
 456         {
 457                 self.aiment = find(world, targetname, self.killtarget);
 458                 if(self.aiment == world)
 459                 {
 460                         error("Warp zone with nonexisting killtarget");
 461                         return;
 462                 }
 463                 self.killtarget = string_null;
 464         }
 465 }
 466
 467 void WarpZonePosition_InitStep_FindTarget()
 468 {SELFPARAM();
 469         if(self.target == "")
 470         {
 471                 error("Warp zone position with no target");
 472                 return;
 473         }
 474         self.enemy = find(world, targetname, self.target);
 475         if(self.enemy == world)
 476         {
 477                 error("Warp zone position with nonexisting target");
 478                 return;
 479         }
 480         if(self.enemy.aiment)
 481         {
 482                 // already is positioned
 483                 error("Warp zone position targeting already oriented warpzone");
 484                 return;
 485         }
 486         self.enemy.aiment = self;
 487 }
 488
 489 void WarpZoneCamera_Think(void)
 490 {SELFPARAM();
 491         if(self.warpzone_save_origin != self.origin
 492         || self.warpzone_save_angles != self.angles
 493         || self.warpzone_save_eorigin != self.enemy.origin
 494         || self.warpzone_save_eangles != self.enemy.angles)
 495         {
 496                 WarpZone_Camera_SetUp(self, self.enemy.origin, self.enemy.angles);
 497                 self.warpzone_save_origin = self.origin;
 498                 self.warpzone_save_angles = self.angles;
 499                 self.warpzone_save_eorigin = self.enemy.origin;
 500                 self.warpzone_save_eangles = self.enemy.angles;
 501         }
 502         self.nextthink = time;
 503 }
 504
 505 void WarpZoneCamera_InitStep_FindTarget()
 506 {SELFPARAM();
 507         entity e;
 508         float i;
 509         if(self.target == "")
 510         {
 511                 error("Camera with no target");
 512                 return;
 513         }
 514         self.enemy = world;
 515         for(e = world, i = 0; (e = find(e, targetname, self.target)); )
 516                 if(random() * ++i < 1)
 517                         self.enemy = e;
 518         if(self.enemy == world)
 519         {
 520                 error("Camera with nonexisting target");
 521                 return;
 522         }
 523         warpzone_cameras_exist = 1;
 524         WarpZone_Camera_SetUp(self, self.enemy.origin, self.enemy.angles);
 525         self.SendFlags = 0xFFFFFF;
 526         if(self.spawnflags & 1)
 527         {
 528                 self.think = WarpZoneCamera_Think;
 529                 self.nextthink = time;
 530         }
 531         else
 532                 self.nextthink = 0;
 533 }
 534
 535 void WarpZone_InitStep_UpdateTransform()
 536 {SELFPARAM();
 537         vector org, ang, norm, point;
 538         float area;
 539         vector tri, a, b, c, n;
 540         float i_s, i_t, n_t;
 541         string tex;
 542
 543         org = self.origin;
 544         if(org == '0 0 0')
 545                 org = 0.5 * (self.mins + self.maxs);
 546
 547         norm = point = '0 0 0';
 548         area = 0;
 549         for(i_s = 0; ; ++i_s)
 550         {
 551                 tex = getsurfacetexture(self, i_s);
 552                 if (!tex)
 553                         break; // this is beyond the last one
 554                 if(tex == "textures/common/trigger" || tex == "trigger")
 555                         continue;
 556                 n_t = getsurfacenumtriangles(self, i_s);
 557                 for(i_t = 0; i_t < n_t; ++i_t)
 558                 {
 559                         tri = getsurfacetriangle(self, i_s, i_t);
 560                         a = getsurfacepoint(self, i_s, tri.x);
 561                         b = getsurfacepoint(self, i_s, tri.y);
 562                         c = getsurfacepoint(self, i_s, tri.z);
 563                         n = cross(c - a, b - a);
 564                         area = area + vlen(n);
 565                         norm = norm + n;
 566                         point = point + vlen(n) * (a + b + c);
 567                 }
 568         }
 569         if(area > 0)
 570         {
 571                 norm = norm * (1 / area);
 572                 point = point * (1 / (3 * area));
 573                 if(vlen(norm) < 0.99)
 574                 {
 575                         LOG_INFO("trigger_warpzone near ", vtos(self.aiment.origin), " is nonplanar. BEWARE.\n");
 576                         area = 0; // no autofixing in this case
 577                 }
 578                 norm = normalize(norm);
 579         }
 580
 581         ang = '0 0 0';
 582         if(self.aiment)
 583         {
 584                 org = self.aiment.origin;
 585                 ang = self.aiment.angles;
 586                 if(area > 0)
 587                 {
 588                         org = org - ((org - point) * norm) * norm; // project to plane
 589                         makevectors(ang);
 590                         if(norm * v_forward < 0)
 591                         {
 592                                 LOG_INFO("Position target of trigger_warpzone near ", vtos(self.aiment.origin), " points into trigger_warpzone. BEWARE.\n");
 593                                 norm = -1 * norm;
 594                         }
 595                         ang = vectoangles2(norm, v_up); // keep rotation, but turn exactly against plane
 596                         ang.x = -ang.x;
 597                         if(norm * v_forward < 0.99)
 598                                 LOG_INFO("trigger_warpzone near ", vtos(self.aiment.origin), " has been turned to match plane orientation (", vtos(self.aiment.angles), " -> ", vtos(ang), "\n");
 599                         if(vlen(org - self.aiment.origin) > 0.5)
 600                                 LOG_INFO("trigger_warpzone near ", vtos(self.aiment.origin), " has been moved to match the plane (", vtos(self.aiment.origin), " -> ", vtos(org), ").\n");
 601                 }
 602         }
 603         else if(area > 0)
 604         {
 605                 org = point;
 606                 ang = vectoangles(norm);
 607                 ang.x = -ang.x;
 608         }
 609         else
 610                 error("cannot infer origin/angles for this warpzone, please use a killtarget or a trigger_warpzone_position");
 611
 612         self.warpzone_origin = org;
 613         self.warpzone_angles = ang;
 614 }
 615
 616 void WarpZone_InitStep_ClearTarget()
 617 {SELFPARAM();
 618         if(self.enemy)
 619                 self.enemy.enemy = world;
 620         self.enemy = world;
 621 }
 622
 623 entity warpzone_first; .entity warpzone_next;
 624 void WarpZone_InitStep_FindTarget()
 625 {SELFPARAM();
 626         float i;
 627         entity e, e2;
 628
 629         if(self.enemy)
 630                 return;
 631
 632         // this way only one of the two ents needs to target
 633         if(self.target != "")
 634         {
 635                 self.enemy = self; // so the if(!e.enemy) check also skips self, saves one IF
 636
 637                 e2 = world;
 638                 for(e = world, i = 0; (e = find(e, targetname, self.target)); )
 639                         if(!e.enemy)
 640                                 if(e.classname == self.classname) // possibly non-warpzones may use the same targetname!
 641                                         if(random() * ++i < 1)
 642                                                 e2 = e;
 643                 if(!e2)
 644                 {
 645                         self.enemy = world;
 646                         error("Warpzone with non-existing target");
 647                         return;
 648                 }
 649                 self.enemy = e2;
 650                 e2.enemy = self;
 651         }
 652 }
 653
 654 void WarpZone_Think();
 655 void WarpZone_InitStep_FinalizeTransform()
 656 {SELFPARAM();
 657         if(!self.enemy || self.enemy.enemy != self)
 658         {
 659                 error("Invalid warp zone detected. Killed.");
 660                 return;
 661         }
 662
 663         warpzone_warpzones_exist = 1;
 664         WarpZone_SetUp(self, self.warpzone_origin, self.warpzone_angles, self.enemy.warpzone_origin, self.enemy.warpzone_angles);
 665         self.touch = WarpZone_Touch;
 666         self.SendFlags = 0xFFFFFF;
 667         if(self.spawnflags & 1)
 668         {
 669                 self.think = WarpZone_Think;
 670                 self.nextthink = time;
 671         }
 672         else
 673                 self.nextthink = 0;
 674 }
 675
 676 float warpzone_initialized;
 677 //entity warpzone_first;
 678 entity warpzone_position_first;
 679 entity warpzone_camera_first;
 680 .entity warpzone_next;
 681 spawnfunc(misc_warpzone_position)
 682 {
 683         // "target", "angles", "origin"
 684         self.warpzone_next = warpzone_position_first;
 685         warpzone_position_first = self;
 686 }
 687 spawnfunc(trigger_warpzone_position)
 688 {
 689         spawnfunc_misc_warpzone_position(this);
 690 }
 691 spawnfunc(trigger_warpzone)
 692 {
 693         // warp zone entities must have:
 694         // "killtarget" pointing to a target_position with a direction arrow
 695         //              that points AWAY from the warp zone, and that is inside
 696         //              the warp zone trigger
 697         // "target"     pointing to an identical warp zone at another place in
 698         //              the map, with another killtarget to designate its
 699         //              orientation
 700
 701         if(!self.scale)
 702                 self.scale = self.modelscale;
 703         if(!self.scale)
 704                 self.scale = 1;
 705         string m;
 706         m = self.model;
 707         WarpZoneLib_ExactTrigger_Init();
 708         if(m != "")
 709         {
 710                 precache_model(m);
 711                 _setmodel(self, m); // no precision needed
 712         }
 713         setorigin(self, self.origin);
 714         if(self.scale)
 715                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 716         else
 717                 setsize(self, self.mins, self.maxs);
 718         self.SendEntity = WarpZone_Send;
 719         self.SendFlags = 0xFFFFFF;
 720         BITSET_ASSIGN(self.effects, EF_NODEPTHTEST);
 721         self.warpzone_next = warpzone_first;
 722         warpzone_first = self;
 723 }
 724 spawnfunc(func_camera)
 725 {
 726         if(!self.scale)
 727                 self.scale = self.modelscale;
 728         if(!self.scale)
 729                 self.scale = 1;
 730         if(self.model != "")
 731         {
 732                 precache_model(self.model);
 733                 _setmodel(self, self.model); // no precision needed
 734         }
 735         setorigin(self, self.origin);
 736         if(self.scale)
 737                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 738         else
 739                 setsize(self, self.mins, self.maxs);
 740         if(!self.solid)
 741                 self.solid = SOLID_BSP;
 742         else if(self.solid < 0)
 743                 self.solid = SOLID_NOT;
 744         self.SendEntity = WarpZone_Camera_Send;
 745         self.SendFlags = 0xFFFFFF;
 746         self.warpzone_next = warpzone_camera_first;
 747         warpzone_camera_first = self;
 748 }
 749 void WarpZones_Reconnect()
 750 {SELFPARAM();
 751         for(setself(warpzone_first); self; setself(self.warpzone_next))
 752                 WarpZone_InitStep_ClearTarget();
 753         for(setself(warpzone_first); self; setself(self.warpzone_next))
 754                 WarpZone_InitStep_FindTarget();
 755         for(setself(warpzone_camera_first); self; setself(self.warpzone_next))
 756                 WarpZoneCamera_InitStep_FindTarget();
 757         for(setself(warpzone_first); self; setself(self.warpzone_next))
 758                 WarpZone_InitStep_FinalizeTransform();
 759         setself(this);
 760 }
 761
 762 void WarpZone_Think()
 763 {SELFPARAM();
 764         if(self.warpzone_save_origin != self.origin
 765         || self.warpzone_save_angles != self.angles
 766         || self.warpzone_save_eorigin != self.enemy.origin
 767         || self.warpzone_save_eangles != self.enemy.angles)
 768         {
 769                 WarpZone_InitStep_UpdateTransform();
 770                 setself(self.enemy);
 771                 WarpZone_InitStep_UpdateTransform();
 772                 setself(this);
 773                 WarpZone_InitStep_FinalizeTransform();
 774                 setself(self.enemy);
 775                 WarpZone_InitStep_FinalizeTransform();
 776                 setself(this);
 777                 self.warpzone_save_origin = self.origin;
 778                 self.warpzone_save_angles = self.angles;
 779                 self.warpzone_save_eorigin = self.enemy.origin;
 780                 self.warpzone_save_eangles = self.enemy.angles;
 781         }
 782         self.nextthink = time;
 783 }
 784
 785 void WarpZone_StartFrame()
 786 {SELFPARAM();
 787         entity e;
 788         if(warpzone_initialized == 0)
 789         {
 790                 warpzone_initialized = 1;
 791                 for(setself(warpzone_first); self; setself(self.warpzone_next))
 792                         WarpZone_InitStep_FindOriginTarget();
 793                 for(setself(warpzone_position_first); self; setself(self.warpzone_next))
 794                         WarpZonePosition_InitStep_FindTarget();
 795                 for(setself(warpzone_first); self; setself(self.warpzone_next))
 796                         WarpZone_InitStep_UpdateTransform();
 797                 setself(this);
 798                 WarpZones_Reconnect();
 799                 WarpZone_PostInitialize_Callback();
 800         }
 801
 802         entity oldother;
 803         oldother = other;
 804         for(e = world; (e = nextent(e)); )
 805         {
 806                 if(warpzone_warpzones_exist) { WarpZone_StoreProjectileData(e); }
 807
 808                 if(IS_REAL_CLIENT(e))
 809                 {
 810                         if(e.solid == SOLID_NOT) // not spectating?
 811                         if(e.movetype == MOVETYPE_NOCLIP || e.movetype == MOVETYPE_FLY || e.movetype == MOVETYPE_FLY_WORLDONLY) // not spectating? (this is to catch observers)
 812                         {
 813                                 other = e; // player
 814
 815                                 // warpzones
 816                                 if(warpzone_warpzones_exist) {
 817                                 setself(WarpZone_Find(e.origin + e.mins, e.origin + e.maxs));
 818                                 if(self)
 819                                 if(!WarpZoneLib_ExactTrigger_Touch())
 820                                         if(WarpZone_PlaneDist(self, e.origin + e.view_ofs) <= 0)
 821                                                 WarpZone_Teleport(self, e, -1, 0); } // NOT triggering targets by this!
 822
 823                                 // teleporters
 824                                 setself(Teleport_Find(e.origin + e.mins, e.origin + e.maxs));
 825                                 if(self)
 826                                 if(!WarpZoneLib_ExactTrigger_Touch())
 827                                         Simple_TeleportPlayer(self, other); // NOT triggering targets by this!
 828                         }
 829                 }
 830
 831                 if(IS_NOT_A_CLIENT(e))
 832                 {
 833                         if(warpzone_warpzones_exist)
 834                                 for (; (e = nextent(e)); )
 835                                         WarpZone_StoreProjectileData(e);
 836                         break;
 837                 }
 838         }
 839         setself(this);
 840         other = oldother;
 841 }
 842
 843 .float warpzone_reconnecting;
 844 float visible_to_some_client(entity ent)
 845 {
 846         entity e;
 847         for(e = nextent(world); !IS_NOT_A_CLIENT(e); e = nextent(e))
 848                 if(IS_PLAYER(e) && IS_REAL_CLIENT(e))
 849                         if(checkpvs(e.origin + e.view_ofs, ent))
 850                                 return 1;
 851         return 0;
 852 }
 853 void trigger_warpzone_reconnect_use()
 854 {SELFPARAM();
 855         entity e;
 856         e = self;
 857         // NOTE: this matches for target, not targetname, but of course
 858         // targetname must be set too on the other entities
 859         for(setself(warpzone_first); self; setself(self.warpzone_next))
 860                 self.warpzone_reconnecting = ((e.target == "" || self.target == e.target) && !((e.spawnflags & 1) && (visible_to_some_client(self) || visible_to_some_client(self.enemy))));
 861         for(setself(warpzone_camera_first); self; setself(self.warpzone_next))
 862                 self.warpzone_reconnecting = ((e.target == "" || self.target == e.target) && !((e.spawnflags & 1) && visible_to_some_client(self)));
 863         for(setself(warpzone_first); self; setself(self.warpzone_next))
 864                 if(self.warpzone_reconnecting)
 865                         WarpZone_InitStep_ClearTarget();
 866         for(setself(warpzone_first); self; setself(self.warpzone_next))
 867                 if(self.warpzone_reconnecting)
 868                         WarpZone_InitStep_FindTarget();
 869         for(setself(warpzone_camera_first); self; setself(self.warpzone_next))
 870                 if(self.warpzone_reconnecting)
 871                         WarpZoneCamera_InitStep_FindTarget();
 872         for(setself(warpzone_first); self; setself(self.warpzone_next))
 873                 if(self.warpzone_reconnecting || self.enemy.warpzone_reconnecting)
 874                         WarpZone_InitStep_FinalizeTransform();
 875         setself(e);
 876 }
 877
 878 spawnfunc(trigger_warpzone_reconnect)
 879 {
 880         self.use = trigger_warpzone_reconnect_use;
 881 }
 882
 883 spawnfunc(target_warpzone_reconnect)
 884 {
 885         spawnfunc_trigger_warpzone_reconnect(this); // both names make sense here :(
 886 }
 887
 888 void WarpZone_PlayerPhysics_FixVAngle(void)
 889 {SELFPARAM();
 890 #ifndef WARPZONE_DONT_FIX_VANGLE
 891         if(IS_REAL_CLIENT(self))
 892         if(self.v_angle.z <= 360) // if not already adjusted
 893         if(time - self.ping * 0.001 < self.warpzone_teleport_time)
 894         {
 895                 self.v_angle = WarpZone_TransformVAngles(self.warpzone_teleport_zone, self.v_angle);
 896                 self.v_angle_z += 720; // mark as adjusted
 897         }
 898 #endif
 899 }