qcsrc/server/arena.qc

   1 float maxspawned;
   2 float numspawned;
   3 float arena_roundbased;
   4 .float spawned;
   5 .entity spawnqueue_next;
   6 .entity spawnqueue_prev;
   7 .float spawnqueue_in;
   8 entity spawnqueue_first;
   9 entity spawnqueue_last;
  10 entity champion;
  11 float warmup;
  12 .float caplayer;
  13
  14 void PutObserverInServer();
  15 void PutClientInServer();
  16
  17 float next_round;
  18 float redalive, bluealive, yellowalive, pinkalive;
  19 float totalalive;
  20 .float redalive_stat, bluealive_stat, yellowalive_stat, pinkalive_stat;
  21 float red_players, blue_players, yellow_players, pink_players;
  22 float total_players;
  23
  24 /**
  25  * Resets the state of all clients, items, flags, runes, keys, weapons, waypoints, ... of the map.
  26  * Sets the 'warmup' global variable.
  27  */
  28 void reset_map(float dorespawn)
  29 {
  30         entity oldself;
  31         oldself = self;
  32
  33         if(g_arena && autocvar_g_arena_warmup)
  34                 warmup = time + autocvar_g_arena_warmup;
  35         else if(g_ca) {
  36                 warmup = time + autocvar_g_ca_warmup;
  37                 allowed_to_spawn = 1;
  38         }
  39         else if(g_freezetag)
  40         {
  41                 warmup = time + autocvar_g_freezetag_warmup;
  42         }
  43
  44         lms_lowest_lives = 999;
  45         lms_next_place = player_count;
  46
  47         race_ReadyRestart();
  48
  49         for(self = world; (self = nextent(self)); )
  50         if(clienttype(self) == CLIENTTYPE_NOTACLIENT && self.items != IT_STRENGTH && self.items != IT_INVINCIBLE) // don't respawn strength or shield, that will only lead to them spawning very early each match
  51         {
  52                 if(self.reset)
  53                 {
  54                         self.reset();
  55                         continue;
  56                 }
  57
  58                 if(self.team_saved)
  59                         self.team = self.team_saved;
  60
  61                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
  62                         remove(self);
  63         }
  64
  65         // Waypoints and assault start come LAST
  66         for(self = world; (self = nextent(self)); )
  67         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
  68         {
  69                 if(self.reset2)
  70                 {
  71                         self.reset2();
  72                         continue;
  73                 }
  74         }
  75
  76         // Moving the player reset code here since the player-reset depends
  77         // on spawnpoint entities which have to be reset first --blub
  78         if(dorespawn)
  79         FOR_EACH_CLIENT(self) {
  80                 if(self.flags & FL_CLIENT)                              // reset all players
  81                 {
  82                         if(g_arena)
  83                         {
  84                                 if(self.spawned)
  85                                         PutClientInServer();
  86                                 else
  87                                         PutObserverInServer();
  88                         }
  89                         else if(g_ca && self.caplayer) {
  90                                 self.classname = "player";
  91                                 PutClientInServer();
  92                         }
  93                         else if(g_freezetag)
  94                         {
  95                                 if(self.classname == "player")
  96                                         PutClientInServer();
  97                         }
  98                         else
  99                         {
 100                                 /*
 101                                 only reset players if a restart countdown is active
 102                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 103                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 104                                 sv_ready_restart_after_countdown is not used and countdown is still running
 105                                 */
 106                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 107                                 {
 108                                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 109                                         if (self.classname == "player") {
 110                                                 //PlayerScore_Clear(self);
 111                                                 if(g_lms)
 112                                                         PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
 113                                                 self.killcount = 0;
 114                                                 //stop the player from moving so that he stands still once he gets respawned
 115                                                 self.velocity = '0 0 0';
 116                                                 self.avelocity = '0 0 0';
 117                                                 self.movement = '0 0 0';
 118                                                 PutClientInServer();
 119                                         }
 120                                 }
 121                         }
 122                 }
 123         }
 124
 125         if(g_keyhunt)
 126                 kh_Controller_SetThink_NoMsg(autocvar_g_balance_keyhunt_delay_round+(game_starttime - time), kh_StartRound);
 127
 128         if(g_arena)
 129         if(champion && champion.classname == "player" && player_count > 1)
 130                 UpdateFrags(champion, +1);
 131
 132         self = oldself;
 133 }
 134
 135 void Spawnqueue_Insert(entity e)
 136 {
 137         if(e.spawnqueue_in)
 138                 return;
 139         dprint(strcat("Into queue: ", e.netname, "\n"));
 140         e.spawnqueue_in = TRUE;
 141         e.spawnqueue_prev = spawnqueue_last;
 142         e.spawnqueue_next = world;
 143         if(spawnqueue_last)
 144                 spawnqueue_last.spawnqueue_next = e;
 145         spawnqueue_last = e;
 146         if(!spawnqueue_first)
 147                 spawnqueue_first = e;
 148 }
 149
 150 void Spawnqueue_Remove(entity e)
 151 {
 152         if(!e.spawnqueue_in)
 153                 return;
 154         dprint(strcat("Out of queue: ", e.netname, "\n"));
 155         e.spawnqueue_in = FALSE;
 156         if(e == spawnqueue_first)
 157                 spawnqueue_first = e.spawnqueue_next;
 158         if(e == spawnqueue_last)
 159                 spawnqueue_last = e.spawnqueue_prev;
 160         if(e.spawnqueue_prev)
 161                 e.spawnqueue_prev.spawnqueue_next = e.spawnqueue_next;
 162         if(e.spawnqueue_next)
 163                 e.spawnqueue_next.spawnqueue_prev = e.spawnqueue_prev;
 164         e.spawnqueue_next = world;
 165         e.spawnqueue_prev = world;
 166 }
 167
 168 void Spawnqueue_Unmark(entity e)
 169 {
 170         if(!e.spawned)
 171                 return;
 172         e.spawned = FALSE;
 173         numspawned = numspawned - 1;
 174 }
 175
 176 void Spawnqueue_Mark(entity e)
 177 {
 178         if(e.spawned)
 179                 return;
 180         e.spawned = TRUE;
 181         numspawned = numspawned + 1;
 182 }
 183
 184 /**
 185  * If roundbased arena game mode is active, it centerprints the texts for the
 186  * player when player is waiting for the countdown to finish.
 187  * Blocks the players movement while countdown is active.
 188  * Unblocks the player once the countdown is over.
 189  *
 190  * Called in StartFrame()
 191  */
 192 float roundStartTime_prev; // prevent networkspam
 193 void Arena_Warmup()
 194 {
 195         float f;
 196         entity e;
 197
 198         if(gameover)
 199         {
 200                 if(champion && g_arena)
 201                 {
 202                         FOR_EACH_CLIENT(e)
 203                                 centerprint(e, strcat("The Champion is ", champion.netname));
 204                         champion = world;
 205                 }
 206                 return;
 207         }
 208         if((!g_arena && !g_ca && !g_freezetag) || (g_arena && !arena_roundbased) || (time < game_starttime))
 209                 return;
 210
 211         f = ceil(warmup - time);
 212
 213         if(inWarmupStage)
 214                 allowed_to_spawn = 1;
 215         else if(!g_ca)
 216                 allowed_to_spawn = 0;
 217
 218         if(time < warmup && !inWarmupStage)
 219         {
 220                 if (g_ca)
 221                         allowed_to_spawn = 1;
 222                 if(champion && g_arena)
 223                 {
 224                         FOR_EACH_PLAYER(e)
 225                                 centerprint(e, strcat("The Champion is ", champion.netname));
 226                 }
 227
 228                 if(f != roundStartTime_prev) {
 229                         roundStartTime_prev = f;
 230                         if(g_ca && !(red_players && blue_players)) {
 231                                 FOR_EACH_PLAYER(self)
 232                                         Send_CSQC_Centerprint_Generic(self, CPID_ROUND_STARTING, "^1Need at least 1 player in each team to play CA", 2, 0);
 233                                 warmup = time + autocvar_g_ca_warmup;
 234                         } else {
 235                                 if(f == 5)
 236                                         Announce("prepareforbattle");
 237                                 else if(f == 3)
 238                                         Announce("3");
 239                                 else if(f == 2)
 240                                         Announce("2");
 241                                 else if(f == 1)
 242                                         Announce("1");
 243
 244                                 FOR_EACH_PLAYER(e)
 245                                         Send_CSQC_Centerprint_Generic(e, CPID_ROUND_STARTING, "Round will start in %d", 1, f);
 246                         }
 247                 }
 248
 249                 if (g_arena) {
 250                         FOR_EACH_CLIENT(e)
 251                         {
 252                                 if(e.spawned && e.classname == "player")
 253                                         e.movetype = MOVETYPE_NONE;
 254                                 e.velocity = '0 0 0';
 255                                 e.avelocity = '0 0 0';
 256                                 e.movement = '0 0 0';
 257                         }
 258                 }
 259         }
 260         else if(f > -1 && f != roundStartTime_prev)
 261         {
 262                 roundStartTime_prev = f;
 263                 if(g_ca) {
 264                         if(red_players && blue_players)
 265                                 allowed_to_spawn = 0;
 266                         else
 267                                 reset_map(TRUE);
 268                 } else {
 269                         Announce("begin");
 270                         FOR_EACH_PLAYER(e)
 271                                 Send_CSQC_Centerprint_Generic(e, CPID_ROUND_STARTING, "^1Begin!", 1, 0);
 272                 }
 273
 274                 if(g_arena) {
 275                         FOR_EACH_PLAYER(e)
 276                         {
 277                                 if(e.health > 0 && e.movetype == MOVETYPE_NONE)
 278                                         e.movetype = MOVETYPE_WALK;
 279                         }
 280                 }
 281         }
 282
 283         // clear champion to avoid centerprinting again the champion msg
 284         if (champion)
 285                 champion = world;
 286 }
 287
 288 void count_players()
 289 {
 290         // count amount of players in each team
 291         total_players = red_players = blue_players = yellow_players = pink_players = 0;
 292         FOR_EACH_PLAYER(self) {
 293                 if (self.team == COLOR_TEAM1)
 294                 {
 295                         red_players += 1;
 296                         total_players += 1;
 297                 }
 298                 else if (self.team == COLOR_TEAM2)
 299                 {
 300                         blue_players += 1;
 301                         total_players += 1;
 302                 }
 303                 else if (self.team == COLOR_TEAM3)
 304                 {
 305                         yellow_players += 1;
 306                         total_players += 1;
 307                 }
 308                 else if (self.team == COLOR_TEAM4)
 309                 {
 310                         pink_players += 1;
 311                         total_players += 1;
 312                 }
 313         }
 314 }
 315
 316 void count_alive_players()
 317 {
 318         totalalive = redalive = bluealive = yellowalive = pinkalive = 0;
 319         if(g_ca)
 320         {
 321                 FOR_EACH_PLAYER(self) {
 322                         if (self.team == COLOR_TEAM1 && self.health >= 1)
 323                         {
 324                                 redalive += 1;
 325                                 totalalive += 1;
 326                         }
 327                         else if (self.team == COLOR_TEAM2 && self.health >= 1)
 328                         {
 329                                 bluealive += 1;
 330                                 totalalive += 1;
 331                         }
 332                 }
 333                 FOR_EACH_REALCLIENT(self) {
 334                         self.redalive_stat = redalive;
 335                         self.bluealive_stat = bluealive;
 336                 }
 337         }
 338         else if(g_freezetag)
 339         {
 340                 // count amount of alive players in each team
 341                 FOR_EACH_PLAYER(self) {
 342                         if (self.team == COLOR_TEAM1 && self.freezetag_frozen == 0 && self.health >= 1)
 343                         {
 344                                 redalive += 1;
 345                                 totalalive += 1;
 346                         }
 347                         else if (self.team == COLOR_TEAM2 && self.freezetag_frozen == 0 && self.health >= 1)
 348                         {
 349                                 bluealive += 1;
 350                                 totalalive += 1;
 351                         }
 352                         else if (self.team == COLOR_TEAM3 && self.freezetag_frozen == 0 && self.health >= 1)
 353                         {
 354                                 yellowalive += 1;
 355                                 totalalive += 1;
 356                         }
 357                         else if (self.team == COLOR_TEAM4 && self.freezetag_frozen == 0 && self.health >= 1)
 358                         {
 359                                 pinkalive += 1;
 360                                 totalalive += 1;
 361                         }
 362                 }
 363                 FOR_EACH_REALCLIENT(self) {
 364                         self.redalive_stat = redalive;
 365                         self.bluealive_stat = bluealive;
 366                         self.yellowalive_stat = yellowalive;
 367                         self.pinkalive_stat = pinkalive;
 368                 }
 369         }
 370
 371 }
 372
 373 /**
 374  * This function finds out whether an arena round is over 1 player is left.
 375  * It determines the last player who's still alive and saves it's entity reference
 376  * in the global variable 'champion'. Then the new enemy/enemies are put into the server.
 377  *
 378  * Gets called in StartFrame()
 379  */
 380 void Spawnqueue_Check()
 381 {
 382         if(warmup == 0 && g_ca)
 383         {
 384                 if(red_players || blue_players)
 385                         reset_map(TRUE);
 386                 return;
 387         }
 388         if(time < warmup + 1 || inWarmupStage || intermission_running)
 389                 return;
 390
 391         if(g_ca) {
 392                 if(allowed_to_spawn) // round is not started yet
 393                         return;
 394                 if(!next_round) {
 395                         if(!(redalive && bluealive)) {
 396                                 // every player of (at least) one team is dead, round ends here
 397                                 if(redalive) {
 398                                         play2all("ctf/red_capture.wav");
 399                                         FOR_EACH_CLIENT(self) centerprint(self, "^1RED ^7team wins the round");
 400                                         TeamScore_AddToTeam(COLOR_TEAM1, ST_SCORE, +1);
 401                                 }
 402                                 else if(bluealive) {
 403                                         play2all("ctf/blue_capture.wav");
 404                                         FOR_EACH_CLIENT(self) centerprint(self, "^4BLUE ^7team wins the round");
 405                                         TeamScore_AddToTeam(COLOR_TEAM2, ST_SCORE, +1);
 406                                 }
 407                                 else
 408                                         FOR_EACH_CLIENT(self) centerprint(self, "^7Round tied");
 409                                 next_round = -1;
 410                         }
 411                         else if(time - warmup > autocvar_g_ca_round_timelimit) {
 412                                 FOR_EACH_CLIENT(self) centerprint(self, "^7Round tied");
 413                                 next_round = time + 5;
 414                         }
 415                 }
 416                 else if(next_round == -1) {
 417                         // wait for killed players to be put as spectators
 418                         if(!(red_players && blue_players))
 419                                 next_round = time + 5;
 420                 }
 421                 else if((next_round > 0 && next_round < time))
 422                 {
 423                         next_round = 0;
 424                         reset_map(TRUE);
 425                 }
 426         } else if(g_freezetag) {
 427                 if((next_round && next_round < time))
 428                 {
 429                         next_round = 0;
 430                         reset_map(TRUE);
 431                 }
 432         } else { // arena
 433                 //extend next_round if it isn't set yet and only 1 player is spawned
 434                 if(!next_round)
 435                 if(numspawned < 2)
 436                         next_round = time + 3;
 437
 438                 if(!arena_roundbased || (next_round && next_round < time && player_count > 1))
 439                 {
 440                         next_round = 0;
 441
 442                         if(arena_roundbased)
 443                         {
 444                                 champion = find(world, classname, "player");
 445                                 while(champion && champion.deadflag)
 446                                         champion = find(champion, classname, "player");
 447                                 reset_map(TRUE);
 448                         }
 449
 450                         while(numspawned < maxspawned && spawnqueue_first)
 451                         {
 452                                 self = spawnqueue_first;
 453
 454                                 bprint ("^4", self.netname, "^4 is the next challenger\n");
 455
 456                                 Spawnqueue_Remove(self);
 457                                 Spawnqueue_Mark(self);
 458
 459                                 self.classname = "player";
 460                                 PutClientInServer();
 461                         }
 462                 }
 463         }
 464 }