qcsrc/menu/xonotic/screenshotlist.qc

   1 #include "screenshotlist.qh"
   2
   3 #include "dialog_multiplayer_media_screenshot.qh"
   4 #include "dialog_multiplayer_media_screenshot_viewer.qh"
   5 #include "inputbox.qh"
   6 #include "../item/modalcontroller.qh"
   7
   8 entity makeXonoticScreenshotList()
   9 {
  10         entity me;
  11         me = NEW(XonoticScreenshotList);
  12         me.configureXonoticScreenshotList(me);
  13         return me;
  14 }
  15
  16 void XonoticScreenshotList_configureXonoticScreenshotList(entity me)
  17 {
  18         me.configureXonoticListBox(me);
  19         me.nItems = 0;
  20 }
  21
  22 string XonoticScreenshotList_screenshotName(entity me, float i)
  23 {
  24         string s;
  25         s = bufstr_get(me.listScreenshot, i);
  26
  27         if(substring(s, 0, 1) == "/")
  28                 s = substring(s, 1, strlen(s) - 1);  // remove the first forward slash
  29
  30         return s;
  31 }
  32
  33 // if subdir is true look in subdirectories too (1 level)
  34 void getScreenshots_for_ext(entity me, string ext, float subdir)
  35 {
  36         string s;
  37         if (subdir)
  38                 s="screenshots/*/";
  39         else
  40                 s="screenshots/";
  41         if(me.filterString)
  42                 s=strcat(s, me.filterString, ext);
  43         else
  44                 s=strcat(s, "*", ext);
  45
  46         float list, i, n;
  47         list = search_begin(s, false, true);
  48         if(list >= 0)
  49         {
  50                 n = search_getsize(list);
  51                 for(i = 0; i < n; ++i)
  52                 {
  53                         s = search_getfilename(list, i); // get initial full file name
  54                         s = substring(s, 12, (strlen(s) - 12 - 4)); // remove "screenshots/" prefix and ".<ext>" suffix
  55                         s = strdecolorize(s); // remove any pre-existing colors
  56                         if(subdir)
  57                         {
  58                                 s = strreplace("/", "^7/", s); // clear colors at the forward slash
  59                                 s = strcat("/", rgb_to_hexcolor(SKINCOLOR_SCREENSHOTLIST_SUBDIR), s); // add a forward slash for sorting, then color
  60                                 bufstr_add(me.listScreenshot, s, true);
  61                         }
  62                         else { bufstr_add(me.listScreenshot, s, true); }
  63                 }
  64                 search_end(list);
  65         }
  66
  67         if (subdir)
  68                 getScreenshots_for_ext(me, ext, false);
  69 }
  70
  71 void XonoticScreenshotList_getScreenshots(entity me)
  72 {
  73         if (me.listScreenshot >= 0)
  74                 buf_del(me.listScreenshot);
  75         me.listScreenshot = buf_create();
  76         if (me.listScreenshot < 0)
  77         {
  78                 me.nItems = 0;
  79                 return;
  80         }
  81         getScreenshots_for_ext(me, ".jpg", true);
  82         getScreenshots_for_ext(me, ".tga", true);
  83         getScreenshots_for_ext(me, ".png", true);
  84         me.nItems = buf_getsize(me.listScreenshot);
  85         if(me.nItems > 0)
  86                 buf_sort(me.listScreenshot, 128, false);
  87 }
  88
  89 void XonoticScreenshotList_destroy(entity me)
  90 {
  91         if(me.nItems > 0)
  92                 buf_del(me.listScreenshot);
  93 }
  94
  95 void XonoticScreenshotList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  96 {
  97         me.itemAbsSize = '0 0 0';
  98         SUPER(XonoticScreenshotList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  99
 100         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 101         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 102         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 103
 104         me.columnNameOrigin = me.realFontSize.x;
 105         me.columnNameSize = 1 - 2 * me.realFontSize.x;
 106 }
 107
 108 void XonoticScreenshotList_setSelected(entity me, float i)
 109 {
 110         if (me.newSlideShowScreenshotTime)
 111                 me.startSlideShow(me);
 112         float selectedItem_save = me.selectedItem;
 113         SUPER(XonoticScreenshotList).setSelected(me, i);
 114         if (me.pressed && me.selectedItem != selectedItem_save)
 115         {
 116                 // avoid immediate image loading on quick repeated selection changes
 117                 me.newScreenshotTime = time + 0.22;
 118         }
 119         else if (time > me.newScreenshotTime)
 120         {
 121                 me.newScreenshotTime = 0;
 122                 me.previewScreenshot(me); // load the preview on selection change
 123         }
 124 }
 125
 126 void XonoticScreenshotList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 127 {
 128         string s;
 129         if(isSelected)
 130                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 131         else if(isFocused)
 132         {
 133                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 134                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 135         }
 136
 137         s = me.screenshotName(me,i);
 138         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 139         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 1);
 140 }
 141
 142 void XonoticScreenshotList_showNotify(entity me)
 143 {
 144         me.getScreenshots(me);
 145         me.previewScreenshot(me);
 146 }
 147
 148 void ScreenshotList_Refresh_Click(entity btn, entity me)
 149 {
 150         me.getScreenshots(me);
 151         me.setSelected(me, 0); //always select the first element after a list update
 152 }
 153
 154 void ScreenshotList_Filter_Change(entity box, entity me)
 155 {
 156         strfree(me.filterString);
 157
 158         if(box.text != "")
 159         {
 160                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0)
 161                         me.filterString = strzone(box.text);
 162                 else
 163                         me.filterString = strzone(strcat("*", box.text, "*"));
 164         }
 165
 166         ScreenshotList_Refresh_Click(NULL, me);
 167 }
 168
 169 void ScreenshotList_Filter_Would_Change(entity box, entity me)
 170 {
 171         me.filterBox = box;
 172         me.filterTime = time + 0.5;
 173 }
 174
 175 void XonoticScreenshotList_draw(entity me)
 176 {
 177         if (me.filterTime && time > me.filterTime)
 178         {
 179                 ScreenshotList_Filter_Change(me.filterBox, me);
 180                 me.filterTime = 0;
 181         }
 182         if (me.newScreenshotTime && time > me.newScreenshotTime)
 183         {
 184                 me.previewScreenshot(me);
 185                 me.newScreenshotTime = 0;
 186         }
 187         else if (me.newSlideShowScreenshotTime && time > me.newSlideShowScreenshotTime)
 188         {
 189                 if (me.selectedItem == me.nItems - 1) //last screenshot?
 190                 {
 191                         // restart from the first screenshot
 192                         me.setSelected(me, 0);
 193                         me.goScreenshot(me, +0);
 194                 }
 195                 else
 196                         me.goScreenshot(me, +1);
 197         }
 198         SUPER(XonoticScreenshotList).draw(me);
 199 }
 200
 201 void XonoticScreenshotList_startSlideShow(entity me)
 202 {
 203         me.newSlideShowScreenshotTime = time + 3;
 204 }
 205
 206 void XonoticScreenshotList_stopSlideShow(entity me)
 207 {
 208         me.newSlideShowScreenshotTime = 0;
 209 }
 210
 211 void XonoticScreenshotList_goScreenshot(entity me, float d)
 212 {
 213         if(!me.screenshotViewerDialog)
 214                 return;
 215         me.setSelected(me, me.selectedItem + d);
 216         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me,me.selectedItem))));
 217 }
 218
 219 void XonoticScreenshotList_startScreenshot(entity me)
 220 {
 221         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me,me.selectedItem))));
 222         // pop up screenshot
 223         DialogOpenButton_Click_withCoords(NULL, me.screenshotViewerDialog, me.origin + eX * (me.columnNameOrigin * me.size.x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size.y), eY * me.itemAbsSize.y + eX * (me.itemAbsSize.x * me.columnNameSize));
 224 }
 225
 226 void XonoticScreenshotList_previewScreenshot(entity me)
 227 {
 228         if(!me.screenshotBrowserDialog)
 229                 return;
 230         if (me.nItems <= 0)
 231                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, "");
 232         else
 233                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me,me.selectedItem))));
 234 }
 235
 236 void StartScreenshot_Click(entity btn, entity me)
 237 {
 238         me.startScreenshot(me);
 239 }
 240
 241 void XonoticScreenshotList_doubleClickListBoxItem(entity me, float i, vector where)
 242 {
 243         me.startScreenshot(me);
 244 }
 245
 246 float XonoticScreenshotList_keyDown(entity me, float scan, float ascii, float shift)
 247 {
 248         if(scan == K_ENTER || scan == K_KP_ENTER || scan == K_MOUSE2 || scan == K_SPACE) {
 249                 me.startScreenshot(me);
 250                 return 1;
 251         }
 252         return SUPER(XonoticScreenshotList).keyDown(me, scan, ascii, shift);
 253 }