qcsrc/menu/xonotic/util.qc

   1 #include "util.qh"
   2 #include "dialog.qh"
   3
   4 #include "../item.qh"
   5
   6 #include "../menu.qh"
   7 #include <common/campaign_common.qh>
   8 #include <common/constants.qh>
   9 #include <common/gamemodes/_mod.qh>
  10 #include <common/util.qh>
  11 #include <common/command/_mod.qh>
  12
  13 float GL_CheckExtension(string ext)
  14 {
  15         return strhasword(cvar_string("gl_info_extensions"), ext);
  16 }
  17
  18 float GL_Have_TextureCompression()
  19 {
  20         return GL_CheckExtension("GL_EXT_texture_compression_s3tc");
  21 }
  22
  23 .entity parent, firstChild, nextSibling;
  24 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  25 {
  26         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  27 }
  28
  29 .string controlledCvar;
  30 void SUB_Null_ee(entity e1, entity e2)
  31 {
  32 }
  33
  34 .void(entity) saveCvars;
  35 void saveCvarsOf(entity ignore, entity e)
  36 {
  37         if(e.saveCvars)
  38                 e.saveCvars(e);
  39 }
  40
  41 .void(entity) loadCvars;
  42 void loadCvarsOf(entity ignore, entity e)
  43 {
  44         if(e.loadCvars)
  45                 e.loadCvars(e);
  46 }
  47 void saveAllCvars(entity root)
  48 {
  49         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  50 }
  51 void loadAllCvars(entity root)
  52 {
  53         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  54 }
  55
  56 .string controlledCvars_Multi;
  57 .void(entity me) saveCvars_Multi;
  58 string getCvarsMulti(entity me)
  59 {
  60         if (me.controlledCvars_Multi)
  61                 return me.controlledCvars_Multi;
  62         return string_null;
  63 }
  64 void saveCvarsMulti(entity me)
  65 {
  66         float n, i;
  67         string s, cvarname;
  68
  69         me.saveCvars_Multi(me);
  70         s = cvar_string(me.controlledCvar);
  71
  72         n = tokenize_console(me.controlledCvars_Multi);
  73         for(i = 0; i < n; ++i)
  74         {
  75                 // cvars prefixed with ! get saved with the inverted value
  76                 if(substring(argv(i), 0, 1) == "!")
  77                 {
  78                         cvarname = substring(argv(i), 1, strlen(argv(i)));
  79                         cvar_set(cvarname, ((s == "0") ? "1" : "0"));
  80                 }
  81                 else
  82                 {
  83                         cvarname = argv(i);
  84                         cvar_set(cvarname, s);
  85                 }
  86
  87                 CheckSendCvars(me, cvarname);
  88         }
  89 }
  90 void makeMulti(entity e, string otherCvars)
  91 {
  92         e.controlledCvars_Multi = otherCvars;
  93         e.saveCvars_Multi = e.saveCvars;
  94         e.saveCvars = saveCvarsMulti;
  95 }
  96
  97 .void(entity me) saveCvars_Callback;
  98 .entity saveCvars_Callback_ent;
  99 .void(entity me, entity cb) saveCvars_Callback_func;
 100 void saveCvarsCallback(entity me)
 101 {
 102         me.saveCvars_Callback(me);
 103         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 104 }
 105 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 106 {
 107         e.saveCvars_Callback = e.saveCvars;
 108         e.saveCvars = saveCvarsCallback;
 109         e.saveCvars_Callback_ent = cbent;
 110         e.saveCvars_Callback_func = cbfunc;
 111 }
 112
 113 .void(entity) draw_setDependent;
 114 .string cvar_setDependent;
 115 .float cvarMin_setDependent;
 116 .float cvarMax_setDependent;
 117 .string cvar2_setDependent;
 118 .float cvar2Min_setDependent;
 119 .float cvar2Max_setDependent;
 120 .string cvar3_setDependent;
 121 .float cvar3Min_setDependent;
 122 .float cvar3Max_setDependent;
 123 .float op_setDependent;
 124 .string cvarString_setDependent;
 125 .string cvarValue_setDependent;
 126 .float(entity) func_setDependent;
 127 .bool disabled;
 128 void setDependent_Check(entity e)
 129 {
 130         bool disabled_prev = e.disabled;
 131         float f;
 132         string s;
 133         if(e.func_setDependent)
 134         {
 135                 e.disabled = !(e.func_setDependent(e));
 136         }
 137         else if(e.cvarString_setDependent)
 138         {
 139                 s = cvar_string(e.cvarString_setDependent);
 140                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 141         }
 142         else
 143         {
 144                 if(e.cvar_setDependent)
 145                 {
 146                         f = cvar(e.cvar_setDependent);
 147                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 148                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 149                         else
 150                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 151                 }
 152                 if(e.cvar2_setDependent)
 153                 {
 154                         f = cvar(e.cvar2_setDependent);
 155                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 156                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 157                         else
 158                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 159                 }
 160                 if(e.cvar3_setDependent)
 161                 {
 162                         f = cvar(e.cvar3_setDependent);
 163                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 164                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 165                         else
 166                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 167                 }
 168         }
 169         if (disabled_prev != e.disabled && e.loadCvars)
 170                 e.loadCvars(e);
 171 }
 172 void setDependent_Draw(entity e)
 173 {
 174         setDependent_Check(e);
 175         e.draw_setDependent(e);
 176 }
 177 .void(entity) draw;
 178 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 179 {
 180         e.draw_setDependent = e.draw;
 181         e.cvar_setDependent = theCvarName;
 182         e.cvarMin_setDependent = theCvarMin;
 183         e.cvarMax_setDependent = theCvarMax;
 184         e.cvar2_setDependent = string_null;
 185         e.cvar3_setDependent = string_null;
 186         e.func_setDependent = func_null;
 187         e.draw = setDependent_Draw;
 188         setDependent_Check(e);
 189 }
 190 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 191 {
 192         e.draw_setDependent = e.draw;
 193         e.cvarString_setDependent = theCvarName;
 194         e.cvarValue_setDependent = theCvarValue;
 195         e.cvar_setDependent = string_null;
 196         e.cvar2_setDependent = string_null;
 197         e.cvar3_setDependent = string_null;
 198         e.func_setDependent = func_null;
 199         e.draw = setDependent_Draw;
 200         setDependent_Check(e);
 201 }
 202 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 203 {
 204         e.draw_setDependent = e.draw;
 205         e.cvar_setDependent = theCvarName;
 206         e.cvarMin_setDependent = theCvarMin;
 207         e.cvarMax_setDependent = theCvarMax;
 208         e.cvar2_setDependent = theCvar2Name;
 209         e.cvar2Min_setDependent = theCvar2Min;
 210         e.cvar2Max_setDependent = theCvar2Max;
 211         e.cvar3_setDependent = string_null;
 212         e.op_setDependent = 0;
 213         e.func_setDependent = func_null;
 214         e.draw = setDependent_Draw;
 215         setDependent_Check(e);
 216 }
 217 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 218 {
 219         e.draw_setDependent = e.draw;
 220         e.cvar_setDependent = theCvarName;
 221         e.cvarMin_setDependent = theCvarMin;
 222         e.cvarMax_setDependent = theCvarMax;
 223         e.cvar2_setDependent = theCvar2Name;
 224         e.cvar2Min_setDependent = theCvar2Min;
 225         e.cvar2Max_setDependent = theCvar2Max;
 226         e.cvar3_setDependent = string_null;
 227         e.op_setDependent = 1;
 228         e.func_setDependent = func_null;
 229         e.draw = setDependent_Draw;
 230         setDependent_Check(e);
 231 }
 232 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 233 {
 234         e.draw_setDependent = e.draw;
 235         e.cvar_setDependent = theCvarName;
 236         e.cvarMin_setDependent = theCvarMin;
 237         e.cvarMax_setDependent = theCvarMax;
 238         e.cvar2_setDependent = theCvar2Name;
 239         e.cvar2Min_setDependent = theCvar2Min;
 240         e.cvar2Max_setDependent = theCvar2Max;
 241         e.cvar3_setDependent = theCvar3Name;
 242         e.cvar3Min_setDependent = theCvar3Min;
 243         e.cvar3Max_setDependent = theCvar3Max;
 244         e.op_setDependent = 0;
 245         e.func_setDependent = func_null;
 246         e.draw = setDependent_Draw;
 247         setDependent_Check(e);
 248 }
 249 void setDependentWeird(entity e, float(entity) func)
 250 {
 251         e.draw_setDependent = e.draw;
 252         e.func_setDependent = func;
 253         e.draw = setDependent_Draw;
 254         setDependent_Check(e);
 255 }
 256
 257 void setZonedTooltip(entity e, string theTooltip, string theCvar)
 258 {
 259         if(theTooltip == "") // no tooltip, use cvar description then
 260         {
 261                 if(theCvar != "" && prvm_language == "en")
 262                 {
 263                         string t = cvar_description(theCvar);
 264                         if(t != "" && t != "custom cvar")
 265                                 theTooltip = t;
 266                 }
 267         }
 268         else if(theTooltip == "-") // no cvar description as tooltip
 269         {
 270                 theTooltip = string_null;
 271         }
 272
 273         strfree(e.tooltip);
 274         e.tooltip = (theTooltip != "") ? strzone(theTooltip) : string_null;
 275 }
 276
 277 void clearTooltip(entity e)
 278 {
 279         setZonedTooltip(e, string_null, string_null);
 280 }
 281
 282 // URI SYSTEM ////////////////////////////////////////////////////////
 283
 284 float _Nex_ExtResponseSystem_Queried;
 285 string _Nex_ExtResponseSystem_UpdateTo;
 286 string _Nex_ExtResponseSystem_UpdateToURL;
 287 string _Nex_ExtResponseSystem_Packs;
 288 float _Nex_ExtResponseSystem_PacksStep;
 289
 290 /** engine callback */
 291 void URI_Get_Callback(float id, float status, string data)
 292 {
 293         if(url_URI_Get_Callback(id, status, data))
 294         {
 295                 // handled
 296         }
 297         else if (id == URI_GET_DISCARD)
 298         {
 299                 // discard
 300         }
 301         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 302         {
 303                 // sv_cmd curl
 304                 Curl_URI_Get_Callback(id, status, data);
 305         }
 306         else if (id == URI_GET_UPDATENOTIFICATION)
 307         {
 308                 UpdateNotification_URI_Get_Callback(id, status, data);
 309         }
 310         else
 311         {
 312                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
 313         }
 314 }
 315
 316 void DisableServerBackwardsCompatibility()
 317 {
 318         cvar_set("gameversion_min", ftos(100 * floor(cvar("gameversion") / 100)));
 319 }
 320
 321 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 322 {
 323         float n;
 324
 325         if(_Nex_ExtResponseSystem_UpdateTo)
 326         {
 327                 LOG_TRACE("error: UpdateNotification_URI_Get_Callback has been called before");
 328                 return;
 329         }
 330         if(status != 0)
 331         {
 332                 LOG_TRACEF("error receiving update notification: status is %d", status);
 333                 return;
 334         }
 335         if(substring(data, 0, 1) == "<")
 336         {
 337                 LOG_TRACE("error: received HTML instead of an update notification");
 338                 return;
 339         }
 340         if(strstrofs(data, "\r", 0) != -1)
 341         {
 342                 LOG_TRACE("error: received carriage returns from update notification server");
 343                 return;
 344         }
 345
 346         if(data == "")
 347                 n = 0;
 348         else
 349                 n = tokenizebyseparator(data, "\n");
 350
 351         float i;
 352         string s;
 353
 354         string un_version = "";
 355         string un_tosversion = "";
 356         string un_download = "";
 357         string un_url = "";
 358         string un_bannedservers = "";
 359         string un_emergency_pk3s = "";
 360         string un_promoted = "";
 361         string un_recommended = "";
 362         string un_compatexpire = "";
 363
 364         for(i = 0; i < n; ++i)
 365         {
 366                 s = substring(argv(i), 2, -1);
 367                 if(s == "") { continue; } // ignore empty lines
 368
 369                 switch(substring(argv(i), 0, 1))
 370                 {
 371                         case "V":
 372                         {
 373                                 un_version = s;
 374                                 break;
 375                         }
 376                         case "T":
 377                         {
 378                                 un_tosversion = s;
 379                                 break;
 380                         }
 381                         case "C":
 382                         {
 383                                 un_compatexpire = s;
 384                                 break;
 385                         }
 386                         case "D":
 387                         {
 388                                 un_download = s;
 389                                 break;
 390                         }
 391                         case "U":
 392                         {
 393                                 un_url = s;
 394                                 break;
 395                         }
 396                         case "B":
 397                         {
 398                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 399                                 break;
 400                         }
 401                         case "E":
 402                         {
 403                                 if(cvar("menu_updatecheck_getpacks"))
 404                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 405                                 break;
 406                         }
 407                         case "P":
 408                         {
 409                                 APPEND_TO_STRING(un_promoted, " ", s);
 410                                 break;
 411                         }
 412                         case "R":
 413                         {
 414                                 APPEND_TO_STRING(un_recommended, " ", s);
 415                                 break;
 416                         }
 417                 }
 418         }
 419
 420         if(un_version != "")
 421         {
 422                 if(vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 423                 {
 424                         // update needed
 425                         _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 426                         if(un_download) { LOG_INFO(_("Update can be downloaded at:"), "\n", un_download); }
 427                         if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 428                         DisableServerBackwardsCompatibility();
 429                 }
 430                 else if(cvar_string("g_xonoticversion") == un_version)
 431                 {
 432                         if(un_compatexpire != "")
 433                         {
 434                                 string curdate = strftime(false, "%Y%m%d%H%M%S");
 435                                 if (strcmp(curdate, un_compatexpire) >= 0)
 436                                         DisableServerBackwardsCompatibility();
 437                         }
 438                 }
 439         }
 440
 441         if(un_tosversion != "")
 442         {
 443                 _Nex_ExtResponseSystem_NewToS = stof(un_tosversion);
 444         }
 445
 446         if(un_bannedservers != "")
 447         {
 448                 _Nex_ExtResponseSystem_BannedServers = strzone(un_bannedservers);
 449                 _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 1;
 450         }
 451
 452         if(un_emergency_pk3s != "")
 453         {
 454                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 455                 _Nex_ExtResponseSystem_PacksStep = 1;
 456         }
 457
 458         if(un_promoted != "")
 459         {
 460                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 461                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 462         }
 463
 464         if(un_recommended != "")
 465         {
 466                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 467                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 468         }
 469 }
 470
 471 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 472
 473 void updateCheck()
 474 {
 475         if(!_Nex_ExtResponseSystem_Queried)
 476         {
 477                 _Nex_ExtResponseSystem_Queried = 1;
 478                 cvar_set("cl_startcount", ftos(cvar("cl_startcount") + 1));
 479                 uri_get("http://update.xonotic.org/checkupdate.txt", URI_GET_UPDATENOTIFICATION);
 480         }
 481
 482         if(_Nex_ExtResponseSystem_PacksStep > 0)
 483         {
 484                 float n, i;
 485                 float allgood;
 486                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 487                 allgood = true;
 488                 for(i = 0; i+1 < n; i += 2)
 489                 {
 490                         if(fexists(argv(i+1)))
 491                                 continue;
 492                         allgood = false;
 493                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 494                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 495                 }
 496                 if(allgood)
 497                 {
 498                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 499                         {
 500                                 if(!Menu_Active)
 501                                         cvar_set("_menu_initialized", "0");
 502                                         // HACK: cause m_hide call on next start
 503                                 localcmd("\nmenu_restart\n");
 504                         }
 505                         _Nex_ExtResponseSystem_PacksStep = 0;
 506                 }
 507                 else
 508                         _Nex_ExtResponseSystem_PacksStep = 2;
 509         }
 510
 511 }
 512
 513 bool show_propermenu = false;
 514
 515 float preMenuInit()
 516 {
 517         vector sz;
 518         vector boxA, boxB;
 519
 520         if(random() < 0.1)
 521                 show_propermenu = true;
 522
 523         updateCheck();
 524
 525         MapInfo_Cache_Create();
 526         MapInfo_Enumerate();
 527         if(!_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 528         {
 529                 draw_reset_cropped();
 530
 531                 sz = eX * 0.025 + eY * 0.025 * (draw_scale.x / draw_scale.y);
 532                 draw_CenterText('0.5 0.5 0' - 1.25 * sz.y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 533
 534                 boxA = '0.05 0.5 0' + 0.25 * sz.y * eY;
 535                 boxB = '0.95 0.5 0' + 1.25 * sz.y * eY;
 536                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 537
 538                 boxA += sz * 0.1;
 539                 boxB -= sz * 0.1;
 540                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 541
 542                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 543                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 544
 545                 return false;
 546         }
 547         return true;
 548 }
 549
 550 string campaign_name_previous;
 551 float campaign_won_previous;
 552 void postMenuDraw() {}
 553 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize);
 554 .entity winnerDialog;
 555 void preMenuDraw()
 556 {
 557         vector fs, sz = '0 0 0', line, mid;
 558
 559         updateCheck();
 560
 561         if(_Nex_ExtResponseSystem_UpdateTo != "" && !(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
 562         {
 563                 // TODO rather turn this into a dialog
 564                 fs = ((1/draw_scale.x) * eX + (1/draw_scale.y) * eY) * 12;
 565                 line = eY * fs.y;
 566                 string l1, l2;
 567                 if(show_propermenu)
 568                         l1 = sprintf("Jeff pay 4 new weapons for %s", _Nex_ExtResponseSystem_UpdateTo);
 569                 else
 570                         l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 571                 l2 = "http://www.xonotic.org/";
 572                 if(_Nex_ExtResponseSystem_UpdateToURL)
 573                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 574
 575                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 576                                 draw_TextWidth(l1, 0, fs),
 577                                 draw_TextWidth(l2, 0, fs)
 578                         );
 579                 sz_y = 3 * fs.y;
 580
 581                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 582                 mid = eX * (0.5 + 0.5 * (1 - sz.x) * cos(time * 0.071))
 583                     + eY * (0.5 + 0.5 * (1 - sz.y) * sin(time * 0.071));
 584
 585                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 586                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 587                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 588         }
 589
 590         if (!campaign_name_previous)
 591                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 592         if(campaign_name == campaign_name_previous)
 593         {
 594                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 595                 {
 596                         if(!campaign_won_previous)
 597                         {
 598                                 m_display();
 599                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 600                         }
 601                         campaign_won_previous = 1;
 602                 }
 603                 else
 604                         campaign_won_previous = 0;
 605         }
 606         else
 607         {
 608                 strcpy(campaign_name_previous, campaign_name);
 609                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 610         }
 611 }
 612
 613 string resolvemod(string m)
 614 {
 615         if(m == "=")
 616                 return getcurrentmod();
 617         else
 618                 return m;
 619 }
 620
 621 float updateCompression()
 622 {
 623         float have_dds, have_jpg, have_tga;
 624         float can_dds;
 625         have_dds = (fexists("dds/particles/particlefont.dds"));
 626         have_jpg = (fexists("particles/particlefont.jpg"));
 627         have_tga = (fexists("particles/particlefont.tga"));
 628         can_dds = GL_Have_TextureCompression();
 629         if(have_dds && (have_jpg || have_tga))
 630         {
 631                 // both? Let's only use good quality precompressed files
 632                 // but ONLY if we actually support it!
 633                 if(can_dds)
 634                 {
 635                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 636                         cvar_set("gl_texturecompression", "0");
 637                         return 1;
 638
 639                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 640                         //return 2;
 641                 }
 642                 else
 643                 {
 644                         cvar_set("gl_texturecompression", "0");
 645                         cvar_set("r_texture_dds_load", "0");
 646                         return 0;
 647                 }
 648         }
 649         else if(have_dds)
 650         {
 651                 // DDS only? We probably always want texture compression
 652                 cvar_set("gl_texturecompression", "1");
 653                 cvar_set("r_texture_dds_load", "1");
 654                 if(!can_dds)
 655                         LOG_INFO(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems."));
 656                 return 0;
 657         }
 658         else
 659         {
 660                 // TGA only? Allow runtime compression
 661                 if(can_dds)
 662                 {
 663                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 664                         return 2;
 665                 }
 666                 else
 667                 {
 668                         cvar_set("gl_texturecompression", "0");
 669                         cvar_set("r_texture_dds_load", "0");
 670                         return 0;
 671                 }
 672         }
 673 }
 674
 675 // note: include only those that should be in the menu!
 676 #define GAMETYPES \
 677         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 678         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 679         GAMETYPE(MAPINFO_TYPE_CTF) \
 680         GAMETYPE(MAPINFO_TYPE_CA) \
 681         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 682         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 683         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 684         GAMETYPE(MAPINFO_TYPE_LMS) \
 685         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 686         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 687         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 688         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 689         /* GAMETYPE(MAPINFO_TYPE_DUEL) */ \
 690         /* GAMETYPE(MAPINFO_TYPE_INVASION) */ \
 691         /**/
 692
 693 // hidden gametypes come last so indexing always works correctly
 694 #define HIDDEN_GAMETYPES \
 695         GAMETYPE(MAPINFO_TYPE_RACE) \
 696         GAMETYPE(MAPINFO_TYPE_CTS) \
 697         /**/
 698
 699 Gametype GameType_GetID(int cnt)
 700 {
 701         int i = 0;
 702         #define GAMETYPE(it) { if (i++ == cnt) return it; }
 703         GAMETYPES
 704         HIDDEN_GAMETYPES
 705         #undef GAMETYPE
 706         return NULL;
 707 }
 708
 709 int GameType_GetCount()
 710 {
 711         int i = 0;
 712         int dev = cvar("developer");
 713         #define GAMETYPE(id) ++i;
 714         GAMETYPES
 715         #undef GAMETYPE
 716         #define GAMETYPE(it) { if (dev > 0) ++i; }
 717         HIDDEN_GAMETYPES
 718         #undef GAMETYPE
 719         return i;
 720 }
 721
 722 int GameType_GetTotalCount()
 723 {
 724         int i = 0;
 725         #define GAMETYPE(id) ++i;
 726         GAMETYPES
 727         HIDDEN_GAMETYPES
 728         #undef GAMETYPE
 729         return i;
 730 }
 731
 732 string GameType_GetName(int cnt)
 733 {
 734         Gametype i = GameType_GetID(cnt);
 735         return i ? MapInfo_Type_ToText(i) : "";
 736 }
 737
 738 string GameType_GetIcon(int cnt)
 739 {
 740         Gametype i = GameType_GetID(cnt);
 741         return i ? strcat("gametype_", MapInfo_Type_ToString(i)) : "";
 742 }
 743
 744 .void(entity) TR;
 745 .void(entity, float, float, entity) TD;
 746 .void(entity, float) TDempty;
 747 .void(entity, float, float) gotoRC;
 748 entity makeXonoticTextLabel(float theAlign, string theText);
 749 entity makeXonoticTextSlider(string);
 750 .void(entity, string, string) addValue;
 751 .void(entity) configureXonoticTextSliderValues;
 752 entity makeXonoticColorpickerString(string theCvar, string theDefaultCvar);
 753 entity makeXonoticCheckBoxString(string, string, string, string);
 754 entity makeXonoticCheckBox(float, string, string);
 755 .bool sendCvars;
 756
 757 void dialog_hudpanel_main_checkbox(entity me, string panelname)
 758 {
 759         entity e;
 760
 761         me.TR(me);
 762                 me.TDempty(me, 1.5);
 763                 me.TD(me, 1, 2.5, e = makeXonoticCheckBox(0, strzone(strcat("hud_panel_", panelname)), _("Enable")));
 764 }
 765
 766 void dialog_hudpanel_main_settings(entity me, string panelname)
 767 {
 768         float i;
 769         entity e;
 770
 771         me.gotoRC(me, me.currentRow + 1.5, 0);
 772                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 773                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 774                                 e.addValue(e, _("Default"), "");
 775                                 e.addValue(e, _("Disable"), "0");
 776                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 777                                 e.configureXonoticTextSliderValues(e);
 778         me.TR(me);
 779                 me.TDempty(me, 0.2);
 780                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 781                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 782                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 783         me.TR(me);
 784                 me.TDempty(me, 0.2);
 785                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 786         me.TR(me);
 787                 me.TDempty(me, 0.2);
 788                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 789                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 790                                 e.addValue(e, _("Default"), "");
 791                                 e.addValue(e, _("Disable"), "0");
 792                                 for(i = 1; i <= 10; ++i)
 793                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 794                                 e.configureXonoticTextSliderValues(e);
 795         me.TR(me);
 796                 me.TDempty(me, 0.2);
 797                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 798                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 799                                 e.addValue(e, _("Default"), "");
 800                                 for(i = 1; i <= 10; ++i)
 801                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 802                                 e.configureXonoticTextSliderValues(e);
 803         me.TR(me);
 804                 me.TDempty(me, 0.2);
 805                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 806                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 807                                 e.addValue(e, _("Default"), "");
 808                                 e.addValue(e, _("Disable"), "0");
 809                                 for(i = 1; i <= 10; ++i)
 810                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 811                                 e.configureXonoticTextSliderValues(e);
 812         me.TR(me);
 813                 me.TDempty(me, 0.4);
 814                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 815         me.TR(me);
 816                 me.TDempty(me, 0.2);
 817                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 818                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 819                                 e.addValue(e, _("Default"), "");
 820                                 for(i = 0; i <= 10; ++i)
 821                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 822                                 e.configureXonoticTextSliderValues(e);
 823 }
 824
 825 bool isServerSingleplayer()
 826 {
 827         return (cvar_string("net_address") == "127.0.0.1" && cvar_string("net_address_ipv6") == "::1");
 828 }
 829
 830 void makeServerSingleplayer()
 831 {
 832         // it doesn't allow clients to connect from different machines
 833         localcmd("defer 0.1 \"sv_cmd settemp net_address 127.0.0.1\"\n");
 834         localcmd("defer 0.1 \"sv_cmd settemp net_address_ipv6 ::1\"\n");
 835 }
 836
 837 float getFadedAlpha(float currentAlpha, float startAlpha, float targetAlpha)
 838 {
 839         if(startAlpha < targetAlpha)
 840                 currentAlpha = min(currentAlpha + frametime * 0.5, targetAlpha);
 841         else
 842                 currentAlpha = max(currentAlpha - frametime * 0.5, targetAlpha);
 843         return currentAlpha;
 844 }
 845
 846 void CheckSendCvars(entity me, string cvarnamestring)
 847 {
 848         if(me.sendCvars)
 849         {
 850                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 851                 {
 852                         LOG_INFOF("Sending cvar: %s -> %s", cvarnamestring, cvar_string(cvarnamestring));
 853                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 854                 }
 855         }
 856 }