qcsrc/server/accuracy.qc

   1 .float accuracy_hit[WEP_MAXCOUNT];
   2 .float accuracy_fired[WEP_MAXCOUNT];
   3 .float accuracy_cnt_hit[WEP_MAXCOUNT];
   4 .float accuracy_cnt_fired[WEP_MAXCOUNT];
   5
   6 float accuracy_byte(float n, float d)
   7 {
   8         //print(sprintf("accuracy: %d / %d\n", n, d));
   9         if(n <= 0)
  10                 return 0;
  11         if(n > d)
  12                 return 255;
  13         return 1 + rint(n * 100.0 / d);
  14 }
  15
  16 float accuracy_send(entity to, float sf)
  17 {
  18         float w, f;
  19         entity a;
  20         WriteByte(MSG_ENTITY, ENT_CLIENT_ACCURACY);
  21
  22         a = self.owner;
  23         if(a.classname == "spectator")
  24                 a = a.enemy;
  25         a = a.accuracy;
  26
  27         if(to != a.owner)
  28                 if not(self.owner.cvar_cl_accuracy_data_share && autocvar_sv_accuracy_data_share)
  29                         sf = 0;
  30         // note: zero sendflags can never be sent... so we can use that to say that we send no accuracy!
  31         WriteInt24_t(MSG_ENTITY, sf);
  32         if(sf == 0)
  33                 return TRUE;
  34         // note: we know that client and server agree about SendFlags...
  35         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
  36         {
  37                 if(sf & f)
  38                         WriteByte(MSG_ENTITY, accuracy_byte(self.(accuracy_hit[w]), self.(accuracy_fired[w])));
  39         }
  40         return TRUE;
  41 }
  42
  43 // init/free
  44 void accuracy_init(entity e)
  45 {
  46         e.accuracy = spawn();
  47         e.accuracy.owner = e;
  48         e.accuracy.classname = "accuracy";
  49         e.accuracy.drawonlytoclient = e;
  50         Net_LinkEntity(e.accuracy, FALSE, 0, accuracy_send);
  51 }
  52
  53 void accuracy_free(entity e)
  54 {
  55         remove(e.accuracy);
  56 }
  57
  58 // force a resend of a player's accuracy stats
  59 void accuracy_resend(entity e)
  60 {
  61         e.accuracy.SendFlags = 0xFFFFFF;
  62 }
  63
  64 // update accuracy stats
  65 .float hit_time;
  66 .float fired_time;
  67
  68 void accuracy_add(entity e, float w, float fired, float hit)
  69 {
  70         entity a;
  71         float b;
  72         if(IS_INDEPENDENT_PLAYER(e))
  73                 return;
  74         a = e.accuracy;
  75         if(!a || !(hit || fired))
  76                 return;
  77         w -= WEP_FIRST;
  78         b = accuracy_byte(a.(accuracy_hit[w]), a.(accuracy_fired[w]));
  79         if(hit)
  80                 a.(accuracy_hit[w]) += hit;
  81         if(fired)
  82                 a.(accuracy_fired[w]) += fired;
  83
  84     if(hit && a.hit_time != time) // only run this once per frame
  85     {
  86         a.(accuracy_cnt_hit[w]) += 1;
  87         a.hit_time = time;
  88     }
  89
  90     if(fired && a.fired_time != time) // only run this once per frame
  91     {
  92         a.(accuracy_cnt_fired[w]) += 1;
  93         a.fired_time = time;
  94     }
  95
  96         if(b == accuracy_byte(a.(accuracy_hit[w]), a.(accuracy_fired[w])))
  97                 return;
  98         w = pow(2, w);
  99         a.SendFlags |= w;
 100         FOR_EACH_CLIENT(a)
 101                 if(a.classname == "spectator")
 102                         if(a.enemy == e)
 103                                 a.SendFlags |= w;
 104 }
 105
 106 float accuracy_isgooddamage(entity attacker, entity targ)
 107 {
 108         if(!inWarmupStage)
 109         if(targ.flags & FL_CLIENT)
 110         if(targ.deadflag == DEAD_NO)
 111         if(IsDifferentTeam(attacker, targ))
 112                 return TRUE;
 113         return FALSE;
 114 }
 115
 116 float accuracy_canbegooddamage(entity attacker)
 117 {
 118         if(!inWarmupStage)
 119                 return TRUE;
 120         return FALSE;
 121 }