qcsrc/menu/xonotic/util.qc

   1 #include "util.qh"
   2
   3 #include "../item.qc"
   4
   5 #include "../menu.qh"
   6 #include "../../common/campaign_common.qh"
   7 #include "../../common/constants.qh"
   8 #include "../../common/mapinfo.qh"
   9 #include "../../common/util.qh"
  10 #include "../../common/command/generic.qh"
  11
  12 float GL_CheckExtension(string ext)
  13 {
  14         return strhasword(cvar_string("gl_info_extensions"), ext);
  15 }
  16
  17 float GL_Have_TextureCompression()
  18 {
  19         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
  20 }
  21
  22 .entity parent, firstChild, nextSibling;
  23 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  24 {
  25         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  26 }
  27
  28 .string cvarName;
  29 void SUB_Null_ee(entity e1, entity e2)
  30 {
  31 }
  32
  33 .void(entity) saveCvars;
  34 void saveCvarsOf(entity ignore, entity e)
  35 {
  36         if(e.saveCvars)
  37                 e.saveCvars(e);
  38 }
  39
  40 .void(entity) loadCvars;
  41 void loadCvarsOf(entity ignore, entity e)
  42 {
  43         if(e.loadCvars)
  44                 e.loadCvars(e);
  45 }
  46 void saveAllCvars(entity root)
  47 {
  48         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  49 }
  50 void loadAllCvars(entity root)
  51 {
  52         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  53 }
  54
  55 .string cvarNames_Multi;
  56 .void(entity me) saveCvars_Multi;
  57 string getCvarsMulti(entity me)
  58 {
  59         if (me.cvarNames_Multi)
  60                 return me.cvarNames_Multi;
  61         return string_null;
  62 }
  63 void saveCvarsMulti(entity me)
  64 {
  65         float n, i;
  66         string s;
  67
  68         me.saveCvars_Multi(me);
  69         s = cvar_string(me.cvarName);
  70
  71         n = tokenize_console(me.cvarNames_Multi);
  72         for(i = 0; i < n; ++i)
  73         {
  74                 if(substring(argv(i), 0, 1) == "!")
  75                         cvar_set(substring(argv(i), 1, strlen(argv(i))), ((s == "0") ? "1" : "0"));
  76                 else
  77                         cvar_set(argv(i), s);
  78
  79                 CheckSendCvars(me, argv(i));
  80         }
  81 }
  82 void makeMulti(entity e, string otherCvars)
  83 {
  84         e.cvarNames_Multi = otherCvars;
  85         e.saveCvars_Multi = e.saveCvars;
  86         e.saveCvars = saveCvarsMulti;
  87 }
  88
  89 .void(entity me) saveCvars_Callback;
  90 .entity saveCvars_Callback_ent;
  91 .void(entity me, entity cb) saveCvars_Callback_func;
  92 void saveCvarsCallback(entity me)
  93 {
  94         me.saveCvars_Callback(me);
  95         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
  96 }
  97 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
  98 {
  99         e.saveCvars_Callback = e.saveCvars;
 100         e.saveCvars = saveCvarsCallback;
 101         e.saveCvars_Callback_ent = cbent;
 102         e.saveCvars_Callback_func = cbfunc;
 103 }
 104
 105 .void(entity) draw_setDependent;
 106 .string cvar_setDependent;
 107 .float cvarMin_setDependent;
 108 .float cvarMax_setDependent;
 109 .string cvar2_setDependent;
 110 .float cvar2Min_setDependent;
 111 .float cvar2Max_setDependent;
 112 .string cvar3_setDependent;
 113 .float cvar3Min_setDependent;
 114 .float cvar3Max_setDependent;
 115 .float op_setDependent;
 116 .string cvarString_setDependent;
 117 .string cvarValue_setDependent;
 118 .float(entity) func_setDependent;
 119 .bool disabled;
 120 void setDependent_Check(entity e)
 121 {
 122         float f;
 123         string s;
 124         if(e.func_setDependent)
 125         {
 126                 e.disabled = !(e.func_setDependent(e));
 127         }
 128         else if(e.cvarString_setDependent)
 129         {
 130                 s = cvar_string(e.cvarString_setDependent);
 131                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 132         }
 133         else
 134         {
 135                 if(e.cvar_setDependent)
 136                 {
 137                         f = cvar(e.cvar_setDependent);
 138                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 139                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 140                         else
 141                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 142                 }
 143                 if(e.cvar2_setDependent)
 144                 {
 145                         f = cvar(e.cvar2_setDependent);
 146                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 147                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 148                         else
 149                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 150                 }
 151                 if(e.cvar3_setDependent)
 152                 {
 153                         f = cvar(e.cvar3_setDependent);
 154                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 155                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 156                         else
 157                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 158                 }
 159         }
 160 }
 161 void setDependent_Draw(entity e)
 162 {
 163         setDependent_Check(e);
 164         e.draw_setDependent(e);
 165 }
 166 .void(entity) draw;
 167 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 168 {
 169         e.draw_setDependent = e.draw;
 170         e.cvar_setDependent = theCvarName;
 171         e.cvarMin_setDependent = theCvarMin;
 172         e.cvarMax_setDependent = theCvarMax;
 173         e.cvar2_setDependent = string_null;
 174         e.cvar3_setDependent = string_null;
 175         e.func_setDependent = func_null;
 176         e.draw = setDependent_Draw;
 177         setDependent_Check(e);
 178 }
 179 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 180 {
 181         e.draw_setDependent = e.draw;
 182         e.cvarString_setDependent = theCvarName;
 183         e.cvarValue_setDependent = theCvarValue;
 184         e.cvar_setDependent = string_null;
 185         e.cvar2_setDependent = string_null;
 186         e.cvar3_setDependent = string_null;
 187         e.func_setDependent = func_null;
 188         e.draw = setDependent_Draw;
 189         setDependent_Check(e);
 190 }
 191 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 192 {
 193         e.draw_setDependent = e.draw;
 194         e.cvar_setDependent = theCvarName;
 195         e.cvarMin_setDependent = theCvarMin;
 196         e.cvarMax_setDependent = theCvarMax;
 197         e.cvar2_setDependent = theCvar2Name;
 198         e.cvar2Min_setDependent = theCvar2Min;
 199         e.cvar2Max_setDependent = theCvar2Max;
 200         e.cvar3_setDependent = string_null;
 201         e.op_setDependent = 0;
 202         e.func_setDependent = func_null;
 203         e.draw = setDependent_Draw;
 204         setDependent_Check(e);
 205 }
 206 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 207 {
 208         e.draw_setDependent = e.draw;
 209         e.cvar_setDependent = theCvarName;
 210         e.cvarMin_setDependent = theCvarMin;
 211         e.cvarMax_setDependent = theCvarMax;
 212         e.cvar2_setDependent = theCvar2Name;
 213         e.cvar2Min_setDependent = theCvar2Min;
 214         e.cvar2Max_setDependent = theCvar2Max;
 215         e.cvar3_setDependent = string_null;
 216         e.op_setDependent = 1;
 217         e.func_setDependent = func_null;
 218         e.draw = setDependent_Draw;
 219         setDependent_Check(e);
 220 }
 221 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 222 {
 223         e.draw_setDependent = e.draw;
 224         e.cvar_setDependent = theCvarName;
 225         e.cvarMin_setDependent = theCvarMin;
 226         e.cvarMax_setDependent = theCvarMax;
 227         e.cvar2_setDependent = theCvar2Name;
 228         e.cvar2Min_setDependent = theCvar2Min;
 229         e.cvar2Max_setDependent = theCvar2Max;
 230         e.cvar3_setDependent = theCvar3Name;
 231         e.cvar3Min_setDependent = theCvar3Min;
 232         e.cvar3Max_setDependent = theCvar3Max;
 233         e.op_setDependent = 0;
 234         e.func_setDependent = func_null;
 235         e.draw = setDependent_Draw;
 236         setDependent_Check(e);
 237 }
 238 void setDependentWeird(entity e, float(entity) func)
 239 {
 240         e.draw_setDependent = e.draw;
 241         e.func_setDependent = func;
 242         e.draw = setDependent_Draw;
 243         setDependent_Check(e);
 244 }
 245
 246 void setZonedTooltip(entity e, string theTooltip, string theCvar)
 247 {
 248         if(theTooltip == "") // no tooltip, use cvar description then
 249         {
 250                 if(theCvar != "" && prvm_language == "en")
 251                 {
 252                         string t = cvar_description(theCvar);
 253                         if(t != "" && t != "custom cvar")
 254                                 theTooltip = t;
 255                 }
 256         }
 257         else if(theTooltip == "-") // no cvar description as tooltip
 258         {
 259                 theTooltip = string_null;
 260         }
 261
 262         if(e.tooltip)
 263                 strunzone(e.tooltip);
 264         e.tooltip = (theTooltip != "") ? strzone(theTooltip) : string_null;
 265 }
 266
 267 void clearTooltip(entity e)
 268 {
 269         setZonedTooltip(e, string_null, string_null);
 270 }
 271
 272 // URI SYSTEM ////////////////////////////////////////////////////////
 273
 274 float _Nex_ExtResponseSystem_Queried;
 275 string _Nex_ExtResponseSystem_UpdateTo;
 276 string _Nex_ExtResponseSystem_UpdateToURL;
 277 string _Nex_ExtResponseSystem_Packs;
 278 float _Nex_ExtResponseSystem_PacksStep;
 279
 280 void URI_Get_Callback(float id, float status, string data)
 281 {
 282         if(url_URI_Get_Callback(id, status, data))
 283         {
 284                 // handled
 285         }
 286         else if (id == URI_GET_DISCARD)
 287         {
 288                 // discard
 289         }
 290         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 291         {
 292                 // sv_cmd curl
 293                 Curl_URI_Get_Callback(id, status, data);
 294         }
 295         else if (id == URI_GET_UPDATENOTIFICATION)
 296         {
 297                 UpdateNotification_URI_Get_Callback(id, status, data);
 298         }
 299         else
 300         {
 301                 LOG_INFOF("Received HTTP request data for an invalid id %d.\n", id);
 302         }
 303 }
 304
 305 void DisableServerBackwardsCompatibility()
 306 {
 307         cvar_set("gameversion_min", ftos(100 * floor(cvar("gameversion") / 100)));
 308 }
 309
 310 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 311 {
 312         float n;
 313
 314         if(_Nex_ExtResponseSystem_UpdateTo)
 315         {
 316                 LOG_TRACE("error: UpdateNotification_URI_Get_Callback has been called before\n");
 317                 return;
 318         }
 319         if(status != 0)
 320         {
 321                 LOG_TRACEF("error receiving update notification: status is %d\n", status);
 322                 return;
 323         }
 324         if(substring(data, 0, 1) == "<")
 325         {
 326                 LOG_TRACE("error: received HTML instead of an update notification\n");
 327                 return;
 328         }
 329         if(strstrofs(data, "\r", 0) != -1)
 330         {
 331                 LOG_TRACE("error: received carriage returns from update notification server\n");
 332                 return;
 333         }
 334
 335         if(data == "")
 336                 n = 0;
 337         else
 338                 n = tokenizebyseparator(data, "\n");
 339
 340         float i;
 341         string s;
 342
 343         string un_version = "";
 344         string un_download = "";
 345         string un_url = "";
 346         string un_bannedservers = "";
 347         string un_emergency_pk3s = "";
 348         string un_promoted = "";
 349         string un_recommended = "";
 350         string un_compatexpire = "";
 351
 352         for(i = 0; i < n; ++i)
 353         {
 354                 s = substring(argv(i), 2, -1);
 355                 if(s == "") { continue; } // ignore empty lines
 356
 357                 switch(substring(argv(i), 0, 1))
 358                 {
 359                         case "V":
 360                         {
 361                                 un_version = s;
 362                                 break;
 363                         }
 364                         case "C":
 365                         {
 366                                 un_compatexpire = s;
 367                                 break;
 368                         }
 369                         case "D":
 370                         {
 371                                 un_download = s;
 372                                 break;
 373                         }
 374                         case "U":
 375                         {
 376                                 un_url = s;
 377                                 break;
 378                         }
 379                         case "B":
 380                         {
 381                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 382                                 break;
 383                         }
 384                         case "E":
 385                         {
 386                                 if(cvar("menu_updatecheck_getpacks"))
 387                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 388                                 break;
 389                         }
 390                         case "P":
 391                         {
 392                                 APPEND_TO_STRING(un_promoted, " ", s);
 393                                 break;
 394                         }
 395                         case "R":
 396                         {
 397                                 APPEND_TO_STRING(un_recommended, " ", s);
 398                                 break;
 399                         }
 400                 }
 401         }
 402
 403         if(un_version != "")
 404         {
 405                 if(vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 406                 {
 407                         // update needed
 408                         _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 409                         if(un_download) { LOG_INFOF(_("Update can be downloaded at:\n%s\n"), un_download); }
 410                         if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 411                         DisableServerBackwardsCompatibility();
 412                 }
 413                 else if(cvar_string("g_xonoticversion") == un_version)
 414                 {
 415                         if(un_compatexpire != "")
 416                         {
 417                                 string curdate = strftime(false, "%Y%m%d%H%M%S");
 418                                 if (strcmp(curdate, un_compatexpire) >= 0)
 419                                         DisableServerBackwardsCompatibility();
 420                         }
 421                 }
 422         }
 423
 424         if(un_emergency_pk3s != "")
 425         {
 426                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 427                 _Nex_ExtResponseSystem_PacksStep = 1;
 428         }
 429
 430         if(un_promoted != "")
 431         {
 432                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 433                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 434         }
 435
 436         if(un_recommended != "")
 437         {
 438                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 439                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 440         }
 441 }
 442
 443 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 444
 445 void updateCheck()
 446 {
 447         if(cvar("menu_updatecheck"))
 448         {
 449                 if(!_Nex_ExtResponseSystem_Queried)
 450                 {
 451                         _Nex_ExtResponseSystem_Queried = 1;
 452                         float startcnt;
 453                         string uri;
 454
 455                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 456
 457                         // for privacy, munge the start count a little
 458                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 459                         uri = sprintf("http://update.xonotic.org/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 460                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 461                 }
 462         }
 463
 464         if(_Nex_ExtResponseSystem_PacksStep > 0)
 465         {
 466                 float n, i;
 467                 float allgood;
 468                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 469                 allgood = true;
 470                 for(i = 0; i+1 < n; i += 2)
 471                 {
 472                         if(fexists(argv(i+1)))
 473                                 continue;
 474                         allgood = false;
 475                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 476                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 477                 }
 478                 if(allgood)
 479                 {
 480                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 481                         {
 482                                 if(!Menu_Active)
 483                                         cvar_set("_menu_initialized", "0");
 484                                         // HACK: cause m_hide call on next start
 485                                 localcmd("\nmenu_restart\n");
 486                         }
 487                         _Nex_ExtResponseSystem_PacksStep = 0;
 488                 }
 489                 else
 490                         _Nex_ExtResponseSystem_PacksStep = 2;
 491         }
 492
 493 }
 494
 495 float preMenuInit()
 496 {
 497         vector sz;
 498         vector boxA, boxB;
 499
 500         updateCheck();
 501
 502         MapInfo_Cache_Create();
 503         MapInfo_Enumerate();
 504         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 505         {
 506                 draw_reset_cropped();
 507
 508                 sz = eX * 0.025 + eY * 0.025 * (draw_scale.x / draw_scale.y);
 509                 draw_CenterText('0.5 0.5 0' - 1.25 * sz.y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 510
 511                 boxA = '0.05 0.5 0' + 0.25 * sz.y * eY;
 512                 boxB = '0.95 0.5 0' + 1.25 * sz.y * eY;
 513                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 514
 515                 boxA += sz * 0.1;
 516                 boxB -= sz * 0.1;
 517                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 518
 519                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 520                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 521
 522                 return false;
 523         }
 524         return true;
 525 }
 526
 527 string campaign_name_previous;
 528 float campaign_won_previous;
 529 #ifdef WATERMARK
 530 string autocvar_menu_watermark = WATERMARK;
 531 #else
 532 string autocvar_menu_watermark = "";
 533 #endif
 534 void postMenuDraw()
 535 {
 536         if(autocvar_menu_watermark != "")
 537         {
 538                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 539         }
 540 }
 541 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize);
 542 .entity winnerDialog;
 543 void preMenuDraw()
 544 {
 545         vector fs, sz = '0 0 0', line, mid;
 546
 547         updateCheck();
 548
 549         if(_Nex_ExtResponseSystem_UpdateTo != "")
 550         {
 551                 // TODO rather turn this into a dialog
 552                 fs = ((1/draw_scale.x) * eX + (1/draw_scale.y) * eY) * 12;
 553                 line = eY * fs.y;
 554                 string l1, l2;
 555                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 556                 l2 = "http://www.xonotic.org/";
 557                 if(_Nex_ExtResponseSystem_UpdateToURL)
 558                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 559
 560                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 561                                 draw_TextWidth(l1, 0, fs),
 562                                 draw_TextWidth(l2, 0, fs)
 563                         );
 564                 sz_y = 3 * fs.y;
 565
 566                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 567                 mid = eX * (0.5 + 0.5 * (1 - sz.x) * cos(time * 0.071))
 568                     + eY * (0.5 + 0.5 * (1 - sz.y) * sin(time * 0.071));
 569
 570                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 571                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 572                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 573         }
 574         if (!campaign_name_previous)
 575                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 576         if(campaign_name == campaign_name_previous)
 577         {
 578                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 579                 {
 580                         if(!campaign_won_previous)
 581                         {
 582                                 m_display();
 583                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 584                         }
 585                         campaign_won_previous = 1;
 586                 }
 587                 else
 588                         campaign_won_previous = 0;
 589         }
 590         else
 591         {
 592                 strunzone(campaign_name_previous);
 593                 campaign_name_previous = strzone(campaign_name);
 594                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 595         }
 596 }
 597
 598 string resolvemod(string m)
 599 {
 600         if(m == "=")
 601                 return getcurrentmod();
 602         else
 603                 return m;
 604 }
 605
 606 float updateCompression()
 607 {
 608         float have_dds, have_jpg, have_tga;
 609         float can_dds;
 610         have_dds = (fexists("dds/particles/particlefont.dds"));
 611         have_jpg = (fexists("particles/particlefont.jpg"));
 612         have_tga = (fexists("particles/particlefont.tga"));
 613         can_dds = GL_Have_TextureCompression();
 614         if(have_dds && (have_jpg || have_tga))
 615         {
 616                 // both? Let's only use good quality precompressed files
 617                 // but ONLY if we actually support it!
 618                 if(can_dds)
 619                 {
 620                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 621                         cvar_set("gl_texturecompression", "0");
 622                         return 1;
 623
 624                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 625                         //return 2;
 626                 }
 627                 else
 628                 {
 629                         cvar_set("gl_texturecompression", "0");
 630                         cvar_set("r_texture_dds_load", "0");
 631                         return 0;
 632                 }
 633         }
 634         else if(have_dds)
 635         {
 636                 // DDS only? We probably always want texture compression
 637                 cvar_set("gl_texturecompression", "1");
 638                 cvar_set("r_texture_dds_load", "1");
 639                 if(!can_dds)
 640                         LOG_INFO(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 641                 return 0;
 642         }
 643         else
 644         {
 645                 // TGA only? Allow runtime compression
 646                 if(can_dds)
 647                 {
 648                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 649                         return 2;
 650                 }
 651                 else
 652                 {
 653                         cvar_set("gl_texturecompression", "0");
 654                         cvar_set("r_texture_dds_load", "0");
 655                         return 0;
 656                 }
 657         }
 658 }
 659
 660 // note: include only those that should be in the menu!
 661 #define GAMETYPES \
 662         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 663         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 664         GAMETYPE(MAPINFO_TYPE_CTF) \
 665         GAMETYPE(MAPINFO_TYPE_CA) \
 666         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 667         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 668         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 669         GAMETYPE(MAPINFO_TYPE_LMS) \
 670         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 671         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 672         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 673         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 674         if (cvar("developer")) GAMETYPE(MAPINFO_TYPE_RACE) \
 675         GAMETYPE(MAPINFO_TYPE_CTS) \
 676         /* GAMETYPE(MAPINFO_TYPE_INVASION) */ \
 677         /**/
 678
 679 int GameType_GetID(int cnt)
 680 {
 681         int i = 0;
 682
 683         #define GAMETYPE(id) { if (i++ == cnt) return id; }
 684         GAMETYPES
 685         #undef GAMETYPE
 686
 687         unused_float = i;
 688
 689         return 0;
 690 }
 691
 692 int GameType_GetCount()
 693 {
 694         int i = 0;
 695
 696         #define GAMETYPE(id) ++i;
 697         GAMETYPES
 698         #undef GAMETYPE
 699
 700         return i;
 701 }
 702
 703 string GameType_GetName(int cnt)
 704 {
 705         int i = GameType_GetID(cnt);
 706
 707         if(i)
 708                 return MapInfo_Type_ToText(i);
 709
 710         return "";
 711 }
 712
 713 string GameType_GetIcon(int cnt)
 714 {
 715         int i = GameType_GetID(cnt);
 716
 717         if(i)
 718                 return strcat("gametype_", MapInfo_Type_ToString(i));
 719
 720         return "";
 721 }
 722
 723 .void(entity) TR;
 724 .void(entity, float, float, entity) TD;
 725 .void(entity, float) TDempty;
 726 entity makeXonoticTextLabel(float theAlign, string theText);
 727 entity makeXonoticTextSlider(string);
 728 .void(entity, string, string) addValue;
 729 .void(entity) configureXonoticTextSliderValues;
 730 entity makeXonoticColorpickerString(string theCvar, string theDefaultCvar);
 731 entity makeXonoticCheckBoxString(string, string, string, string);
 732 entity makeXonoticCheckBox(float, string, string);
 733 .bool sendCvars;
 734
 735 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 736 {
 737         float i;
 738         entity e;
 739
 740         me.TR(me);
 741                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 742                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 743                                 e.addValue(e, _("Default"), "");
 744                                 e.addValue(e, _("Disable"), "0");
 745                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 746                                 e.configureXonoticTextSliderValues(e);
 747         me.TR(me);
 748                 me.TDempty(me, 0.2);
 749                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 750                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 751                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 752         me.TR(me);
 753                 me.TDempty(me, 0.2);
 754                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 755         me.TR(me);
 756                 me.TDempty(me, 0.2);
 757                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 758                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 759                                 e.addValue(e, _("Default"), "");
 760                                 e.addValue(e, _("Disable"), "0");
 761                                 for(i = 1; i <= 10; ++i)
 762                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 763                                 e.configureXonoticTextSliderValues(e);
 764         me.TR(me);
 765                 me.TDempty(me, 0.2);
 766                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 767                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 768                                 e.addValue(e, _("Default"), "");
 769                                 for(i = 1; i <= 10; ++i)
 770                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 771                                 e.configureXonoticTextSliderValues(e);
 772         me.TR(me);
 773                 me.TDempty(me, 0.2);
 774                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 775                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 776                                 e.addValue(e, _("Default"), "");
 777                                 e.addValue(e, _("Disable"), "0");
 778                                 for(i = 1; i <= 10; ++i)
 779                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 780                                 e.configureXonoticTextSliderValues(e);
 781         me.TR(me);
 782                 me.TDempty(me, 0.4);
 783                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 784         me.TR(me);
 785                 me.TDempty(me, 0.2);
 786                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 787                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 788                                 e.addValue(e, _("Default"), "");
 789                                 for(i = 0; i <= 10; ++i)
 790                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 791                                 e.configureXonoticTextSliderValues(e);
 792 }
 793
 794 float getFadedAlpha(float currentAlpha, float startAlpha, float targetAlpha)
 795 {
 796         if(startAlpha < targetAlpha)
 797                 currentAlpha = min(currentAlpha + frametime * 0.5, targetAlpha);
 798         else
 799                 currentAlpha = max(currentAlpha - frametime * 0.5, targetAlpha);
 800         return currentAlpha;
 801 }
 802
 803 void CheckSendCvars(entity me, string cvarnamestring)
 804 {
 805         if(me.sendCvars)
 806         {
 807                 LOG_INFOF("Sending cvar: %s -> %s\n", cvarnamestring, cvar_string(cvarnamestring));
 808                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 809                 {
 810                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 811                 }
 812         }
 813 }