qcsrc/menu/xonotic/util.qc

   1 float GL_CheckExtension(string ext)
   2 {
   3         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
   4 }
   5
   6 float GL_Have_TextureCompression()
   7 {
   8         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
   9 }
  10
  11 void loadTooltips()
  12 {
  13         tooltipdb = db_load(language_filename("tooltips.db"));
  14 }
  15 void unloadTooltips()
  16 {
  17         if(tooltipdb >= 0)
  18                 db_close(tooltipdb);
  19         tooltipdb = -1;
  20 }
  21 string getZonedTooltipForIdentifier(string s)
  22 {
  23         string t;
  24         if(s == "")
  25                 return string_null;
  26         if(tooltipdb >= 0)
  27         {
  28                 t = db_get(tooltipdb, s);
  29                 if(t == "-")
  30                         return string_null;
  31                 if(t != "")
  32                         return strzone(t);
  33         }
  34         if(prvm_language == "en")
  35         {
  36                 t = cvar_description(s);
  37                 if(t != "" && t != "custom cvar")
  38                         return strzone(t);
  39         }
  40         dprint("WARNING: no tooltip set for ", s, "\n");
  41         return string_null;
  42 }
  43
  44 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  45 {
  46         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  47 }
  48
  49 .string cvarName;
  50 void SUB_Null_ee(entity e1, entity e2)
  51 {
  52 }
  53 void saveCvarsOf(entity ignore, entity e)
  54 {
  55         if(e.saveCvars)
  56                 e.saveCvars(e);
  57 }
  58 void loadCvarsOf(entity ignore, entity e)
  59 {
  60         if(e.loadCvars)
  61                 e.loadCvars(e);
  62 }
  63 void saveAllCvars(entity root)
  64 {
  65         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  66 }
  67 void loadAllCvars(entity root)
  68 {
  69         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  70 }
  71
  72 .string cvarNames_Multi;
  73 .void(entity me) saveCvars_Multi;
  74 string getCvarsMulti(entity me)
  75 {
  76         if (me.cvarNames_Multi)
  77                 return me.cvarNames_Multi;
  78         return string_null;
  79 }
  80 void saveCvarsMulti(entity me)
  81 {
  82         float n, i;
  83         string s;
  84
  85         me.saveCvars_Multi(me);
  86         s = cvar_string(me.cvarName);
  87
  88         n = tokenize_console(me.cvarNames_Multi);
  89         for(i = 0; i < n; ++i)
  90                 cvar_set(argv(i), s);
  91 }
  92 void makeMulti(entity e, string otherCvars)
  93 {
  94         e.cvarNames_Multi = otherCvars;
  95         e.saveCvars_Multi = e.saveCvars;
  96         e.saveCvars = saveCvarsMulti;
  97 }
  98
  99 .void(entity me) saveCvars_Callback;
 100 .entity saveCvars_Callback_ent;
 101 .void(entity me, entity cb) saveCvars_Callback_func;
 102 void saveCvarsCallback(entity me)
 103 {
 104         me.saveCvars_Callback(me);
 105         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 106 }
 107 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 108 {
 109         e.saveCvars_Callback = e.saveCvars;
 110         e.saveCvars = saveCvarsCallback;
 111         e.saveCvars_Callback_ent = cbent;
 112         e.saveCvars_Callback_func = cbfunc;
 113 }
 114
 115 .void(entity) draw_setDependent;
 116 .string cvar_setDependent;
 117 .float cvarMin_setDependent;
 118 .float cvarMax_setDependent;
 119 .string cvar2_setDependent;
 120 .float cvar2Min_setDependent;
 121 .float cvar2Max_setDependent;
 122 .string cvar3_setDependent;
 123 .float cvar3Min_setDependent;
 124 .float cvar3Max_setDependent;
 125 .float op_setDependent;
 126 .string cvarString_setDependent;
 127 .string cvarValue_setDependent;
 128 .float(entity) func_setDependent;
 129 void setDependent_Check(entity e)
 130 {
 131         float f;
 132         string s;
 133         if(e.func_setDependent)
 134         {
 135                 e.disabled = !(e.func_setDependent(e));
 136         }
 137         else if(e.cvarString_setDependent)
 138         {
 139                 s = cvar_string(e.cvarString_setDependent);
 140                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 141         }
 142         else
 143         {
 144                 if(e.cvar_setDependent)
 145                 {
 146                         f = cvar(e.cvar_setDependent);
 147                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 148                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 149                         else
 150                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 151                 }
 152                 if(e.cvar2_setDependent)
 153                 {
 154                         f = cvar(e.cvar2_setDependent);
 155                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 156                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 157                         else
 158                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 159                 }
 160                 if(e.cvar3_setDependent)
 161                 {
 162                         f = cvar(e.cvar3_setDependent);
 163                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 164                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 165                         else
 166                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 167                 }
 168         }
 169 }
 170 void setDependent_Draw(entity e)
 171 {
 172         setDependent_Check(e);
 173         e.draw_setDependent(e);
 174 }
 175 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 176 {
 177         e.draw_setDependent = e.draw;
 178         e.cvar_setDependent = theCvarName;
 179         e.cvarMin_setDependent = theCvarMin;
 180         e.cvarMax_setDependent = theCvarMax;
 181         e.cvar2_setDependent = string_null;
 182         e.cvar3_setDependent = string_null;
 183         e.func_setDependent = func_null;
 184         e.draw = setDependent_Draw;
 185         setDependent_Check(e);
 186 }
 187 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 188 {
 189         e.draw_setDependent = e.draw;
 190         e.cvarString_setDependent = theCvarName;
 191         e.cvarValue_setDependent = theCvarValue;
 192         e.cvar_setDependent = string_null;
 193         e.cvar2_setDependent = string_null;
 194         e.cvar3_setDependent = string_null;
 195         e.func_setDependent = func_null;
 196         e.draw = setDependent_Draw;
 197         setDependent_Check(e);
 198 }
 199 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 200 {
 201         e.draw_setDependent = e.draw;
 202         e.cvar_setDependent = theCvarName;
 203         e.cvarMin_setDependent = theCvarMin;
 204         e.cvarMax_setDependent = theCvarMax;
 205         e.cvar2_setDependent = theCvar2Name;
 206         e.cvar2Min_setDependent = theCvar2Min;
 207         e.cvar2Max_setDependent = theCvar2Max;
 208         e.cvar3_setDependent = string_null;
 209         e.op_setDependent = 0;
 210         e.func_setDependent = func_null;
 211         e.draw = setDependent_Draw;
 212         setDependent_Check(e);
 213 }
 214 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 215 {
 216         e.draw_setDependent = e.draw;
 217         e.cvar_setDependent = theCvarName;
 218         e.cvarMin_setDependent = theCvarMin;
 219         e.cvarMax_setDependent = theCvarMax;
 220         e.cvar2_setDependent = theCvar2Name;
 221         e.cvar2Min_setDependent = theCvar2Min;
 222         e.cvar2Max_setDependent = theCvar2Max;
 223         e.cvar3_setDependent = string_null;
 224         e.op_setDependent = 1;
 225         e.func_setDependent = func_null;
 226         e.draw = setDependent_Draw;
 227         setDependent_Check(e);
 228 }
 229 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 230 {
 231         e.draw_setDependent = e.draw;
 232         e.cvar_setDependent = theCvarName;
 233         e.cvarMin_setDependent = theCvarMin;
 234         e.cvarMax_setDependent = theCvarMax;
 235         e.cvar2_setDependent = theCvar2Name;
 236         e.cvar2Min_setDependent = theCvar2Min;
 237         e.cvar2Max_setDependent = theCvar2Max;
 238         e.cvar3_setDependent = theCvar3Name;
 239         e.cvar3Min_setDependent = theCvar3Min;
 240         e.cvar3Max_setDependent = theCvar3Max;
 241         e.op_setDependent = 0;
 242         e.func_setDependent = func_null;
 243         e.draw = setDependent_Draw;
 244         setDependent_Check(e);
 245 }
 246 void setDependentWeird(entity e, float(entity) func)
 247 {
 248         e.draw_setDependent = e.draw;
 249         e.func_setDependent = func;
 250         e.draw = setDependent_Draw;
 251         setDependent_Check(e);
 252 }
 253
 254 // URI SYSTEM ////////////////////////////////////////////////////////
 255
 256 float _Nex_ExtResponseSystem_Queried;
 257 string _Nex_ExtResponseSystem_UpdateTo;
 258 string _Nex_ExtResponseSystem_UpdateToURL;
 259 string _Nex_ExtResponseSystem_Packs;
 260 float _Nex_ExtResponseSystem_PacksStep;
 261
 262 void URI_Get_Callback(float id, float status, string data)
 263 {
 264         if(url_URI_Get_Callback(id, status, data))
 265         {
 266                 // handled
 267         }
 268         else if (id == URI_GET_DISCARD)
 269         {
 270                 // discard
 271         }
 272         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 273         {
 274                 // sv_cmd curl
 275                 Curl_URI_Get_Callback(id, status, data);
 276         }
 277         else if (id == URI_GET_UPDATENOTIFICATION)
 278         {
 279                 UpdateNotification_URI_Get_Callback(id, status, data);
 280         }
 281         else
 282         {
 283                 print(sprintf("Received HTTP request data for an invalid id %d.\n", id));
 284         }
 285 }
 286
 287 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 288 {
 289         float n;
 290
 291         if(_Nex_ExtResponseSystem_UpdateTo)
 292         {
 293                 dprint("error: UpdateNotification_URI_Get_Callback has been called before\n");
 294                 return;
 295         }
 296         if(status != 0)
 297         {
 298                 print(sprintf(_("error receiving update notification: status is %d\n"), status));
 299                 return;
 300         }
 301         if(substring(data, 0, 1) == "<")
 302         {
 303                 print(_("error: received HTML instead of an update notification\n"));
 304                 return;
 305         }
 306         if(strstrofs(data, "\r", 0) != -1)
 307         {
 308                 print(_("error: received carriage returns from update notification server\n"));
 309                 return;
 310         }
 311
 312         if(data == "")
 313                 n = 0;
 314         else
 315                 n = tokenizebyseparator(data, "\n");
 316
 317         if(n >= 1)
 318         {
 319                 _Nex_ExtResponseSystem_UpdateTo = argv(0);
 320
 321                 if(vercmp(cvar_string("g_xonoticversion"), _Nex_ExtResponseSystem_UpdateTo) >= 0)
 322                 {
 323                         _Nex_ExtResponseSystem_UpdateTo = ""; // no update needed
 324                 }
 325                 else
 326                 {
 327                         // update needed
 328                         if(n >= 2)
 329                                 print(sprintf(_("Update can be downloaded at:\n%s\n"), argv(1)));
 330                         if(n >= 3)
 331                                 _Nex_ExtResponseSystem_UpdateToURL = strzone(argv(2));
 332                 }
 333
 334                 _Nex_ExtResponseSystem_UpdateTo = strzone(_Nex_ExtResponseSystem_UpdateTo);
 335
 336                 if(n >= 4)
 337                 {
 338                         _Nex_ExtResponseSystem_BannedServers = strzone(argv(3));
 339                         _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 1;
 340                 }
 341
 342                 if(n >= 5)
 343                 {
 344                         if(cvar("menu_updatecheck_getpacks"))
 345                         {
 346                                 _Nex_ExtResponseSystem_Packs = strzone(argv(4));
 347                                 _Nex_ExtResponseSystem_PacksStep = 1;
 348                         }
 349                 }
 350
 351                 if(n >= 6)
 352                 {
 353                         _Nex_ExtResponseSystem_RecommendedServers = strzone(argv(5));
 354                         _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 355                 }
 356         }
 357 }
 358
 359 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 360
 361 void updateCheck()
 362 {
 363         if(cvar("menu_updatecheck"))
 364         {
 365                 if(!_Nex_ExtResponseSystem_Queried)
 366                 {
 367                         _Nex_ExtResponseSystem_Queried = 1;
 368                         float startcnt;
 369                         string uri;
 370
 371                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 372
 373                         // for privacy, munge the start count a little
 374                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 375                         uri = sprintf("http://www.xonotic.org/dl/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 376
 377 #ifdef CVAR_POPCON
 378                         float cvar_handle, popcon_handle;
 379                         float n, i, j;
 380                         string k, s;
 381                         cvar_handle = buf_create();
 382                         buf_cvarlist(cvar_handle, "", "");
 383                         n = buf_getsize(cvar_handle);
 384                         popcon_handle = buf_create();
 385                         for(i= 0, j = 0; i < n; ++i)
 386                         {
 387                                 k = bufstr_get(cvar_handle, i);
 388                                 if(!(cvar_type(k) & CVAR_TYPEFLAG_SAVED))
 389                                         continue;
 390                                 s = sprintf("%s=%d", uri_escape(k), cvar_string(k) != cvar_defstring(k));
 391                                 bufstr_set(popcon_handle, j, s);
 392                                 ++j;
 393                         }
 394                         buf_del(cvar_handle);
 395                         uri_postbuf(
 396                                 uri, URI_GET_UPDATENOTIFICATION,
 397                                 "application/x-www-form-urlencoded",
 398                                 "&",
 399                                 popcon_handle
 400                         );
 401                         buf_del(popcon_handle);
 402 #else
 403                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 404 #endif
 405                 }
 406         }
 407
 408         if(_Nex_ExtResponseSystem_PacksStep > 0)
 409         {
 410                 float n, i;
 411                 float allgood;
 412                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 413                 allgood = TRUE;
 414                 for(i = 0; i+1 < n; i += 2)
 415                 {
 416                         if(fexists(argv(i+1)))
 417                                 continue;
 418                         allgood = FALSE;
 419                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 420                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 421                 }
 422                 if(allgood)
 423                 {
 424                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 425                         {
 426                                 if(!Menu_Active)
 427                                         cvar_set("_menu_initialized", "0");
 428                                         // HACK: cause m_hide call on next start
 429                                 localcmd("\nmenu_restart\n");
 430                         }
 431                         _Nex_ExtResponseSystem_PacksStep = 0;
 432                 }
 433                 else
 434                         _Nex_ExtResponseSystem_PacksStep = 2;
 435         }
 436
 437 }
 438
 439 float preMenuInit()
 440 {
 441         vector sz;
 442         vector boxA, boxB;
 443
 444         updateCheck();
 445
 446         MapInfo_Cache_Create();
 447         MapInfo_Enumerate();
 448         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 449         {
 450                 draw_reset_cropped();
 451
 452                 sz = eX * 0.025 + eY * 0.025 * (draw_scale_x / draw_scale_y);
 453                 draw_CenterText('0.5 0.5 0' - 1.25 * sz_y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 454
 455                 boxA = '0.05 0.5 0' + 0.25 * sz_y * eY;
 456                 boxB = '0.95 0.5 0' + 1.25 * sz_y * eY;
 457                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 458
 459                 boxA += sz * 0.1;
 460                 boxB -= sz * 0.1;
 461                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 462
 463                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 464                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 465
 466                 return FALSE;
 467         }
 468         return TRUE;
 469 }
 470
 471 string campaign_name_previous;
 472 float campaign_won_previous;
 473 #ifdef WATERMARK
 474 var string autocvar_menu_watermark = WATERMARK;
 475 #else
 476 var string autocvar_menu_watermark = "";
 477 #endif
 478 void postMenuDraw()
 479 {
 480         if(autocvar_menu_watermark != "")
 481         {
 482                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 483         }
 484 }
 485 void preMenuDraw()
 486 {
 487         vector fs, sz = '0 0 0', line, mid;
 488
 489         updateCheck();
 490
 491         if(_Nex_ExtResponseSystem_UpdateTo != "")
 492         {
 493                 // TODO rather turn this into a dialog
 494                 fs = ((1/draw_scale_x) * eX + (1/draw_scale_y) * eY) * 12;
 495                 line = eY * fs_y;
 496                 string l1, l2;
 497                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 498                 l2 = "http://www.xonotic.org/";
 499                 if(_Nex_ExtResponseSystem_UpdateToURL)
 500                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 501
 502                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 503                                 draw_TextWidth(l1, 0, fs),
 504                                 draw_TextWidth(l2, 0, fs)
 505                         );
 506                 sz_y = 3 * fs_y;
 507
 508                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 509                 mid = eX * (0.5 + 0.5 * (1 - sz_x) * cos(time * 0.071))
 510                     + eY * (0.5 + 0.5 * (1 - sz_y) * sin(time * 0.071));
 511
 512                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 513                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 514                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 515         }
 516         if not(campaign_name_previous)
 517                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 518         if(campaign_name == campaign_name_previous)
 519         {
 520                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 521                 {
 522                         if(!campaign_won_previous)
 523                         {
 524                                 m_display();
 525                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 526                         }
 527                         campaign_won_previous = 1;
 528                 }
 529                 else
 530                         campaign_won_previous = 0;
 531         }
 532         else
 533         {
 534                 strunzone(campaign_name_previous);
 535                 campaign_name_previous = strzone(campaign_name);
 536                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 537         }
 538 }
 539
 540 string resolvemod(string m)
 541 {
 542         if(m == "=")
 543                 return getcurrentmod();
 544         else
 545                 return m;
 546 }
 547
 548 float updateCompression()
 549 {
 550         float have_dds, have_jpg, have_tga;
 551         float can_dds;
 552         have_dds = (fexists("dds/particles/particlefont.dds"));
 553         have_jpg = (fexists("particles/particlefont.jpg"));
 554         have_tga = (fexists("particles/particlefont.tga"));
 555         can_dds = GL_Have_TextureCompression();
 556         if(have_dds && (have_jpg || have_tga))
 557         {
 558                 // both? Let's only use good quality precompressed files
 559                 // but ONLY if we actually support it!
 560                 if(can_dds)
 561                 {
 562                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 563                         cvar_set("gl_texturecompression", "0");
 564                         return 1;
 565
 566                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 567                         //return 2;
 568                 }
 569                 else
 570                 {
 571                         cvar_set("gl_texturecompression", "0");
 572                         cvar_set("r_texture_dds_load", "0");
 573                         return 0;
 574                 }
 575         }
 576         else if(have_dds)
 577         {
 578                 // DDS only? We probably always want texture compression
 579                 cvar_set("gl_texturecompression", "1");
 580                 cvar_set("r_texture_dds_load", "1");
 581                 if(!can_dds)
 582                         print(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 583                 return 0;
 584         }
 585         else
 586         {
 587                 // TGA only? Allow runtime compression
 588                 if(can_dds)
 589                 {
 590                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 591                         return 2;
 592                 }
 593                 else
 594                 {
 595                         cvar_set("gl_texturecompression", "0");
 596                         cvar_set("r_texture_dds_load", "0");
 597                         return 0;
 598                 }
 599         }
 600 }
 601
 602 // note: include only those that should be in the menu!
 603 #define GAMETYPES \
 604         GAMETYPE(MAPINFO_TYPE_ARENA) \
 605         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 606         GAMETYPE(MAPINFO_TYPE_CTF) \
 607         GAMETYPE(MAPINFO_TYPE_CA) \
 608         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 609         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 610         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 611         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 612         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 613         GAMETYPE(MAPINFO_TYPE_LMS) \
 614         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 615         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 616         GAMETYPE(MAPINFO_TYPE_RACE) \
 617         GAMETYPE(MAPINFO_TYPE_CTS) \
 618         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 619         /* nothing */
 620
 621 float GameType_GetID(float cnt)
 622 {
 623         float i;
 624         i = 0;
 625
 626         #define GAMETYPE(id) if(i++ == cnt) return id;
 627         GAMETYPES
 628         #undef GAMETYPE
 629
 630         unused_float = i;
 631
 632         return 0;
 633 }
 634
 635 float GameType_GetCount()
 636 {
 637         float i;
 638         i = 0;
 639
 640         #define GAMETYPE(id) ++i;
 641         GAMETYPES
 642         #undef GAMETYPE
 643
 644         return i;
 645 }
 646
 647 string GameType_GetName(float cnt)
 648 {
 649         float i = GameType_GetID(cnt);
 650
 651         if(i)
 652                 return MapInfo_Type_ToText(i);
 653
 654         return "";
 655 }
 656
 657 string GameType_GetIcon(float cnt)
 658 {
 659         float i = GameType_GetID(cnt);
 660
 661         if(i)
 662                 return strcat("gametype_", MapInfo_Type_ToString(i));
 663
 664         return "";
 665 }
 666
 667 /*string GameType_GetTeams(float cnt) // poor implementation, later something else could be done that's better?
 668 {
 669         float i = GameType_GetID(cnt);
 670         string s = _MapInfo_GetDefaultEx(i);
 671
 672         if(i)
 673         {
 674                 if(strstrofs(s, "teams", 0) >= 0)
 675                         return _("teamplay");
 676                 else
 677                         return _("free for all");
 678         }
 679
 680         return _("tuba for all");
 681 }*/
 682
 683 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 684 {
 685         float i;
 686         entity e;
 687
 688         me.TR(me);
 689                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 690                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 691                                 e.addValue(e, _("Default"), "");
 692                                 e.addValue(e, _("Disable"), "0");
 693                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 694                                 e.configureXonoticTextSliderValues(e);
 695         me.TR(me);
 696                 me.TDempty(me, 0.2);
 697                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 698                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 699                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 700         me.TR(me);
 701                 me.TDempty(me, 0.2);
 702                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 703         me.TR(me);
 704                 me.TDempty(me, 0.2);
 705                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 706                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 707                                 e.addValue(e, _("Default"), "");
 708                                 e.addValue(e, _("Disable"), "0");
 709                                 for(i = 1; i <= 10; ++i)
 710                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 711                                 e.configureXonoticTextSliderValues(e);
 712         me.TR(me);
 713                 me.TDempty(me, 0.2);
 714                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 715                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 716                                 e.addValue(e, _("Default"), "");
 717                                 for(i = 1; i <= 10; ++i)
 718                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 719                                 e.configureXonoticTextSliderValues(e);
 720         me.TR(me);
 721                 me.TDempty(me, 0.2);
 722                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 723                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 724                                 e.addValue(e, _("Default"), "");
 725                                 e.addValue(e, _("Disable"), "0");
 726                                 for(i = 1; i <= 10; ++i)
 727                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 728                                 e.configureXonoticTextSliderValues(e);
 729         me.TR(me);
 730                 me.TDempty(me, 0.4);
 731                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 732         me.TR(me);
 733                 me.TDempty(me, 0.2);
 734                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 735                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 736                                 e.addValue(e, _("Default"), "");
 737                                 for(i = 0; i <= 10; ++i)
 738                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 739                                 e.configureXonoticTextSliderValues(e);
 740 }