qcsrc/menu/xonotic/dialog_multiplayer_create_mutators.qc

   1 #ifdef INTERFACE
   2 CLASS(XonoticMutatorsDialog) EXTENDS(XonoticDialog)
   3         METHOD(XonoticMutatorsDialog, toString, string(entity))
   4         METHOD(XonoticMutatorsDialog, fill, void(entity))
   5         METHOD(XonoticMutatorsDialog, showNotify, void(entity))
   6         METHOD(XonoticMutatorsDialog, close, void(entity))
   7         ATTRIB(XonoticMutatorsDialog, title, string, _("Mutators"))
   8         ATTRIB(XonoticMutatorsDialog, color, vector, SKINCOLOR_DIALOG_MUTATORS)
   9         ATTRIB(XonoticMutatorsDialog, intendedWidth, float, 0.9)
  10         ATTRIB(XonoticMutatorsDialog, rows, float, 20)
  11         ATTRIB(XonoticMutatorsDialog, columns, float, 6)
  12         ATTRIB(XonoticMutatorsDialog, refilterEntity, entity, NULL)
  13 ENDCLASS(XonoticMutatorsDialog)
  14 #endif
  15
  16 #ifdef IMPLEMENTATION
  17 void XonoticMutatorsDialog_showNotify(entity me)
  18 {
  19         loadAllCvars(me);
  20 }
  21
  22 string weaponarenastring;
  23 string weaponarenastring_cvar;
  24 string WeaponArenaString()
  25 {
  26         string s;
  27         float n, i, j;
  28         entity e;
  29         s = cvar_string("g_weaponarena");
  30         if(s == "0")
  31                 return "";
  32         if(s == "all" || s == "1")
  33                 return _("All Weapons Arena");
  34         if(s == "most")
  35                 return _("Most Weapons Arena");
  36         if(s == weaponarenastring_cvar)
  37                 return weaponarenastring;
  38         if(weaponarenastring)
  39                 strunzone(weaponarenastring);
  40         if(weaponarenastring_cvar)
  41                 strunzone(weaponarenastring_cvar);
  42
  43         weaponarenastring_cvar = strzone(s);
  44
  45         n = tokenize_console(s);
  46         s = "";
  47         for(i = 0; i < n; ++i)
  48         {
  49                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  50                 {
  51                         e = get_weaponinfo(j);
  52                         if(argv(i) == e.netname)
  53                                 s = strcat(s, " & ", e.message);
  54                 }
  55         }
  56         s = sprintf(_("%s Arena"), substring(s, 3, strlen(s) - 3));
  57
  58         weaponarenastring = strzone(s);
  59
  60         return weaponarenastring;
  61 }
  62
  63 string XonoticMutatorsDialog_toString(entity me)
  64 {
  65         string s;
  66         s = "";
  67         if(cvar("g_dodging"))
  68                 s = strcat(s, ", ", _("Dodging"));
  69         if(cvar("g_instagib"))
  70                 s = strcat(s, ", ", _("InstaGib"));
  71         if(cvar("g_new_toys"))
  72                 s = strcat(s, ", ", _("New Toys"));
  73         if(cvar("g_nix"))
  74                 s = strcat(s, ", ", _("NIX"));
  75         if(cvar("g_rocket_flying"))
  76                 s = strcat(s, ", ", _("Rocket Flying"));
  77         if(cvar("g_invincible_projectiles"))
  78                 s = strcat(s, ", ", _("Invincible Projectiles"));
  79         if(cvar_string("g_weaponarena") != "0")
  80                 s = strcat(s, ", ", WeaponArenaString());
  81         if(cvar("g_balance_blaster_weaponstart") == 0)
  82                 s = strcat(s, ", ", _("No start weapons"));
  83         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
  84                 s = strcat(s, ", ", _("Low gravity"));
  85         if(cvar("g_cloaked"))
  86                 s = strcat(s, ", ", _("Cloaked"));
  87         if(cvar("g_grappling_hook"))
  88                 s = strcat(s, ", ", _("Hook"));
  89         if(cvar("g_midair"))
  90                 s = strcat(s, ", ", _("Midair"));
  91         if(cvar("g_vampire"))
  92                 s = strcat(s, ", ", _("Vampire"));
  93         if(cvar("g_pinata"))
  94                 s = strcat(s, ", ", _("Piñata"));
  95         if(cvar("g_weapon_stay"))
  96                 s = strcat(s, ", ", _("Weapons stay"));
  97         if(cvar("g_bloodloss") > 0)
  98                 s = strcat(s, ", ", _("Blood loss"));
  99         if(cvar("g_jetpack"))
 100                 s = strcat(s, ", ", _("Jet pack"));
 101         if(cvar("g_buffs"))
 102                 s = strcat(s, ", ", _("Buffs"));
 103         if(cvar("g_overkill"))
 104                 s = strcat(s, ", ", _("Overkill"));
 105         if(cvar("g_powerups") == 0)
 106                 s = strcat(s, ", ", _("No powerups"));
 107         if(cvar("g_powerups") > 0)
 108                 s = strcat(s, ", ", _("Powerups"));
 109         if(cvar("g_touchexplode") > 0)
 110                 s = strcat(s, ", ", _("Touch explode"));
 111         if(s == "")
 112                 return ZCTX(_("MUT^None"));
 113         else
 114                 return substring(s, 2, strlen(s) - 2);
 115 }
 116
 117 float checkCompatibility_pinata(entity me)
 118 {
 119         if(cvar("g_instagib"))
 120                 return 0;
 121         if(cvar("g_nix"))
 122                 return 0;
 123         if(cvar_string("g_weaponarena") != "0")
 124                 return 0;
 125         return 1;
 126 }
 127 float checkCompatibility_weaponstay(entity me)
 128 {
 129         return checkCompatibility_pinata(me);
 130 }
 131 float checkCompatibility_newtoys(entity me)
 132 {
 133         if(cvar("g_instagib"))
 134                 return 0;
 135         if(cvar_string("g_weaponarena") == "most")
 136                 return 1;
 137         if(cvar_string("g_weaponarena") == "all" || cvar_string("g_weaponarena") == "1")
 138                 return 1;
 139         if(cvar_string("g_weaponarena") != "0")
 140                 return 0;
 141         return 1;
 142 }
 143 float checkCompatibility_weaponarena_weapon(entity me)
 144 {
 145         if(cvar("g_instagib"))
 146                 return 0;
 147         if(cvar_string("g_weaponarena") == "most")
 148                 return 0;
 149         if(cvar_string("g_weaponarena") == "all" || cvar_string("g_weaponarena") == "1")
 150                 return 0;
 151         if(cvar_string("g_weaponarena") == "0")
 152                 return 0;
 153         if(cvar_string("g_balance_blaster_weaponstart") == "0")
 154                 return 0;
 155         return 1;
 156 }
 157
 158 void XonoticMutatorsDialog_fill(entity me)
 159 {
 160         entity e, s, w;
 161         float i, j;
 162         me.TR(me);
 163                 me.TD(me, 1, 2, makeXonoticTextLabel(0, _("Gameplay mutators:")));
 164         me.TR(me);
 165                 me.TDempty(me, 0.2);
 166                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_dodging", _("Dodging")));
 167         me.TR(me);
 168                 me.TDempty(me, 0.2);
 169                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_touchexplode", _("Touch explode")));
 170         me.TR(me);
 171                 me.TDempty(me, 0.2);
 172                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_cloaked", _("Cloaked")));
 173         me.TR(me);
 174                 me.TDempty(me, 0.2);
 175                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_buffs", _("Buffs")));
 176         me.TR(me);
 177                 me.TDempty(me, 0.2);
 178                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_midair", _("Midair")));
 179         me.TR(me);
 180                 me.TDempty(me, 0.2);
 181                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_vampire", _("Vampire")));
 182                         setDependent(e, "g_instagib", 0, 0);
 183         me.TR(me);
 184                 me.TDempty(me, 0.2);
 185                 s = makeXonoticSlider(10, 50, 1, "g_bloodloss");
 186                 me.TD(me, 1, 1.8, e = makeXonoticSliderCheckBox(0, 1, s, _("Blood loss")));
 187                         setDependent(e, "g_instagib", 0, 0);
 188         me.TR(me);
 189                 me.TDempty(me, 0.4);
 190                 me.TD(me, 1, 1.6, s);
 191         me.TR(me);
 192                 me.TDempty(me, 0.2);
 193                 s = makeXonoticSlider(80, 400, 8, "sv_gravity");
 194                         s.valueDigits = 0;
 195                         s.valueDisplayMultiplier = 0.125; // show gravity in percent
 196                 me.TD(me, 1, 1.8, e = makeXonoticSliderCheckBox(800, 1, s, _("Low gravity")));
 197                         e.savedValue = 200; // good on silvercity
 198         me.TR(me);
 199                 me.TDempty(me, 0.4);
 200                 me.TD(me, 1, 1.6, s);
 201         me.TR(me);
 202                 me.TD(me, 1, 2, makeXonoticTextLabel(0, _("Weapon & item mutators:")));
 203         me.TR(me);
 204                 me.TDempty(me, 0.2);
 205                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_grappling_hook", _("Grappling hook")));
 206         me.TR(me);
 207                 me.TDempty(me, 0.2);
 208                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_jetpack", _("Jet pack")));
 209         me.TR(me);
 210                 me.TDempty(me, 0.2);
 211                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_invincible_projectiles", _("Invincible Projectiles")));
 212                         setDependent(e, "g_instagib", 0, 0);
 213         me.TR(me);
 214                 me.TDempty(me, 0.2);
 215                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_new_toys", _("New Toys")));
 216                         setDependentWeird(e, checkCompatibility_newtoys);
 217         me.TR(me);
 218                 me.TDempty(me, 0.2);
 219                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_rocket_flying", _("Rocket Flying")));
 220                         setDependent(e, "g_instagib", 0, 0);
 221         me.TR(me);
 222                 me.TDempty(me, 0.2);
 223                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_pinata", _("Piñata")));
 224                         setDependentWeird(e, checkCompatibility_pinata);
 225         me.TR(me);
 226                 me.TDempty(me, 0.2);
 227                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_weapon_stay", _("Weapons stay")));
 228                         setDependentWeird(e, checkCompatibility_weaponstay);
 229         me.TR(me);
 230
 231         me.gotoRC(me, 0, 2); me.setFirstColumn(me, me.currentColumn);
 232                 me.TD(me, 1, 2, e = makeXonoticRadioButton(1, string_null, string_null, _("Regular (no arena)")));
 233         me.TR(me);
 234                 me.TD(me, 1, 2, e = makeXonoticRadioButton(1, "g_weaponarena", "menu_weaponarena", _("Weapon arenas:")));
 235                         e.getCvarValueFromCvar = TRUE;
 236                         e.cvarOffValue = "0";
 237         for(i = WEP_FIRST, j = 0; i <= WEP_LAST; ++i)
 238         {
 239                 w = get_weaponinfo(i);
 240                 if(w.spawnflags & WEP_FLAG_HIDDEN)
 241                         continue;
 242                 if((j & 1) == 0)
 243                         me.TR(me);
 244                 me.TDempty(me, 0.2);
 245                 me.TD(me, 1, 1.8, e = makeXonoticWeaponarenaCheckBox(strzone(w.netname), strzone(w.message)));
 246                         setDependentWeird(e, checkCompatibility_weaponarena_weapon);
 247                 ++j;
 248         }
 249         me.TR(me);
 250                 me.TDempty(me, 0.2);
 251                 me.TD(me, 1, 1.8, e = makeXonoticRadioButton(1, "g_weaponarena", "most", _("Most weapons")));
 252                         e.cvarOffValue = "0";
 253         me.TR(me);
 254                 me.TDempty(me, 0.2);
 255                 me.TD(me, 1, 1.8, e = makeXonoticRadioButton(1, "g_weaponarena", "all", _("All weapons")));
 256                         e.cvarOffValue = "0";
 257         me.TR(me);
 258                 me.TD(me, 1, 4, makeXonoticTextLabel(0, _("Special arenas:")));
 259         me.TR(me);
 260                 me.TDempty(me, 0.2);
 261                 me.TD(me, 1, 1.8, e = makeXonoticRadioButton(1, "g_instagib", "1", _("InstaGib")));
 262                         e.cvarOffValue = "0";
 263         me.TR(me);
 264                 me.TDempty(me, 0.2);
 265                 me.TD(me, 1, 1.8, e = makeXonoticRadioButton(1, "g_nix", "1", _("NIX")));
 266                         e.cvarOffValue = "0";
 267         me.TR(me);
 268                 me.TDempty(me, 0.4);
 269                 me.TD(me, 1, 1.6, e = makeXonoticCheckBox(0, "g_nix_with_blaster", _("with blaster")));
 270                         setDependent(e, "g_nix", 1, 1);
 271         me.TR(me);
 272                 me.TDempty(me, 0.2);
 273                 me.TD(me, 1, 1.8, e = makeXonoticRadioButton(1, "g_balance_blaster_weaponstart", "0", _("No start weapons")));
 274                         e.cvarOffValue = "-1";
 275                         makeMulti(e, "g_balance_shotgun_weaponstart g_balance_machinegun_weaponstart g_balance_devastator_weaponstart g_balance_minelayer_weaponstart g_balance_electro_weaponstart g_balance_crylink_weaponstart g_balance_hagar_weaponstart g_balance_porto_weaponstart g_balance_vaporizer_weaponstart g_balance_hook_weaponstart g_balance_rifle_weaponstart g_balance_fireball_weaponstart g_balance_seeker_weaponstart g_balance_tuba_weaponstart g_balance_arc_weaponstart g_balance_vortex_weaponstart g_balance_mortar_weaponstart");
 276
 277         me.gotoRC(me, me.rows - 1, 0);
 278                 me.TD(me, 1, me.columns, e = makeXonoticButton(_("OK"), '0 0 0'));
 279                         e.onClick = Dialog_Close;
 280                         e.onClickEntity = me;
 281 }
 282
 283 void XonoticMutatorsDialog_close(entity me)
 284 {
 285         if(me.refilterEntity)
 286                 me.refilterEntity.refilter(me.refilterEntity);
 287         SUPER(XonoticMutatorsDialog).close(me);
 288 }
 289 #endif