qcsrc/menu/xonotic/serverlist.qc

   1 #include "serverlist.qh"
   2
   3 #include "checkbox.qh"
   4 #include "inputbox.qh"
   5 #include "mainwindow.qh"
   6 #include "dialog_multiplayer_join_serverinfo.qh"
   7 #include <common/mapinfo.qh>
   8
   9 void SL_ProcessCategoryOverrides(.string override_field_string, .float override_field)
  10 {
  11         for (int i = 0; i < category_ent_count; ++i)
  12         {
  13                 string s = categories[i].override_field_string;
  14                 if (s != "" && s != categories[i].cat_name)
  15                 {
  16                         int catnum = 0;
  17                         for (int x = 0; x < category_ent_count; ++x)
  18                         {
  19                                 if(categories[x].cat_name == s)
  20                                 {
  21                                         catnum = x + 1;
  22                                         break;
  23                                 }
  24                         }
  25                         if (catnum)
  26                         {
  27                                 strfree(categories[i].override_field_string);
  28                                 categories[i].override_field = catnum;
  29                                 continue;
  30                         }
  31                         LOG_INFOF("RegisterSLCategories(): Improper override '%s' for category '%s'!", s, categories[i].cat_name);
  32                 }
  33                 strfree(categories[i].override_field_string);
  34                 categories[i].override_field = 0;
  35         }
  36 }
  37
  38 void RegisterSLCategories()
  39 {
  40         entity cat;
  41         #define SLIST_CATEGORY(name,enoverride,dioverride,str) \
  42                 SET_FIELD_COUNT(name, CATEGORY_FIRST, category_ent_count) \
  43                 CHECK_MAX_COUNT(name, MAX_CATEGORIES, category_ent_count, "SLIST_CATEGORY") \
  44                 cat = categories[name - 1] = new(slist_category); \
  45                 cat.cat_name = #name; \
  46                 cat.cat_enoverride_string = strzone(SLIST_CATEGORY_AUTOCVAR(name)); \
  47                 cat.cat_dioverride_string = strzone(dioverride); \
  48                 cat.cat_string = strzone(str);
  49         SLIST_CATEGORIES
  50         #undef SLIST_CATEGORY
  51
  52         SL_ProcessCategoryOverrides(cat_enoverride_string, cat_enoverride);
  53         SL_ProcessCategoryOverrides(cat_dioverride_string, cat_dioverride);
  54 }
  55
  56 // Supporting Functions
  57 entity RetrieveCategoryEnt(int catnum)
  58 {
  59         if((catnum > 0) && (catnum <= category_ent_count))
  60         {
  61                 return categories[catnum - 1];
  62         }
  63         else
  64         {
  65                 error(sprintf("RetrieveCategoryEnt(%d): Improper category number!\n", catnum));
  66                 return NULL;
  67         }
  68 }
  69
  70 bool IsServerInList(string list, string srv)
  71 {
  72         if(srv == "")
  73                 return false;
  74         srv = netaddress_resolve(srv, 26000);
  75         if(srv == "")
  76                 return false;
  77         string p = crypto_getidfp(srv);
  78         int n = tokenize_console(list);
  79         for(int i = 0; i < n; ++i)
  80         {
  81                 if(substring(argv(i), 0, 1) != "[" && strlen(argv(i)) == 44 && strstrofs(argv(i), ".", 0) < 0)
  82                 {
  83                         if(p && argv(i) == p)
  84                                 return true;
  85                 }
  86                 else
  87                 {
  88                         if(srv == netaddress_resolve(argv(i), 26000))
  89                                 return true;
  90                 }
  91         }
  92         return false;
  93 }
  94
  95 int CategoryOverride(int cat)
  96 {
  97         entity catent = RetrieveCategoryEnt(cat);
  98         if(catent)
  99         {
 100                 int override = (autocvar_menu_slist_categories ? catent.cat_enoverride : catent.cat_dioverride);
 101                 if(override) { return override; }
 102                 else { return cat; }
 103         }
 104         else
 105         {
 106                 error(sprintf("CategoryOverride(%d): Improper category number!\n", cat));
 107                 return cat;
 108         }
 109 }
 110
 111 int CategoryForEntry(int entry)
 112 {
 113         string s, k, v, modtype = "";
 114         int j, m, impure = 0, freeslots = 0, sflags = 0;
 115         s = gethostcachestring(SLIST_FIELD_QCSTATUS, entry);
 116         m = tokenizebyseparator(s, ":");
 117
 118         for(j = 2; j < m; ++j)
 119         {
 120                 if(argv(j) == "") { break; }
 121                 k = substring(argv(j), 0, 1);
 122                 v = substring(argv(j), 1, -1);
 123                 switch(k)
 124                 {
 125                         case "P": { impure = stof(v); break; }
 126                         case "S": { freeslots = stof(v); break; }
 127                         case "F": { sflags = stof(v); break; }
 128                         case "M": { modtype = strtolower(v); break; }
 129                 }
 130         }
 131
 132         if(modtype != "xonotic") { impure += autocvar_menu_slist_modimpurity; }
 133
 134         // check if this server is favorited
 135         if(gethostcachenumber(SLIST_FIELD_ISFAVORITE, entry)) { return CAT_FAVORITED; }
 136
 137         // now check if it's recommended
 138         if(autocvar_menu_slist_recommendations)
 139         {
 140                 string cname = gethostcachestring(SLIST_FIELD_CNAME, entry);
 141
 142                 if(IsPromoted(cname)) { return CAT_RECOMMENDED; }
 143                 else
 144                 {
 145                         float recommended = 0;
 146                         if(autocvar_menu_slist_recommendations & 1)
 147                         {
 148                                 if(IsRecommended(cname)) { ++recommended; }
 149                                 else { --recommended; }
 150                         }
 151                         if(autocvar_menu_slist_recommendations & 2)
 152                         {
 153                                 if(
 154                                         ///// check for minimum free slots
 155                                         (freeslots >= autocvar_menu_slist_recommendations_minfreeslots)
 156
 157                                         && // check for purity requirement
 158                                         (
 159                                                 (autocvar_menu_slist_recommendations_purethreshold < 0)
 160                                                 ||
 161                                                 (impure <= autocvar_menu_slist_recommendations_purethreshold)
 162                                         )
 163
 164                                         && // check for minimum amount of humans
 165                                         (
 166                                                 gethostcachenumber(SLIST_FIELD_NUMHUMANS, entry)
 167                                                 >=
 168                                                 autocvar_menu_slist_recommendations_minhumans
 169                                         )
 170
 171                                         && // check for maximum latency
 172                                         (
 173                                                 gethostcachenumber(SLIST_FIELD_PING, entry)
 174                                                 <=
 175                                                 autocvar_menu_slist_recommendations_maxping
 176                                         )
 177                                 )
 178                                         { ++recommended; }
 179                                 else
 180                                         { --recommended; }
 181                         }
 182                         if(recommended > 0) { return CAT_RECOMMENDED; }
 183                 }
 184         }
 185
 186         // if not favorited or recommended, check modname
 187         if(modtype != "xonotic")
 188         {
 189                 switch(modtype)
 190                 {
 191                         // old servers which don't report their mod name are considered modified now
 192                         case "": { return CAT_MODIFIED; }
 193
 194                         case "xpm": { return CAT_XPM; }
 195                         case "minstagib":
 196                         case "instagib": { return CAT_INSTAGIB; }
 197                         case "overkill": { return CAT_OVERKILL; }
 198
 199                         // "cts" is allowed as compat, xdf is replacement
 200                         case "cts":
 201                         case "xdf": { return CAT_DEFRAG; }
 202
 203                         default: { LOG_TRACEF("Found strange mod type: %s", modtype); return CAT_MODIFIED; }
 204                 }
 205         }
 206
 207         // must be normal or impure server
 208         return ((impure > autocvar_menu_slist_purethreshold) ? CAT_MODIFIED : CAT_NORMAL);
 209 }
 210
 211 METHOD(XonoticServerList, toggleFavorite, void(XonoticServerList this, string srv))
 212 {
 213         bool adding = true;
 214         string srv_resolved = netaddress_resolve(srv, 26000);
 215         string p = crypto_getidfp(srv_resolved);
 216         string s = cvar_string("net_slist_favorites");
 217         string ret = s;
 218         for (int i = 0, n = tokenize_console(s); i < n; ++i)
 219         {
 220                 bool match;
 221                 if (substring(argv(i), 0, 1) != "[" && strlen(argv(i)) == 44 && strstrofs(argv(i), ".", 0) < 0)
 222                 {
 223                         // it's a pubkey hash
 224                         match = (p && p == argv(i));
 225                 }
 226                 else
 227                 {
 228                         // it's an ip
 229                         match = (srv_resolved == netaddress_resolve(argv(i), 26000));
 230                 }
 231                 if (!match) continue;
 232                 // on match: remove
 233                 adding = false;
 234                 string before = (i > 0) ? substring(s, 0, argv_end_index(i - 1)) : "";
 235                 string after = (i < n - 1) ? substring(s, argv_start_index(i + 1), -1) : "";
 236                 s = strcat(before, (before != "" && after != "" ? " " : ""), after);
 237                 ret = s;
 238                 // keep searching
 239                 // TODO: why not break here?
 240                 n = tokenize_console(s);
 241                 --i; // offset the increment that is about to happen
 242         }
 243         if (adding)
 244         {
 245                 ret = strcat(s, (s != "" ? " " : ""), p ? p : srv);
 246         }
 247         cvar_set("net_slist_favorites", ret);
 248         this.refreshServerList(this, REFRESHSERVERLIST_RESORT);
 249 }
 250
 251 void ServerList_Update_favoriteButton(entity btn, entity me)
 252 {
 253         entity e = me.favoriteButton;
 254         if(IsFavorite(me.ipAddressBox.text))
 255         {
 256                 e.setText(e, ZCTX(_("SERVER^Remove favorite")));
 257                 setZonedTooltip(e, _("Remove the currently highlighted server from bookmarks"), string_null);
 258         }
 259         else
 260         {
 261                 e.setText(e, ZCTX(_("SERVER^Favorite")));
 262                 setZonedTooltip(e, _("Bookmark the currently highlighted server so that it's faster to find in the future"), string_null);
 263         }
 264 }
 265
 266 entity makeXonoticServerList()
 267 {
 268         entity me;
 269         me = NEW(XonoticServerList);
 270         me.configureXonoticServerList(me);
 271         return me;
 272 }
 273 void XonoticServerList_configureXonoticServerList(entity me)
 274 {
 275         me.configureXonoticListBox(me);
 276
 277         // update field ID's
 278         #define SLIST_FIELD(suffix,name) SLIST_FIELD_##suffix = gethostcacheindexforkey(name);
 279         SLIST_FIELDS
 280         #undef SLIST_FIELD
 281
 282         // clear list
 283         me.nItems = 0;
 284 }
 285 void XonoticServerList_setSelected(entity me, int i)
 286 {
 287         me.lockedSelectedItem = false;
 288         //int save = me.selectedItem;
 289         SUPER(XonoticServerList).setSelected(me, i);
 290         /*
 291         if(me.selectedItem == save)
 292                 return;
 293         */
 294         if(me.nItems == 0)
 295                 return;
 296         if(gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT) != me.nItems)
 297                 return; // sorry, it would be wrong
 298
 299         strcpy(me.selectedServer, gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem));
 300
 301         me.ipAddressBox.setText(me.ipAddressBox, me.selectedServer);
 302         me.ipAddressBox.cursorPos = strlen(me.selectedServer);
 303         me.ipAddressBoxFocused = -1;
 304 }
 305 void XonoticServerList_refreshServerList(entity me, int mode)
 306 {
 307         //print("refresh of type ", ftos(mode), "\n");
 308
 309         if(mode >= REFRESHSERVERLIST_REFILTER)
 310         {
 311                 string s = me.filterString;
 312
 313                 string typestr;
 314                 int m = strstrofs(s, ":", 0);
 315                 if(m >= 0)
 316                 {
 317                         typestr = substring(s, 0, m);
 318                         s = substring(s, m + 1, strlen(s) - m - 1);
 319                         while(substring(s, 0, 1) == " ")
 320                                 s = substring(s, 1, strlen(s) - 1);
 321                 }
 322                 else
 323                         typestr = "";
 324
 325                 string modstr = cvar_string("menu_slist_modfilter");
 326
 327                 m = SLIST_MASK_AND - 1;
 328                 resethostcachemasks();
 329
 330                 // ping: reject negative ping (no idea why this happens in the first place, engine bug)
 331                 sethostcachemasknumber(++m, SLIST_FIELD_PING, 0, SLIST_TEST_GREATEREQUAL);
 332
 333                 // show full button
 334                 if(!me.filterShowFull)
 335                 {
 336                         sethostcachemasknumber(++m, SLIST_FIELD_FREESLOTS, 1, SLIST_TEST_GREATEREQUAL); // legacy
 337                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, ":S0:", SLIST_TEST_NOTCONTAIN); // g_maxplayers support
 338                 }
 339
 340                 // show empty button
 341                 if(!me.filterShowEmpty)
 342                         sethostcachemasknumber(++m, SLIST_FIELD_NUMHUMANS, 1, SLIST_TEST_GREATEREQUAL);
 343
 344                 // show laggy button
 345                 if(!me.filterShowLaggy && autocvar_menu_slist_maxping > 0)
 346                         sethostcachemasknumber(++m, SLIST_FIELD_PING, autocvar_menu_slist_maxping, SLIST_TEST_LESSEQUAL);
 347
 348                 // gametype filtering
 349                 if(typestr != "")
 350                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, strcat(typestr, ":"), SLIST_TEST_STARTSWITH);
 351
 352                 // mod filtering
 353                 if(modstr != "")
 354                 {
 355                         if(substring(modstr, 0, 1) == "!")
 356                                 sethostcachemaskstring(++m, SLIST_FIELD_MOD, resolvemod(substring(modstr, 1, strlen(modstr) - 1)), SLIST_TEST_NOTEQUAL);
 357                         else
 358                                 sethostcachemaskstring(++m, SLIST_FIELD_MOD, resolvemod(modstr), SLIST_TEST_EQUAL);
 359                 }
 360
 361                 // server banning
 362                 int n = tokenizebyseparator(_Nex_ExtResponseSystem_BannedServers, " ");
 363                 for(int i = 0; i < n; ++i)
 364                         if(argv(i) != "")
 365                                 sethostcachemaskstring(++m, SLIST_FIELD_CNAME, argv(i), SLIST_TEST_NOTSTARTSWITH);
 366
 367                 m = SLIST_MASK_OR - 1;
 368                 if(s != "")
 369                 {
 370                         sethostcachemaskstring(++m, SLIST_FIELD_NAME, s, SLIST_TEST_CONTAINS);
 371                         sethostcachemaskstring(++m, SLIST_FIELD_MAP, s, SLIST_TEST_CONTAINS);
 372                         sethostcachemaskstring(++m, SLIST_FIELD_PLAYERS, s, SLIST_TEST_CONTAINS);
 373                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, strcat(s, ":"), SLIST_TEST_STARTSWITH);
 374                 }
 375
 376                 int sorting_flags = 0;
 377                 //sorting_flags |= SLSF_FAVORITES;
 378                 sorting_flags |= SLSF_CATEGORIES;
 379                 if(me.currentSortOrder < 0) { sorting_flags |= SLSF_DESCENDING; }
 380                 sethostcachesort(me.currentSortField, sorting_flags);
 381         }
 382
 383         resorthostcache();
 384         if(mode >= REFRESHSERVERLIST_ASK)
 385                 refreshhostcache(mode >= REFRESHSERVERLIST_RESET);
 386 }
 387 void XonoticServerList_focusEnter(entity me)
 388 {
 389         SUPER(XonoticServerList).focusEnter(me);
 390         if(time < me.nextRefreshTime)
 391         {
 392                 //print("sorry, no refresh yet\n");
 393                 return;
 394         }
 395         me.nextRefreshTime = time + 10;
 396         me.refreshServerList(me, REFRESHSERVERLIST_ASK);
 397 }
 398
 399 void XonoticServerList_draw(entity me)
 400 {
 401         if(_Nex_ExtResponseSystem_BannedServersNeedsRefresh)
 402         {
 403                 if(!me.needsRefresh)
 404                         me.needsRefresh = 2;
 405                 _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 0;
 406         }
 407
 408         if(_Nex_ExtResponseSystem_PromotedServersNeedsRefresh)
 409         {
 410                 if(!me.needsRefresh)
 411                         me.needsRefresh = 3;
 412                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 0;
 413         }
 414
 415         if(_Nex_ExtResponseSystem_RecommendedServersNeedsRefresh)
 416         {
 417                 if(!me.needsRefresh)
 418                         me.needsRefresh = 3;
 419                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 0;
 420         }
 421
 422         if(me.currentSortField == -1)
 423         {
 424                 me.setSortOrder(me, SLIST_FIELD_PING, +1);
 425                 me.refreshServerList(me, REFRESHSERVERLIST_RESET);
 426         }
 427         else if(me.needsRefresh == 1)
 428         {
 429                 me.needsRefresh = 2; // delay by one frame to make sure "slist" has been executed
 430         }
 431         else if(me.needsRefresh == 2)
 432         {
 433                 me.needsRefresh = 0;
 434                 me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 435         }
 436         else if(me.needsRefresh == 3)
 437         {
 438                 me.needsRefresh = 0;
 439                 me.refreshServerList(me, REFRESHSERVERLIST_RESORT);
 440         }
 441
 442         bool owned = ((me.selectedServer == me.ipAddressBox.text) && (me.ipAddressBox.text != ""));
 443
 444         for(int i = 0; i < category_draw_count; ++i) { category_name[i] = -1; category_item[i] = -1; }
 445         category_draw_count = 0;
 446
 447         if(autocvar_menu_slist_categories >= 0) // if less than 0, don't even draw a category heading for favorites
 448         {
 449                 float itemcount = gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT);
 450                 me.nItems = itemcount;
 451
 452                 //float visible = floor(me.scrollPos / me.itemHeight);
 453                 // ^ unfortunately no such optimization can be made-- we must process through the
 454                 // entire list, otherwise there is no way to know which item is first in its category.
 455
 456                 // binary search method suggested by div
 457                 float begin = 0;
 458                 for(int j = 1; j <= category_ent_count; ++j) {
 459                         float first = begin;
 460                         float last = (itemcount - 1);
 461                         if (first > last) {
 462                                 // List is empty.
 463                                 break;
 464                         }
 465                         float catf = gethostcachenumber(SLIST_FIELD_CATEGORY, first);
 466                         float catl = gethostcachenumber(SLIST_FIELD_CATEGORY, last);
 467                         if (catf > j) {
 468                                 // The first one is already > j.
 469                                 // Therefore, category j does not exist.
 470                                 // Higher numbered categories do exist though.
 471                         } else if (catl < j) {
 472                                 // The last one is < j.
 473                                 // Thus this category - and any following -
 474                                 // don't exist.
 475                                 break;
 476                         } else if (catf == j) {
 477                                 // Starts at first. This breaks the loop
 478                                 // invariant in the binary search and thus has
 479                                 // to be handled separately.
 480                                 if(gethostcachenumber(SLIST_FIELD_CATEGORY, first) != j)
 481                                         error("Category mismatch I");
 482                                 if(first > 0)
 483                                         if(gethostcachenumber(SLIST_FIELD_CATEGORY, first - 1) == j)
 484                                                 error("Category mismatch II");
 485                                 category_name[category_draw_count] = j;
 486                                 category_item[category_draw_count] = first;
 487                                 ++category_draw_count;
 488                                 begin = first + 1;
 489                         } else {
 490                                 // At this point, catf <= j < catl, thus
 491                                 // catf < catl, thus first < last.
 492                                 // INVARIANTS:
 493                                 // last - first >= 1
 494                                 // catf == gethostcachenumber(SLIST_FIELD_CATEGORY(first)
 495                                 // catl == gethostcachenumber(SLIST_FIELD_CATEGORY(last)
 496                                 // catf < j
 497                                 // catl >= j
 498                                 while (last - first > 1) {
 499                                         float middle = floor((first + last) / 2);
 500                                         // By loop condition, middle != first && middle != last.
 501                                         float cat = gethostcachenumber(SLIST_FIELD_CATEGORY, middle);
 502                                         if (cat >= j) {
 503                                                 last = middle;
 504                                                 catl = cat;
 505                                         } else {
 506                                                 first = middle;
 507                                                 catf = cat;
 508                                         }
 509                                 }
 510                                 if (catl == j) {
 511                                         if(gethostcachenumber(SLIST_FIELD_CATEGORY, last) != j)
 512                                                 error("Category mismatch III");
 513                                         if(last > 0)
 514                                                 if(gethostcachenumber(SLIST_FIELD_CATEGORY, last - 1) == j)
 515                                                         error("Category mismatch IV");
 516                                         category_name[category_draw_count] = j;
 517                                         category_item[category_draw_count] = last;
 518                                         ++category_draw_count;
 519                                         begin = last + 1; // already scanned through these, skip 'em
 520                                 }
 521                                 else
 522                                         begin = last; // already scanned through these, skip 'em
 523                         }
 524                 }
 525                 if(autocvar_menu_slist_categories_onlyifmultiple && (category_draw_count == 1))
 526                 {
 527                         category_name[0] = -1;
 528                         category_item[0] = -1;
 529                         category_draw_count = 0;
 530                         me.nItems = itemcount;
 531                 }
 532         }
 533         else { me.nItems = gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT); }
 534
 535         me.connectButton.disabled = (me.ipAddressBox.text == "");
 536         me.infoButton.disabled = !owned;
 537         me.favoriteButton.disabled = (me.ipAddressBox.text == "");
 538
 539         bool found = false;
 540         if(me.lockedSelectedItem)
 541         {
 542                 if(me.nItems > 0)
 543                 {
 544                         if(gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem) != me.selectedServer)
 545                         {
 546                                 strcpy(me.selectedServer, gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem));
 547                         }
 548                         found = true;
 549                 }
 550         }
 551         else if(me.selectedServer)
 552         {
 553                 for(int i = 0; i < me.nItems; ++i)
 554                 {
 555                         if(gethostcachestring(SLIST_FIELD_CNAME, i) == me.selectedServer)
 556                         {
 557                                 // don't follow the selected item with SUPER(XonoticServerList).setSelected(me, i);
 558                                 me.selectedItem = i;
 559                                 found = true;
 560                                 break;
 561                         }
 562                 }
 563         }
 564         if(!found)
 565         {
 566                 if(me.nItems > 0)
 567                 {
 568                         // selected server disappeared, select the last server (scrolling to it)
 569                         if(me.selectedItem >= me.nItems)
 570                                 SUPER(XonoticServerList).setSelected(me, me.nItems - 1);
 571                         strcpy(me.selectedServer, gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem));
 572                 }
 573         }
 574
 575         if(owned)
 576         {
 577                 if(me.selectedServer != me.ipAddressBox.text)
 578                 {
 579                         me.ipAddressBox.setText(me.ipAddressBox, me.selectedServer);
 580                         me.ipAddressBox.cursorPos = strlen(me.selectedServer);
 581                         me.ipAddressBoxFocused = -1;
 582                 }
 583         }
 584
 585         if(me.ipAddressBoxFocused != me.ipAddressBox.focused)
 586         {
 587                 if(me.ipAddressBox.focused || me.ipAddressBoxFocused < 0)
 588                         ServerList_Update_favoriteButton(NULL, me);
 589                 me.ipAddressBoxFocused = me.ipAddressBox.focused;
 590         }
 591
 592         SUPER(XonoticServerList).draw(me);
 593 }
 594 void ServerList_PingSort_Click(entity btn, entity me)
 595 {
 596         me.setSortOrder(me, SLIST_FIELD_PING, +1);
 597 }
 598 void ServerList_NameSort_Click(entity btn, entity me)
 599 {
 600         me.setSortOrder(me, SLIST_FIELD_NAME, -1); // why?
 601 }
 602 void ServerList_MapSort_Click(entity btn, entity me)
 603 {
 604         me.setSortOrder(me, SLIST_FIELD_MAP, -1); // why?
 605 }
 606 void ServerList_PlayerSort_Click(entity btn, entity me)
 607 {
 608         me.setSortOrder(me, SLIST_FIELD_NUMHUMANS, -1);
 609 }
 610 void ServerList_TypeSort_Click(entity btn, entity me)
 611 {
 612         string s = me.filterString;
 613         int m = strstrofs(s, ":", 0);
 614         if(m >= 0)
 615         {
 616                 s = substring(s, 0, m);
 617                 while(substring(s, m+1, 1) == " ") // skip spaces
 618                         ++m;
 619         }
 620         else
 621                 s = "";
 622
 623         Gametype first = NULL; FOREACH(Gametypes, !first, first = it; break);
 624         bool flag = false;
 625         FOREACH(Gametypes, s == MapInfo_Type_ToString(it), {
 626                 // the type was found
 627                 // choose the next one
 628                 flag = true;
 629                 s = MapInfo_Type_ToString(REGISTRY_GET(Gametypes, it.m_id + 1));
 630                 if (s == "") s = MapInfo_Type_ToString(first);
 631                 break;
 632         });
 633         if (!flag) {
 634                 // no type was found
 635                 // choose the first one
 636                 s = MapInfo_Type_ToString(first);
 637         }
 638
 639         if(s != "") s = strcat(s, ":");
 640         s = strcat(s, substring(me.filterString, m+1, strlen(me.filterString) - m - 1));
 641
 642         me.controlledTextbox.setText(me.controlledTextbox, s);
 643         me.controlledTextbox.keyDown(me.controlledTextbox, K_END, 0, 0);
 644         me.controlledTextbox.keyUp(me.controlledTextbox, K_END, 0, 0);
 645         //ServerList_Filter_Change(me.controlledTextbox, me);
 646 }
 647 void ServerList_Filter_Change(entity box, entity me)
 648 {
 649         strfree(me.filterString);
 650         if(box.text != "")
 651                 me.filterString = strzone(box.text);
 652         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 653
 654         me.ipAddressBox.setText(me.ipAddressBox, "");
 655         me.ipAddressBox.cursorPos = 0;
 656         me.ipAddressBoxFocused = -1;
 657 }
 658 void ServerList_Categories_Click(entity box, entity me)
 659 {
 660         box.setChecked(box, autocvar_menu_slist_categories = !autocvar_menu_slist_categories);
 661         me.refreshServerList(me, REFRESHSERVERLIST_RESORT);
 662
 663         me.ipAddressBox.setText(me.ipAddressBox, "");
 664         me.ipAddressBox.cursorPos = 0;
 665         me.ipAddressBoxFocused = -1;
 666 }
 667 void ServerList_ShowEmpty_Click(entity box, entity me)
 668 {
 669         box.setChecked(box, me.filterShowEmpty = !me.filterShowEmpty);
 670         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 671
 672         me.ipAddressBox.setText(me.ipAddressBox, "");
 673         me.ipAddressBox.cursorPos = 0;
 674         me.ipAddressBoxFocused = -1;
 675 }
 676 void ServerList_ShowFull_Click(entity box, entity me)
 677 {
 678         box.setChecked(box, me.filterShowFull = !me.filterShowFull);
 679         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 680
 681         me.ipAddressBox.setText(me.ipAddressBox, "");
 682         me.ipAddressBox.cursorPos = 0;
 683         me.ipAddressBoxFocused = -1;
 684 }
 685 void ServerList_ShowLaggy_Click(entity box, entity me)
 686 {
 687         box.setChecked(box, me.filterShowLaggy = !me.filterShowLaggy);
 688         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 689
 690         me.ipAddressBox.setText(me.ipAddressBox, "");
 691         me.ipAddressBox.cursorPos = 0;
 692         me.ipAddressBoxFocused = -1;
 693 }
 694 void XonoticServerList_setSortOrder(entity me, int fld, int direction)
 695 {
 696         if(me.currentSortField == fld)
 697                 direction = -me.currentSortOrder;
 698         me.currentSortOrder = direction;
 699         me.currentSortField = fld;
 700         me.sortButton1.forcePressed = (fld == SLIST_FIELD_PING);
 701         me.sortButton2.forcePressed = (fld == SLIST_FIELD_NAME);
 702         me.sortButton3.forcePressed = (fld == SLIST_FIELD_MAP);
 703         me.sortButton4.forcePressed = 0;
 704         me.sortButton5.forcePressed = (fld == SLIST_FIELD_NUMHUMANS);
 705         me.selectedItem = 0;
 706         strfree(me.selectedServer);
 707         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 708 }
 709 void XonoticServerList_positionSortButton(entity me, entity btn, float theOrigin, float theSize, string theTitle, void(entity, entity) theFunc)
 710 {
 711         vector originInLBSpace = eY * (-me.itemHeight);
 712         vector sizeInLBSpace = eY * me.itemHeight + eX * (1 - me.controlWidth);
 713
 714         vector originInDialogSpace = boxToGlobal(originInLBSpace, me.Container_origin, me.Container_size);
 715         vector sizeInDialogSpace = boxToGlobalSize(sizeInLBSpace, me.Container_size);
 716
 717         btn.Container_origin_x = originInDialogSpace.x + sizeInDialogSpace.x * theOrigin;
 718         btn.Container_size_x   =                         sizeInDialogSpace.x * theSize;
 719         btn.setText(btn, theTitle);
 720         btn.onClick = theFunc;
 721         btn.onClickEntity = me;
 722         btn.resized = 1;
 723 }
 724 void XonoticServerList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 725 {
 726         SUPER(XonoticServerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 727
 728         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
 729         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
 730         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 731
 732         me.columnIconsOrigin = 0;
 733         me.columnIconsSize = me.realFontSize.x * 4 * me.iconsSizeFactor;
 734         me.columnPingSize = me.realFontSize.x * 3;
 735         me.columnMapSize = me.realFontSize.x * 10;
 736         me.columnTypeSize = me.realFontSize.x * 4;
 737         me.columnPlayersSize = me.realFontSize.x * 5;
 738         me.columnNameSize = 1 - me.columnPlayersSize - me.columnMapSize - me.columnPingSize - me.columnIconsSize - me.columnTypeSize - 5 * me.realFontSize.x;
 739         me.columnPingOrigin = me.columnIconsOrigin + me.columnIconsSize + me.realFontSize.x;
 740         me.columnNameOrigin = me.columnPingOrigin + me.columnPingSize + me.realFontSize.x;
 741         me.columnMapOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x;
 742         me.columnTypeOrigin = me.columnMapOrigin + me.columnMapSize + me.realFontSize.x;
 743         me.columnPlayersOrigin = me.columnTypeOrigin + me.columnTypeSize + me.realFontSize.x;
 744
 745         me.positionSortButton(me, me.sortButton1, me.columnPingOrigin, me.columnPingSize, _("Ping"), ServerList_PingSort_Click);
 746         me.positionSortButton(me, me.sortButton2, me.columnNameOrigin, me.columnNameSize, _("Hostname"), ServerList_NameSort_Click);
 747         me.positionSortButton(me, me.sortButton3, me.columnMapOrigin, me.columnMapSize, _("Map"), ServerList_MapSort_Click);
 748         me.positionSortButton(me, me.sortButton4, me.columnTypeOrigin, me.columnTypeSize, _("Type"), ServerList_TypeSort_Click);
 749         me.positionSortButton(me, me.sortButton5, me.columnPlayersOrigin, me.columnPlayersSize, _("Players"), ServerList_PlayerSort_Click);
 750
 751         int f = me.currentSortField;
 752         if(f >= 0)
 753         {
 754                 me.currentSortField = -1;
 755                 me.setSortOrder(me, f, me.currentSortOrder); // force resetting the sort order
 756         }
 757 }
 758 void ServerList_Connect_Click(entity btn, entity me)
 759 {
 760         if (me.ipAddressBox.text != "")
 761                 localcmd(sprintf("connect %s\n", me.ipAddressBox.text));
 762 }
 763 void ServerList_Favorite_Click(entity btn, entity this)
 764 {
 765         string addr = this.ipAddressBox.text;
 766         string ipstr = netaddress_resolve(addr, 26000);
 767         if (ipstr == "") return;
 768         m_play_click_sound(MENU_SOUND_SELECT);
 769         this.toggleFavorite(this, addr);
 770         this.ipAddressBoxFocused = -1;
 771 }
 772 void ServerList_Info_Click(entity btn, entity me)
 773 {
 774         if (me.nItems != 0)
 775                 main.serverInfoDialog.loadServerInfo(main.serverInfoDialog, me.selectedItem);
 776
 777         vector org = boxToGlobal(eY * (me.selectedItem * me.itemHeight - me.scrollPos), me.origin, me.size);
 778         vector sz = boxToGlobalSize(eY * me.itemHeight + eX * (1 - me.controlWidth), me.size);
 779         DialogOpenButton_Click_withCoords(me, main.serverInfoDialog, org, sz);
 780 }
 781 void XonoticServerList_doubleClickListBoxItem(entity me, int i, vector where)
 782 {
 783         ServerList_Connect_Click(NULL, me);
 784 }
 785 void XonoticServerList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 786 {
 787         vector oldscale = draw_scale;
 788         vector oldshift = draw_shift;
 789 #define SET_YRANGE(start,end) \
 790         draw_scale = boxToGlobalSize(eX + eY * (end - start), oldscale); \
 791         draw_shift = boxToGlobal(eY * start, oldshift, oldscale);
 792
 793         int c;
 794         for (c = 0; c < category_draw_count; ++c) {
 795                 // Matches exactly the headings with increased height.
 796                 if (i == category_item[c])
 797                         break;
 798         }
 799
 800         if (c < category_draw_count)
 801         {
 802                 entity catent = RetrieveCategoryEnt(category_name[c]);
 803                 if(catent)
 804                 {
 805                         SET_YRANGE(
 806                                 (me.categoriesHeight - 1) / (me.categoriesHeight + 1),
 807                                 me.categoriesHeight / (me.categoriesHeight + 1)
 808                         );
 809                         draw_Text(
 810                                 eY * me.realUpperMargin
 811                                 +
 812 #if 0
 813                                 eX * (me.columnNameOrigin + (me.columnNameSize - draw_TextWidth(catent.cat_string, 0, me.realFontSize)) * 0.5),
 814                                 catent.cat_string,
 815 #else
 816                                 eX * (me.columnNameOrigin),
 817                                 strcat(catent.cat_string, ":"),
 818 #endif
 819                                 me.realFontSize,
 820                                 SKINCOLOR_SERVERLIST_CATEGORY,
 821                                 SKINALPHA_SERVERLIST_CATEGORY,
 822                                 0
 823                         );
 824                         SET_YRANGE(me.categoriesHeight / (me.categoriesHeight + 1), 1);
 825                 }
 826         }
 827
 828         if(isSelected && !me.lockedSelectedItem)
 829                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 830         else if(isFocused)
 831         {
 832                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 833                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 834         }
 835
 836         string s = gethostcachestring(SLIST_FIELD_QCSTATUS, i);
 837         int m = tokenizebyseparator(s, ":");
 838         string typestr = "", versionstr = "";
 839         if(m >= 2)
 840         {
 841                 typestr = argv(0);
 842                 versionstr = argv(1);
 843         }
 844         bool pure = false, pure_available = false;
 845         int freeslots = -1, sflags = -1;
 846         string modname = "";
 847         for(int j = 2; j < m; ++j)
 848         {
 849                 if(argv(j) == "")
 850                         break;
 851                 string key = substring(argv(j), 0, 1);
 852                 string value = substring(argv(j), 1, -1);
 853                 if(key == "P")
 854                 {
 855                         pure = (stof(value) == 0);
 856                         pure_available = true;
 857                 }
 858                 else if(key == "S")
 859                         freeslots = stof(value);
 860                 else if(key == "F")
 861                         sflags = stoi(value);
 862                 else if(key == "M")
 863                         modname = value;
 864         }
 865
 866 #ifdef COMPAT_NO_MOD_IS_XONOTIC
 867         if(modname == "")
 868                 modname = "Xonotic";
 869 #endif
 870
 871         string original_modname = modname;
 872         modname = strtolower(modname);
 873
 874         /*
 875         SLIST_FIELD_MOD = gethostcacheindexforkey("mod");
 876         s = gethostcachestring(SLIST_FIELD_MOD, i);
 877         if(s != "data")
 878                 if(modname == "xonotic")
 879                         modname = s;
 880         */
 881
 882         // list the mods here on which the pure server check actually works
 883         if(modname != "xonotic")
 884         if(modname != "instagib" || modname != "minstagib")
 885         if(modname != "cts")
 886         if(modname != "nix")
 887         if(modname != "newtoys")
 888                 pure_available = false;
 889
 890         float theAlpha;
 891         if(gethostcachenumber(SLIST_FIELD_FREESLOTS, i) <= 0)
 892                 theAlpha = SKINALPHA_SERVERLIST_FULL;
 893         else if(freeslots == 0)
 894                 theAlpha = SKINALPHA_SERVERLIST_FULL; // g_maxplayers support
 895         else if (!gethostcachenumber(SLIST_FIELD_NUMHUMANS, i))
 896                 theAlpha = SKINALPHA_SERVERLIST_EMPTY;
 897         else
 898                 theAlpha = 1;
 899
 900         float ping = gethostcachenumber(SLIST_FIELD_PING, i);
 901         const int PING_LOW = 75;
 902         const int PING_MED = 200;
 903         const int PING_HIGH = 500;
 904         vector theColor;
 905         if(ping < PING_LOW)
 906                 theColor = SKINCOLOR_SERVERLIST_LOWPING + (SKINCOLOR_SERVERLIST_MEDPING - SKINCOLOR_SERVERLIST_LOWPING) * (ping / PING_LOW);
 907         else if(ping < PING_MED)
 908                 theColor = SKINCOLOR_SERVERLIST_MEDPING + (SKINCOLOR_SERVERLIST_HIGHPING - SKINCOLOR_SERVERLIST_MEDPING) * ((ping - PING_LOW) / (PING_MED - PING_LOW));
 909         else if(ping < PING_HIGH)
 910         {
 911                 theColor = SKINCOLOR_SERVERLIST_HIGHPING;
 912                 theAlpha *= 1 + (SKINALPHA_SERVERLIST_HIGHPING - 1) * ((ping - PING_MED) / (PING_HIGH - PING_MED));
 913         }
 914         else
 915         {
 916                 theColor = eX;
 917                 theAlpha *= SKINALPHA_SERVERLIST_HIGHPING;
 918         }
 919
 920         if(gethostcachenumber(SLIST_FIELD_ISFAVORITE, i))
 921         {
 922                 theColor = theColor * (1 - SKINALPHA_SERVERLIST_FAVORITE) + SKINCOLOR_SERVERLIST_FAVORITE * SKINALPHA_SERVERLIST_FAVORITE;
 923                 theAlpha = theAlpha * (1 - SKINALPHA_SERVERLIST_FAVORITE) + SKINALPHA_SERVERLIST_FAVORITE;
 924         }
 925
 926         s = gethostcachestring(SLIST_FIELD_CNAME, i);
 927
 928         bool isv4 = false, isv6 = false;
 929         if(substring(s, 0, 1) == "[")
 930         {
 931                 isv6 = true;
 932                 me.seenIPv6 += 1;
 933         }
 934         else if(IS_DIGIT(substring(s, 0, 1)))
 935         {
 936                 isv4 = true;
 937                 me.seenIPv4 += 1;
 938         }
 939
 940         int crypto = stof(substring(crypto_getencryptlevel(s), 0, 1));
 941         if((crypto <= 0 && cvar("crypto_aeslevel") >= 3) || (crypto >= 3 && cvar("crypto_aeslevel") <= 0))
 942         {
 943                 theColor = SKINCOLOR_SERVERLIST_IMPOSSIBLE;
 944                 theAlpha = SKINALPHA_SERVERLIST_IMPOSSIBLE;
 945         }
 946
 947         if(crypto == 1)
 948         {
 949                 if(cvar("crypto_aeslevel") >= 2)
 950                         crypto |= 4;
 951         }
 952         if(crypto == 2)
 953         {
 954                 if(cvar("crypto_aeslevel") >= 1)
 955                         crypto |= 4;
 956         }
 957         if(crypto == 3)
 958                 crypto = 5;
 959         else if(crypto >= 3)
 960                 crypto -= 2;
 961         // possible status:
 962         // 0: crypto off
 963         // 1: AES possible
 964         // 2: AES recommended but not available
 965         // 3: AES possible and will be used
 966         // 4: AES recommended and will be used
 967         // 5: AES required
 968
 969         // --------------
 970         //  RENDER ICONS
 971         // --------------
 972         vector iconSize = '0 0 0';
 973         iconSize_y = me.realFontSize.y * me.iconsSizeFactor;
 974         iconSize_x = me.realFontSize.x * me.iconsSizeFactor;
 975
 976         vector iconPos = '0 0 0';
 977         iconPos_x = (me.columnIconsSize - 3 * iconSize.x) * 0.5;
 978         iconPos_y = (1 - iconSize.y) * 0.5;
 979
 980         // IP
 981         if(me.seenIPv4 && me.seenIPv6)
 982         {
 983                 if(isv6)
 984                         draw_Picture(iconPos, "icon_ipv6", iconSize, '1 1 1', 1);
 985                 else if(isv4)
 986                         draw_Picture(iconPos, "icon_ipv4", iconSize, '1 1 1', 1);
 987         }
 988
 989         iconPos.x += iconSize.x;
 990
 991         // AES
 992         if(crypto > 0)
 993                 draw_Picture(iconPos, strcat("icon_aeslevel", ftos(crypto)), iconSize, '1 1 1', 1);
 994
 995         iconPos.x += iconSize.x;
 996
 997         // Mod
 998         if(modname == "xonotic")
 999         {
1000                 // Here, pure_available should always be set. If not, consider
1001                 // it an impurity.
1002                 if(pure_available && pure)
1003                         draw_Picture(iconPos, "icon_pure1", iconSize, '1 1 1', 1);
1004         }
1005         else
1006         {
1007                 string icon = strcat("icon_mod_", modname);
1008                 if(draw_PictureSize(icon) == '0 0 0')
1009                         icon = "icon_mod_";
1010
1011                 // In mods, pure_available not being present indicates
1012                 // non-support of the feature. Just show the mod icon as is
1013                 // then.
1014                 if(pure_available && !pure)
1015                         draw_Picture(iconPos, icon, iconSize, '1 1 1', SKINALPHA_SERVERLIST_ICON_NONPURE);
1016                 else
1017                         draw_Picture(iconPos, icon, iconSize, '1 1 1', 1);
1018         }
1019
1020         iconPos.x += iconSize.x;
1021
1022         // Stats
1023         if(sflags >= 0 && (sflags & SERVERFLAG_PLAYERSTATS))
1024                 draw_Picture(iconPos, "icon_stats1", iconSize, '1 1 1', 1);
1025
1026         if(isFocused && me.mouseOverIcons && !me.tooltip)
1027         {
1028                 string t = "";
1029                 if(me.seenIPv4 && me.seenIPv6)
1030                         t = strcat(t, (isv6) ? "IPv6, " : "IPv4, ");
1031                 t = strcat(t, _("encryption:"), " ", (crypto ? sprintf(_("AES level %d"), crypto) : ZCTX(_("ENC^none"))), ", ");
1032                 t = strcat(t, sprintf(_("mod: %s"), ((modname == "xonotic") ? ZCTX(_("MOD^Default")) : original_modname)));
1033                 if(pure_available)
1034                         t = strcat(t, sprintf(" (%s)", (pure) ? _("official settings") : _("modified settings")));
1035                 t = strcat(t, ", ");
1036                 t = strcat(t, ((sflags >= 0 && (sflags & SERVERFLAG_PLAYERSTATS)) ? _("stats enabled") : _("stats disabled")));
1037                 setZonedTooltip(me, t, string_null);
1038         }
1039         // --------------
1040         //  RENDER TEXT
1041         // --------------
1042
1043         // ping
1044         s = ftos(ping);
1045         draw_Text(me.realUpperMargin * eY + (me.columnPingOrigin + me.columnPingSize - draw_TextWidth(s, 0, me.realFontSize)) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1046
1047         // server name
1048         s = draw_TextShortenToWidth(gethostcachestring(SLIST_FIELD_NAME, i), me.columnNameSize, 0, me.realFontSize);
1049         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
1050
1051         // server map
1052         s = draw_TextShortenToWidth(gethostcachestring(SLIST_FIELD_MAP, i), me.columnMapSize, 0, me.realFontSize);
1053         draw_Text(me.realUpperMargin * eY + (me.columnMapOrigin + (me.columnMapSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1054
1055         // server gametype
1056         s = draw_TextShortenToWidth(typestr, me.columnTypeSize, 0, me.realFontSize);
1057         draw_Text(me.realUpperMargin * eY + (me.columnTypeOrigin + (me.columnTypeSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1058
1059         // server playercount
1060         s = strcat(ftos(gethostcachenumber(SLIST_FIELD_NUMHUMANS, i)), "/", ftos(gethostcachenumber(SLIST_FIELD_MAXPLAYERS, i)));
1061         draw_Text(me.realUpperMargin * eY + (me.columnPlayersOrigin + (me.columnPlayersSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1062 }
1063
1064 void XonoticServerList_focusedItemChangeNotify(entity me)
1065 {
1066         clearTooltip(me);
1067 }
1068
1069 float XonoticServerList_mouseMove(entity me, vector pos)
1070 {
1071         if(!SUPER(XonoticServerList).mouseMove(me, pos))
1072         {
1073                 me.mouseOverIcons = false;
1074                 clearTooltip(me);
1075                 return 1;
1076         }
1077
1078         me.mouseOverIcons = (pos_x <= me.columnIconsSize);
1079         if(!me.mouseOverIcons)
1080                 clearTooltip(me);
1081         return 1;
1082 }
1083
1084 bool XonoticServerList_keyDown(entity me, int scan, bool ascii, bool shift)
1085 {
1086         if(scan == K_ENTER || scan == K_KP_ENTER)
1087         {
1088                 ServerList_Connect_Click(NULL, me);
1089                 return true;
1090         }
1091         else if(scan == K_MOUSE2 || scan == K_SPACE)
1092         {
1093                 if(me.nItems != 0)
1094                 {
1095                         vector org = boxToGlobal(eY * (me.selectedItem * me.itemHeight - me.scrollPos), me.origin, me.size);
1096                         vector sz = boxToGlobalSize(eY * me.itemHeight + eX * (1 - me.controlWidth), me.size);
1097                         m_play_click_sound(MENU_SOUND_OPEN);
1098                         main.serverInfoDialog.loadServerInfo(main.serverInfoDialog, me.selectedItem);
1099                         DialogOpenButton_Click_withCoords(me, main.serverInfoDialog, org, sz);
1100                         return true;
1101                 }
1102                 return false;
1103         }
1104         else if(scan == K_INS || scan == K_MOUSE3 || scan == K_KP_INS)
1105         {
1106                 if(me.nItems != 0)
1107                 {
1108                         me.toggleFavorite(me, me.selectedServer);
1109                         me.ipAddressBoxFocused = -1;
1110                         return true;
1111                 }
1112                 return false;
1113         }
1114         else if(SUPER(XonoticServerList).keyDown(me, scan, ascii, shift))
1115                 return true;
1116         else if(!me.controlledTextbox)
1117                 return false;
1118         else
1119                 return me.controlledTextbox.keyDown(me.controlledTextbox, scan, ascii, shift);
1120 }
1121
1122 float XonoticServerList_getTotalHeight(entity me)
1123 {
1124         float num_normal_rows = me.nItems;
1125         int num_headers = category_draw_count;
1126         return me.itemHeight * (num_normal_rows + me.categoriesHeight * num_headers);
1127 }
1128 int XonoticServerList_getItemAtPos(entity me, float pos)
1129 {
1130         pos = pos / me.itemHeight;
1131         for (int i = category_draw_count - 1; i >= 0; --i) {
1132                 int itemidx = category_item[i];
1133                 float itempos = i * me.categoriesHeight + category_item[i];
1134                 if (pos >= itempos + me.categoriesHeight + 1)
1135                         return itemidx + 1 + floor(pos - (itempos + me.categoriesHeight + 1));
1136                 if (pos >= itempos)
1137                         return itemidx;
1138         }
1139         // No category matches? Note that category 0 is... 0. Therefore no headings exist at all.
1140         return floor(pos);
1141 }
1142 float XonoticServerList_getItemStart(entity me, int item)
1143 {
1144         for (int i = category_draw_count - 1; i >= 0; --i) {
1145                 int itemidx = category_item[i];
1146                 float itempos = i * me.categoriesHeight + category_item[i];
1147                 if (item >= itemidx + 1)
1148                         return (itempos + me.categoriesHeight + 1 + item - (itemidx + 1)) * me.itemHeight;
1149                 if (item >= itemidx)
1150                         return itempos * me.itemHeight;
1151         }
1152         // No category matches? Note that category 0 is... 0. Therefore no headings exist at all.
1153         return item * me.itemHeight;
1154 }
1155 float XonoticServerList_getItemHeight(entity me, int item)
1156 {
1157         for (int i = 0; i < category_draw_count; ++i) {
1158                 // Matches exactly the headings with increased height.
1159                 if (item == category_item[i])
1160                         return me.itemHeight * (me.categoriesHeight + 1);
1161         }
1162         return me.itemHeight;
1163 }