qcsrc/server/arena.qc

   1 float maxspawned;
   2 float numspawned;
   3 float arena_roundbased;
   4 .float spawned;
   5 .entity spawnqueue_next;
   6 .entity spawnqueue_prev;
   7 .float spawnqueue_in;
   8 entity spawnqueue_first;
   9 entity spawnqueue_last;
  10 entity champion;
  11 string champion_name;
  12 float warmup;
  13 float ca_players;
  14 float required_ca_players;
  15 .float caplayer;
  16
  17 void PutObserverInServer();
  18 void PutClientInServer();
  19 void(entity e) ReturnFlag;
  20 void dom_controlpoint_setup();
  21 void onslaught_generator_reset();
  22 void onslaught_controlpoint_reset();
  23 void func_breakable_reset();
  24 void assault_objective_reset();
  25 void target_assault_roundend_reset();
  26
  27 float next_round;
  28 float stopalivecheck;
  29 float redalive, bluealive, yellowalive, pinkalive;
  30 float totalalive;
  31 .float redalive_stat, bluealive_stat, yellowalive_stat, pinkalive_stat;
  32 float redspawned, bluespawned, yellowspawned, pinkspawned;
  33 float totalspawned;
  34
  35 /**
  36  * Resets the state of all clients, items, flags, runes, keys, weapons, waypoints, ... of the map.
  37  * Sets the 'warmup' global variable.
  38  */
  39 void reset_map(float dorespawn)
  40 {
  41         entity oldself;
  42         oldself = self;
  43
  44         if(g_arena && autocvar_g_arena_warmup)
  45                 warmup = time + autocvar_g_arena_warmup;
  46         else if(g_ca) {
  47                 warmup = time + autocvar_g_ca_warmup;
  48                 allowed_to_spawn = 1;
  49         }
  50         else if(g_freezetag)
  51         {
  52                 warmup = time + autocvar_g_freezetag_warmup;
  53         }
  54
  55         lms_lowest_lives = 999;
  56         lms_next_place = player_count;
  57
  58         race_ReadyRestart();
  59
  60         for(self = world; (self = nextent(self)); )
  61         if(clienttype(self) == CLIENTTYPE_NOTACLIENT && self.items != IT_STRENGTH && self.items != IT_INVINCIBLE) // don't respawn strength or shield, that will only lead to them spawning very early each match
  62         {
  63                 if(self.reset)
  64                 {
  65                         self.reset();
  66                         continue;
  67                 }
  68
  69                 if(self.team_saved)
  70                         self.team = self.team_saved;
  71
  72                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
  73                 {
  74                         stopsound(self, CHAN_PAIN);
  75                         remove(self);
  76                 }
  77         }
  78
  79         // Waypoints and assault start come LAST
  80         for(self = world; (self = nextent(self)); )
  81         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
  82         {
  83                 if(self.reset2)
  84                 {
  85                         self.reset2();
  86                         continue;
  87                 }
  88         }
  89
  90         // Moving the player reset code here since the player-reset depends
  91         // on spawnpoint entities which have to be reset first --blub
  92         if(dorespawn)
  93         FOR_EACH_CLIENT(self) {
  94                 if(self.flags & FL_CLIENT)                              // reset all players
  95                 {
  96                         if(g_arena)
  97                         {
  98                                 if(self.spawned)
  99                                         PutClientInServer();
 100                                 else
 101                                         PutObserverInServer();
 102                         }
 103                         else if(g_ca && self.caplayer) {
 104                                 self.classname = "player";
 105                                 PutClientInServer();
 106                         }
 107                         else if(g_freezetag)
 108                         {
 109                                 if(self.classname == "player")
 110                                         PutClientInServer();
 111                         }
 112                         else
 113                         {
 114                                 /*
 115                                 only reset players if a restart countdown is active
 116                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 117                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 118                                 sv_ready_restart_after_countdown is not used and countdown is still running
 119                                 */
 120                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 121                                 {
 122                                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 123                                         if (self.classname == "player") {
 124                                                 //PlayerScore_Clear(self);
 125                                                 if(g_lms)
 126                                                         PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
 127                                                 self.killcount = 0;
 128                                                 //stop the player from moving so that he stands still once he gets respawned
 129                                                 self.velocity = '0 0 0';
 130                                                 self.avelocity = '0 0 0';
 131                                                 self.movement = '0 0 0';
 132                                                 PutClientInServer();
 133                                         }
 134                                 }
 135                         }
 136                 }
 137         }
 138
 139         if(g_keyhunt)
 140                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round+(game_starttime - time), "", kh_StartRound);
 141
 142         if(g_arena)
 143         if(champion && champion.classname == "player" && player_count > 1)
 144                 UpdateFrags(champion, +1);
 145
 146         self = oldself;
 147 }
 148
 149 void Spawnqueue_Insert(entity e)
 150 {
 151         if(e.spawnqueue_in)
 152                 return;
 153         dprint(strcat("Into queue: ", e.netname, "\n"));
 154         e.spawnqueue_in = TRUE;
 155         e.spawnqueue_prev = spawnqueue_last;
 156         e.spawnqueue_next = world;
 157         if(spawnqueue_last)
 158                 spawnqueue_last.spawnqueue_next = e;
 159         spawnqueue_last = e;
 160         if(!spawnqueue_first)
 161                 spawnqueue_first = e;
 162 }
 163
 164 void Spawnqueue_Remove(entity e)
 165 {
 166         if(!e.spawnqueue_in)
 167                 return;
 168         dprint(strcat("Out of queue: ", e.netname, "\n"));
 169         e.spawnqueue_in = FALSE;
 170         if(e == spawnqueue_first)
 171                 spawnqueue_first = e.spawnqueue_next;
 172         if(e == spawnqueue_last)
 173                 spawnqueue_last = e.spawnqueue_prev;
 174         if(e.spawnqueue_prev)
 175                 e.spawnqueue_prev.spawnqueue_next = e.spawnqueue_next;
 176         if(e.spawnqueue_next)
 177                 e.spawnqueue_next.spawnqueue_prev = e.spawnqueue_prev;
 178         e.spawnqueue_next = world;
 179         e.spawnqueue_prev = world;
 180 }
 181
 182 void Spawnqueue_Unmark(entity e)
 183 {
 184         if(!e.spawned)
 185                 return;
 186         e.spawned = FALSE;
 187         numspawned = numspawned - 1;
 188 }
 189
 190 void Spawnqueue_Mark(entity e)
 191 {
 192         if(e.spawned)
 193                 return;
 194         e.spawned = TRUE;
 195         numspawned = numspawned + 1;
 196 }
 197
 198 /**
 199  * If roundbased arena game mode is active, it centerprints the texts for the
 200  * player when player is waiting for the countdown to finish.
 201  * Blocks the players movement while countdown is active.
 202  * Unblocks the player once the countdown is over.
 203  *
 204  * Called in PlayerPostThink()
 205  */
 206 float roundStartTime_prev; // prevent networkspam
 207 void Arena_Warmup()
 208 {
 209         float f;
 210         string msg;
 211     entity e;
 212
 213         if((!g_arena && !g_ca && !g_freezetag) || (g_arena && !arena_roundbased) || (time < game_starttime))
 214                 return;
 215
 216         f = ceil(warmup - time);
 217         if(f > 0)
 218                 champion = world; // this is done because a if(champion) will not execute if champion = world
 219
 220         allowed_to_spawn = 0;
 221
 222         if(inWarmupStage)
 223                 allowed_to_spawn = 1;
 224         if(ca_players < required_ca_players)
 225                 allowed_to_spawn = 1;
 226
 227         msg = NEWLINES;
 228         if(time < warmup && !inWarmupStage)
 229         {
 230                 if (g_ca)
 231                         allowed_to_spawn = 1;
 232                 if(champion && g_arena)
 233                         msg = strcat("The Champion is ", champion_name, "^7\n");
 234                         //centerprint(self, strcat(msg, "The Champion is ", champion.netname, "^7\n"));
 235
 236                 if(f != roundStartTime_prev) {
 237                         msg = strcat(msg, "Round will start in ", ftos(f),"\n");
 238                         //centerprint(self, strcat("Round will start in ", ftos(f),"\n"));
 239                         roundStartTime_prev = f;
 240                         if(f == 5)
 241                                 Announce("prepareforbattle");
 242                         else if(f == 3)
 243                                 Announce("3");
 244                         else if(f == 2)
 245                                 Announce("2");
 246                         else if(f == 1)
 247                                 Announce("1");
 248
 249             FOR_EACH_PLAYER(e)
 250                 centerprint(e, msg);
 251                 }
 252
 253                 if (g_arena) {
 254                         if(self.spawned && self.classname == "player")
 255                                 self.movetype = MOVETYPE_NONE;
 256
 257                         self.velocity = '0 0 0';
 258                         self.avelocity = '0 0 0';
 259                         self.movement = '0 0 0';
 260                 }
 261         }
 262
 263         else if(f > -1 && f != roundStartTime_prev)
 264         {
 265                 roundStartTime_prev = f;
 266                 Announce("begin");
 267                 centerprint(self, "^1Begin!\n");
 268
 269                 if(g_ca) {
 270                         ca_players = 0;
 271
 272             FOR_EACH_PLAYER(e)
 273                                 ca_players += 1;
 274                 }
 275
 276         if(self.classname == "player" && self.health > 0 && self.movetype == MOVETYPE_NONE)
 277             self.movetype = MOVETYPE_WALK;
 278         }
 279 }
 280
 281 void count_spawned_players()
 282 {
 283         // TODO fix "*spawned" name, it should rather be "*players" or so
 284         // not doing this now to prevent merge hell with Tag
 285         // fix after merging with Tag
 286
 287         // count amount of players in each team
 288         totalspawned = redspawned = bluespawned = yellowspawned = pinkspawned = 0;
 289         FOR_EACH_PLAYER(self) {
 290                 if (self.team == COLOR_TEAM1)
 291                 {
 292                         redspawned += 1;
 293                         totalspawned += 1;
 294                 }
 295                 else if (self.team == COLOR_TEAM2)
 296                 {
 297                         bluespawned += 1;
 298                         totalspawned += 1;
 299                 }
 300                 else if (self.team == COLOR_TEAM3)
 301                 {
 302                         yellowspawned += 1;
 303                         totalspawned += 1;
 304                 }
 305                 else if (self.team == COLOR_TEAM4)
 306                 {
 307                         pinkspawned += 1;
 308                         totalspawned += 1;
 309                 }
 310         }
 311 }
 312
 313 void count_alive_players()
 314 {
 315         totalalive = redalive = bluealive = yellowalive = pinkalive = 0;
 316         if(g_ca)
 317         {
 318                 FOR_EACH_PLAYER(self) {
 319                         if (self.team == COLOR_TEAM1 && self.health >= 1)
 320                         {
 321                                 redalive += 1;
 322                                 totalalive += 1;
 323                         }
 324                         else if (self.team == COLOR_TEAM2 && self.health >= 1)
 325                         {
 326                                 bluealive += 1;
 327                                 totalalive += 1;
 328                         }
 329                 }
 330                 FOR_EACH_REALCLIENT(self) {
 331                         self.redalive_stat = redalive;
 332                         self.bluealive_stat = bluealive;
 333                 }
 334         }
 335         else if(g_freezetag)
 336         {
 337                 // count amount of alive players in each team
 338                 FOR_EACH_PLAYER(self) {
 339                         if (self.team == COLOR_TEAM1 && self.freezetag_frozen == 0 && self.health >= 1)
 340                         {
 341                                 redalive += 1;
 342                                 totalalive += 1;
 343                         }
 344                         else if (self.team == COLOR_TEAM2 && self.freezetag_frozen == 0 && self.health >= 1)
 345                         {
 346                                 bluealive += 1;
 347                                 totalalive += 1;
 348                         }
 349                         else if (self.team == COLOR_TEAM3 && self.freezetag_frozen == 0 && self.health >= 1)
 350                         {
 351                                 yellowalive += 1;
 352                                 totalalive += 1;
 353                         }
 354                         else if (self.team == COLOR_TEAM4 && self.freezetag_frozen == 0 && self.health >= 1)
 355                         {
 356                                 pinkalive += 1;
 357                                 totalalive += 1;
 358                         }
 359                 }
 360                 FOR_EACH_REALCLIENT(self) {
 361                         self.redalive_stat = redalive;
 362                         self.bluealive_stat = bluealive;
 363                         self.yellowalive_stat = yellowalive;
 364                         self.pinkalive_stat = pinkalive;
 365                 }
 366         }
 367
 368 }
 369
 370 /**
 371  * This function finds out whether an arena round is over 1 player is left.
 372  * It determines the last player who's still alive and saves it's entity reference
 373  * in the global variable 'champion'. Then the new enemy/enemies are put into the server.
 374  *
 375  * Gets called in StartFrame()
 376  */
 377 void Spawnqueue_Check()
 378 {
 379         count_spawned_players();
 380         if(g_ca || g_freezetag) // we want to perform this before the return block below (CA)...
 381         {
 382                 count_alive_players();
 383         }
 384         if(time < warmup + 1 || inWarmupStage || intermission_running)
 385                 return;
 386
 387         if(g_ca) {
 388                 required_ca_players = max(2, fabs(autocvar_bot_vs_human + 1));
 389
 390                 if(ca_players < required_ca_players && (redspawned && bluespawned)) {
 391                         reset_map(TRUE);
 392                 }
 393                 else if(ca_players < required_ca_players) {
 394                         FOR_EACH_PLAYER(self)
 395                                 centerprint(self, strcat("^1Need at least 1 player in each team to play CA", "^7\n"));
 396                         return;
 397                 }
 398                 else if(!next_round) {
 399                         if((redspawned && !bluespawned) || (bluespawned && !redspawned)) {
 400                                 next_round = time + 5;
 401                                 champion = find(world, classname, "player");
 402                                 if(champion_name)
 403                                         strunzone(champion_name);
 404                                 champion_name = strzone(champion.netname);
 405                         }
 406                         else if((!redspawned && !bluespawned) || time - warmup > autocvar_g_ca_round_timelimit) {
 407                                 FOR_EACH_CLIENT(self) centerprint(self, strcat("^7Round tied.", "^7\n"));
 408                                 next_round = time + 5;
 409                         }
 410
 411                 }
 412                 if(!stopalivecheck)
 413                 {
 414                         if(redalive && !bluealive)
 415                         {
 416                                 play2all("ctf/red_capture.wav");
 417                                 FOR_EACH_CLIENT(self) centerprint(self, "^1 RED ^7team wins the round.\n");
 418                                 TeamScore_AddToTeam(COLOR_TEAM1, ST_SCORE, +1);
 419                                 stopalivecheck = TRUE;
 420                         }
 421                         else if(bluealive && !redalive)
 422                         {
 423                                 play2all("ctf/blue_capture.wav");
 424                                 FOR_EACH_CLIENT(self) centerprint(self, "^4 BLUE ^7team wins the round.\n");
 425                                 TeamScore_AddToTeam(COLOR_TEAM2, ST_SCORE, +1);
 426                                 stopalivecheck = TRUE;
 427                         }
 428                 }
 429
 430                 if((next_round && next_round < time))
 431                 {
 432                         stopalivecheck = FALSE;
 433                         next_round = 0;
 434                         reset_map(TRUE);
 435                 }
 436         } else if(g_freezetag) {
 437                 if((next_round && next_round < time))
 438                 {
 439                         next_round = 0;
 440                         reset_map(TRUE);
 441                 }
 442         } else { // arena
 443                 //extend next_round if it isn't set yet and only 1 player is spawned
 444                 if(!next_round)
 445                 if(numspawned < 2)
 446                         next_round = time + 3;
 447
 448                 if(!arena_roundbased || (next_round && next_round < time && player_count > 1))
 449                 {
 450                         next_round = 0;
 451
 452                         if(arena_roundbased)
 453                         {
 454                                 champion = find(world, classname, "player");
 455                                 while(champion && champion.deadflag)
 456                                         champion = find(champion, classname, "player");
 457                                 reset_map(TRUE);
 458                         }
 459
 460                         while(numspawned < maxspawned && spawnqueue_first)
 461                         {
 462                                 self = spawnqueue_first;
 463
 464                                 bprint ("^4", self.netname, "^4 is the next challenger\n");
 465
 466                                 Spawnqueue_Remove(self);
 467                                 Spawnqueue_Mark(self);
 468
 469                                 self.classname = "player";
 470                                 PutClientInServer();
 471                         }
 472                 }
 473         }
 474 }