qcsrc/server/arena.qc

   1 float maxspawned;
   2 float numspawned;
   3 float arena_roundbased;
   4 .float spawned;
   5 .entity spawnqueue_next;
   6 .entity spawnqueue_prev;
   7 .float spawnqueue_in;
   8 entity spawnqueue_first;
   9 entity spawnqueue_last;
  10 entity champion;
  11 float warmup;
  12 .float caplayer;
  13
  14 void PutObserverInServer();
  15 void PutClientInServer();
  16
  17 float next_round;
  18 float redalive, bluealive, yellowalive, pinkalive;
  19 float totalalive;
  20 .float redalive_stat, bluealive_stat, yellowalive_stat, pinkalive_stat;
  21 float red_players, blue_players, yellow_players, pink_players;
  22 float total_players;
  23
  24 /**
  25  * Resets the state of all clients, items, flags, runes, keys, weapons, waypoints, ... of the map.
  26  * Sets the 'warmup' global variable.
  27  */
  28 void reset_map(float dorespawn)
  29 {
  30         entity oldself;
  31         oldself = self;
  32
  33         if(g_arena && autocvar_g_arena_warmup)
  34                 warmup = time + autocvar_g_arena_warmup;
  35         else if(g_ca) {
  36                 warmup = time + autocvar_g_ca_warmup;
  37                 allowed_to_spawn = 1;
  38         }
  39         else if(g_freezetag)
  40         {
  41                 warmup = time + autocvar_g_freezetag_warmup;
  42         }
  43
  44         lms_lowest_lives = 999;
  45         lms_next_place = player_count;
  46
  47         race_ReadyRestart();
  48
  49         for(self = world; (self = nextent(self)); )
  50         if(clienttype(self) == CLIENTTYPE_NOTACLIENT && self.items != IT_STRENGTH && self.items != IT_INVINCIBLE) // don't respawn strength or shield, that will only lead to them spawning very early each match
  51         {
  52                 if(self.reset)
  53                 {
  54                         self.reset();
  55                         continue;
  56                 }
  57
  58                 if(self.team_saved)
  59                         self.team = self.team_saved;
  60
  61                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
  62                         remove(self);
  63         }
  64
  65         // Waypoints and assault start come LAST
  66         for(self = world; (self = nextent(self)); )
  67         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
  68         {
  69                 if(self.reset2)
  70                 {
  71                         self.reset2();
  72                         continue;
  73                 }
  74         }
  75
  76         // Moving the player reset code here since the player-reset depends
  77         // on spawnpoint entities which have to be reset first --blub
  78         if(dorespawn)
  79         FOR_EACH_CLIENT(self) {
  80                 if(self.flags & FL_CLIENT)                              // reset all players
  81                 {
  82                         if(g_arena)
  83                         {
  84                                 if(self.spawned)
  85                                         PutClientInServer();
  86                                 else
  87                                         PutObserverInServer();
  88                         }
  89                         else if(g_ca && self.caplayer) {
  90                                 self.classname = "player";
  91                                 PutClientInServer();
  92                         }
  93                         else if(g_freezetag)
  94                         {
  95                                 if(self.classname == "player")
  96                                         PutClientInServer();
  97                         }
  98                         else
  99                         {
 100                                 /*
 101                                 only reset players if a restart countdown is active
 102                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 103                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 104                                 sv_ready_restart_after_countdown is not used and countdown is still running
 105                                 */
 106                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 107                                 {
 108                                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 109                                         if (self.classname == "player") {
 110                                                 //PlayerScore_Clear(self);
 111                                                 if(g_lms)
 112                                                         PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
 113                                                 self.killcount = 0;
 114                                                 //stop the player from moving so that he stands still once he gets respawned
 115                                                 self.velocity = '0 0 0';
 116                                                 self.avelocity = '0 0 0';
 117                                                 self.movement = '0 0 0';
 118                                                 PutClientInServer();
 119                                         }
 120                                 }
 121                         }
 122                 }
 123         }
 124
 125         if(g_keyhunt)
 126                 kh_Controller_SetThink_NoMsg(autocvar_g_balance_keyhunt_delay_round+(game_starttime - time), kh_StartRound);
 127
 128         if(g_arena)
 129         if(champion && champion.classname == "player" && player_count > 1)
 130                 UpdateFrags(champion, +1);
 131
 132         self = oldself;
 133 }
 134
 135 void Spawnqueue_Insert(entity e)
 136 {
 137         if(e.spawnqueue_in)
 138                 return;
 139         dprint(strcat("Into queue: ", e.netname, "\n"));
 140         e.spawnqueue_in = TRUE;
 141         e.spawnqueue_prev = spawnqueue_last;
 142         e.spawnqueue_next = world;
 143         if(spawnqueue_last)
 144                 spawnqueue_last.spawnqueue_next = e;
 145         spawnqueue_last = e;
 146         if(!spawnqueue_first)
 147                 spawnqueue_first = e;
 148 }
 149
 150 void Spawnqueue_Remove(entity e)
 151 {
 152         if(!e.spawnqueue_in)
 153                 return;
 154         dprint(strcat("Out of queue: ", e.netname, "\n"));
 155         e.spawnqueue_in = FALSE;
 156         if(e == spawnqueue_first)
 157                 spawnqueue_first = e.spawnqueue_next;
 158         if(e == spawnqueue_last)
 159                 spawnqueue_last = e.spawnqueue_prev;
 160         if(e.spawnqueue_prev)
 161                 e.spawnqueue_prev.spawnqueue_next = e.spawnqueue_next;
 162         if(e.spawnqueue_next)
 163                 e.spawnqueue_next.spawnqueue_prev = e.spawnqueue_prev;
 164         e.spawnqueue_next = world;
 165         e.spawnqueue_prev = world;
 166 }
 167
 168 void Spawnqueue_Unmark(entity e)
 169 {
 170         if(!e.spawned)
 171                 return;
 172         e.spawned = FALSE;
 173         numspawned = numspawned - 1;
 174 }
 175
 176 void Spawnqueue_Mark(entity e)
 177 {
 178         if(e.spawned)
 179                 return;
 180         e.spawned = TRUE;
 181         numspawned = numspawned + 1;
 182 }
 183
 184 /**
 185  * If roundbased arena game mode is active, it centerprints the texts for the
 186  * player when player is waiting for the countdown to finish.
 187  * Blocks the players movement while countdown is active.
 188  * Unblocks the player once the countdown is over.
 189  *
 190  * Called in StartFrame()
 191  */
 192 float roundStartTime_prev; // prevent networkspam
 193 void Arena_Warmup()
 194 {
 195         float f;
 196         entity e;
 197
 198         if(gameover)
 199         {
 200                 if(warmup && time < warmup)
 201                 {
 202                         FOR_EACH_REALCLIENT(e)
 203                                 Send_CSQC_Centerprint_Generic_Expire(e, CPID_ROUND_STARTING);
 204                         warmup = 0;
 205                 }
 206                 if(champion && g_arena)
 207                 {
 208                         FOR_EACH_REALCLIENT(e)
 209                                 centerprint(e, strcat("The Champion is ", champion.netname));
 210                         champion = world;
 211                 }
 212                 return;
 213         }
 214         if((!g_arena && !g_ca && !g_freezetag) || (g_arena && !arena_roundbased) || (time < game_starttime))
 215                 return;
 216
 217         f = ceil(warmup - time);
 218
 219         if(inWarmupStage)
 220                 allowed_to_spawn = 1;
 221         else if(!g_ca)
 222                 allowed_to_spawn = 0;
 223
 224         if(time < warmup && !inWarmupStage)
 225         {
 226                 if (g_ca)
 227                         allowed_to_spawn = 1;
 228                 if(champion && g_arena)
 229                 {
 230                         FOR_EACH_REALCLIENT(e)
 231                                 centerprint(e, strcat("The Champion is ", champion.netname));
 232                 }
 233
 234                 if(f != roundStartTime_prev) {
 235                         roundStartTime_prev = f;
 236                         if(g_ca && !(red_players && blue_players)) {
 237                                 FOR_EACH_REALCLIENT(self)
 238                                         Send_CSQC_Centerprint_Generic(self, CPID_ROUND_STARTING, "^1Need at least 1 player in each team to play CA", 2, 0);
 239                                 warmup = time + autocvar_g_ca_warmup;
 240                         } else {
 241                                 if(f == 5)
 242                                         Announce("prepareforbattle");
 243                                 else if(f == 3)
 244                                         Announce("3");
 245                                 else if(f == 2)
 246                                         Announce("2");
 247                                 else if(f == 1)
 248                                         Announce("1");
 249
 250                                 FOR_EACH_REALCLIENT(e)
 251                                         Send_CSQC_Centerprint_Generic(e, CPID_ROUND_STARTING, "Round will start in %d", 1, f);
 252                         }
 253                 }
 254
 255                 if (g_arena) {
 256                         FOR_EACH_CLIENT(e)
 257                         {
 258                                 if(e.spawned && e.classname == "player")
 259                                         e.movetype = MOVETYPE_NONE;
 260                                 e.velocity = '0 0 0';
 261                                 e.avelocity = '0 0 0';
 262                                 e.movement = '0 0 0';
 263                         }
 264                 }
 265         }
 266         else if(f > -1 && f != roundStartTime_prev)
 267         {
 268                 roundStartTime_prev = f;
 269                 if(g_ca) {
 270                         if(red_players && blue_players)
 271                                 allowed_to_spawn = 0;
 272                         else
 273                                 reset_map(TRUE);
 274                 } else {
 275                         Announce("begin");
 276                         FOR_EACH_REALCLIENT(e)
 277                                 Send_CSQC_Centerprint_Generic(e, CPID_ROUND_STARTING, "^1Begin!", 1, 0);
 278                 }
 279
 280                 if(g_arena) {
 281                         FOR_EACH_PLAYER(e)
 282                         {
 283                                 if(e.health > 0 && e.movetype == MOVETYPE_NONE)
 284                                         e.movetype = MOVETYPE_WALK;
 285                         }
 286                 }
 287         }
 288
 289         // clear champion to avoid centerprinting again the champion msg
 290         if (champion)
 291                 champion = world;
 292 }
 293
 294 void count_players()
 295 {
 296         // count amount of players in each team
 297         total_players = red_players = blue_players = yellow_players = pink_players = 0;
 298         FOR_EACH_PLAYER(self) {
 299                 if (self.team == COLOR_TEAM1)
 300                 {
 301                         red_players += 1;
 302                         total_players += 1;
 303                 }
 304                 else if (self.team == COLOR_TEAM2)
 305                 {
 306                         blue_players += 1;
 307                         total_players += 1;
 308                 }
 309                 else if (self.team == COLOR_TEAM3)
 310                 {
 311                         yellow_players += 1;
 312                         total_players += 1;
 313                 }
 314                 else if (self.team == COLOR_TEAM4)
 315                 {
 316                         pink_players += 1;
 317                         total_players += 1;
 318                 }
 319         }
 320 }
 321
 322 void count_alive_players()
 323 {
 324         totalalive = redalive = bluealive = yellowalive = pinkalive = 0;
 325         if(g_ca)
 326         {
 327                 FOR_EACH_PLAYER(self) {
 328                         if (self.team == COLOR_TEAM1 && self.health >= 1)
 329                         {
 330                                 redalive += 1;
 331                                 totalalive += 1;
 332                         }
 333                         else if (self.team == COLOR_TEAM2 && self.health >= 1)
 334                         {
 335                                 bluealive += 1;
 336                                 totalalive += 1;
 337                         }
 338                 }
 339                 FOR_EACH_REALCLIENT(self) {
 340                         self.redalive_stat = redalive;
 341                         self.bluealive_stat = bluealive;
 342                 }
 343         }
 344         else if(g_freezetag)
 345         {
 346                 // count amount of alive players in each team
 347                 FOR_EACH_PLAYER(self) {
 348                         if (self.team == COLOR_TEAM1 && self.freezetag_frozen == 0 && self.health >= 1)
 349                         {
 350                                 redalive += 1;
 351                                 totalalive += 1;
 352                         }
 353                         else if (self.team == COLOR_TEAM2 && self.freezetag_frozen == 0 && self.health >= 1)
 354                         {
 355                                 bluealive += 1;
 356                                 totalalive += 1;
 357                         }
 358                         else if (self.team == COLOR_TEAM3 && self.freezetag_frozen == 0 && self.health >= 1)
 359                         {
 360                                 yellowalive += 1;
 361                                 totalalive += 1;
 362                         }
 363                         else if (self.team == COLOR_TEAM4 && self.freezetag_frozen == 0 && self.health >= 1)
 364                         {
 365                                 pinkalive += 1;
 366                                 totalalive += 1;
 367                         }
 368                 }
 369                 FOR_EACH_REALCLIENT(self) {
 370                         self.redalive_stat = redalive;
 371                         self.bluealive_stat = bluealive;
 372                         self.yellowalive_stat = yellowalive;
 373                         self.pinkalive_stat = pinkalive;
 374                 }
 375         }
 376
 377 }
 378
 379 /**
 380  * This function finds out whether an arena round is over 1 player is left.
 381  * It determines the last player who's still alive and saves it's entity reference
 382  * in the global variable 'champion'. Then the new enemy/enemies are put into the server.
 383  *
 384  * Gets called in StartFrame()
 385  */
 386 void Spawnqueue_Check()
 387 {
 388         if(warmup == 0 && g_ca)
 389         {
 390                 if(red_players || blue_players)
 391                         reset_map(TRUE);
 392                 return;
 393         }
 394         if(time < warmup + 1 || inWarmupStage || intermission_running)
 395                 return;
 396
 397         if(g_ca) {
 398                 if(allowed_to_spawn) // round is not started yet
 399                         return;
 400                 if(!next_round) {
 401                         if(!(redalive && bluealive)) {
 402                                 // every player of (at least) one team is dead, round ends here
 403                                 if(redalive) {
 404                                         play2all("ctf/red_capture.wav");
 405                                         FOR_EACH_CLIENT(self) centerprint(self, "^1RED ^7team wins the round");
 406                                         TeamScore_AddToTeam(COLOR_TEAM1, ST_SCORE, +1);
 407                                 }
 408                                 else if(bluealive) {
 409                                         play2all("ctf/blue_capture.wav");
 410                                         FOR_EACH_CLIENT(self) centerprint(self, "^4BLUE ^7team wins the round");
 411                                         TeamScore_AddToTeam(COLOR_TEAM2, ST_SCORE, +1);
 412                                 }
 413                                 else
 414                                         FOR_EACH_CLIENT(self) centerprint(self, "^7Round tied");
 415                                 next_round = -1;
 416                         }
 417                         else if(time - warmup > autocvar_g_ca_round_timelimit) {
 418                                 FOR_EACH_CLIENT(self) centerprint(self, "^7Round tied");
 419                                 next_round = time + 5;
 420                         }
 421                 }
 422                 else if(next_round == -1) {
 423                         // wait for killed players to be put as spectators
 424                         if(!(red_players && blue_players))
 425                                 next_round = time + 5;
 426                 }
 427                 else if((next_round > 0 && next_round < time))
 428                 {
 429                         next_round = 0;
 430                         reset_map(TRUE);
 431                 }
 432         } else if(g_freezetag) {
 433                 if((next_round && next_round < time))
 434                 {
 435                         next_round = 0;
 436                         reset_map(TRUE);
 437                 }
 438         } else { // arena
 439                 //extend next_round if it isn't set yet and only 1 player is spawned
 440                 if(!next_round)
 441                 if(numspawned < 2)
 442                         next_round = time + 3;
 443
 444                 if(!arena_roundbased || (next_round && next_round < time && player_count > 1))
 445                 {
 446                         next_round = 0;
 447
 448                         if(arena_roundbased)
 449                         {
 450                                 champion = find(world, classname, "player");
 451                                 while(champion && champion.deadflag)
 452                                         champion = find(champion, classname, "player");
 453                                 reset_map(TRUE);
 454                         }
 455
 456                         while(numspawned < maxspawned && spawnqueue_first)
 457                         {
 458                                 self = spawnqueue_first;
 459
 460                                 bprint ("^4", self.netname, "^4 is the next challenger\n");
 461
 462                                 Spawnqueue_Remove(self);
 463                                 Spawnqueue_Mark(self);
 464
 465                                 self.classname = "player";
 466                                 PutClientInServer();
 467                         }
 468                 }
 469         }
 470 }