qcsrc/menu/xonotic/gametypelist.qc

   1 #include "gametypelist.qh"
   2
   3 #include "dialog_multiplayer_create.qh"
   4 #include <common/gamemodes/_mod.qh>
   5 #include <common/mapinfo.qh>
   6
   7 entity makeXonoticGametypeList()
   8 {
   9         entity me;
  10         me = NEW(XonoticGametypeList);
  11         me.configureXonoticGametypeList(me);
  12         return me;
  13 }
  14 void XonoticGametypeList_configureXonoticGametypeList(entity me)
  15 {
  16         me.configureXonoticListBox(me);
  17         me.nItems = GameType_GetCount();
  18
  19         if(SKINBOOL_GAMETYPELIST_ICON_BLUR)
  20         {
  21                 for(int i = 0; i < GameType_GetTotalCount(); ++i)
  22                         draw_PreloadPictureWithFlags(GameType_GetIcon(i), PRECACHE_PIC_MIPMAP);
  23         }
  24
  25         me.loadCvars(me);
  26 }
  27 void XonoticGametypeList_setSelected(entity me, float i)
  28 {
  29         SUPER(XonoticGametypeList).setSelected(me, i);
  30         me.saveCvars(me);
  31 }
  32 void XonoticGametypeList_loadCvars(entity me)
  33 {
  34         Gametype t = MapInfo_CurrentGametype();
  35         int cnt = GameType_GetCount();
  36         float i;
  37         for(i = 0; i < cnt; ++i)
  38                 if(t == GameType_GetID(i))
  39                         break;
  40         if(i >= cnt)
  41         {
  42                 for(i = 0; i < cnt; ++i)
  43                         if(t == MAPINFO_TYPE_DEATHMATCH)
  44                                 break;
  45                 if(i >= cnt)
  46                         i = 0;
  47         }
  48         me.setSelected(me, i);
  49         // do we need this: me.parent.gameTypeChangeNotify(me.parent); // to make sure
  50 }
  51 void XonoticGametypeList_saveCvars(entity me)
  52 {
  53         Gametype t = GameType_GetID(me.selectedItem);
  54         if (t == MapInfo_CurrentGametype()) {
  55                 return;
  56         }
  57         MapInfo_SwitchGameType(t);
  58         entity owner = me.parent;
  59         if (owner) { // not set immediately
  60                 owner.gameTypeChangeNotify(owner);
  61         }
  62 }
  63 void XonoticGametypeList_draw(entity me)
  64 {
  65         if(me.nItems != GameType_GetCount())
  66         {
  67                 me.nItems = GameType_GetCount();
  68                 me.setSelected(me, 0);
  69         }
  70         SUPER(XonoticGametypeList).draw(me);
  71 }
  72 void XonoticGametypeList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
  73 {
  74         string s1, s2;
  75
  76         if(isSelected)
  77                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  78         else if(isFocused)
  79         {
  80                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
  81                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
  82         }
  83
  84         draw_Picture(me.columnIconOrigin * eX, GameType_GetIcon(i), me.columnIconSize * eX + eY, '1 1 1', SKINALPHA_LISTBOX_SELECTED);
  85         s1 = GameType_GetName(i);
  86
  87         if(_MapInfo_GetTeamPlayBool(GameType_GetID(i)))
  88                 s2 = _("teamplay");
  89         else
  90                 s2 = _("free for all");
  91
  92         vector save_fontscale = draw_fontscale;
  93         float f = draw_CondensedFontFactor(strcat(s1, " ", s2), false, me.realFontSize, 1);
  94         draw_fontscale.x *= f;
  95         vector fs = me.realFontSize;
  96         fs.x *= f;
  97         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s1, fs, '1 1 1', SKINALPHA_TEXT, 0);
  98         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 1.0 * (me.columnNameSize - draw_TextWidth(s2, 0, fs))) * eX, s2, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  99         draw_fontscale = save_fontscale;
 100 }
 101 void XonoticGametypeList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 102 {
 103         me.itemAbsSize = '0 0 0';
 104         SUPER(XonoticGametypeList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 105
 106         me.itemAbsSize.y = absSize.y * me.itemHeight;
 107         me.itemAbsSize.x = absSize.x * (1 - me.controlWidth);
 108         me.realFontSize.y = me.fontSize / me.itemAbsSize.y;
 109         me.realFontSize.x = me.fontSize / me.itemAbsSize.x;
 110         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 111         me.columnIconOrigin = 0;
 112         me.columnIconSize = me.itemAbsSize.y / me.itemAbsSize.x;
 113         me.columnNameOrigin = me.columnIconOrigin + me.columnIconSize + (0.5 * me.realFontSize.x);
 114         me.columnNameSize = 1 - me.columnIconSize - (1.5 * me.realFontSize.x);
 115 }
 116 float XonoticGametypeList_keyDown(entity me, float scan, float ascii, float shift)
 117 {
 118         if(scan == K_ENTER || scan == K_KP_ENTER)
 119         {
 120                 m_play_click_sound(MENU_SOUND_EXECUTE);
 121                 me.parent.gameTypeSelectNotify(me.parent);
 122                 return 1;
 123         }
 124
 125         return SUPER(XonoticGametypeList).keyDown(me, scan, ascii, shift);
 126 }
 127 void XonoticGametypeList_clickListBoxItem(entity me, float i, vector where)
 128 {
 129         m_play_click_sound(MENU_SOUND_SELECT);
 130 }
 131 void XonoticGametypeList_focusedItemChangeNotify(entity me)
 132 {
 133         if(me.focusedItem >= 0)
 134                 setZonedTooltip(me, MapInfo_Type_Description(GameType_GetID(me.focusedItem)), string_null);
 135         else
 136                 clearTooltip(me);
 137 }