qcsrc/menu/xonotic/util.qc

   1 #include "util.qh"
   2 #include "dialog.qh"
   3
   4 #include "../item.qh"
   5
   6 #include "../menu.qh"
   7 #include <common/campaign_common.qh>
   8 #include <common/constants.qh>
   9 #include <common/mapinfo.qh>
  10 #include <common/util.qh>
  11 #include <common/command/_mod.qh>
  12
  13 float GL_CheckExtension(string ext)
  14 {
  15         return strhasword(cvar_string("gl_info_extensions"), ext);
  16 }
  17
  18 float GL_Have_TextureCompression()
  19 {
  20         return GL_CheckExtension("GL_EXT_texture_compression_s3tc");
  21 }
  22
  23 .entity parent, firstChild, nextSibling;
  24 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  25 {
  26         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  27 }
  28
  29 .string cvarName;
  30 void SUB_Null_ee(entity e1, entity e2)
  31 {
  32 }
  33
  34 .void(entity) saveCvars;
  35 void saveCvarsOf(entity ignore, entity e)
  36 {
  37         if(e.saveCvars)
  38                 e.saveCvars(e);
  39 }
  40
  41 .void(entity) loadCvars;
  42 void loadCvarsOf(entity ignore, entity e)
  43 {
  44         if(e.loadCvars)
  45                 e.loadCvars(e);
  46 }
  47 void saveAllCvars(entity root)
  48 {
  49         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  50 }
  51 void loadAllCvars(entity root)
  52 {
  53         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  54 }
  55
  56 .string cvarNames_Multi;
  57 .void(entity me) saveCvars_Multi;
  58 string getCvarsMulti(entity me)
  59 {
  60         if (me.cvarNames_Multi)
  61                 return me.cvarNames_Multi;
  62         return string_null;
  63 }
  64 void saveCvarsMulti(entity me)
  65 {
  66         float n, i;
  67         string s, cvarname;
  68
  69         me.saveCvars_Multi(me);
  70         s = cvar_string(me.cvarName);
  71
  72         n = tokenize_console(me.cvarNames_Multi);
  73         for(i = 0; i < n; ++i)
  74         {
  75                 // cvars prefixed with ! get saved with the inverted value
  76                 if(substring(argv(i), 0, 1) == "!")
  77                 {
  78                         cvarname = substring(argv(i), 1, strlen(argv(i)));
  79                         cvar_set(cvarname, ((s == "0") ? "1" : "0"));
  80                 }
  81                 else
  82                 {
  83                         cvarname = argv(i);
  84                         cvar_set(cvarname, s);
  85                 }
  86
  87                 CheckSendCvars(me, cvarname);
  88         }
  89 }
  90 void makeMulti(entity e, string otherCvars)
  91 {
  92         e.cvarNames_Multi = otherCvars;
  93         e.saveCvars_Multi = e.saveCvars;
  94         e.saveCvars = saveCvarsMulti;
  95 }
  96
  97 .void(entity me) saveCvars_Callback;
  98 .entity saveCvars_Callback_ent;
  99 .void(entity me, entity cb) saveCvars_Callback_func;
 100 void saveCvarsCallback(entity me)
 101 {
 102         me.saveCvars_Callback(me);
 103         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 104 }
 105 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 106 {
 107         e.saveCvars_Callback = e.saveCvars;
 108         e.saveCvars = saveCvarsCallback;
 109         e.saveCvars_Callback_ent = cbent;
 110         e.saveCvars_Callback_func = cbfunc;
 111 }
 112
 113 .void(entity) draw_setDependent;
 114 .string cvar_setDependent;
 115 .float cvarMin_setDependent;
 116 .float cvarMax_setDependent;
 117 .string cvar2_setDependent;
 118 .float cvar2Min_setDependent;
 119 .float cvar2Max_setDependent;
 120 .string cvar3_setDependent;
 121 .float cvar3Min_setDependent;
 122 .float cvar3Max_setDependent;
 123 .float op_setDependent;
 124 .string cvarString_setDependent;
 125 .string cvarValue_setDependent;
 126 .float(entity) func_setDependent;
 127 .bool disabled;
 128 void setDependent_Check(entity e)
 129 {
 130         bool disabled_prev = e.disabled;
 131         float f;
 132         string s;
 133         if(e.func_setDependent)
 134         {
 135                 e.disabled = !(e.func_setDependent(e));
 136         }
 137         else if(e.cvarString_setDependent)
 138         {
 139                 s = cvar_string(e.cvarString_setDependent);
 140                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 141         }
 142         else
 143         {
 144                 if(e.cvar_setDependent)
 145                 {
 146                         f = cvar(e.cvar_setDependent);
 147                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 148                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 149                         else
 150                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 151                 }
 152                 if(e.cvar2_setDependent)
 153                 {
 154                         f = cvar(e.cvar2_setDependent);
 155                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 156                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 157                         else
 158                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 159                 }
 160                 if(e.cvar3_setDependent)
 161                 {
 162                         f = cvar(e.cvar3_setDependent);
 163                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 164                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 165                         else
 166                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 167                 }
 168         }
 169         if (disabled_prev != e.disabled && e.loadCvars)
 170                 e.loadCvars(e);
 171 }
 172 void setDependent_Draw(entity e)
 173 {
 174         setDependent_Check(e);
 175         e.draw_setDependent(e);
 176 }
 177 .void(entity) draw;
 178 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 179 {
 180         e.draw_setDependent = e.draw;
 181         e.cvar_setDependent = theCvarName;
 182         e.cvarMin_setDependent = theCvarMin;
 183         e.cvarMax_setDependent = theCvarMax;
 184         e.cvar2_setDependent = string_null;
 185         e.cvar3_setDependent = string_null;
 186         e.func_setDependent = func_null;
 187         e.draw = setDependent_Draw;
 188         setDependent_Check(e);
 189 }
 190 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 191 {
 192         e.draw_setDependent = e.draw;
 193         e.cvarString_setDependent = theCvarName;
 194         e.cvarValue_setDependent = theCvarValue;
 195         e.cvar_setDependent = string_null;
 196         e.cvar2_setDependent = string_null;
 197         e.cvar3_setDependent = string_null;
 198         e.func_setDependent = func_null;
 199         e.draw = setDependent_Draw;
 200         setDependent_Check(e);
 201 }
 202 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 203 {
 204         e.draw_setDependent = e.draw;
 205         e.cvar_setDependent = theCvarName;
 206         e.cvarMin_setDependent = theCvarMin;
 207         e.cvarMax_setDependent = theCvarMax;
 208         e.cvar2_setDependent = theCvar2Name;
 209         e.cvar2Min_setDependent = theCvar2Min;
 210         e.cvar2Max_setDependent = theCvar2Max;
 211         e.cvar3_setDependent = string_null;
 212         e.op_setDependent = 0;
 213         e.func_setDependent = func_null;
 214         e.draw = setDependent_Draw;
 215         setDependent_Check(e);
 216 }
 217 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 218 {
 219         e.draw_setDependent = e.draw;
 220         e.cvar_setDependent = theCvarName;
 221         e.cvarMin_setDependent = theCvarMin;
 222         e.cvarMax_setDependent = theCvarMax;
 223         e.cvar2_setDependent = theCvar2Name;
 224         e.cvar2Min_setDependent = theCvar2Min;
 225         e.cvar2Max_setDependent = theCvar2Max;
 226         e.cvar3_setDependent = string_null;
 227         e.op_setDependent = 1;
 228         e.func_setDependent = func_null;
 229         e.draw = setDependent_Draw;
 230         setDependent_Check(e);
 231 }
 232 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 233 {
 234         e.draw_setDependent = e.draw;
 235         e.cvar_setDependent = theCvarName;
 236         e.cvarMin_setDependent = theCvarMin;
 237         e.cvarMax_setDependent = theCvarMax;
 238         e.cvar2_setDependent = theCvar2Name;
 239         e.cvar2Min_setDependent = theCvar2Min;
 240         e.cvar2Max_setDependent = theCvar2Max;
 241         e.cvar3_setDependent = theCvar3Name;
 242         e.cvar3Min_setDependent = theCvar3Min;
 243         e.cvar3Max_setDependent = theCvar3Max;
 244         e.op_setDependent = 0;
 245         e.func_setDependent = func_null;
 246         e.draw = setDependent_Draw;
 247         setDependent_Check(e);
 248 }
 249 void setDependentWeird(entity e, float(entity) func)
 250 {
 251         e.draw_setDependent = e.draw;
 252         e.func_setDependent = func;
 253         e.draw = setDependent_Draw;
 254         setDependent_Check(e);
 255 }
 256
 257 void setZonedTooltip(entity e, string theTooltip, string theCvar)
 258 {
 259         if(theTooltip == "") // no tooltip, use cvar description then
 260         {
 261                 if(theCvar != "" && prvm_language == "en")
 262                 {
 263                         string t = cvar_description(theCvar);
 264                         if(t != "" && t != "custom cvar")
 265                                 theTooltip = t;
 266                 }
 267         }
 268         else if(theTooltip == "-") // no cvar description as tooltip
 269         {
 270                 theTooltip = string_null;
 271         }
 272
 273         strfree(e.tooltip);
 274         e.tooltip = (theTooltip != "") ? strzone(theTooltip) : string_null;
 275 }
 276
 277 void clearTooltip(entity e)
 278 {
 279         setZonedTooltip(e, string_null, string_null);
 280 }
 281
 282 // URI SYSTEM ////////////////////////////////////////////////////////
 283
 284 float _Nex_ExtResponseSystem_Queried;
 285 string _Nex_ExtResponseSystem_UpdateTo;
 286 string _Nex_ExtResponseSystem_UpdateToURL;
 287 string _Nex_ExtResponseSystem_Packs;
 288 float _Nex_ExtResponseSystem_PacksStep;
 289
 290 /** engine callback */
 291 void URI_Get_Callback(float id, float status, string data)
 292 {
 293         if(url_URI_Get_Callback(id, status, data))
 294         {
 295                 // handled
 296         }
 297         else if (id == URI_GET_DISCARD)
 298         {
 299                 // discard
 300         }
 301         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 302         {
 303                 // sv_cmd curl
 304                 Curl_URI_Get_Callback(id, status, data);
 305         }
 306         else if (id == URI_GET_UPDATENOTIFICATION)
 307         {
 308                 UpdateNotification_URI_Get_Callback(id, status, data);
 309         }
 310         else
 311         {
 312                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
 313         }
 314 }
 315
 316 void DisableServerBackwardsCompatibility()
 317 {
 318         cvar_set("gameversion_min", ftos(100 * floor(cvar("gameversion") / 100)));
 319 }
 320
 321 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 322 {
 323         float n;
 324
 325         if(_Nex_ExtResponseSystem_UpdateTo)
 326         {
 327                 LOG_TRACE("error: UpdateNotification_URI_Get_Callback has been called before");
 328                 return;
 329         }
 330         if(status != 0)
 331         {
 332                 LOG_TRACEF("error receiving update notification: status is %d", status);
 333                 return;
 334         }
 335         if(substring(data, 0, 1) == "<")
 336         {
 337                 LOG_TRACE("error: received HTML instead of an update notification");
 338                 return;
 339         }
 340         if(strstrofs(data, "\r", 0) != -1)
 341         {
 342                 LOG_TRACE("error: received carriage returns from update notification server");
 343                 return;
 344         }
 345
 346         if(data == "")
 347                 n = 0;
 348         else
 349                 n = tokenizebyseparator(data, "\n");
 350
 351         float i;
 352         string s;
 353
 354         string un_version = "";
 355         string un_download = "";
 356         string un_url = "";
 357         string un_bannedservers = "";
 358         string un_emergency_pk3s = "";
 359         string un_promoted = "";
 360         string un_recommended = "";
 361         string un_compatexpire = "";
 362
 363         for(i = 0; i < n; ++i)
 364         {
 365                 s = substring(argv(i), 2, -1);
 366                 if(s == "") { continue; } // ignore empty lines
 367
 368                 switch(substring(argv(i), 0, 1))
 369                 {
 370                         case "V":
 371                         {
 372                                 un_version = s;
 373                                 break;
 374                         }
 375                         case "C":
 376                         {
 377                                 un_compatexpire = s;
 378                                 break;
 379                         }
 380                         case "D":
 381                         {
 382                                 un_download = s;
 383                                 break;
 384                         }
 385                         case "U":
 386                         {
 387                                 un_url = s;
 388                                 break;
 389                         }
 390                         case "B":
 391                         {
 392                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 393                                 break;
 394                         }
 395                         case "E":
 396                         {
 397                                 if(cvar("menu_updatecheck_getpacks"))
 398                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 399                                 break;
 400                         }
 401                         case "P":
 402                         {
 403                                 APPEND_TO_STRING(un_promoted, " ", s);
 404                                 break;
 405                         }
 406                         case "R":
 407                         {
 408                                 APPEND_TO_STRING(un_recommended, " ", s);
 409                                 break;
 410                         }
 411                 }
 412         }
 413
 414         if(un_version != "")
 415         {
 416                 if(vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 417                 {
 418                         // update needed
 419                         _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 420                         if(un_download) { LOG_INFO(_("Update can be downloaded at:"), "\n", un_download); }
 421                         if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 422                         DisableServerBackwardsCompatibility();
 423                 }
 424                 else if(cvar_string("g_xonoticversion") == un_version)
 425                 {
 426                         if(un_compatexpire != "")
 427                         {
 428                                 string curdate = strftime(false, "%Y%m%d%H%M%S");
 429                                 if (strcmp(curdate, un_compatexpire) >= 0)
 430                                         DisableServerBackwardsCompatibility();
 431                         }
 432                 }
 433         }
 434
 435         if(un_bannedservers != "")
 436         {
 437                 _Nex_ExtResponseSystem_BannedServers = strzone(un_bannedservers);
 438                 _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 1;
 439         }
 440
 441         if(un_emergency_pk3s != "")
 442         {
 443                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 444                 _Nex_ExtResponseSystem_PacksStep = 1;
 445         }
 446
 447         if(un_promoted != "")
 448         {
 449                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 450                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 451         }
 452
 453         if(un_recommended != "")
 454         {
 455                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 456                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 457         }
 458 }
 459
 460 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 461
 462 void updateCheck()
 463 {
 464         if(!_Nex_ExtResponseSystem_Queried)
 465         {
 466                 _Nex_ExtResponseSystem_Queried = 1;
 467                 float startcnt;
 468                 string uri;
 469
 470                 cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 471
 472                 // for privacy, munge the start count a little
 473                 startcnt = floor((floor(startcnt / 10) + random()) * 10);
 474                 uri = sprintf("http://update.xonotic.org/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 475                 uri_get(uri, URI_GET_UPDATENOTIFICATION);
 476         }
 477
 478         if(_Nex_ExtResponseSystem_PacksStep > 0)
 479         {
 480                 float n, i;
 481                 float allgood;
 482                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 483                 allgood = true;
 484                 for(i = 0; i+1 < n; i += 2)
 485                 {
 486                         if(fexists(argv(i+1)))
 487                                 continue;
 488                         allgood = false;
 489                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 490                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 491                 }
 492                 if(allgood)
 493                 {
 494                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 495                         {
 496                                 if(!Menu_Active)
 497                                         cvar_set("_menu_initialized", "0");
 498                                         // HACK: cause m_hide call on next start
 499                                 localcmd("\nmenu_restart\n");
 500                         }
 501                         _Nex_ExtResponseSystem_PacksStep = 0;
 502                 }
 503                 else
 504                         _Nex_ExtResponseSystem_PacksStep = 2;
 505         }
 506
 507 }
 508
 509 bool show_propermenu = false;
 510
 511 float preMenuInit()
 512 {
 513         vector sz;
 514         vector boxA, boxB;
 515
 516         if(random() < 0.1)
 517                 show_propermenu = true;
 518
 519         updateCheck();
 520
 521         MapInfo_Cache_Create();
 522         MapInfo_Enumerate();
 523         if(!_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 524         {
 525                 draw_reset_cropped();
 526
 527                 sz = eX * 0.025 + eY * 0.025 * (draw_scale.x / draw_scale.y);
 528                 draw_CenterText('0.5 0.5 0' - 1.25 * sz.y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 529
 530                 boxA = '0.05 0.5 0' + 0.25 * sz.y * eY;
 531                 boxB = '0.95 0.5 0' + 1.25 * sz.y * eY;
 532                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 533
 534                 boxA += sz * 0.1;
 535                 boxB -= sz * 0.1;
 536                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 537
 538                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 539                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 540
 541                 return false;
 542         }
 543         return true;
 544 }
 545
 546 string campaign_name_previous;
 547 float campaign_won_previous;
 548 void postMenuDraw() {}
 549 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize);
 550 .entity winnerDialog;
 551 void preMenuDraw()
 552 {
 553         vector fs, sz = '0 0 0', line, mid;
 554
 555         updateCheck();
 556
 557         if(_Nex_ExtResponseSystem_UpdateTo != "" && !(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
 558         {
 559                 // TODO rather turn this into a dialog
 560                 fs = ((1/draw_scale.x) * eX + (1/draw_scale.y) * eY) * 12;
 561                 line = eY * fs.y;
 562                 string l1, l2;
 563                 if(show_propermenu)
 564                         l1 = sprintf("Jeff pay 4 new weapons for %s", _Nex_ExtResponseSystem_UpdateTo);
 565                 else
 566                         l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 567                 l2 = "http://www.xonotic.org/";
 568                 if(_Nex_ExtResponseSystem_UpdateToURL)
 569                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 570
 571                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 572                                 draw_TextWidth(l1, 0, fs),
 573                                 draw_TextWidth(l2, 0, fs)
 574                         );
 575                 sz_y = 3 * fs.y;
 576
 577                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 578                 mid = eX * (0.5 + 0.5 * (1 - sz.x) * cos(time * 0.071))
 579                     + eY * (0.5 + 0.5 * (1 - sz.y) * sin(time * 0.071));
 580
 581                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 582                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 583                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 584         }
 585         if (!campaign_name_previous)
 586                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 587         if(campaign_name == campaign_name_previous)
 588         {
 589                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 590                 {
 591                         if(!campaign_won_previous)
 592                         {
 593                                 m_display();
 594                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 595                         }
 596                         campaign_won_previous = 1;
 597                 }
 598                 else
 599                         campaign_won_previous = 0;
 600         }
 601         else
 602         {
 603                 strcpy(campaign_name_previous, campaign_name);
 604                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 605         }
 606 }
 607
 608 string resolvemod(string m)
 609 {
 610         if(m == "=")
 611                 return getcurrentmod();
 612         else
 613                 return m;
 614 }
 615
 616 float updateCompression()
 617 {
 618         float have_dds, have_jpg, have_tga;
 619         float can_dds;
 620         have_dds = (fexists("dds/particles/particlefont.dds"));
 621         have_jpg = (fexists("particles/particlefont.jpg"));
 622         have_tga = (fexists("particles/particlefont.tga"));
 623         can_dds = GL_Have_TextureCompression();
 624         if(have_dds && (have_jpg || have_tga))
 625         {
 626                 // both? Let's only use good quality precompressed files
 627                 // but ONLY if we actually support it!
 628                 if(can_dds)
 629                 {
 630                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 631                         cvar_set("gl_texturecompression", "0");
 632                         return 1;
 633
 634                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 635                         //return 2;
 636                 }
 637                 else
 638                 {
 639                         cvar_set("gl_texturecompression", "0");
 640                         cvar_set("r_texture_dds_load", "0");
 641                         return 0;
 642                 }
 643         }
 644         else if(have_dds)
 645         {
 646                 // DDS only? We probably always want texture compression
 647                 cvar_set("gl_texturecompression", "1");
 648                 cvar_set("r_texture_dds_load", "1");
 649                 if(!can_dds)
 650                         LOG_INFO(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems."));
 651                 return 0;
 652         }
 653         else
 654         {
 655                 // TGA only? Allow runtime compression
 656                 if(can_dds)
 657                 {
 658                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 659                         return 2;
 660                 }
 661                 else
 662                 {
 663                         cvar_set("gl_texturecompression", "0");
 664                         cvar_set("r_texture_dds_load", "0");
 665                         return 0;
 666                 }
 667         }
 668 }
 669
 670 // note: include only those that should be in the menu!
 671 #define GAMETYPES \
 672         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 673         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 674         GAMETYPE(MAPINFO_TYPE_CTF) \
 675         GAMETYPE(MAPINFO_TYPE_CA) \
 676         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 677         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 678         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 679         GAMETYPE(MAPINFO_TYPE_LMS) \
 680         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 681         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 682         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 683         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 684         /* GAMETYPE(MAPINFO_TYPE_DUEL) */ \
 685         /* GAMETYPE(MAPINFO_TYPE_INVASION) */ \
 686         /**/
 687
 688 // hidden gametypes come last so indexing always works correctly
 689 #define HIDDEN_GAMETYPES \
 690         GAMETYPE(MAPINFO_TYPE_RACE) \
 691         GAMETYPE(MAPINFO_TYPE_CTS) \
 692         /**/
 693
 694 Gametype GameType_GetID(int cnt)
 695 {
 696         int i = 0;
 697         #define GAMETYPE(it) { if (i++ == cnt) return it; }
 698         GAMETYPES
 699         HIDDEN_GAMETYPES
 700         #undef GAMETYPE
 701         return NULL;
 702 }
 703
 704 int GameType_GetCount()
 705 {
 706         int i = 0;
 707         int dev = cvar("developer");
 708         #define GAMETYPE(id) ++i;
 709         GAMETYPES
 710         #undef GAMETYPE
 711         #define GAMETYPE(it) { if (dev > 0) ++i; }
 712         HIDDEN_GAMETYPES
 713         #undef GAMETYPE
 714         return i;
 715 }
 716
 717 int GameType_GetTotalCount()
 718 {
 719         int i = 0;
 720         #define GAMETYPE(id) ++i;
 721         GAMETYPES
 722         HIDDEN_GAMETYPES
 723         #undef GAMETYPE
 724         return i;
 725 }
 726
 727 string GameType_GetName(int cnt)
 728 {
 729         Gametype i = GameType_GetID(cnt);
 730         return i ? MapInfo_Type_ToText(i) : "";
 731 }
 732
 733 string GameType_GetIcon(int cnt)
 734 {
 735         Gametype i = GameType_GetID(cnt);
 736         return i ? strcat("gametype_", MapInfo_Type_ToString(i)) : "";
 737 }
 738
 739 .void(entity) TR;
 740 .void(entity, float, float, entity) TD;
 741 .void(entity, float) TDempty;
 742 .void(entity, float, float) gotoRC;
 743 entity makeXonoticTextLabel(float theAlign, string theText);
 744 entity makeXonoticTextSlider(string);
 745 .void(entity, string, string) addValue;
 746 .void(entity) configureXonoticTextSliderValues;
 747 entity makeXonoticColorpickerString(string theCvar, string theDefaultCvar);
 748 entity makeXonoticCheckBoxString(string, string, string, string);
 749 entity makeXonoticCheckBox(float, string, string);
 750 .bool sendCvars;
 751
 752 void dialog_hudpanel_main_checkbox(entity me, string panelname)
 753 {
 754         entity e;
 755
 756         me.TR(me);
 757                 me.TDempty(me, 1.5);
 758                 me.TD(me, 1, 2.5, e = makeXonoticCheckBox(0, strzone(strcat("hud_panel_", panelname)), _("Enable")));
 759 }
 760
 761 void dialog_hudpanel_main_settings(entity me, string panelname)
 762 {
 763         float i;
 764         entity e;
 765
 766         me.gotoRC(me, me.currentRow + 1.5, 0);
 767                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 768                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 769                                 e.addValue(e, _("Default"), "");
 770                                 e.addValue(e, _("Disable"), "0");
 771                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 772                                 e.configureXonoticTextSliderValues(e);
 773         me.TR(me);
 774                 me.TDempty(me, 0.2);
 775                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 776                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 777                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 778         me.TR(me);
 779                 me.TDempty(me, 0.2);
 780                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 781         me.TR(me);
 782                 me.TDempty(me, 0.2);
 783                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 784                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 785                                 e.addValue(e, _("Default"), "");
 786                                 e.addValue(e, _("Disable"), "0");
 787                                 for(i = 1; i <= 10; ++i)
 788                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 789                                 e.configureXonoticTextSliderValues(e);
 790         me.TR(me);
 791                 me.TDempty(me, 0.2);
 792                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 793                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 794                                 e.addValue(e, _("Default"), "");
 795                                 for(i = 1; i <= 10; ++i)
 796                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 797                                 e.configureXonoticTextSliderValues(e);
 798         me.TR(me);
 799                 me.TDempty(me, 0.2);
 800                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 801                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 802                                 e.addValue(e, _("Default"), "");
 803                                 e.addValue(e, _("Disable"), "0");
 804                                 for(i = 1; i <= 10; ++i)
 805                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 806                                 e.configureXonoticTextSliderValues(e);
 807         me.TR(me);
 808                 me.TDempty(me, 0.4);
 809                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 810         me.TR(me);
 811                 me.TDempty(me, 0.2);
 812                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 813                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 814                                 e.addValue(e, _("Default"), "");
 815                                 for(i = 0; i <= 10; ++i)
 816                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 817                                 e.configureXonoticTextSliderValues(e);
 818 }
 819
 820 float getFadedAlpha(float currentAlpha, float startAlpha, float targetAlpha)
 821 {
 822         if(startAlpha < targetAlpha)
 823                 currentAlpha = min(currentAlpha + frametime * 0.5, targetAlpha);
 824         else
 825                 currentAlpha = max(currentAlpha - frametime * 0.5, targetAlpha);
 826         return currentAlpha;
 827 }
 828
 829 void CheckSendCvars(entity me, string cvarnamestring)
 830 {
 831         if(me.sendCvars)
 832         {
 833                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 834                 {
 835                         LOG_INFOF("Sending cvar: %s -> %s", cvarnamestring, cvar_string(cvarnamestring));
 836                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 837                 }
 838         }
 839 }