qcsrc/menu/xonotic/dialog_multiplayer_profile.qc

   1 #include "dialog_multiplayer_profile.qh"
   2
   3 #include "playermodel.qh"
   4 #include "statslist.qh"
   5 #include "languagelist.qh"
   6 #include "textlabel.qh"
   7 #include "commandbutton.qh"
   8 #include "inputbox.qh"
   9 #include "colorpicker.qh"
  10 #include "charmap.qh"
  11 #include "colorbutton.qh"
  12 #include "checkbox.qh"
  13 #include "radiobutton.qh"
  14
  15 entity makeXonoticProfileTab()
  16 {
  17         entity me;
  18         me = NEW(XonoticProfileTab);
  19         me.configureDialog(me);
  20         return me;
  21 }
  22 void XonoticProfileTab_draw(entity me)
  23 {
  24         if(cvar_string("_cl_name") == "Player")
  25                 me.playerNameLabel.alpha = ((mod(time * 2, 2) < 1) ? 1 : 0);
  26         else
  27                 me.playerNameLabel.alpha = me.playerNameLabelAlpha;
  28         SUPER(XonoticProfileTab).draw(me);
  29 }
  30 void language_selector_click(entity me, entity btn)
  31 {
  32         localcmd("\nmenu_cmd languageselect\n");
  33 }
  34 void XonoticProfileTab_fill(entity me)
  35 {
  36         entity e, pms, label, box;
  37         float i;
  38         entity profileApplyButton = makeXonoticCommandButton(_("Apply immediately"), '0 0 0',
  39                 "color -1 -1;"
  40                 "name \"$_cl_name\";"
  41                 "playermodel $_cl_playermodel;"
  42                 "playerskin $_cl_playerskin;"
  43                 "sendcvar cl_allow_uidtracking;"
  44                 "sendcvar cl_allow_uid2name;"
  45                 , COMMANDBUTTON_APPLY);
  46         profileApplyButton.disableOnClick = true;
  47
  48         // ==============
  49         //  NAME SECTION
  50         // ==============
  51         me.gotoRC(me, 0.5, 0);
  52                 me.TD(me, 1, 3, me.playerNameLabel = makeXonoticHeaderLabel(_("Name")));
  53
  54         me.gotoRC(me, 1.5, 0);
  55                 me.TD(me, 1, 3, label = makeXonoticTextLabel(0.5, string_null));
  56                         label.allowCut = 1;
  57                         label.allowColors = 1;
  58                         label.alpha = 1;
  59                         label.isBold = true;
  60                         label.fontSize = SKINFONTSIZE_TITLE;
  61
  62         me.gotoRC(me, 2.5, 0);
  63                 me.TD(me, 1, 3.0, box = makeXonoticInputBox_T(1, "_cl_name",
  64                         _("Name under which you will appear in the game")));
  65                         box.forbiddenCharacters = "\r\n\\\"$"; // don't care, isn't getting saved
  66                         box.maxLength = -127; // negative means encoded length in bytes
  67                         box.saveImmediately = 0;  // Sorry, can't do this, it spams "name" commands.
  68                         box.enableClearButton = 0;
  69                         box.applyButton = profileApplyButton;
  70                         label.textEntity = box;
  71         me.TR(me);
  72                 me.TD(me, 5, 1, e = makeXonoticColorpicker(box));
  73                 me.TD(me, 5, 2, e = makeXonoticCharmap(box));
  74
  75         // ===============
  76         //  MODEL SECTION
  77         // ===============
  78         //me.gotoRC(me, 0.5, 3.1); me.setFirstColumn(me, me.currentColumn); // TOP RIGHT
  79         //me.gotoRC(me, 9, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM RIGHT
  80         me.gotoRC(me, 9, 0); me.setFirstColumn(me, me.currentColumn); // BOTTOM LEFT
  81                 me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Model")));
  82
  83         me.TR(me);
  84                 //me.TDempty(me, 0); // MODEL LEFT, COLOR RIGHT
  85                 me.TDempty(me, 1); // MODEL RIGHT, COLOR LEFT
  86                 pms = makeXonoticPlayerModelSelector();
  87                 me.TD(me, 1, 0.3, e = makeXonoticButton("<<", '0 0 0'));
  88                         e.onClick = PlayerModelSelector_Prev_Click;
  89                         e.onClickEntity = pms;
  90                         e.applyButton = profileApplyButton;
  91                 me.TD(me, 11.5, 1.4, pms);
  92                 me.TD(me, 1, 0.3, e = makeXonoticButton(">>", '0 0 0'));
  93                         e.onClick = PlayerModelSelector_Next_Click;
  94                         e.onClickEntity = pms;
  95                         e.applyButton = profileApplyButton;
  96
  97         //me.setFirstColumn(me, me.currentColumn + 2); // MODEL LEFT, COLOR RIGHT
  98         me.gotoRC(me, me.currentRow, 0); me.setFirstColumn(me, me.currentColumn); // MODEL RIGHT, COLOR LEFT
  99         me.TR(me);
 100                 me.TD(me, 1, 1, e = makeXonoticHeaderLabel(_("Glowing color")));
 101                 for(i = 0; i < 15; ++i)
 102                 {
 103                         if(mod(i, 5) == 0)
 104                                 me.TR(me);
 105                         me.TDNoMargin(me, 1, 0.2, e = makeXonoticColorButton(1, 0, i), '0 1 0');
 106                                 e.applyButton = profileApplyButton;
 107                 }
 108         me.TR(me);
 109         me.TR(me);
 110                 me.TD(me, 1, 1, e = makeXonoticHeaderLabel(_("Detail color")));
 111                 for(i = 0; i < 15; ++i)
 112                 {
 113                         if(mod(i, 5) == 0)
 114                                 me.TR(me);
 115                         me.TDNoMargin(me, 1, 0.2, e = makeXonoticColorButton(2, 1, i), '0 1 0');
 116                                 e.applyButton = profileApplyButton;
 117                 }
 118
 119         // ====================
 120         //  STATISTICS SECTION
 121         // ====================
 122         me.gotoRC(me, 0.5, 3.1); me.setFirstColumn(me, me.currentColumn); // TOP RIGHT
 123         //me.gotoRC(me, 9, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM RIGHT
 124         //me.gotoRC(me, 9, 0); me.setFirstColumn(me, me.currentColumn); // BOTTOM LEFT
 125                 me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Statistics")));
 126
 127         me.TR(me);
 128                 me.TDempty(me, 0.25);
 129                 me.TD(me, 1, 2.5, e = makeXonoticCheckBox(0, "cl_allow_uidtracking", _("Allow player statistics to track your client")));
 130                         e.applyButton = profileApplyButton;
 131         me.TR(me);
 132                 me.TDempty(me, 0.25);
 133                 me.TD(me, 1, 2.5, e = makeXonoticCheckBox(0, "cl_allow_uid2name", _("Allow player statistics to use your nickname")));
 134                         e.applyButton = profileApplyButton;
 135                         setDependent(e, "cl_allow_uidtracking", 1, 1);
 136         me.gotoRC(me, 4, 3.1); // TOP RIGHT
 137         //me.gotoRC(me, 12.5, 3.1); // BOTTOM RIGHT
 138         //me.gotoRC(me, 12.5, 0); // BOTTOM LEFT
 139                 me.TDempty(me, 0.25);
 140                 me.TD(me, 9, 2.5, statslist = makeXonoticStatsList());
 141                 //setDependent(statslist, "cl_allow_uidtracking", 1, 1);
 142
 143         // =================
 144         //  COUNTRY SECTION
 145         // =================
 146         me.gotoRC(me, 16, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM SECTION, TOP POS
 147         //me.gotoRC(me, 13.5, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM SECTION, TOP POS
 148         //me.gotoRC(me, 0.5, 3.1); me.setFirstColumn(me, me.currentColumn); // TOP SECTION, TOP POS
 149                 me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Country")));
 150
 151         me.TR(me);
 152                 me.TDempty(me, 0.75);
 153                 me.TD(me, 1, 1.5, e = makeXonoticButton(_("Select language..."), '0 0 0'));
 154                         e.onClick = language_selector_click;
 155                         e.onClickEntity = me;
 156                 /*
 157                 me.TDempty(me, 0.5);
 158                 me.TD(me, 4.5, 2, e = makeXonoticLanguageList()); // todo: cl_country: create proper country list
 159                 */
 160
 161
 162         // ================
 163         //  GENDER SECTION
 164         // ================
 165         me.gotoRC(me, 13.5, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM SECTION, TOP POS
 166         //me.gotoRC(me, 19.5, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM SECTION, BOTTOM POS
 167         //me.gotoRC(me, 6.5, 3.1); me.setFirstColumn(me, me.currentColumn); // TOP SECTION, BOTTOM POS
 168         #if 0
 169                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Gender:")));
 170                 me.TD(me, 1, 2, e = makeXonoticTextSlider("_cl_gender"));
 171                         e.addValue(e, _("Undisclosed"), "0");
 172                         e.addValue(e, _("Female"), "1");
 173                         e.addValue(e, _("Male"), "2");
 174                         e.configureXonoticTextSliderValues(e);
 175         #else
 176                         me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Gender")));
 177                 me.TR(me);
 178                         #define GENDERWIDTH_OFFSET 0.25
 179                         #define GENDERWIDTH_LENGTH 2.5
 180                         #define GENDERWIDTH_ITEM (GENDERWIDTH_LENGTH / 3)
 181                         me.TDempty(me, GENDERWIDTH_OFFSET);
 182                         me.TD(me, 1, GENDERWIDTH_ITEM, e = makeXonoticRadioButton(3, "_cl_gender", "2", _("Female")));
 183                         me.TD(me, 1, GENDERWIDTH_ITEM, e = makeXonoticRadioButton(3, "_cl_gender", "1", _("Male")));
 184                         me.TD(me, 1, GENDERWIDTH_ITEM, e = makeXonoticRadioButton(3, "_cl_gender", "0", _("Undisclosed")));
 185         #endif
 186
 187         me.gotoRC(me, me.rows - 1, 0);
 188                 me.TD(me, 1, me.columns, profileApplyButton);
 189 }