qcsrc/menu/xonotic/skinlist.qc

   1 #include "skinlist.qh"
   2
   3 const float SKINPARM_NAME = 0;
   4 const float SKINPARM_TITLE = 1;
   5 const float SKINPARM_AUTHOR = 2;
   6 const float SKINPARM_PREVIEW = 3;
   7 const float SKINPARM_COUNT = 4;
   8
   9 entity makeXonoticSkinList()
  10 {
  11         entity me;
  12         me = NEW(XonoticSkinList);
  13         me.configureXonoticSkinList(me);
  14         return me;
  15 }
  16
  17 void XonoticSkinList_configureXonoticSkinList(entity me)
  18 {
  19         me.configureXonoticListBox(me);
  20         me.getSkins(me);
  21         me.loadCvars(me);
  22 }
  23
  24 void XonoticSkinList_loadCvars(entity me)
  25 {
  26         string s;
  27         float i, n;
  28         s = cvar_string("menu_skin");
  29         n = me.nItems;
  30         for(i = 0; i < n; ++i)
  31         {
  32                 if(me.skinParameter(me, i, SKINPARM_NAME) == s)
  33                 {
  34                         me.setSelected(me, i);
  35                         break;
  36                 }
  37         }
  38 }
  39
  40 void XonoticSkinList_saveCvars(entity me)
  41 {
  42         cvar_set("menu_skin", me.skinParameter(me, me.selectedItem, SKINPARM_NAME));
  43 }
  44
  45 string XonoticSkinList_skinParameter(entity me, float i, float key)
  46 {
  47         return bufstr_get(me.skinlist, i * SKINPARM_COUNT + key);
  48 }
  49
  50 void XonoticSkinList_getSkins(entity me)
  51 {
  52         float glob, buf, i, n, fh;
  53         string s, name;
  54
  55         buf = buf_create();
  56         glob = search_begin("gfx/menu/*/skinvalues.txt", true, true);
  57         if(glob < 0)
  58         {
  59                 me.skinlist = buf;
  60                 me.nItems = 0;
  61                 return;
  62         }
  63
  64         n = search_getsize(glob);
  65         for(i = 0; i < n; ++i)
  66         {
  67                 s = search_getfilename(glob, i);
  68                 name = substring(s, 9, strlen(s) - 24); // the * part
  69                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_NAME, name);
  70                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_TITLE, _("<TITLE>"));
  71                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_AUTHOR, _("<AUTHOR>"));
  72                 if(draw_PictureSize(strcat("/gfx/menu/", substring(s, 9, strlen(s) - 24), "/skinpreview")) == '0 0 0')
  73                         bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_PREVIEW, "nopreview_menuskin");
  74                 else
  75                         bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_PREVIEW, strcat("/gfx/menu/", substring(s, 9, strlen(s) - 24), "/skinpreview"));
  76                 fh = fopen(s, FILE_READ);
  77                 if(fh < 0)
  78                 {
  79                         LOG_INFO("Warning: can't open skinvalues.txt file\n");
  80                         continue;
  81                 }
  82                 while((s = fgets(fh)))
  83                 {
  84                         // these two are handled by skinlist.qc
  85                         if(substring(s, 0, 6) == "title ")
  86                         {
  87                                 if (name == cvar_defstring("menu_skin"))
  88                                         bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_TITLE, strcat(substring(s, 6, strlen(s) - 6), " (", _("Default"), ")"));
  89                                 else
  90                                         bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_TITLE, substring(s, 6, strlen(s) - 6));
  91                         }
  92                         else if(substring(s, 0, 7) == "author ")
  93                                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_AUTHOR, substring(s, 7, strlen(s) - 7));
  94                 }
  95                 fclose(fh);
  96         }
  97
  98         search_end(glob);
  99
 100         me.skinlist = buf;
 101         me.nItems = n;
 102 }
 103
 104 void XonoticSkinList_destroy(entity me)
 105 {
 106         buf_del(me.skinlist);
 107 }
 108
 109 void XonoticSkinList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 110 {
 111         me.itemAbsSize = '0 0 0';
 112         SUPER(XonoticSkinList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 113
 114         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 115         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 116         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize.y);
 117         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize.y;
 118
 119         me.columnPreviewOrigin = 0;
 120         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
 121         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
 122         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize.x;
 123 }
 124
 125 void XonoticSkinList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 126 {
 127         string s;
 128
 129         if(isSelected)
 130                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 131         else if(isFocused)
 132         {
 133                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 134                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 135         }
 136
 137         s = me.skinParameter(me, i, SKINPARM_PREVIEW);
 138         draw_Picture(me.columnPreviewOrigin * eX, s, me.columnPreviewSize * eX + eY, '1 1 1', 1);
 139
 140         s = me.skinParameter(me, i, SKINPARM_TITLE);
 141         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 142         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_SKINLIST_TITLE, SKINALPHA_TEXT, 0);
 143
 144         s = me.skinParameter(me, i, SKINPARM_AUTHOR);
 145         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 146         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_SKINLIST_AUTHOR, SKINALPHA_TEXT, 0);
 147 }
 148
 149 void XonoticSkinList_setSkin(entity me)
 150 {
 151         me.saveCvars(me);
 152         localcmd("\nmenu_restart\nmenu_cmd skinselect\n");
 153 }
 154
 155 void SetSkin_Click(entity btn, entity me)
 156 {
 157         me.setSkin(me);
 158 }
 159
 160 void XonoticSkinList_doubleClickListBoxItem(entity me, float i, vector where)
 161 {
 162         m_play_click_sound(MENU_SOUND_EXECUTE);
 163         me.setSkin(me);
 164 }
 165
 166 float XonoticSkinList_keyDown(entity me, float scan, float ascii, float shift)
 167 {
 168         if(scan == K_ENTER || scan == K_KP_ENTER)
 169         {
 170                 m_play_click_sound(MENU_SOUND_EXECUTE);
 171                 me.setSkin(me);
 172                 return 1;
 173         }
 174         else
 175                 return SUPER(XonoticSkinList).keyDown(me, scan, ascii, shift);
 176 }