qcsrc/menu/xonotic/soundlist.qc

   1 #include "soundlist.qh"
   2
   3 #include "inputbox.qh"
   4 #include "playlist.qh"
   5
   6 entity makeXonoticSoundList()
   7 {
   8         entity me;
   9         me = NEW(XonoticSoundList);
  10         me.configureXonoticSoundList(me);
  11         return me;
  12 }
  13
  14 void XonoticSoundList_configureXonoticSoundList(entity me)
  15 {
  16         me.configureXonoticListBox(me);
  17         me.nItems = 0;
  18 }
  19
  20 string XonoticSoundList_soundName(entity me, int i)
  21 {
  22         string s;
  23         s = search_getfilename(me.listSound, i);
  24         s = substring(s, 15, strlen(s) - 15 - 4);  // sound/cdtracks/, .ogg
  25         return s;
  26 }
  27
  28
  29 void XonoticSoundList_getSounds(entity me)
  30 {
  31         string s;
  32
  33         if(me.filterString)
  34                 //subdirectory in filterString allowed
  35                 s = strcat("sound/cdtracks/*", me.filterString, "*.ogg");
  36         else
  37                 s = "sound/cdtracks/*.ogg";
  38
  39         if(me.listSound >= 0)
  40                 search_end(me.listSound);
  41
  42         me.listSound = search_begin(s, false, true);
  43
  44         me.nItems = (me.listSound < 0) ? 0 : search_getsize(me.listSound);
  45 }
  46
  47 void XonoticSoundList_destroy(entity me)
  48 {
  49         if(me.listSound >= 0)
  50                 search_end(me.listSound);
  51 }
  52
  53 void XonoticSoundList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  54 {
  55         me.itemAbsSize = '0 0 0';
  56         SUPER(XonoticSoundList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  57
  58         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
  59         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
  60         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
  61
  62         me.columnNumberOrigin = 0;
  63         me.columnNumberSize = me.realFontSize.x * 3;
  64
  65         me.columnNameOrigin = me.columnNumberSize;
  66         me.columnNameSize = 1 - me.columnNameOrigin - me.realFontSize.x;
  67 }
  68
  69 void XonoticSoundList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
  70 {
  71         string s;
  72         if(isSelected)
  73                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  74         else if(isFocused)
  75         {
  76                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
  77                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
  78         }
  79
  80         s = me.soundName(me, i);
  81         if(s == cvar_string("menu_cdtrack")) // current menu track
  82                 draw_CenterText((me.columnNumberOrigin + 0.5 * me.columnNumberSize) * eX + me.realUpperMargin * eY, "[C]", me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  83         else if(s == cvar_defstring("menu_cdtrack")) // default menu track
  84                 draw_CenterText((me.columnNumberOrigin + 0.5 * me.columnNumberSize) * eX + me.realUpperMargin * eY, "[D]", me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  85
  86         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
  87         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  88 }
  89
  90 void XonoticSoundList_showNotify(entity me)
  91 {
  92         me.getSounds(me);
  93 }
  94
  95 void SoundList_Menu_Track_Change(entity box, entity me)
  96 {
  97         cvar_set("menu_cdtrack", me.soundName(me, me.selectedItem));
  98 }
  99
 100 void SoundList_Menu_Track_Reset(entity box, entity me)
 101 {
 102         cvar_set("menu_cdtrack", cvar_defstring("menu_cdtrack"));
 103 }
 104
 105 void SoundList_Filter_Change(entity box, entity me)
 106 {
 107         strfree(me.filterString);
 108
 109         if(box.text != "")
 110                 me.filterString = strzone(box.text);
 111
 112         me.getSounds(me);
 113 }
 114
 115 void SoundList_Add(entity box, entity me)
 116 {
 117         me.playlist.addToPlayList(me.playlist, me.soundName(me, me.selectedItem));
 118 }
 119
 120 void SoundList_Add_All(entity box, entity me)
 121 {
 122         int i;
 123         for(i = 0; i < me.nItems; ++i)
 124                 me.playlist.addToPlayList(me.playlist, me.soundName(me, i));
 125 }
 126
 127 void XonoticSoundList_doubleClickListBoxItem(entity me, int i, vector where)
 128 {
 129         me.playlist.addToPlayList(me.playlist, me.soundName(me, i));
 130 }
 131
 132 float XonoticSoundList_keyDown(entity me, float scan, float ascii, float shift)
 133 {
 134         if(scan == K_ENTER || scan == K_KP_ENTER || scan == K_SPACE) {
 135                 me.playlist.addToPlayList(me.playlist, me.soundName(me, me.selectedItem));
 136                 return 1;
 137         }
 138         else
 139                 return SUPER(XonoticSoundList).keyDown(me, scan, ascii, shift);
 140 }