qcsrc/menu/xonotic/cvarlist.qc

   1 #include "cvarlist.qh"
   2
   3 #include "inputbox.qh"
   4 #include "../item/container.qh"
   5
   6 entity makeXonoticCvarList()
   7 {
   8         entity me;
   9         me = NEW(XonoticCvarList);
  10         me.configureXonoticCvarList(me);
  11         return me;
  12 }
  13 void XonoticCvarList_configureXonoticCvarList(entity me)
  14 {
  15         me.configureXonoticListBox(me);
  16         me.handle = buf_create();
  17         me.nItems = 0;
  18 }
  19 void XonoticCvarList_showNotify(entity me)
  20 {
  21         bool force_initial_selection = false;
  22         if(me.handle >= 0 && me.nItems <= 0) // me.handle not loaded yet?
  23                 force_initial_selection = true;
  24         buf_cvarlist(me.handle, "", "_");
  25         me.nItems = buf_getsize(me.handle);
  26         if(force_initial_selection)
  27                 me.setSelected(me, 0);
  28 }
  29 void XonoticCvarList_destroy(entity me)
  30 {
  31         buf_del(me.handle);
  32 }
  33 string autocvar_menu_forced_saved_cvars;
  34 string autocvar_menu_reverted_nonsaved_cvars;
  35 float XonoticCvarList_updateCvarType(entity me)
  36 {
  37         float t;
  38         t = cvar_type(me.cvarName);
  39         me.cvarType = "";
  40         float needsForcing;
  41         if(strhasword(autocvar_menu_forced_saved_cvars, me.cvarName))
  42         {
  43                 me.cvarType = strcat(me.cvarType, ", ", _("forced to be saved to config.cfg"));
  44                 needsForcing = 0;
  45         }
  46         else if(strhasword(autocvar_menu_reverted_nonsaved_cvars, me.cvarName))
  47         {
  48                 // Currently claims to be saved, but won't be on next startup.
  49                 me.cvarType = strcat(me.cvarType, ", ", _("will not be saved"));
  50                 needsForcing = 1;
  51         }
  52         else if(t & CVAR_TYPEFLAG_SAVED)
  53         {
  54                 me.cvarType = strcat(me.cvarType, ", ", _("will be saved to config.cfg"));
  55                 needsForcing = 0;
  56         }
  57         else
  58         {
  59                 me.cvarType = strcat(me.cvarType, ", ", _("will not be saved"));
  60                 needsForcing = 1;
  61         }
  62         if(t & CVAR_TYPEFLAG_PRIVATE)
  63                 me.cvarType = strcat(me.cvarType, ", ", _("private"));
  64         if(t & CVAR_TYPEFLAG_ENGINE)
  65                 me.cvarType = strcat(me.cvarType, ", ", _("engine setting"));
  66         if(t & CVAR_TYPEFLAG_READONLY)
  67                 me.cvarType = strcat(me.cvarType, ", ", _("read only"));
  68         me.cvarType = strzone(substring(me.cvarType, 2, strlen(me.cvarType) - 2));
  69         me.cvarTypeBox.setText(me.cvarTypeBox, me.cvarType);
  70         return needsForcing;
  71 }
  72 void XonoticCvarList_setSelected(entity me, float i)
  73 {
  74         string s;
  75
  76         SUPER(XonoticCvarList).setSelected(me, i);
  77         if(me.nItems == 0)
  78                 return;
  79
  80         if(me.cvarName)
  81                 strunzone(me.cvarName);
  82         if(me.cvarDescription)
  83                 strunzone(me.cvarDescription);
  84         if(me.cvarType)
  85                 strunzone(me.cvarType);
  86         if(me.cvarDefault)
  87                 strunzone(me.cvarDefault);
  88         me.cvarName = strzone(bufstr_get(me.handle, me.selectedItem));
  89         me.cvarDescription = strzone(cvar_description(me.cvarName));
  90         me.cvarDefault = strzone(cvar_defstring(me.cvarName));
  91         me.cvarNameBox.setText(me.cvarNameBox, me.cvarName);
  92         me.cvarDescriptionBox.setText(me.cvarDescriptionBox, me.cvarDescription);
  93         float needsForcing = me.updateCvarType(me);
  94         me.cvarDefaultBox.setText(me.cvarDefaultBox, me.cvarDefault);
  95
  96         // this one can handle tempstrings
  97         s = cvar_string(me.cvarName);
  98         me.cvarNeedsForcing = 0;
  99         me.cvarValueBox.setText(me.cvarValueBox, s);
 100         me.cvarNeedsForcing = needsForcing;
 101         me.cvarValueBox.cursorPos = strlen(s);
 102 }
 103 void CvarList_Filter_Change(entity box, entity me)
 104 {
 105         buf_cvarlist(me.handle, box.text, "_");
 106         me.nItems = buf_getsize(me.handle);
 107
 108         me.setSelected(me, 0);
 109 }
 110 void XonoticCvarList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 111 {
 112         SUPER(XonoticCvarList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 113
 114         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
 115         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
 116         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 117
 118         me.columnNameOrigin = 0;
 119         me.columnValueSize = me.realFontSize.x * 20;
 120         me.columnNameSize = 1 - me.columnValueSize - me.realFontSize.x;
 121         me.columnValueOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x;
 122 }
 123 void XonoticCvarList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 124 {
 125         string k, v, d;
 126         float t;
 127
 128         vector theColor;
 129         float theAlpha;
 130
 131         string s;
 132
 133         if(isSelected)
 134                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 135         else if(isFocused)
 136         {
 137                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 138                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 139         }
 140
 141         k = bufstr_get(me.handle, i);
 142
 143         v = cvar_string(k);
 144         d = cvar_defstring(k);
 145         t = cvar_type(k);
 146         if(strhasword(autocvar_menu_forced_saved_cvars, k))
 147                 theAlpha = SKINALPHA_CVARLIST_SAVED;
 148         else if(strhasword(autocvar_menu_reverted_nonsaved_cvars, k))
 149                 theAlpha = SKINALPHA_CVARLIST_TEMPORARY;
 150         else if(t & CVAR_TYPEFLAG_SAVED)
 151                 theAlpha = SKINALPHA_CVARLIST_SAVED;
 152         else
 153                 theAlpha = SKINALPHA_CVARLIST_TEMPORARY;
 154         if(v == d)
 155                 theColor = SKINCOLOR_CVARLIST_UNCHANGED;
 156         else
 157                 theColor = SKINCOLOR_CVARLIST_CHANGED;
 158
 159         s = draw_TextShortenToWidth(k, me.columnNameSize, 0, me.realFontSize);
 160         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
 161         s = draw_TextShortenToWidth(v, me.columnValueSize, 0, me.realFontSize);
 162         draw_Text(me.realUpperMargin * eY + me.columnValueOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
 163 }
 164
 165 float XonoticCvarList_keyDown(entity me, float scan, float ascii, float shift)
 166 {
 167         if (scan == K_MOUSE3 || ((shift & S_CTRL) && scan == K_SPACE))
 168         {
 169                 CvarList_Revert_Click(NULL, me);
 170                 return 1;
 171         }
 172         else if(scan == K_ENTER)
 173         {
 174                 me.cvarValueBox.parent.setFocus(me.cvarValueBox.parent, me.cvarValueBox);
 175                 return 1;
 176         }
 177         else if(SUPER(XonoticCvarList).keyDown(me, scan, ascii, shift))
 178                 return 1;
 179         else if(!me.controlledTextbox)
 180                 return 0;
 181         else
 182                 return me.controlledTextbox.keyDown(me.controlledTextbox, scan, ascii, shift);
 183 }
 184
 185 float XonoticCvarList_mouseRelease(entity me, vector pos)
 186 {
 187         if(me.pressed == 2)
 188                 me.cvarValueBox.parent.setFocus(me.cvarValueBox.parent, me.cvarValueBox);
 189         return SUPER(XonoticCvarList).mouseRelease(me, pos);
 190 }
 191
 192 void CvarList_Value_Change(entity box, entity me)
 193 {
 194         cvar_set(me.cvarNameBox.text, box.text);
 195         if(me.cvarNeedsForcing)
 196         {
 197                 localcmd(sprintf("\nseta %1$s \"$%1$s\"\n", me.cvarName));
 198                 cvar_set("menu_reverted_nonsaved_cvars", substring(strreplace(strcat(" ", me.cvarName, " "), " ", strcat(" ", autocvar_menu_reverted_nonsaved_cvars, " ")), 1, -2));
 199                 if (autocvar_menu_forced_saved_cvars == "")
 200                         cvar_set("menu_forced_saved_cvars", me.cvarName);
 201                 else
 202                         cvar_set("menu_forced_saved_cvars", strcat(autocvar_menu_forced_saved_cvars, " ", me.cvarName));
 203                 me.cvarNeedsForcing = 0;
 204                 me.updateCvarType(me);
 205         }
 206 }
 207
 208 void CvarList_Revert_Click(entity btn, entity me)
 209 {
 210         me.cvarValueBox.setText(me.cvarValueBox, me.cvarDefault);
 211         me.cvarValueBox.cursorPos = strlen(me.cvarDefault);
 212         if(strhasword(autocvar_menu_forced_saved_cvars, me.cvarName))
 213         {
 214                 cvar_set("menu_forced_saved_cvars", substring(strreplace(strcat(" ", me.cvarName, " "), " ", strcat(" ", autocvar_menu_forced_saved_cvars, " ")), 1, -2));
 215                 if (autocvar_menu_reverted_nonsaved_cvars == "")
 216                         cvar_set("menu_reverted_nonsaved_cvars", me.cvarName);
 217                 else
 218                         cvar_set("menu_reverted_nonsaved_cvars", strcat(autocvar_menu_reverted_nonsaved_cvars, " ", me.cvarName));
 219         }
 220         me.cvarNeedsForcing = me.updateCvarType(me);
 221 }
 222
 223 void CvarList_End_Editing(entity box, entity me)
 224 {
 225         box.parent.setFocus(box.parent, me);
 226 }