qcsrc/menu/xonotic/util.qc

   1 float GL_CheckExtension(string ext)
   2 {
   3         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
   4 }
   5
   6 float GL_Have_TextureCompression()
   7 {
   8         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
   9 }
  10
  11 void loadTooltips()
  12 {
  13         tooltipdb = db_load(language_filename("tooltips.db"));
  14 }
  15 void unloadTooltips()
  16 {
  17         if(tooltipdb >= 0)
  18                 db_close(tooltipdb);
  19         tooltipdb = -1;
  20 }
  21 string getZonedTooltipForIdentifier(string s)
  22 {
  23         string t;
  24         if(s == "")
  25                 return string_null;
  26         if(tooltipdb >= 0)
  27         {
  28                 t = db_get(tooltipdb, s);
  29                 if(t == "-")
  30                         return string_null;
  31                 if(t != "")
  32                         return strzone(t);
  33         }
  34         if(prvm_language == "en" || prvm_language == "")
  35         {
  36                 t = cvar_description(s);
  37                 if(t != "" && t != "custom cvar")
  38                         return strzone(t);
  39         }
  40         dprint("WARNING: no tooltip set for ", s, "\n");
  41         return string_null;
  42 }
  43
  44 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  45 {
  46         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  47 }
  48
  49 .string cvarName;
  50 void SUB_Null_ee(entity e1, entity e2)
  51 {
  52 }
  53 void saveCvarsOf(entity ignore, entity e)
  54 {
  55         if(e.saveCvars)
  56                 e.saveCvars(e);
  57 }
  58 void loadCvarsOf(entity ignore, entity e)
  59 {
  60         if(e.loadCvars)
  61                 e.loadCvars(e);
  62 }
  63 void saveAllCvars(entity root)
  64 {
  65         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  66 }
  67 void loadAllCvars(entity root)
  68 {
  69         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  70 }
  71
  72 .string cvarNames_Multi;
  73 .void(entity me) saveCvars_Multi;
  74 string getCvarsMulti(entity me)
  75 {
  76         if (me.cvarNames_Multi)
  77                 return me.cvarNames_Multi;
  78         return string_null;
  79 }
  80 void saveCvarsMulti(entity me)
  81 {
  82         float n, i;
  83         string s;
  84
  85         me.saveCvars_Multi(me);
  86         s = cvar_string(me.cvarName);
  87
  88         n = tokenize_console(me.cvarNames_Multi);
  89         for(i = 0; i < n; ++i)
  90                 cvar_set(argv(i), s);
  91 }
  92 void makeMulti(entity e, string otherCvars)
  93 {
  94         e.cvarNames_Multi = otherCvars;
  95         e.saveCvars_Multi = e.saveCvars;
  96         e.saveCvars = saveCvarsMulti;
  97 }
  98
  99 .void(entity me) saveCvars_Callback;
 100 .entity saveCvars_Callback_ent;
 101 .void(entity me, entity cb) saveCvars_Callback_func;
 102 void saveCvarsCallback(entity me)
 103 {
 104         me.saveCvars_Callback(me);
 105         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 106 }
 107 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 108 {
 109         e.saveCvars_Callback = e.saveCvars;
 110         e.saveCvars = saveCvarsCallback;
 111         e.saveCvars_Callback_ent = cbent;
 112         e.saveCvars_Callback_func = cbfunc;
 113 }
 114
 115 .void(entity) draw_setDependent;
 116 .string cvar_setDependent;
 117 .float cvarMin_setDependent;
 118 .float cvarMax_setDependent;
 119 .string cvar2_setDependent;
 120 .float cvar2Min_setDependent;
 121 .float cvar2Max_setDependent;
 122 .string cvar3_setDependent;
 123 .float cvar3Min_setDependent;
 124 .float cvar3Max_setDependent;
 125 .float op_setDependent;
 126 .string cvarString_setDependent;
 127 .string cvarValue_setDependent;
 128 .float(entity) func_setDependent;
 129 void setDependent_Check(entity e)
 130 {
 131         float f;
 132         string s;
 133         if(e.func_setDependent)
 134         {
 135                 e.disabled = !(e.func_setDependent(e));
 136         }
 137         else if(e.cvarString_setDependent)
 138         {
 139                 s = cvar_string(e.cvarString_setDependent);
 140                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 141         }
 142         else
 143         {
 144                 if(e.cvar_setDependent)
 145                 {
 146                         f = cvar(e.cvar_setDependent);
 147                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 148                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 149                         else
 150                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 151                 }
 152                 if(e.cvar2_setDependent)
 153                 {
 154                         f = cvar(e.cvar2_setDependent);
 155                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 156                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 157                         else
 158                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 159                 }
 160                 if(e.cvar3_setDependent)
 161                 {
 162                         f = cvar(e.cvar3_setDependent);
 163                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 164                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 165                         else
 166                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 167                 }
 168         }
 169 }
 170 void setDependent_Draw(entity e)
 171 {
 172         setDependent_Check(e);
 173         e.draw_setDependent(e);
 174 }
 175 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 176 {
 177         e.draw_setDependent = e.draw;
 178         e.cvar_setDependent = theCvarName;
 179         e.cvarMin_setDependent = theCvarMin;
 180         e.cvarMax_setDependent = theCvarMax;
 181         e.cvar2_setDependent = string_null;
 182         e.cvar3_setDependent = string_null;
 183         e.func_setDependent = func_null;
 184         e.draw = setDependent_Draw;
 185         setDependent_Check(e);
 186 }
 187 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 188 {
 189         e.draw_setDependent = e.draw;
 190         e.cvarString_setDependent = theCvarName;
 191         e.cvarValue_setDependent = theCvarValue;
 192         e.cvar_setDependent = string_null;
 193         e.cvar2_setDependent = string_null;
 194         e.cvar3_setDependent = string_null;
 195         e.func_setDependent = func_null;
 196         e.draw = setDependent_Draw;
 197         setDependent_Check(e);
 198 }
 199 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 200 {
 201         e.draw_setDependent = e.draw;
 202         e.cvar_setDependent = theCvarName;
 203         e.cvarMin_setDependent = theCvarMin;
 204         e.cvarMax_setDependent = theCvarMax;
 205         e.cvar2_setDependent = theCvar2Name;
 206         e.cvar2Min_setDependent = theCvar2Min;
 207         e.cvar2Max_setDependent = theCvar2Max;
 208         e.cvar3_setDependent = string_null;
 209         e.op_setDependent = 0;
 210         e.func_setDependent = func_null;
 211         e.draw = setDependent_Draw;
 212         setDependent_Check(e);
 213 }
 214 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 215 {
 216         e.draw_setDependent = e.draw;
 217         e.cvar_setDependent = theCvarName;
 218         e.cvarMin_setDependent = theCvarMin;
 219         e.cvarMax_setDependent = theCvarMax;
 220         e.cvar2_setDependent = theCvar2Name;
 221         e.cvar2Min_setDependent = theCvar2Min;
 222         e.cvar2Max_setDependent = theCvar2Max;
 223         e.cvar3_setDependent = string_null;
 224         e.op_setDependent = 1;
 225         e.func_setDependent = func_null;
 226         e.draw = setDependent_Draw;
 227         setDependent_Check(e);
 228 }
 229 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 230 {
 231         e.draw_setDependent = e.draw;
 232         e.cvar_setDependent = theCvarName;
 233         e.cvarMin_setDependent = theCvarMin;
 234         e.cvarMax_setDependent = theCvarMax;
 235         e.cvar2_setDependent = theCvar2Name;
 236         e.cvar2Min_setDependent = theCvar2Min;
 237         e.cvar2Max_setDependent = theCvar2Max;
 238         e.cvar3_setDependent = theCvar3Name;
 239         e.cvar3Min_setDependent = theCvar3Min;
 240         e.cvar3Max_setDependent = theCvar3Max;
 241         e.op_setDependent = 0;
 242         e.func_setDependent = func_null;
 243         e.draw = setDependent_Draw;
 244         setDependent_Check(e);
 245 }
 246 void setDependentWeird(entity e, float(entity) func)
 247 {
 248         e.draw_setDependent = e.draw;
 249         e.func_setDependent = func;
 250         e.draw = setDependent_Draw;
 251         setDependent_Check(e);
 252 }
 253
 254 // URI SYSTEM ////////////////////////////////////////////////////////
 255
 256 float _Nex_ExtResponseSystem_Queried;
 257 string _Nex_ExtResponseSystem_UpdateTo;
 258 string _Nex_ExtResponseSystem_UpdateToURL;
 259
 260 void URI_Get_Callback(float id, float status, string data)
 261 {
 262         if (id == URI_GET_DISCARD)
 263         {
 264                 // discard
 265         }
 266         else if(id == URI_GET_UPDATENOTIFICATION)
 267         {
 268                 UpdateNotification_URI_Get_Callback(id, status, data);
 269         }
 270         else if(id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 271         {
 272                 Curl_URI_Get_Callback(id, status, data);
 273         }
 274         else
 275         {
 276                 print(sprintf(_("Received HTTP request data for an invalid id %d.\n"), id));
 277         }
 278 }
 279
 280 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 281 {
 282         float n;
 283
 284         if(_Nex_ExtResponseSystem_UpdateTo)
 285         {
 286                 dprint("error: UpdateNotification_URI_Get_Callback has been called before\n");
 287                 return;
 288         }
 289         if(status != 0)
 290         {
 291                 print(sprintf(_("error receiving update notification: status is %d\n"), status));
 292                 return;
 293         }
 294         if(substring(data, 0, 1) == "<")
 295         {
 296                 print(_("error: received HTML instead of an update notification\n"));
 297                 return;
 298         }
 299         if(strstrofs(data, "\r", 0) != -1)
 300         {
 301                 print(_("error: received carriage returns from update notification server\n"));
 302                 return;
 303         }
 304
 305         if(data == "")
 306                 n = 0;
 307         else
 308                 n = tokenizebyseparator(data, "\n");
 309
 310         if(n >= 1)
 311         {
 312                 _Nex_ExtResponseSystem_UpdateTo = argv(0);
 313
 314                 if(vercmp(cvar_string("g_xonoticversion"), _Nex_ExtResponseSystem_UpdateTo) >= 0)
 315                 {
 316                         _Nex_ExtResponseSystem_UpdateTo = ""; // no update needed
 317                 }
 318                 else
 319                 {
 320                         // update needed
 321                         if(n >= 2)
 322                                 print(sprintf(_("Update can be downloaded at:\n%s\n"), argv(1)));
 323                         if(n >= 3)
 324                                 _Nex_ExtResponseSystem_UpdateToURL = strzone(argv(2));
 325                 }
 326
 327                 _Nex_ExtResponseSystem_UpdateTo = strzone(_Nex_ExtResponseSystem_UpdateTo);
 328
 329                 if(n >= 4)
 330                 {
 331                         _Nex_ExtResponseSystem_BannedServers = strzone(argv(3));
 332                         _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 1;
 333                 }
 334         }
 335 }
 336
 337 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 338
 339 float preMenuInit()
 340 {
 341         vector sz;
 342         vector boxA, boxB;
 343
 344         MapInfo_Cache_Create();
 345         MapInfo_Enumerate();
 346         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 347         {
 348                 draw_reset_cropped();
 349
 350                 sz = eX * 0.025 + eY * 0.025 * (draw_scale_x / draw_scale_y);
 351                 draw_CenterText('0.5 0.5 0' - 1.25 * sz_y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 352
 353                 boxA = '0.05 0.5 0' + 0.25 * sz_y * eY;
 354                 boxB = '0.95 0.5 0' + 1.25 * sz_y * eY;
 355                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 356
 357                 boxA += sz * 0.1;
 358                 boxB -= sz * 0.1;
 359                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 360
 361                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 362                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 363
 364                 return FALSE;
 365         }
 366         return TRUE;
 367 }
 368
 369 string campaign_name_previous;
 370 float campaign_won_previous;
 371 #ifdef WATERMARK
 372 var string autocvar_menu_watermark = WATERMARK();
 373 #else
 374 var string autocvar_menu_watermark = "";
 375 #endif
 376 void postMenuDraw()
 377 {
 378         if(autocvar_menu_watermark != "")
 379         {
 380                 vector fs = '48 48 0';
 381                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 382         }
 383 }
 384 void preMenuDraw()
 385 {
 386         vector fs, sz, line, mid;
 387
 388         if(cvar("menu_updatecheck"))
 389         {
 390                 if(!_Nex_ExtResponseSystem_Queried)
 391                 {
 392                         _Nex_ExtResponseSystem_Queried = 1;
 393                         float startcnt;
 394                         string uri;
 395
 396                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 397
 398                         // for privacy, munge the start count a little
 399                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 400                         uri = sprintf("http://www.xonotic.org/dl/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 401
 402 #ifdef CVAR_POPCON
 403                         float cvar_handle, popcon_handle;
 404                         float n, i, j;
 405                         string k, s;
 406                         cvar_handle = buf_create();
 407                         buf_cvarlist(cvar_handle, "", "");
 408                         n = buf_getsize(cvar_handle);
 409                         popcon_handle = buf_create();
 410                         for(i= 0, j = 0; i < n; ++i)
 411                         {
 412                                 k = bufstr_get(cvar_handle, i);
 413                                 if(!(cvar_type(k) & CVAR_TYPEFLAG_SAVED))
 414                                         continue;
 415                                 s = sprintf("%s=%d", uri_escape(k), cvar_string(k) != cvar_defstring(k));
 416                                 bufstr_set(popcon_handle, j, s);
 417                                 ++j;
 418                         }
 419                         buf_del(cvar_handle);
 420                         uri_postbuf(
 421                                 uri, URI_GET_UPDATENOTIFICATION,
 422                                 "application/x-www-form-urlencoded",
 423                                 "&",
 424                                 popcon_handle
 425                         );
 426                         buf_del(popcon_handle);
 427 #else
 428                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 429 #endif
 430                 }
 431         }
 432
 433         if(_Nex_ExtResponseSystem_UpdateTo != "")
 434         {
 435                 // TODO rather turn this into a dialog
 436                 fs = ((1/draw_scale_x) * eX + (1/draw_scale_y) * eY) * 12;
 437                 line = eY * fs_y;
 438                 string l1, l2;
 439                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 440                 l2 = "http://www.xonotic.org/";
 441                 if(_Nex_ExtResponseSystem_UpdateToURL)
 442                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 443
 444                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 445                                 draw_TextWidth(l1, 0, fs),
 446                                 draw_TextWidth(l2, 0, fs)
 447                         );
 448                 sz_y = 3 * fs_y;
 449
 450                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 451                 mid = eX * (0.5 + 0.5 * (1 - sz_x) * cos(time * 0.071))
 452                     + eY * (0.5 + 0.5 * (1 - sz_y) * sin(time * 0.071));
 453
 454                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 455                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 456                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 457         }
 458         if not(campaign_name_previous)
 459                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 460         if(campaign_name == campaign_name_previous)
 461         {
 462                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 463                 {
 464                         if(!campaign_won_previous)
 465                         {
 466                                 m_display();
 467                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 468                         }
 469                         campaign_won_previous = 1;
 470                 }
 471                 else
 472                         campaign_won_previous = 0;
 473         }
 474         else
 475         {
 476                 strunzone(campaign_name_previous);
 477                 campaign_name_previous = strzone(campaign_name);
 478                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 479         }
 480 }
 481
 482 string resolvemod(string m)
 483 {
 484         if(m == "=")
 485                 return getcurrentmod();
 486         else
 487                 return m;
 488 }
 489
 490 float updateCompression()
 491 {
 492         float have_dds, have_jpg, have_tga;
 493         float can_dds;
 494         have_dds = (fexists("dds/particles/particlefont.dds"));
 495         have_jpg = (fexists("particles/particlefont.jpg"));
 496         have_tga = (fexists("particles/particlefont.tga"));
 497         can_dds = GL_Have_TextureCompression();
 498         if(have_dds && (have_jpg || have_tga))
 499         {
 500                 // both? Let's only use good quality precompressed files
 501                 // but ONLY if we actually support it!
 502                 if(can_dds)
 503                 {
 504                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 505                         cvar_set("gl_texturecompression", "0");
 506                         return 1;
 507
 508                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 509                         //return 2;
 510                 }
 511                 else
 512                 {
 513                         cvar_set("gl_texturecompression", "0");
 514                         cvar_set("r_texture_dds_load", "0");
 515                         return 0;
 516                 }
 517         }
 518         else if(have_dds)
 519         {
 520                 // DDS only? We probably always want texture compression
 521                 cvar_set("gl_texturecompression", "1");
 522                 cvar_set("r_texture_dds_load", "1");
 523                 if(!can_dds)
 524                         print(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 525                 return 0;
 526         }
 527         else
 528         {
 529                 // TGA only? Allow runtime compression
 530                 if(can_dds)
 531                 {
 532                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 533                         return 2;
 534                 }
 535                 else
 536                 {
 537                         cvar_set("gl_texturecompression", "0");
 538                         cvar_set("r_texture_dds_load", "0");
 539                         return 0;
 540                 }
 541         }
 542 }
 543
 544 // note: include only those that should be in the menu!
 545 #define GAMETYPES \
 546         GAMETYPE(MAPINFO_TYPE_ARENA) \
 547         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 548         GAMETYPE(MAPINFO_TYPE_CTF) \
 549         GAMETYPE(MAPINFO_TYPE_CA) \
 550         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 551         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 552         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 553         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 554         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 555         GAMETYPE(MAPINFO_TYPE_LMS) \
 556         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 557         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 558         GAMETYPE(MAPINFO_TYPE_RACE) \
 559         GAMETYPE(MAPINFO_TYPE_CTS) \
 560         GAMETYPE(MAPINFO_TYPE_RUNEMATCH) \
 561         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 562         /* nothing */
 563
 564 float GameType_GetID(float cnt)
 565 {
 566         float i;
 567         i = 0;
 568
 569         #define GAMETYPE(id) if(i++ == cnt) return id;
 570         GAMETYPES
 571         #undef GAMETYPE
 572
 573         return 0;
 574 }
 575
 576 float GameType_GetCount()
 577 {
 578         float i;
 579         i = 0;
 580
 581         #define GAMETYPE(id) ++i;
 582         GAMETYPES
 583         #undef GAMETYPE
 584
 585         return i;
 586 }
 587
 588 string GameType_GetName(float cnt)
 589 {
 590         float i = GameType_GetID(cnt);
 591
 592         if(i)
 593                 return MapInfo_Type_ToText(i);
 594
 595         return "";
 596 }
 597
 598 string GameType_GetIcon(float cnt)
 599 {
 600         float i = GameType_GetID(cnt);
 601
 602         if(i)
 603                 return strcat("gametype_", MapInfo_Type_ToString(i));
 604
 605         return "";
 606 }
 607
 608 /*string GameType_GetTeams(float cnt) // poor implementation, later something else could be done that's better?
 609 {
 610         float i = GameType_GetID(cnt);
 611         string s = _MapInfo_GetDefaultEx(i);
 612
 613         if(i)
 614         {
 615                 if(strstrofs(s, "teams", 0) >= 0)
 616                         return _("teamplay");
 617                 else
 618                         return _("free for all");
 619         }
 620
 621         return _("tuba for all");
 622 }*/
 623
 624 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 625 {
 626         float i;
 627         entity e;
 628
 629         me.TR(me);
 630                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 631                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 632                                 e.addValue(e, _("Default"), "");
 633                                 e.addValue(e, _("Disable"), "0");
 634                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 635                                 e.configureXonoticTextSliderValues(e);
 636         me.TR(me);
 637                 me.TDempty(me, 0.2);
 638                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 639                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 640                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 641         me.TR(me);
 642                 me.TDempty(me, 0.2);
 643                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 644         me.TR(me);
 645                 me.TDempty(me, 0.2);
 646                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 647                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 648                                 e.addValue(e, _("Default"), "");
 649                                 e.addValue(e, _("Disable"), "0");
 650                                 for(i = 1; i <= 10; ++i)
 651                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 652                                 e.configureXonoticTextSliderValues(e);
 653         me.TR(me);
 654                 me.TDempty(me, 0.2);
 655                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 656                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 657                                 e.addValue(e, _("Default"), "");
 658                                 for(i = 1; i <= 10; ++i)
 659                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 660                                 e.configureXonoticTextSliderValues(e);
 661         me.TR(me);
 662                 me.TDempty(me, 0.2);
 663                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 664                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 665                                 e.addValue(e, _("Default"), "");
 666                                 e.addValue(e, _("Disable"), "0");
 667                                 for(i = 1; i <= 10; ++i)
 668                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 669                                 e.configureXonoticTextSliderValues(e);
 670         me.TR(me);
 671                 me.TDempty(me, 0.4);
 672                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 673         me.TR(me);
 674                 me.TDempty(me, 0.2);
 675                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 676                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 677                                 e.addValue(e, _("Default"), "");
 678                                 for(i = 0; i <= 10; ++i)
 679                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 680                                 e.configureXonoticTextSliderValues(e);
 681 }