qcsrc/menu/xonotic/maplist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticMapList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticMapList, configureXonoticMapList, void(entity))
   4         ATTRIB(XonoticMapList, rowsPerItem, float, 4)
   5         METHOD(XonoticMapList, draw, void(entity))
   6         METHOD(XonoticMapList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(XonoticMapList, clickListBoxItem, void(entity, float, vector))
   8         METHOD(XonoticMapList, resizeNotify, void(entity, vector, vector, vector, vector))
   9         METHOD(XonoticMapList, refilter, void(entity))
  10         METHOD(XonoticMapList, refilterCallback, void(entity, entity))
  11         METHOD(XonoticMapList, keyDown, float(entity, float, float, float))
  12
  13         ATTRIB(XonoticMapList, realFontSize, vector, '0 0 0')
  14         ATTRIB(XonoticMapList, columnPreviewOrigin, float, 0)
  15         ATTRIB(XonoticMapList, columnPreviewSize, float, 0)
  16         ATTRIB(XonoticMapList, columnNameOrigin, float, 0)
  17         ATTRIB(XonoticMapList, columnNameSize, float, 0)
  18         ATTRIB(XonoticMapList, checkMarkOrigin, vector, '0 0 0')
  19         ATTRIB(XonoticMapList, checkMarkSize, vector, '0 0 0')
  20         ATTRIB(XonoticMapList, realUpperMargin1, float, 0)
  21         ATTRIB(XonoticMapList, realUpperMargin2, float, 0)
  22
  23         ATTRIB(XonoticMapList, lastClickedMap, float, -1)
  24         ATTRIB(XonoticMapList, lastClickedTime, float, 0)
  25
  26         ATTRIB(XonoticMapList, lastGametype, float, 0)
  27         ATTRIB(XonoticMapList, lastFeatures, float, 0)
  28
  29         ATTRIB(XonoticMapList, origin, vector, '0 0 0')
  30         ATTRIB(XonoticMapList, itemAbsSize, vector, '0 0 0')
  31
  32         ATTRIB(XonoticMapList, g_maplistCache, string, string_null)
  33         METHOD(XonoticMapList, g_maplistCacheToggle, void(entity, float))
  34         METHOD(XonoticMapList, g_maplistCacheQuery, float(entity, float))
  35
  36         ATTRIB(XonoticMapList, startButton, entity, NULL)
  37
  38         METHOD(XonoticMapList, loadCvars, void(entity))
  39
  40         ATTRIB(XonoticMapList, typeToSearchString, string, string_null)
  41         ATTRIB(XonoticMapList, typeToSearchTime, float, 0)
  42
  43         METHOD(XonoticMapList, destroy, void(entity))
  44
  45         ATTRIB(XonoticListBox, alphaBG, float, 0)
  46 ENDCLASS(XonoticMapList)
  47 entity makeXonoticMapList();
  48 void MapList_All(entity btn, entity me);
  49 void MapList_None(entity btn, entity me);
  50 void MapList_LoadMap(entity btn, entity me);
  51 #endif
  52
  53 #ifdef IMPLEMENTATION
  54 void XonoticMapList_destroy(entity me)
  55 {
  56         MapInfo_Shutdown();
  57 }
  58
  59 entity makeXonoticMapList()
  60 {
  61         entity me;
  62         me = spawnXonoticMapList();
  63         me.configureXonoticMapList(me);
  64         return me;
  65 }
  66
  67 void XonoticMapList_configureXonoticMapList(entity me)
  68 {
  69         me.configureXonoticListBox(me);
  70         me.refilter(me);
  71 }
  72
  73 void XonoticMapList_loadCvars(entity me)
  74 {
  75         me.refilter(me);
  76 }
  77
  78 float XonoticMapList_g_maplistCacheQuery(entity me, float i)
  79 {
  80         return stof(substring(me.g_maplistCache, i, 1));
  81 }
  82 void XonoticMapList_g_maplistCacheToggle(entity me, float i)
  83 {
  84         string a, b, c, s, bspname;
  85         float n;
  86         s = me.g_maplistCache;
  87         if not(s)
  88                 return;
  89         b = substring(s, i, 1);
  90         if(b == "0")
  91                 b = "1";
  92         else if(b == "1")
  93                 b = "0";
  94         else
  95                 return; // nothing happens
  96         a = substring(s, 0, i);
  97         c = substring(s, i+1, strlen(s) - (i+1));
  98         strunzone(s);
  99         me.g_maplistCache = strzone(strcat(a, b, c));
 100         // TODO also update the actual cvar
 101         if not((bspname = MapInfo_BSPName_ByID(i)))
 102                 return;
 103         if(b == "1")
 104                 cvar_set("g_maplist", strcat(bspname, " ", cvar_string("g_maplist")));
 105         else
 106         {
 107                 s = "";
 108                 n = tokenize_console(cvar_string("g_maplist"));
 109                 for(i = 0; i < n; ++i)
 110                         if(argv(i) != bspname)
 111                                 s = strcat(s, " ", argv(i));
 112                 cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 113         }
 114 }
 115
 116 void XonoticMapList_draw(entity me)
 117 {
 118         if(me.startButton)
 119                 me.startButton.disabled = ((me.selectedItem < 0) || (me.selectedItem >= me.nItems));
 120         SUPER(XonoticMapList).draw(me);
 121 }
 122
 123 void XonoticMapList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 124 {
 125         me.itemAbsSize = '0 0 0';
 126         SUPER(XonoticMapList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 127
 128         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 129         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 130         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize_y);
 131         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize_y;
 132
 133         me.columnPreviewOrigin = 0;
 134         me.columnPreviewSize = me.itemAbsSize_y / me.itemAbsSize_x * 4 / 3;
 135         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize_x;
 136         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize_x;
 137
 138         me.checkMarkSize = (eX * (me.itemAbsSize_y / me.itemAbsSize_x) + eY) * 0.5;
 139         me.checkMarkOrigin = eY + eX * (me.columnPreviewOrigin + me.columnPreviewSize) - me.checkMarkSize;
 140 }
 141
 142 void XonoticMapList_clickListBoxItem(entity me, float i, vector where)
 143 {
 144         if(where_x <= me.columnPreviewOrigin + me.columnPreviewSize)
 145         {
 146                 if(where_x >= 0)
 147                         me.g_maplistCacheToggle(me, i);
 148         }
 149         if(where_x >= me.columnNameOrigin)
 150                 if(where_x <= 1)
 151                         {
 152                                 if(i == me.lastClickedMap)
 153                                         if(time < me.lastClickedTime + 0.3)
 154                                         {
 155                                                 // DOUBLE CLICK!
 156                                                 // pop up map info screen
 157                                                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, i, me);
 158                                                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * i - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 159                                                 return;
 160                                         }
 161                                 me.lastClickedMap = i;
 162                                 me.lastClickedTime = time;
 163                         }
 164 }
 165
 166 void XonoticMapList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 167 {
 168         // layout: Ping, Map name, Map name, NP, TP, MP
 169         string s;
 170         float p;
 171         float theAlpha;
 172         float included;
 173
 174         if(!MapInfo_Get_ByID(i))
 175                 return;
 176
 177         included = me.g_maplistCacheQuery(me, i);
 178         if(included || isSelected)
 179                 theAlpha = SKINALPHA_MAPLIST_INCLUDEDFG;
 180         else
 181                 theAlpha = SKINALPHA_MAPLIST_NOTINCLUDEDFG;
 182
 183         if(isSelected)
 184                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 185         else if(included)
 186                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_MAPLIST_INCLUDEDBG, SKINALPHA_MAPLIST_INCLUDEDBG);
 187
 188         s = ftos(p);
 189         if(draw_PictureSize(strcat("/maps/", MapInfo_Map_bspname)) == '0 0 0')
 190                 draw_Picture(me.columnPreviewOrigin * eX, "nopreview_map", me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 191         else
 192                 draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", MapInfo_Map_bspname), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 193
 194         if(included)
 195                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 196         s = draw_TextShortenToWidth(strdecolorize(MapInfo_Map_titlestring), me.columnNameSize, 0, me.realFontSize);
 197         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_TITLE, theAlpha, 0);
 198         s = draw_TextShortenToWidth(strdecolorize(MapInfo_Map_author), me.columnNameSize, 0,  me.realFontSize);
 199         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_AUTHOR, theAlpha, 0);
 200
 201         MapInfo_ClearTemps();
 202 }
 203
 204 void XonoticMapList_refilter(entity me)
 205 {
 206         float i, j, n;
 207         string s;
 208         float gt, f;
 209         gt = MapInfo_CurrentGametype();
 210         f = MapInfo_CurrentFeatures();
 211         MapInfo_FilterGametype(gt, f, MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 212         me.nItems = MapInfo_count;
 213         for(i = 0; i < MapInfo_count; ++i)
 214                 draw_PreloadPicture(strcat("/maps/", MapInfo_BSPName_ByID(i)));
 215         if(me.g_maplistCache)
 216                 strunzone(me.g_maplistCache);
 217         s = "0";
 218         for(i = 1; i < MapInfo_count; i *= 2)
 219                 s = strcat(s, s);
 220         n = tokenize_console(cvar_string("g_maplist"));
 221         for(i = 0; i < n; ++i)
 222         {
 223                 j = MapInfo_FindName(argv(i));
 224                 if(j >= 0)
 225                         s = strcat(
 226                                 substring(s, 0, j),
 227                                 "1",
 228                                 substring(s, j+1, MapInfo_count - (j+1))
 229                         );
 230         }
 231         me.g_maplistCache = strzone(s);
 232         if(gt != me.lastGametype || f != me.lastFeatures)
 233         {
 234                 me.lastGametype = gt;
 235                 me.lastFeatures = f;
 236                 me.setSelected(me, 0);
 237         }
 238 }
 239
 240 void XonoticMapList_refilterCallback(entity me, entity cb)
 241 {
 242         me.refilter(me);
 243 }
 244
 245 void MapList_All(entity btn, entity me)
 246 {
 247         float i;
 248         string s;
 249         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, MAPINFO_FLAG_FORBIDDEN | MAPINFO_FLAG_HIDDEN, 0); // all
 250         s = "";
 251         for(i = 0; i < MapInfo_count; ++i)
 252                 s = strcat(s, " ", MapInfo_BSPName_ByID(i));
 253         cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 254         me.refilter(me);
 255 }
 256
 257 void MapList_None(entity btn, entity me)
 258 {
 259         cvar_set("g_maplist", "");
 260         me.refilter(me);
 261 }
 262
 263 void MapList_LoadMap(entity btn, entity me)
 264 {
 265         string m;
 266         float i;
 267
 268         i = me.selectedItem;
 269
 270         if(btn.parent.instanceOfXonoticMapInfoDialog)
 271         {
 272                 i = btn.parent.currentMapIndex;
 273                 Dialog_Close(btn, btn.parent);
 274         }
 275
 276         if(i >= me.nItems || i < 0)
 277                 return;
 278
 279         m = MapInfo_BSPName_ByID(i);
 280         if not(m)
 281         {
 282                 print(_("Huh? Can't play this (m is NULL). Refiltering so this won't happen again.\n"));
 283                 me.refilter(me);
 284                 return;
 285         }
 286         if(MapInfo_CheckMap(m))
 287         {
 288                 localcmd("\nmenu_loadmap_prepare\n");
 289                 if(cvar("menu_use_default_hostname"))
 290                         localcmd("hostname \"", sprintf(_("%s's Xonotic Server"), strdecolorize(cvar_string("_cl_name"))), "\"\n");
 291                 MapInfo_LoadMap(m, 1);
 292         }
 293         else
 294         {
 295                 print(_("Huh? Can't play this (invalid game type). Refiltering so this won't happen again.\n"));
 296                 me.refilter(me);
 297                 return;
 298         }
 299 }
 300
 301 float XonoticMapList_keyDown(entity me, float scan, float ascii, float shift)
 302 {
 303         string ch, save;
 304         if(me.nItems <= 0)
 305                 return SUPER(XonoticMapList).keyDown(me, scan, ascii, shift);
 306         if(scan == K_ENTER || scan == K_KP_ENTER)
 307         {
 308                 // pop up map info screen
 309                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, me.selectedItem, me);
 310                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 311         }
 312         else if(scan == K_SPACE)
 313         {
 314                 me.g_maplistCacheToggle(me, me.selectedItem);
 315         }
 316         else if(ascii == 43) // +
 317         {
 318                 if not(me.g_maplistCacheQuery(me, me.selectedItem))
 319                         me.g_maplistCacheToggle(me, me.selectedItem);
 320         }
 321         else if(ascii == 45) // -
 322         {
 323                 if(me.g_maplistCacheQuery(me, me.selectedItem))
 324                         me.g_maplistCacheToggle(me, me.selectedItem);
 325         }
 326         else if(scan == K_BACKSPACE)
 327         {
 328                 if(time < me.typeToSearchTime)
 329                 {
 330                         save = substring(me.typeToSearchString, 0, strlen(me.typeToSearchString) - 1);
 331                         if(me.typeToSearchString)
 332                                 strunzone(me.typeToSearchString);
 333                         me.typeToSearchString = strzone(save);
 334                         me.typeToSearchTime = time + 0.5;
 335                         if(strlen(me.typeToSearchString))
 336                         {
 337                                 MapInfo_FindName(me.typeToSearchString);
 338                                 if(MapInfo_FindName_firstResult >= 0)
 339                                         me.setSelected(me, MapInfo_FindName_firstResult);
 340                         }
 341                 }
 342         }
 343         else if(ascii >= 32 && ascii != 127)
 344         {
 345                 ch = chr(ascii);
 346                 if(time > me.typeToSearchTime)
 347                         save = ch;
 348                 else
 349                         save = strcat(me.typeToSearchString, ch);
 350                 if(me.typeToSearchString)
 351                         strunzone(me.typeToSearchString);
 352                 me.typeToSearchString = strzone(save);
 353                 me.typeToSearchTime = time + 0.5;
 354                 MapInfo_FindName(me.typeToSearchString);
 355                 if(MapInfo_FindName_firstResult >= 0)
 356                         me.setSelected(me, MapInfo_FindName_firstResult);
 357         }
 358         else
 359                 return SUPER(XonoticMapList).keyDown(me, scan, ascii, shift);
 360         return 1;
 361 }
 362
 363 #endif