qcsrc/menu/xonotic/util.qc

   1 float GL_CheckExtension(string ext)
   2 {
   3         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
   4 }
   5
   6 float GL_Have_TextureCompression()
   7 {
   8         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
   9 }
  10
  11 void loadTooltips()
  12 {
  13         tooltipdb = db_load(language_filename("tooltips.db"));
  14 }
  15 void unloadTooltips()
  16 {
  17         if(tooltipdb >= 0)
  18                 db_close(tooltipdb);
  19         tooltipdb = -1;
  20 }
  21 string getZonedTooltipForIdentifier(string s)
  22 {
  23         string t;
  24         if(s == "")
  25                 return string_null;
  26         if(tooltipdb >= 0)
  27         {
  28                 t = db_get(tooltipdb, s);
  29                 if(t == "-")
  30                         return string_null;
  31                 if(t != "")
  32                         return strzone(t);
  33         }
  34         if(prvm_language == "en" || prvm_language == "")
  35         {
  36                 t = cvar_description(s);
  37                 if(t != "" && t != "custom cvar")
  38                         return strzone(t);
  39         }
  40         dprint("WARNING: no tooltip set for ", s, "\n");
  41         return string_null;
  42 }
  43
  44 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  45 {
  46         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  47 }
  48
  49 .string cvarName;
  50 void SUB_Null_ee(entity e1, entity e2)
  51 {
  52 }
  53 void saveCvarsOf(entity ignore, entity e)
  54 {
  55         if(e.saveCvars)
  56                 e.saveCvars(e);
  57 }
  58 void loadCvarsOf(entity ignore, entity e)
  59 {
  60         if(e.loadCvars)
  61                 e.loadCvars(e);
  62 }
  63 void saveAllCvars(entity root)
  64 {
  65         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  66 }
  67 void loadAllCvars(entity root)
  68 {
  69         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  70 }
  71
  72 .string cvarNames_Multi;
  73 .void(entity me) saveCvars_Multi;
  74 string getCvarsMulti(entity me)
  75 {
  76         if (me.cvarNames_Multi)
  77                 return me.cvarNames_Multi;
  78         return string_null;
  79 }
  80 void saveCvarsMulti(entity me)
  81 {
  82         float n, i;
  83         string s;
  84
  85         me.saveCvars_Multi(me);
  86         s = cvar_string(me.cvarName);
  87
  88         n = tokenize_console(me.cvarNames_Multi);
  89         for(i = 0; i < n; ++i)
  90                 cvar_set(argv(i), s);
  91 }
  92 void makeMulti(entity e, string otherCvars)
  93 {
  94         e.cvarNames_Multi = otherCvars;
  95         e.saveCvars_Multi = e.saveCvars;
  96         e.saveCvars = saveCvarsMulti;
  97 }
  98
  99 .void(entity me) saveCvars_Callback;
 100 .entity saveCvars_Callback_ent;
 101 .void(entity me, entity cb) saveCvars_Callback_func;
 102 void saveCvarsCallback(entity me)
 103 {
 104         me.saveCvars_Callback(me);
 105         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 106 }
 107 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 108 {
 109         e.saveCvars_Callback = e.saveCvars;
 110         e.saveCvars = saveCvarsCallback;
 111         e.saveCvars_Callback_ent = cbent;
 112         e.saveCvars_Callback_func = cbfunc;
 113 }
 114
 115 .void(entity) draw_setDependent;
 116 .string cvar_setDependent;
 117 .float cvarMin_setDependent;
 118 .float cvarMax_setDependent;
 119 .string cvar2_setDependent;
 120 .float cvar2Min_setDependent;
 121 .float cvar2Max_setDependent;
 122 .string cvar3_setDependent;
 123 .float cvar3Min_setDependent;
 124 .float cvar3Max_setDependent;
 125 .float op_setDependent;
 126 .string cvarString_setDependent;
 127 .string cvarValue_setDependent;
 128 .float(entity) func_setDependent;
 129 void setDependent_Check(entity e)
 130 {
 131         float f;
 132         string s;
 133         if(e.func_setDependent)
 134         {
 135                 e.disabled = !(e.func_setDependent(e));
 136         }
 137         else if(e.cvarString_setDependent)
 138         {
 139                 s = cvar_string(e.cvarString_setDependent);
 140                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 141         }
 142         else
 143         {
 144                 if(e.cvar_setDependent)
 145                 {
 146                         f = cvar(e.cvar_setDependent);
 147                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 148                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 149                         else
 150                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 151                 }
 152                 if(e.cvar2_setDependent)
 153                 {
 154                         f = cvar(e.cvar2_setDependent);
 155                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 156                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 157                         else
 158                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 159                 }
 160                 if(e.cvar3_setDependent)
 161                 {
 162                         f = cvar(e.cvar3_setDependent);
 163                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 164                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 165                         else
 166                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 167                 }
 168         }
 169 }
 170 void setDependent_Draw(entity e)
 171 {
 172         setDependent_Check(e);
 173         e.draw_setDependent(e);
 174 }
 175 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 176 {
 177         e.draw_setDependent = e.draw;
 178         e.cvar_setDependent = theCvarName;
 179         e.cvarMin_setDependent = theCvarMin;
 180         e.cvarMax_setDependent = theCvarMax;
 181         e.cvar2_setDependent = string_null;
 182         e.cvar3_setDependent = string_null;
 183         e.func_setDependent = func_null;
 184         e.draw = setDependent_Draw;
 185         setDependent_Check(e);
 186 }
 187 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 188 {
 189         e.draw_setDependent = e.draw;
 190         e.cvarString_setDependent = theCvarName;
 191         e.cvarValue_setDependent = theCvarValue;
 192         e.cvar_setDependent = string_null;
 193         e.cvar2_setDependent = string_null;
 194         e.cvar3_setDependent = string_null;
 195         e.func_setDependent = func_null;
 196         e.draw = setDependent_Draw;
 197         setDependent_Check(e);
 198 }
 199 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 200 {
 201         e.draw_setDependent = e.draw;
 202         e.cvar_setDependent = theCvarName;
 203         e.cvarMin_setDependent = theCvarMin;
 204         e.cvarMax_setDependent = theCvarMax;
 205         e.cvar2_setDependent = theCvar2Name;
 206         e.cvar2Min_setDependent = theCvar2Min;
 207         e.cvar2Max_setDependent = theCvar2Max;
 208         e.cvar3_setDependent = string_null;
 209         e.op_setDependent = 0;
 210         e.func_setDependent = func_null;
 211         e.draw = setDependent_Draw;
 212         setDependent_Check(e);
 213 }
 214 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 215 {
 216         e.draw_setDependent = e.draw;
 217         e.cvar_setDependent = theCvarName;
 218         e.cvarMin_setDependent = theCvarMin;
 219         e.cvarMax_setDependent = theCvarMax;
 220         e.cvar2_setDependent = theCvar2Name;
 221         e.cvar2Min_setDependent = theCvar2Min;
 222         e.cvar2Max_setDependent = theCvar2Max;
 223         e.cvar3_setDependent = string_null;
 224         e.op_setDependent = 1;
 225         e.func_setDependent = func_null;
 226         e.draw = setDependent_Draw;
 227         setDependent_Check(e);
 228 }
 229 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 230 {
 231         e.draw_setDependent = e.draw;
 232         e.cvar_setDependent = theCvarName;
 233         e.cvarMin_setDependent = theCvarMin;
 234         e.cvarMax_setDependent = theCvarMax;
 235         e.cvar2_setDependent = theCvar2Name;
 236         e.cvar2Min_setDependent = theCvar2Min;
 237         e.cvar2Max_setDependent = theCvar2Max;
 238         e.cvar3_setDependent = theCvar3Name;
 239         e.cvar3Min_setDependent = theCvar3Min;
 240         e.cvar3Max_setDependent = theCvar3Max;
 241         e.op_setDependent = 0;
 242         e.func_setDependent = func_null;
 243         e.draw = setDependent_Draw;
 244         setDependent_Check(e);
 245 }
 246 void setDependentWeird(entity e, float(entity) func)
 247 {
 248         e.draw_setDependent = e.draw;
 249         e.func_setDependent = func;
 250         e.draw = setDependent_Draw;
 251         setDependent_Check(e);
 252 }
 253
 254 // URI SYSTEM ////////////////////////////////////////////////////////
 255
 256 float _Nex_ExtResponseSystem_Queried;
 257 string _Nex_ExtResponseSystem_UpdateTo;
 258 string _Nex_ExtResponseSystem_UpdateToURL;
 259
 260 void URI_Get_Callback(float id, float status, string data)
 261 {
 262         if (id == URI_GET_DISCARD)
 263         {
 264                 // discard
 265         }
 266         else if(id == URI_GET_UPDATENOTIFICATION)
 267         {
 268                 UpdateNotification_URI_Get_Callback(id, status, data);
 269         }
 270         else if(id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 271         {
 272                 Curl_URI_Get_Callback(id, status, data);
 273         }
 274         else
 275         {
 276                 print(sprintf(_("Received HTTP request data for an invalid id %d.\n"), id));
 277         }
 278 }
 279
 280 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 281 {
 282         float n;
 283
 284         if(_Nex_ExtResponseSystem_UpdateTo)
 285         {
 286                 dprint("error: UpdateNotification_URI_Get_Callback has been called before\n");
 287                 return;
 288         }
 289         if(status != 0)
 290         {
 291                 print(sprintf(_("error receiving update notification: status is %d\n"), status));
 292                 return;
 293         }
 294         if(substring(data, 0, 1) == "<")
 295         {
 296                 print(_("error: received HTML instead of an update notification\n"));
 297                 return;
 298         }
 299         if(strstrofs(data, "\r", 0) != -1)
 300         {
 301                 print(_("error: received carriage returns from update notification server\n"));
 302                 return;
 303         }
 304
 305         if(data == "")
 306                 n = 0;
 307         else
 308                 n = tokenizebyseparator(data, "\n");
 309
 310         if(n >= 1)
 311         {
 312                 _Nex_ExtResponseSystem_UpdateTo = argv(0);
 313
 314                 if(vercmp(cvar_string("g_xonoticversion"), _Nex_ExtResponseSystem_UpdateTo) >= 0)
 315                 {
 316                         _Nex_ExtResponseSystem_UpdateTo = ""; // no update needed
 317                 }
 318                 else
 319                 {
 320                         // update needed
 321                         if(n >= 2)
 322                                 print(sprintf(_("Update can be downloaded at:\n%s\n"), argv(1)));
 323                         if(n >= 3)
 324                                 _Nex_ExtResponseSystem_UpdateToURL = strzone(argv(2));
 325                 }
 326
 327                 _Nex_ExtResponseSystem_UpdateTo = strzone(_Nex_ExtResponseSystem_UpdateTo);
 328         }
 329 }
 330
 331 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 332
 333 float preMenuInit()
 334 {
 335         vector sz;
 336         vector boxA, boxB;
 337
 338         MapInfo_Cache_Create();
 339         MapInfo_Enumerate();
 340         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 341         {
 342                 draw_reset_cropped();
 343
 344                 sz = eX * 0.025 + eY * 0.025 * (draw_scale_x / draw_scale_y);
 345                 draw_CenterText('0.5 0.5 0' - 1.25 * sz_y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 346
 347                 boxA = '0.05 0.5 0' + 0.25 * sz_y * eY;
 348                 boxB = '0.95 0.5 0' + 1.25 * sz_y * eY;
 349                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 350
 351                 boxA += sz * 0.1;
 352                 boxB -= sz * 0.1;
 353                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 354
 355                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 356                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 357
 358                 return FALSE;
 359         }
 360         return TRUE;
 361 }
 362
 363 string campaign_name_previous;
 364 float campaign_won_previous;
 365 #ifdef WATERMARK
 366 var string autocvar_menu_watermark = WATERMARK();
 367 #else
 368 var string autocvar_menu_watermark = "";
 369 #endif
 370 void postMenuDraw()
 371 {
 372         if(autocvar_menu_watermark != "")
 373         {
 374                 vector fs = '48 48 0';
 375                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 376         }
 377 }
 378 void preMenuDraw()
 379 {
 380         vector fs, sz, line, mid;
 381
 382         if(cvar("menu_updatecheck"))
 383         {
 384                 if(!_Nex_ExtResponseSystem_Queried)
 385                 {
 386                         _Nex_ExtResponseSystem_Queried = 1;
 387                         float startcnt;
 388                         string uri;
 389
 390                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 391
 392                         // for privacy, munge the start count a little
 393                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 394                         uri = sprintf("http://www.xonotic.org/dl/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 395
 396 #ifdef CVAR_POPCON
 397                         float cvar_handle, popcon_handle;
 398                         float n, i, j;
 399                         string k, s;
 400                         cvar_handle = buf_create();
 401                         buf_cvarlist(cvar_handle, "", "");
 402                         n = buf_getsize(cvar_handle);
 403                         popcon_handle = buf_create();
 404                         for(i= 0, j = 0; i < n; ++i)
 405                         {
 406                                 k = bufstr_get(cvar_handle, i);
 407                                 if(!(cvar_type(k) & CVAR_TYPEFLAG_SAVED))
 408                                         continue;
 409                                 s = sprintf("%s=%d", uri_escape(k), cvar_string(k) != cvar_defstring(k));
 410                                 bufstr_set(popcon_handle, j, s);
 411                                 ++j;
 412                         }
 413                         buf_del(cvar_handle);
 414                         uri_postbuf(
 415                                 uri, URI_GET_UPDATENOTIFICATION,
 416                                 "application/x-www-form-urlencoded",
 417                                 "&",
 418                                 popcon_handle
 419                         );
 420                         buf_del(popcon_handle);
 421 #else
 422                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 423 #endif
 424                 }
 425         }
 426
 427         if(_Nex_ExtResponseSystem_UpdateTo != "")
 428         {
 429                 // TODO rather turn this into a dialog
 430                 fs = ((1/draw_scale_x) * eX + (1/draw_scale_y) * eY) * 12;
 431                 line = eY * fs_y;
 432                 string l1, l2;
 433                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 434                 l2 = "http://www.xonotic.org/";
 435                 if(_Nex_ExtResponseSystem_UpdateToURL)
 436                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 437
 438                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 439                                 draw_TextWidth(l1, 0, fs),
 440                                 draw_TextWidth(l2, 0, fs)
 441                         );
 442                 sz_y = 3 * fs_y;
 443
 444                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 445                 mid = eX * (0.5 + 0.5 * (1 - sz_x) * cos(time * 0.071))
 446                     + eY * (0.5 + 0.5 * (1 - sz_y) * sin(time * 0.071));
 447
 448                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 449                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 450                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 451         }
 452         if not(campaign_name_previous)
 453                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 454         if(campaign_name == campaign_name_previous)
 455         {
 456                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 457                 {
 458                         if(!campaign_won_previous)
 459                         {
 460                                 m_display();
 461                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 462                         }
 463                         campaign_won_previous = 1;
 464                 }
 465                 else
 466                         campaign_won_previous = 0;
 467         }
 468         else
 469         {
 470                 strunzone(campaign_name_previous);
 471                 campaign_name_previous = strzone(campaign_name);
 472                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 473         }
 474 }
 475
 476 string resolvemod(string m)
 477 {
 478         if(m == "=")
 479                 return getcurrentmod();
 480         else
 481                 return m;
 482 }
 483
 484 float updateCompression()
 485 {
 486         float have_dds, have_jpg, have_tga;
 487         float can_dds;
 488         have_dds = (fexists("dds/particles/particlefont.dds"));
 489         have_jpg = (fexists("particles/particlefont.jpg"));
 490         have_tga = (fexists("particles/particlefont.tga"));
 491         can_dds = GL_Have_TextureCompression();
 492         if(have_dds && (have_jpg || have_tga))
 493         {
 494                 // both? Let's only use good quality precompressed files
 495                 // but ONLY if we actually support it!
 496                 if(can_dds)
 497                 {
 498                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 499                         cvar_set("gl_texturecompression", "0");
 500                         return 1;
 501
 502                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 503                         //return 2;
 504                 }
 505                 else
 506                 {
 507                         cvar_set("gl_texturecompression", "0");
 508                         cvar_set("r_texture_dds_load", "0");
 509                         return 0;
 510                 }
 511         }
 512         else if(have_dds)
 513         {
 514                 // DDS only? We probably always want texture compression
 515                 cvar_set("gl_texturecompression", "1");
 516                 cvar_set("r_texture_dds_load", "1");
 517                 if(!can_dds)
 518                         print(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 519                 return 0;
 520         }
 521         else
 522         {
 523                 // TGA only? Allow runtime compression
 524                 if(can_dds)
 525                 {
 526                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 527                         return 2;
 528                 }
 529                 else
 530                 {
 531                         cvar_set("gl_texturecompression", "0");
 532                         cvar_set("r_texture_dds_load", "0");
 533                         return 0;
 534                 }
 535         }
 536 }
 537
 538 // note: include only those that should be in the menu!
 539 #define GAMETYPES \
 540         GAMETYPE(MAPINFO_TYPE_ARENA, _("Arena")) \
 541         GAMETYPE(MAPINFO_TYPE_ASSAULT, _("Assault")) \
 542         GAMETYPE(MAPINFO_TYPE_CTF, _("Capture The Flag")) \
 543         GAMETYPE(MAPINFO_TYPE_CA, _("Clan Arena")) \
 544         GAMETYPE(MAPINFO_TYPE_DEATHMATCH, _("Deathmatch")) \
 545         GAMETYPE(MAPINFO_TYPE_DOMINATION, _("Domination")) \
 546         GAMETYPE(MAPINFO_TYPE_FREEZETAG, _("Freeze Tag")) \
 547         GAMETYPE(MAPINFO_TYPE_KEEPAWAY, _("Keepaway")) \
 548         GAMETYPE(MAPINFO_TYPE_KEYHUNT, _("Key Hunt")) \
 549         GAMETYPE(MAPINFO_TYPE_LMS, _("Last Man Standing")) \
 550         GAMETYPE(MAPINFO_TYPE_NEXBALL, _("Nexball")) \
 551         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT, _("Onslaught")) \
 552         GAMETYPE(MAPINFO_TYPE_RACE, _("Race")) \
 553         GAMETYPE(MAPINFO_TYPE_CTS, _("Race CTS")) \
 554         GAMETYPE(MAPINFO_TYPE_RUNEMATCH, _("Runematch")) \
 555         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH, _("Team Deathmatch")) \
 556         /* nothing */
 557
 558 float GameType_GetID(float cnt)
 559 {
 560         float i;
 561         i = 0;
 562 #define GAMETYPE(id,name) if(i++ == cnt) return id;
 563         GAMETYPES
 564 #undef GAMETYPE
 565         return 0;
 566 }
 567 string GameType_GetName(float cnt)
 568 {
 569         float i;
 570         i = 0;
 571 #define GAMETYPE(id,name) if(i++ == cnt) return name;
 572         GAMETYPES
 573 #undef GAMETYPE
 574         return _("@!#%'n Tuba Throwing");
 575 }
 576 float GameType_GetCount()
 577 {
 578         float i;
 579         i = 0;
 580 #define GAMETYPE(id,name) ++i;
 581         GAMETYPES
 582 #undef GAMETYPE
 583         return i;
 584 }
 585
 586 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 587 {
 588         float i;
 589         entity e;
 590
 591         me.TR(me);
 592                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 593                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 594                                 e.addValue(e, _("Default"), "");
 595                                 e.addValue(e, _("Disable"), "0");
 596                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 597                                 e.configureXonoticTextSliderValues(e);
 598         me.TR(me);
 599                 me.TDempty(me, 0.2);
 600                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 601                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 602                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 603         me.TR(me);
 604                 me.TDempty(me, 0.2);
 605                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 606         me.TR(me);
 607                 me.TDempty(me, 0.2);
 608                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 609                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 610                                 e.addValue(e, _("Default"), "");
 611                                 e.addValue(e, _("Disable"), "0");
 612                                 for(i = 1; i <= 10; ++i)
 613                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 614                                 e.configureXonoticTextSliderValues(e);
 615         me.TR(me);
 616                 me.TDempty(me, 0.2);
 617                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 618                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 619                                 e.addValue(e, _("Default"), "");
 620                                 for(i = 1; i <= 10; ++i)
 621                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 622                                 e.configureXonoticTextSliderValues(e);
 623         me.TR(me);
 624                 me.TDempty(me, 0.2);
 625                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 626                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 627                                 e.addValue(e, _("Default"), "");
 628                                 e.addValue(e, _("Disable"), "0");
 629                                 for(i = 1; i <= 10; ++i)
 630                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 631                                 e.configureXonoticTextSliderValues(e);
 632         me.TR(me);
 633                 me.TDempty(me, 0.4);
 634                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 635         me.TR(me);
 636                 me.TDempty(me, 0.2);
 637                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 638                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 639                                 e.addValue(e, _("Default"), "");
 640                                 for(i = 0; i <= 10; ++i)
 641                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 642                                 e.configureXonoticTextSliderValues(e);
 643 }