qcsrc/menu/xonotic/util.qc

   1 #include "util.qh"
   2 #include "../menu.qh"
   3 #include "../oo/base.qh"
   4 #include "../../common/campaign_common.qh"
   5 #include "../../common/constants.qh"
   6 #include "../../common/mapinfo.qh"
   7 #include "../../common/util.qh"
   8 #include "../../common/command/generic.qh"
   9
  10 float GL_CheckExtension(string ext)
  11 {
  12         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
  13 }
  14
  15 float GL_Have_TextureCompression()
  16 {
  17         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
  18 }
  19
  20 void loadTooltips()
  21 {
  22         tooltipdb = db_load(language_filename("tooltips.db"));
  23 }
  24 void unloadTooltips()
  25 {
  26         if(tooltipdb >= 0)
  27                 db_close(tooltipdb);
  28         tooltipdb = -1;
  29 }
  30 string getZonedTooltipForIdentifier(string s)
  31 {
  32         string t;
  33         if(s == "")
  34                 return string_null;
  35         if(tooltipdb >= 0)
  36         {
  37                 t = db_get(tooltipdb, s);
  38                 if(t == "-")
  39                         return string_null;
  40                 if(t != "")
  41                         return strzone(t);
  42         }
  43         if(prvm_language == "en")
  44         {
  45                 t = cvar_description(s);
  46                 if(t != "" && t != "custom cvar")
  47                         return strzone(t);
  48         }
  49         LOG_TRACE("WARNING: no tooltip set for ", s, "\n");
  50         return string_null;
  51 }
  52
  53 .entity parent, firstChild, nextSibling;
  54 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  55 {
  56         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  57 }
  58
  59 .string cvarName;
  60 void SUB_Null_ee(entity e1, entity e2)
  61 {
  62 }
  63
  64 .void(entity) saveCvars;
  65 void saveCvarsOf(entity ignore, entity e)
  66 {
  67         if(e.saveCvars)
  68                 e.saveCvars(e);
  69 }
  70
  71 .void(entity) loadCvars;
  72 void loadCvarsOf(entity ignore, entity e)
  73 {
  74         if(e.loadCvars)
  75                 e.loadCvars(e);
  76 }
  77 void saveAllCvars(entity root)
  78 {
  79         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  80 }
  81 void loadAllCvars(entity root)
  82 {
  83         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  84 }
  85
  86 .string cvarNames_Multi;
  87 .void(entity me) saveCvars_Multi;
  88 string getCvarsMulti(entity me)
  89 {
  90         if (me.cvarNames_Multi)
  91                 return me.cvarNames_Multi;
  92         return string_null;
  93 }
  94 void saveCvarsMulti(entity me)
  95 {
  96         float n, i;
  97         string s;
  98
  99         me.saveCvars_Multi(me);
 100         s = cvar_string(me.cvarName);
 101
 102         n = tokenize_console(me.cvarNames_Multi);
 103         for(i = 0; i < n; ++i)
 104         {
 105                 if(substring(argv(i), 0, 1) == "!")
 106                         cvar_set(substring(argv(i), 1, strlen(argv(i))), ((s == "0") ? "1" : "0"));
 107                 else
 108                         cvar_set(argv(i), s);
 109
 110                 CheckSendCvars(me, argv(i));
 111         }
 112 }
 113 void makeMulti(entity e, string otherCvars)
 114 {
 115         e.cvarNames_Multi = otherCvars;
 116         e.saveCvars_Multi = e.saveCvars;
 117         e.saveCvars = saveCvarsMulti;
 118 }
 119
 120 .void(entity me) saveCvars_Callback;
 121 .entity saveCvars_Callback_ent;
 122 .void(entity me, entity cb) saveCvars_Callback_func;
 123 void saveCvarsCallback(entity me)
 124 {
 125         me.saveCvars_Callback(me);
 126         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 127 }
 128 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 129 {
 130         e.saveCvars_Callback = e.saveCvars;
 131         e.saveCvars = saveCvarsCallback;
 132         e.saveCvars_Callback_ent = cbent;
 133         e.saveCvars_Callback_func = cbfunc;
 134 }
 135
 136 .void(entity) draw_setDependent;
 137 .string cvar_setDependent;
 138 .float cvarMin_setDependent;
 139 .float cvarMax_setDependent;
 140 .string cvar2_setDependent;
 141 .float cvar2Min_setDependent;
 142 .float cvar2Max_setDependent;
 143 .string cvar3_setDependent;
 144 .float cvar3Min_setDependent;
 145 .float cvar3Max_setDependent;
 146 .float op_setDependent;
 147 .string cvarString_setDependent;
 148 .string cvarValue_setDependent;
 149 .float(entity) func_setDependent;
 150 .bool disabled;
 151 void setDependent_Check(entity e)
 152 {
 153         float f;
 154         string s;
 155         if(e.func_setDependent)
 156         {
 157                 e.disabled = !(e.func_setDependent(e));
 158         }
 159         else if(e.cvarString_setDependent)
 160         {
 161                 s = cvar_string(e.cvarString_setDependent);
 162                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 163         }
 164         else
 165         {
 166                 if(e.cvar_setDependent)
 167                 {
 168                         f = cvar(e.cvar_setDependent);
 169                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 170                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 171                         else
 172                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 173                 }
 174                 if(e.cvar2_setDependent)
 175                 {
 176                         f = cvar(e.cvar2_setDependent);
 177                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 178                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 179                         else
 180                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 181                 }
 182                 if(e.cvar3_setDependent)
 183                 {
 184                         f = cvar(e.cvar3_setDependent);
 185                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 186                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 187                         else
 188                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 189                 }
 190         }
 191 }
 192 void setDependent_Draw(entity e)
 193 {
 194         setDependent_Check(e);
 195         e.draw_setDependent(e);
 196 }
 197 .void(entity) draw;
 198 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 199 {
 200         e.draw_setDependent = e.draw;
 201         e.cvar_setDependent = theCvarName;
 202         e.cvarMin_setDependent = theCvarMin;
 203         e.cvarMax_setDependent = theCvarMax;
 204         e.cvar2_setDependent = string_null;
 205         e.cvar3_setDependent = string_null;
 206         e.func_setDependent = func_null;
 207         e.draw = setDependent_Draw;
 208         setDependent_Check(e);
 209 }
 210 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 211 {
 212         e.draw_setDependent = e.draw;
 213         e.cvarString_setDependent = theCvarName;
 214         e.cvarValue_setDependent = theCvarValue;
 215         e.cvar_setDependent = string_null;
 216         e.cvar2_setDependent = string_null;
 217         e.cvar3_setDependent = string_null;
 218         e.func_setDependent = func_null;
 219         e.draw = setDependent_Draw;
 220         setDependent_Check(e);
 221 }
 222 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 223 {
 224         e.draw_setDependent = e.draw;
 225         e.cvar_setDependent = theCvarName;
 226         e.cvarMin_setDependent = theCvarMin;
 227         e.cvarMax_setDependent = theCvarMax;
 228         e.cvar2_setDependent = theCvar2Name;
 229         e.cvar2Min_setDependent = theCvar2Min;
 230         e.cvar2Max_setDependent = theCvar2Max;
 231         e.cvar3_setDependent = string_null;
 232         e.op_setDependent = 0;
 233         e.func_setDependent = func_null;
 234         e.draw = setDependent_Draw;
 235         setDependent_Check(e);
 236 }
 237 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 238 {
 239         e.draw_setDependent = e.draw;
 240         e.cvar_setDependent = theCvarName;
 241         e.cvarMin_setDependent = theCvarMin;
 242         e.cvarMax_setDependent = theCvarMax;
 243         e.cvar2_setDependent = theCvar2Name;
 244         e.cvar2Min_setDependent = theCvar2Min;
 245         e.cvar2Max_setDependent = theCvar2Max;
 246         e.cvar3_setDependent = string_null;
 247         e.op_setDependent = 1;
 248         e.func_setDependent = func_null;
 249         e.draw = setDependent_Draw;
 250         setDependent_Check(e);
 251 }
 252 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 253 {
 254         e.draw_setDependent = e.draw;
 255         e.cvar_setDependent = theCvarName;
 256         e.cvarMin_setDependent = theCvarMin;
 257         e.cvarMax_setDependent = theCvarMax;
 258         e.cvar2_setDependent = theCvar2Name;
 259         e.cvar2Min_setDependent = theCvar2Min;
 260         e.cvar2Max_setDependent = theCvar2Max;
 261         e.cvar3_setDependent = theCvar3Name;
 262         e.cvar3Min_setDependent = theCvar3Min;
 263         e.cvar3Max_setDependent = theCvar3Max;
 264         e.op_setDependent = 0;
 265         e.func_setDependent = func_null;
 266         e.draw = setDependent_Draw;
 267         setDependent_Check(e);
 268 }
 269 void setDependentWeird(entity e, float(entity) func)
 270 {
 271         e.draw_setDependent = e.draw;
 272         e.func_setDependent = func;
 273         e.draw = setDependent_Draw;
 274         setDependent_Check(e);
 275 }
 276
 277 // URI SYSTEM ////////////////////////////////////////////////////////
 278
 279 float _Nex_ExtResponseSystem_Queried;
 280 string _Nex_ExtResponseSystem_UpdateTo;
 281 string _Nex_ExtResponseSystem_UpdateToURL;
 282 string _Nex_ExtResponseSystem_Packs;
 283 float _Nex_ExtResponseSystem_PacksStep;
 284
 285 void URI_Get_Callback(float id, float status, string data)
 286 {
 287         if(url_URI_Get_Callback(id, status, data))
 288         {
 289                 // handled
 290         }
 291         else if (id == URI_GET_DISCARD)
 292         {
 293                 // discard
 294         }
 295         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 296         {
 297                 // sv_cmd curl
 298                 Curl_URI_Get_Callback(id, status, data);
 299         }
 300         else if (id == URI_GET_UPDATENOTIFICATION)
 301         {
 302                 UpdateNotification_URI_Get_Callback(id, status, data);
 303         }
 304         else
 305         {
 306                 LOG_INFOF("Received HTTP request data for an invalid id %d.\n", id);
 307         }
 308 }
 309
 310 void DisableServerBackwardsCompatibility()
 311 {
 312         cvar_set("gameversion_min", ftos(100 * floor(cvar("gameversion") / 100)));
 313 }
 314
 315 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 316 {
 317         float n;
 318
 319         if(_Nex_ExtResponseSystem_UpdateTo)
 320         {
 321                 LOG_TRACE("error: UpdateNotification_URI_Get_Callback has been called before\n");
 322                 return;
 323         }
 324         if(status != 0)
 325         {
 326                 LOG_TRACEF("error receiving update notification: status is %d\n", status);
 327                 return;
 328         }
 329         if(substring(data, 0, 1) == "<")
 330         {
 331                 LOG_TRACE("error: received HTML instead of an update notification\n");
 332                 return;
 333         }
 334         if(strstrofs(data, "\r", 0) != -1)
 335         {
 336                 LOG_TRACE("error: received carriage returns from update notification server\n");
 337                 return;
 338         }
 339
 340         if(data == "")
 341                 n = 0;
 342         else
 343                 n = tokenizebyseparator(data, "\n");
 344
 345         float i;
 346         string s;
 347
 348         string un_version = "";
 349         string un_download = "";
 350         string un_url = "";
 351         string un_bannedservers = "";
 352         string un_emergency_pk3s = "";
 353         string un_promoted = "";
 354         string un_recommended = "";
 355         string un_compatexpire = "";
 356
 357         for(i = 0; i < n; ++i)
 358         {
 359                 s = substring(argv(i), 2, -1);
 360                 if(s == "") { continue; } // ignore empty lines
 361
 362                 switch(substring(argv(i), 0, 1))
 363                 {
 364                         case "V":
 365                         {
 366                                 un_version = s;
 367                                 break;
 368                         }
 369                         case "C":
 370                         {
 371                                 un_compatexpire = s;
 372                                 break;
 373                         }
 374                         case "D":
 375                         {
 376                                 un_download = s;
 377                                 break;
 378                         }
 379                         case "U":
 380                         {
 381                                 un_url = s;
 382                                 break;
 383                         }
 384                         case "B":
 385                         {
 386                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 387                                 break;
 388                         }
 389                         case "E":
 390                         {
 391                                 if(cvar("menu_updatecheck_getpacks"))
 392                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 393                                 break;
 394                         }
 395                         case "P":
 396                         {
 397                                 APPEND_TO_STRING(un_promoted, " ", s);
 398                                 break;
 399                         }
 400                         case "R":
 401                         {
 402                                 APPEND_TO_STRING(un_recommended, " ", s);
 403                                 break;
 404                         }
 405                 }
 406         }
 407
 408         if(un_version != "")
 409         {
 410                 if(vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 411                 {
 412                         // update needed
 413                         _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 414                         if(un_download) { LOG_INFOF(_("Update can be downloaded at:\n%s\n"), un_download); }
 415                         if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 416                         DisableServerBackwardsCompatibility();
 417                 }
 418                 else if(cvar_string("g_xonoticversion") == un_version)
 419                 {
 420                         if(un_compatexpire != "")
 421                         {
 422                                 string curdate = strftime(false, "%Y%m%d%H%M%S");
 423                                 if (strcmp(curdate, un_compatexpire) >= 0)
 424                                         DisableServerBackwardsCompatibility();
 425                         }
 426                 }
 427         }
 428
 429         if(un_emergency_pk3s != "")
 430         {
 431                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 432                 _Nex_ExtResponseSystem_PacksStep = 1;
 433         }
 434
 435         if(un_promoted != "")
 436         {
 437                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 438                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 439         }
 440
 441         if(un_recommended != "")
 442         {
 443                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 444                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 445         }
 446 }
 447
 448 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 449
 450 void updateCheck()
 451 {
 452         if(cvar("menu_updatecheck"))
 453         {
 454                 if(!_Nex_ExtResponseSystem_Queried)
 455                 {
 456                         _Nex_ExtResponseSystem_Queried = 1;
 457                         float startcnt;
 458                         string uri;
 459
 460                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 461
 462                         // for privacy, munge the start count a little
 463                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 464                         uri = sprintf("http://update.xonotic.org/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 465                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 466                 }
 467         }
 468
 469         if(_Nex_ExtResponseSystem_PacksStep > 0)
 470         {
 471                 float n, i;
 472                 float allgood;
 473                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 474                 allgood = true;
 475                 for(i = 0; i+1 < n; i += 2)
 476                 {
 477                         if(fexists(argv(i+1)))
 478                                 continue;
 479                         allgood = false;
 480                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 481                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 482                 }
 483                 if(allgood)
 484                 {
 485                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 486                         {
 487                                 if(!Menu_Active)
 488                                         cvar_set("_menu_initialized", "0");
 489                                         // HACK: cause m_hide call on next start
 490                                 localcmd("\nmenu_restart\n");
 491                         }
 492                         _Nex_ExtResponseSystem_PacksStep = 0;
 493                 }
 494                 else
 495                         _Nex_ExtResponseSystem_PacksStep = 2;
 496         }
 497
 498 }
 499
 500 float preMenuInit()
 501 {
 502         vector sz;
 503         vector boxA, boxB;
 504
 505         updateCheck();
 506
 507         MapInfo_Cache_Create();
 508         MapInfo_Enumerate();
 509         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 510         {
 511                 draw_reset_cropped();
 512
 513                 sz = eX * 0.025 + eY * 0.025 * (draw_scale.x / draw_scale.y);
 514                 draw_CenterText('0.5 0.5 0' - 1.25 * sz.y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 515
 516                 boxA = '0.05 0.5 0' + 0.25 * sz.y * eY;
 517                 boxB = '0.95 0.5 0' + 1.25 * sz.y * eY;
 518                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 519
 520                 boxA += sz * 0.1;
 521                 boxB -= sz * 0.1;
 522                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 523
 524                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 525                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 526
 527                 return false;
 528         }
 529         return true;
 530 }
 531
 532 string campaign_name_previous;
 533 float campaign_won_previous;
 534 #ifdef WATERMARK
 535 string autocvar_menu_watermark = WATERMARK;
 536 #else
 537 string autocvar_menu_watermark = "";
 538 #endif
 539 void postMenuDraw()
 540 {
 541         if(autocvar_menu_watermark != "")
 542         {
 543                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 544         }
 545 }
 546 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize);
 547 .entity winnerDialog;
 548 void preMenuDraw()
 549 {
 550         vector fs, sz = '0 0 0', line, mid;
 551
 552         updateCheck();
 553
 554         if(_Nex_ExtResponseSystem_UpdateTo != "")
 555         {
 556                 // TODO rather turn this into a dialog
 557                 fs = ((1/draw_scale.x) * eX + (1/draw_scale.y) * eY) * 12;
 558                 line = eY * fs.y;
 559                 string l1, l2;
 560                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 561                 l2 = "http://www.xonotic.org/";
 562                 if(_Nex_ExtResponseSystem_UpdateToURL)
 563                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 564
 565                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 566                                 draw_TextWidth(l1, 0, fs),
 567                                 draw_TextWidth(l2, 0, fs)
 568                         );
 569                 sz_y = 3 * fs.y;
 570
 571                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 572                 mid = eX * (0.5 + 0.5 * (1 - sz.x) * cos(time * 0.071))
 573                     + eY * (0.5 + 0.5 * (1 - sz.y) * sin(time * 0.071));
 574
 575                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 576                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 577                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 578         }
 579         if (!campaign_name_previous)
 580                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 581         if(campaign_name == campaign_name_previous)
 582         {
 583                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 584                 {
 585                         if(!campaign_won_previous)
 586                         {
 587                                 m_display();
 588                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 589                         }
 590                         campaign_won_previous = 1;
 591                 }
 592                 else
 593                         campaign_won_previous = 0;
 594         }
 595         else
 596         {
 597                 strunzone(campaign_name_previous);
 598                 campaign_name_previous = strzone(campaign_name);
 599                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 600         }
 601 }
 602
 603 string resolvemod(string m)
 604 {
 605         if(m == "=")
 606                 return getcurrentmod();
 607         else
 608                 return m;
 609 }
 610
 611 float updateCompression()
 612 {
 613         float have_dds, have_jpg, have_tga;
 614         float can_dds;
 615         have_dds = (fexists("dds/particles/particlefont.dds"));
 616         have_jpg = (fexists("particles/particlefont.jpg"));
 617         have_tga = (fexists("particles/particlefont.tga"));
 618         can_dds = GL_Have_TextureCompression();
 619         if(have_dds && (have_jpg || have_tga))
 620         {
 621                 // both? Let's only use good quality precompressed files
 622                 // but ONLY if we actually support it!
 623                 if(can_dds)
 624                 {
 625                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 626                         cvar_set("gl_texturecompression", "0");
 627                         return 1;
 628
 629                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 630                         //return 2;
 631                 }
 632                 else
 633                 {
 634                         cvar_set("gl_texturecompression", "0");
 635                         cvar_set("r_texture_dds_load", "0");
 636                         return 0;
 637                 }
 638         }
 639         else if(have_dds)
 640         {
 641                 // DDS only? We probably always want texture compression
 642                 cvar_set("gl_texturecompression", "1");
 643                 cvar_set("r_texture_dds_load", "1");
 644                 if(!can_dds)
 645                         LOG_INFO(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 646                 return 0;
 647         }
 648         else
 649         {
 650                 // TGA only? Allow runtime compression
 651                 if(can_dds)
 652                 {
 653                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 654                         return 2;
 655                 }
 656                 else
 657                 {
 658                         cvar_set("gl_texturecompression", "0");
 659                         cvar_set("r_texture_dds_load", "0");
 660                         return 0;
 661                 }
 662         }
 663 }
 664
 665 // note: include only those that should be in the menu!
 666 #define GAMETYPES \
 667         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 668         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 669         GAMETYPE(MAPINFO_TYPE_CTF) \
 670         GAMETYPE(MAPINFO_TYPE_CA) \
 671         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 672         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 673         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 674         GAMETYPE(MAPINFO_TYPE_LMS) \
 675         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 676         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 677         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 678         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 679         if (cvar("developer")) GAMETYPE(MAPINFO_TYPE_RACE) \
 680         GAMETYPE(MAPINFO_TYPE_CTS) \
 681         //GAMETYPE(MAPINFO_TYPE_INVASION) \
 682         /* nothing */
 683
 684 int GameType_GetID(int cnt)
 685 {
 686         int i = 0;
 687
 688         #define GAMETYPE(id) { if (i++ == cnt) return id; }
 689         GAMETYPES
 690         #undef GAMETYPE
 691
 692         unused_float = i;
 693
 694         return 0;
 695 }
 696
 697 int GameType_GetCount()
 698 {
 699         int i = 0;
 700
 701         #define GAMETYPE(id) ++i;
 702         GAMETYPES
 703         #undef GAMETYPE
 704
 705         return i;
 706 }
 707
 708 string GameType_GetName(int cnt)
 709 {
 710         int i = GameType_GetID(cnt);
 711
 712         if(i)
 713                 return MapInfo_Type_ToText(i);
 714
 715         return "";
 716 }
 717
 718 string GameType_GetIcon(int cnt)
 719 {
 720         int i = GameType_GetID(cnt);
 721
 722         if(i)
 723                 return strcat("gametype_", MapInfo_Type_ToString(i));
 724
 725         return "";
 726 }
 727
 728 .void(entity) TR;
 729 .void(entity, float, float, entity) TD;
 730 .void(entity, float) TDempty;
 731 entity makeXonoticTextLabel(float theAlign, string theText);
 732 entity makeXonoticTextSlider(string);
 733 .void(entity, string, string) addValue;
 734 .void(entity) configureXonoticTextSliderValues;
 735 entity makeXonoticColorpickerString(string theCvar, string theDefaultCvar);
 736 entity makeXonoticCheckBoxString(string, string, string, string);
 737 entity makeXonoticCheckBox(float, string, string);
 738 .bool sendCvars;
 739
 740 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 741 {
 742         float i;
 743         entity e;
 744
 745         me.TR(me);
 746                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 747                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 748                                 e.addValue(e, _("Default"), "");
 749                                 e.addValue(e, _("Disable"), "0");
 750                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 751                                 e.configureXonoticTextSliderValues(e);
 752         me.TR(me);
 753                 me.TDempty(me, 0.2);
 754                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 755                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 756                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 757         me.TR(me);
 758                 me.TDempty(me, 0.2);
 759                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 760         me.TR(me);
 761                 me.TDempty(me, 0.2);
 762                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 763                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 764                                 e.addValue(e, _("Default"), "");
 765                                 e.addValue(e, _("Disable"), "0");
 766                                 for(i = 1; i <= 10; ++i)
 767                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 768                                 e.configureXonoticTextSliderValues(e);
 769         me.TR(me);
 770                 me.TDempty(me, 0.2);
 771                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 772                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 773                                 e.addValue(e, _("Default"), "");
 774                                 for(i = 1; i <= 10; ++i)
 775                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 776                                 e.configureXonoticTextSliderValues(e);
 777         me.TR(me);
 778                 me.TDempty(me, 0.2);
 779                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 780                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 781                                 e.addValue(e, _("Default"), "");
 782                                 e.addValue(e, _("Disable"), "0");
 783                                 for(i = 1; i <= 10; ++i)
 784                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 785                                 e.configureXonoticTextSliderValues(e);
 786         me.TR(me);
 787                 me.TDempty(me, 0.4);
 788                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 789         me.TR(me);
 790                 me.TDempty(me, 0.2);
 791                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 792                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 793                                 e.addValue(e, _("Default"), "");
 794                                 for(i = 0; i <= 10; ++i)
 795                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 796                                 e.configureXonoticTextSliderValues(e);
 797 }
 798
 799 float getFadedAlpha(float currentAlpha, float startAlpha, float targetAlpha)
 800 {
 801         if(startAlpha < targetAlpha)
 802                 currentAlpha = min(currentAlpha + frametime * 0.5, targetAlpha);
 803         else
 804                 currentAlpha = max(currentAlpha - frametime * 0.5, targetAlpha);
 805         return currentAlpha;
 806 }
 807
 808 void CheckSendCvars(entity me, string cvarnamestring)
 809 {
 810         if(me.sendCvars)
 811         {
 812                 LOG_INFOF("Sending cvar: %s -> %s\n", cvarnamestring, cvar_string(cvarnamestring));
 813                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 814                 {
 815                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 816                 }
 817         }
 818 }