qcsrc/menu/xonotic/dialog_multiplayer_create_mutators.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticMutatorsDialog) EXTENDS(XonoticDialog)
   3         METHOD(XonoticMutatorsDialog, toString, string(entity))
   4         METHOD(XonoticMutatorsDialog, fill, void(entity))
   5         METHOD(XonoticMutatorsDialog, showNotify, void(entity))
   6         METHOD(XonoticMutatorsDialog, close, void(entity))
   7         ATTRIB(XonoticMutatorsDialog, title, string, _("Mutators"))
   8         ATTRIB(XonoticMutatorsDialog, color, vector, SKINCOLOR_DIALOG_MUTATORS)
   9         ATTRIB(XonoticMutatorsDialog, intendedWidth, float, 0.9)
  10         ATTRIB(XonoticMutatorsDialog, rows, float, 17)
  11         ATTRIB(XonoticMutatorsDialog, columns, float, 6)
  12         ATTRIB(XonoticMutatorsDialog, refilterEntity, entity, NULL)
  13 ENDCLASS(XonoticMutatorsDialog)
  14 #endif
  15
  16 #ifdef IMPLEMENTATION
  17 void XonoticMutatorsDialog_showNotify(entity me)
  18 {
  19         loadAllCvars(me);
  20 }
  21
  22 string weaponarenastring;
  23 string weaponarenastring_cvar;
  24 string WeaponArenaString()
  25 {
  26         string s;
  27         float n, i, j;
  28         entity e;
  29         s = cvar_string("g_weaponarena");
  30         if(s == "0")
  31                 return "";
  32         if(s == "all")
  33                 return _("All Weapons Arena");
  34         if(s == "most")
  35                 return _("Most Weapons Arena");
  36         if(s == weaponarenastring_cvar)
  37                 return weaponarenastring;
  38         if(weaponarenastring)
  39                 strunzone(weaponarenastring);
  40         if(weaponarenastring_cvar)
  41                 strunzone(weaponarenastring_cvar);
  42
  43         weaponarenastring_cvar = strzone(s);
  44
  45         n = tokenize_console(s);
  46         s = "";
  47         for(i = 0; i < n; ++i)
  48         {
  49                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  50                 {
  51                         e = get_weaponinfo(j);
  52                         if(argv(i) == e.netname)
  53                                 s = strcat(s, " & ", e.message);
  54                 }
  55         }
  56         s = sprintf(_("%s Arena"), substring(s, 3, strlen(s) - 3));
  57
  58         weaponarenastring = strzone(s);
  59
  60         return weaponarenastring;
  61 }
  62
  63 string XonoticMutatorsDialog_toString(entity me)
  64 {
  65         string s;
  66         s = "";
  67         if(cvar("g_dodging"))
  68                 s = strcat(s, ", ", _("Dodging"));
  69         if(cvar("g_minstagib"))
  70                 s = strcat(s, ", ", _("MinstaGib"));
  71         if(cvar("g_nix"))
  72                 s = strcat(s, ", ", _("NIX"));
  73         if(cvar("g_rocket_flying"))
  74                 s = strcat(s, ", ", _("Rocket Flying"));
  75         if(cvar("g_invincible_projectiles"))
  76                 s = strcat(s, ", ", _("Invincible Projectiles"));
  77         if(cvar_string("g_weaponarena") != "0")
  78                 s = strcat(s, ", ", WeaponArenaString());
  79         if(cvar("g_start_weapon_laser") == 0)
  80                 s = strcat(s, ", ", _("No start weapons"));
  81         if(cvar("sv_gravity") < 800)
  82                 s = strcat(s, ", ", _("Low gravity"));
  83         if(cvar("g_cloaked"))
  84                 s = strcat(s, ", ", _("Cloaked"));
  85         if(cvar("g_grappling_hook"))
  86                 s = strcat(s, ", ", _("Hook"));
  87         if(cvar("g_midair"))
  88                 s = strcat(s, ", ", _("Midair"));
  89         if(cvar("g_vampire"))
  90                 s = strcat(s, ", ", _("Vampire"));
  91         if(cvar("g_pinata"))
  92                 s = strcat(s, ", ", _("Piñata"));
  93         if(cvar("g_weapon_stay"))
  94                 s = strcat(s, ", ", _("Weapons stay"));
  95         if(cvar("g_bloodloss") > 0)
  96                 s = strcat(s, ", ", _("Blood loss"));
  97         if(cvar("g_jetpack"))
  98                 s = strcat(s, ", ", _("Jet pack"));
  99         if(cvar("g_powerups") == 0)
 100                 s = strcat(s, ", ", _("No powerups"));
 101         if(cvar("g_powerups") > 0)
 102                 s = strcat(s, ", ", _("Powerups"));
 103         if(s == "")
 104                 return ZCTX(_("MUT^None"));
 105         else
 106                 return substring(s, 2, strlen(s) - 2);
 107 }
 108
 109
 110
 111 // WARNING: dirty hack. TODO clean this up by putting this behaviour in extra classes.
 112 void loadCvarsLaserWeaponArenaWeaponButton(entity me)
 113 {
 114         tokenize_console(cvar_string("g_weaponarena"));
 115         me.checked = (argv(0) == me.cvarValue);
 116 }
 117
 118 void saveCvarsLaserWeaponArenaWeaponButton(entity me)
 119 {
 120         string suffix;
 121
 122         suffix = "";
 123         if(me.cvarValue != "laser" && me.cvarValue != "most")
 124                 if(cvar("menu_weaponarena_with_laser"))
 125                         suffix = " laser";
 126         if(me.checked)
 127                 cvar_set("g_weaponarena", strcat(me.cvarValue, suffix));
 128         else
 129                 cvar_set("g_weaponarena", me.cvarOffValue);
 130 }
 131
 132 .void(entity) draw_weaponarena;
 133 .void(entity) saveCvars_weaponarena;
 134 void saveCvarsLaserWeaponArenaLaserButton(entity me)
 135 {
 136         // run the old function
 137         me.saveCvars_weaponarena(me);
 138
 139         me.disabled = ((cvar_string("g_weaponarena") == "0") || (cvar_string("g_weaponarena") == "laser") || (cvar_string("g_weaponarena") == "most"));
 140
 141         if not(me.disabled)
 142         {
 143                 // check for the laser suffix
 144                 string s;
 145                 s = cvar_string("g_weaponarena");
 146                 if(me.checked && substring(s, strlen(s) - 6, 6) != " laser")
 147                         s = strcat(s, " laser");
 148                 else if(!me.checked && substring(s, strlen(s) - 6, 6) == " laser")
 149                         s = substring(s, 0, strlen(s) - 6);
 150                 cvar_set("g_weaponarena", s);
 151         }
 152 }
 153
 154 void preDrawLaserWeaponArenaLaserButton(entity me)
 155 {
 156         me.disabled = ((cvar_string("g_weaponarena") == "0") || (cvar_string("g_weaponarena") == "laser") || (cvar_string("g_weaponarena") == "most"));
 157         // run the old function
 158         me.draw_weaponarena(me);
 159 }
 160 // WARNING: end of dirty hack. Do not try this at home.
 161
 162
 163
 164 void XonoticMutatorsDialog_fill(entity me)
 165 {
 166         entity e, s, w;
 167         float i, j;
 168         string str, hstr;
 169         me.TR(me);
 170                 me.TD(me, 1, 2, makeXonoticTextLabel(0, _("Gameplay mutators:")));
 171         me.TR(me);
 172                 me.TDempty(me, 0.2);
 173                 me.TD(me, 1, 2, e = makeXonoticCheckBox(0, "g_dodging", _("Dodging")));
 174         me.TR(me);
 175                 me.TDempty(me, 0.2);
 176                 me.TD(me, 1, 2, e = makeXonoticCheckBox(0, "g_cloaked", _("Cloaked")));
 177         me.TR(me);
 178                 me.TDempty(me, 0.2);
 179                 me.TD(me, 1, 2, e = makeXonoticCheckBox(0, "g_midair", _("Midair")));
 180         me.TR(me);
 181                 me.TDempty(me, 0.2);
 182                 me.TD(me, 1, 2, e = makeXonoticCheckBox(0, "g_vampire", _("Vampire")));
 183         me.TR(me);
 184                 me.TDempty(me, 0.2);
 185                 s = makeXonoticSlider(10, 50, 1, "g_bloodloss");
 186                 me.TD(me, 1, 2, e = makeXonoticSliderCheckBox(0, 1, s, _("Blood loss")));
 187         me.TR(me);
 188                 me.TDempty(me, 0.4);
 189                 me.TD(me, 1, 1.8, s);
 190         me.TR(me);
 191                 me.TDempty(me, 0.2);
 192                 s = makeXonoticSlider(80, 400, 8, "sv_gravity");
 193                         s.valueDigits = 0;
 194                         s.valueDisplayMultiplier = 0.125; // show gravity in percent
 195                 me.TD(me, 1, 2, e = makeXonoticSliderCheckBox(800, 1, s, _("Low gravity")));
 196                         e.savedValue = 200; // good on silvercity
 197         me.TR(me);
 198                 me.TDempty(me, 0.4);
 199                 me.TD(me, 1, 1.8, s);
 200         me.TR(me);
 201                 me.TD(me, 1, 2, makeXonoticTextLabel(0, _("Weapon & item mutators:")));
 202         me.TR(me);
 203                 me.TDempty(me, 0.2);
 204                 me.TD(me, 1, 2, e = makeXonoticCheckBox(0, "g_grappling_hook", _("Grappling hook")));
 205         me.TR(me);
 206                 me.TDempty(me, 0.2);
 207                 me.TD(me, 1, 2, e = makeXonoticCheckBox(0, "g_jetpack", _("Jet pack")));
 208         me.TR(me);
 209                 me.TDempty(me, 0.2);
 210                 me.TD(me, 1, 2, e = makeXonoticCheckBox(0, "g_invincible_projectiles", _("Invincible Projectiles")));
 211         me.TR(me);
 212                 me.TDempty(me, 0.2);
 213                 me.TD(me, 1, 2, e = makeXonoticCheckBox(0, "g_rocket_flying", _("Rocket Flying")));
 214         me.TR(me);
 215                 me.TDempty(me, 0.2);
 216                 me.TD(me, 1, 2, e = makeXonoticCheckBox(0, "g_pinata", _("Piñata")));
 217         me.TR(me);
 218                 me.TDempty(me, 0.2);
 219                 me.TD(me, 1, 2, e = makeXonoticCheckBox(0, "g_weapon_stay", _("Weapons stay")));
 220         me.TR(me);
 221
 222         me.gotoRC(me, 0, 2); me.setFirstColumn(me, me.currentColumn);
 223                 me.TD(me, 1, 4, makeXonoticTextLabel(0, _("Weapon arenas:")));
 224         me.TR(me);
 225                 me.TDempty(me, 0.2);
 226                 me.TD(me, 1, 2, e = makeXonoticRadioButton(1, string_null, string_null, _("Regular (no arena)")));
 227         for(i = WEP_FIRST, j = 0; i <= WEP_LAST; ++i)
 228         {
 229                 w = get_weaponinfo(i);
 230                 if(w.spawnflags & WEP_FLAG_HIDDEN)
 231                         continue;
 232                 if(j & 1 == 0)
 233                         me.TR(me);
 234                 str = w.netname;
 235                 hstr = w.message;
 236                 me.TDempty(me, 0.2);
 237                 me.TD(me, 1, 2, e = makeXonoticRadioButton(1, "g_weaponarena", strzone(str), strzone(hstr)));
 238                         e.cvarOffValue = "0";
 239                         // custom load/save logic that ignores a " laser" suffix, or adds it
 240                         e.loadCvars = loadCvarsLaserWeaponArenaWeaponButton;
 241                         e.saveCvars = saveCvarsLaserWeaponArenaWeaponButton;
 242                         e.loadCvars(e);
 243                 ++j;
 244         }
 245         me.TR(me);
 246                 me.TDempty(me, 0.2);
 247                 me.TD(me, 1, 1, e = makeXonoticCheckBox(0, "menu_weaponarena_with_laser", _("with laser")));
 248                         // hook the draw function to gray it out
 249                         e.draw_weaponarena = e.draw;
 250                         e.draw = preDrawLaserWeaponArenaLaserButton;
 251                         // hook the save function to notify about the cvar
 252                         e.saveCvars_weaponarena = e.saveCvars;
 253                         e.saveCvars = saveCvarsLaserWeaponArenaLaserButton;
 254         me.TR(me);
 255                 me.TD(me, 1, 4, makeXonoticTextLabel(0, _("Special arenas:")));
 256         me.TR(me);
 257                 me.TDempty(me, 0.2);
 258                 me.TD(me, 1, 2, e = makeXonoticRadioButton(1, "g_minstagib", string_null, _("MinstaGib")));
 259         me.TR(me);
 260                 me.TDempty(me, 0.2);
 261                 me.TD(me, 1, 2, e = makeXonoticRadioButton(1, "g_nix", string_null, _("NIX")));
 262         me.TR(me);
 263                 me.TDempty(me, 0.4);
 264                 me.TD(me, 1, 1, e = makeXonoticCheckBox(0, "g_nix_with_laser", _("with laser")));
 265                         setDependent(e, "g_nix", 1, 1);
 266         me.TR(me);
 267                 me.TDempty(me, 0.2);
 268                 me.TD(me, 1, 2, e = makeXonoticRadioButton(1, "g_weaponarena", "most", _("Most weapons")));
 269                         e.cvarOffValue = "0";
 270         me.TR(me);
 271                 me.TDempty(me, 0.2);
 272                 me.TD(me, 1, 2, e = makeXonoticRadioButton(1, "g_start_weapon_laser", "0", _("No start weapons")));
 273                         e.cvarOffValue = "-1";
 274                         makeMulti(e, "g_start_weapon_shotgun g_start_weapon_uzi g_start_weapon_grenadelauncher g_start_weapon_minelayer g_start_weapon_electro g_start_weapon_crylink g_start_weapon_nex g_start_weapon_hagar g_start_weapon_rocketlauncher g_start_weapon_rifle g_start_weapon_hlac g_start_weapon_seeker g_start_weapon_minstanex g_start_weapon_hook g_start_weapon_porto g_start_weapon_tuba g_start_weapon_minelayer");
 275
 276         me.gotoRC(me, me.rows - 1, 0);
 277                 me.TD(me, 1, me.columns, e = makeXonoticButton(_("OK"), '0 0 0'));
 278                         e.onClick = Dialog_Close;
 279                         e.onClickEntity = me;
 280 }
 281
 282 void XonoticMutatorsDialog_close(entity me)
 283 {
 284         if(me.refilterEntity)
 285                 me.refilterEntity.refilter(me.refilterEntity);
 286         SUPER(XonoticMutatorsDialog).close(me);
 287 }
 288 #endif