qcsrc/server/attic/monsters/m_monsters.qc

   1 /* ALL MONSTERS SHOULD BE 1 0 0 IN COLOR */
   2
   3 // name =[framenum,     nexttime, nextthink] {code}
   4 // expands to:
   5 // name ()
   6 // {
   7 //              self.frame=framenum;
   8 //              self.nextthink = time + nexttime;
   9 //              self.think = nextthink
  10 //              <code>
  11 // }
  12
  13 .float ismonster;
  14
  15 .float modelindex2;
  16
  17 /*
  18 ================
  19 monster_use
  20
  21 Using a monster makes it angry at the current activator
  22 LordHavoc: using a monster with the spawnflag 'Appear' makes it appear
  23 ================
  24 */
  25 void() monster_use =
  26 {
  27         if (self.enemy)
  28                 return;
  29         if (self.health < 1)
  30                 return;
  31         if (self.mdl)
  32         if (self.spawnflags & MONSTER_APPEAR)
  33         {
  34                 self.nextthink = time + 0.1;
  35                 self.spawnflags = self.spawnflags - MONSTER_APPEAR;
  36                 self.solid = SOLID_SLIDEBOX;
  37                 self.takedamage = DAMAGE_AIM;
  38                 //self.movetype = MOVETYPE_STEP;
  39                 self.model = self.mdl;
  40                 self.mdl = "";
  41                 self.modelindex = self.modelindex2;
  42                 self.modelindex2 = 0;
  43                 //setorigin(self, self.origin + '0 0 1');
  44                 spawn_tdeath(self.origin, self, self.origin);
  45                 return;
  46         }
  47
  48 #if 0
  49         if (activator.items & IT_INVISIBILITY)
  50                 return;
  51 #endif
  52         if (activator.flags & FL_NOTARGET)
  53                 return;
  54         if (activator.classname != "player")
  55                 return;
  56
  57         // delay reaction so if the monster is teleported, its sound is still heard
  58         self.enemy = activator;
  59         self.nextthink = time + 0.1;
  60         self.think = FoundTarget;
  61 }
  62
  63 void() monster_appearsetup =
  64 {
  65         if ((self.spawnflags & MONSTER_APPEAR) == 0)
  66                 return;
  67         self.mdl = self.model;
  68         self.modelindex2 = self.modelindex;
  69         self.modelindex = 0;
  70         self.solid = SOLID_NOT;
  71         self.takedamage = DAMAGE_NO;
  72         //self.movetype = MOVETYPE_NONE;
  73         self.nextthink = -1;
  74         self.model = "";
  75 }
  76
  77 /*
  78 ================
  79 monster_setalpha
  80
  81 Sets relative alpha of monster in skill 4 mode.
  82 ================
  83 */
  84 void(float a) monster_setalpha =
  85 {
  86         if (skill < 4 || self.classname == "monster_hellfish")
  87         {
  88                 self.alpha = 1.0;
  89                 return;
  90         }
  91
  92         if (skill >= 5)
  93         {
  94                 // randomly forget enemy, this makes monsters randomly return to their normal ghostlike state
  95                 if (a == 0)
  96                 if (self.enemy)
  97                 if (random() < 0.1)
  98                         self.enemy = world;
  99                 // randomly blink (playing the same alarming sound as if attacking)
 100                 if (self.enemy == world)
 101                 {
 102                         a = 0;
 103                         if (time >= 0.3) // don't blink during the init process because it might become permanent
 104                         if (random() < 0.005)
 105                         {
 106                                 // blink for an instant, this causes the appear sound, alarming the player as if under attack
 107                                 /* PLEASE FIX THE SOUND CHANNEL BEFORE ACTIVATING THIS
 108                                 sound(self, CHAN_AUTO, "wizard/wsight.wav", 1, ATTN_NORM);
 109                                 */
 110                                 a = 1;
 111                         }
 112                 }
 113                 // if ghosted, become non-solid and immune to damage
 114                 if (a <= 0 || self.enemy == world)
 115                 {
 116                         self.solid = SOLID_NOT;
 117                         self.takedamage = DAMAGE_NO;
 118                 }
 119                 else
 120                 {
 121                         // if unghosting, make sure we have an enemy, otherwise stay ghosted (even if blinking) so we can't be shot while blinking
 122                         /* PLEASE FIX THE SOUND CHANNEL BEFORE ACTIVATING THIS
 123                         if (self.solid != SOLID_SLIDEBOX)
 124                                 sound(self, CHAN_AUTO, "wizard/wsight.wav", 1, ATTN_NORM);
 125                         */
 126                         self.solid = SOLID_SLIDEBOX;
 127                         self.takedamage = DAMAGE_AIM;
 128                 }
 129         }
 130         self.alpha = SKILL4_MINALPHA + (1 - SKILL4_MINALPHA) * bound(0, a, 1);
 131 }
 132
 133 /*
 134 ================
 135 monster_death_use
 136
 137 When a mosnter dies, it fires all of its targets with the current
 138 enemy as activator.
 139 ================
 140 */
 141 void() monster_death_use =
 142 {
 143 // fall to ground
 144         if (self.flags & FL_FLY)
 145                 self.flags = self.flags - FL_FLY;
 146         if (self.flags & FL_SWIM)
 147                 self.flags = self.flags - FL_SWIM;
 148
 149         if (!self.target)
 150                 return;
 151
 152         activator = self.enemy;
 153         SUB_UseTargets ();
 154 }
 155
 156
 157 void() monsterinwall =
 158 {
 159         entity e;
 160         if (!autocvar_developer)
 161                 return;
 162         // this is handy for level designers,
 163         // puts a spikey ball where the error is...
 164         e = spawn();
 165         setorigin(e, self.origin);
 166         setmodel (e, "models/ebomb.mdl");
 167         e.movetype = MOVETYPE_NONE;
 168         e.solid = SOLID_NOT;
 169         e.think = SUB_Null;
 170         e.nextthink = -1;
 171         e.scale = 16;
 172 }
 173
 174 //============================================================================
 175
 176 void() walkmonster_start_go =
 177 {
 178         self.origin_z = self.origin_z + 1; // raise off floor a bit
 179
 180         tracebox(self.origin, self.mins, self.maxs, self.origin, TRUE, self);
 181         if (trace_startsolid)
 182         {
 183                 dprint("walkmonster in wall at: ");
 184                 dprint(vtos(self.origin));
 185                 dprint("\n");
 186                 monsterinwall();
 187                 droptofloor();
 188         }
 189         else
 190         {
 191                 droptofloor();
 192                 if (!walkmove(0,0))
 193                 {
 194                         dprint("walkmonster in wall at: ");
 195                         dprint(vtos(self.origin));
 196                         dprint("\n");
 197                         monsterinwall();
 198                 }
 199         }
 200
 201         //self.cantrigger = TRUE;
 202
 203         self.takedamage = DAMAGE_AIM;
 204
 205         self.ideal_yaw = self.angles * '0 1 0';
 206         if (!self.yaw_speed)
 207                 self.yaw_speed = 20;
 208         self.view_ofs = '0 0 25';
 209         self.use = monster_use;
 210
 211         self.flags = self.flags | FL_MONSTER;
 212
 213         if (monsterwander)
 214                 self.spawnflags = self.spawnflags | MONSTER_WANDER;
 215
 216         if (self.target)
 217         {
 218                 self.goalentity = self.movetarget = find(world, targetname, self.target);
 219                 self.ideal_yaw = vectoyaw(self.goalentity.origin - self.origin);
 220                 if (!self.movetarget)
 221                 {
 222                         dprint("Monster can't find target at ");
 223                         dprint(vtos(self.origin));
 224                         dprint("\n");
 225                 }
 226                 // this used to be an objerror
 227                 if (self.movetarget.classname == "path_corner")
 228                         self.th_walk ();
 229                 else
 230                 {
 231                         if ((self.spawnflags & MONSTER_WANDER) && (!self.monsterawaitingteleport) && (self.spawnflags & 3) == 0 && (world.model != "maps/e1m7.bsp"))
 232                         {
 233                                 monster_spawnwanderpath();
 234                                 self.ideal_yaw = vectoyaw(self.goalentity.origin - self.origin);
 235                                 self.th_walk ();
 236                         }
 237                         else
 238                         {
 239                                 self.pausetime = 99999999;
 240                                 self.th_stand ();
 241                         }
 242                 }
 243         }
 244         else
 245         {
 246                 if ((self.spawnflags & MONSTER_WANDER) && (!self.monsterawaitingteleport) && (self.spawnflags & 3) == 0 && (world.model != "maps/e1m7.bsp"))
 247                 {
 248                         monster_spawnwanderpath();
 249                         self.ideal_yaw = vectoyaw(self.goalentity.origin - self.origin);
 250                         self.th_walk ();
 251                 }
 252                 else
 253                 {
 254                         self.pausetime = 99999999;
 255                         self.th_stand ();
 256                 }
 257         }
 258
 259 // spread think times so they don't all happen at same time
 260         self.nextthink = self.nextthink + random()*0.5 + 0.1;
 261         self.iscreature = TRUE;
 262         self.damagedbycontents = TRUE;
 263
 264         force_retouch = 2; // mainly to detect teleports
 265
 266         monster_appearsetup();
 267 }
 268
 269
 270 void() walkmonster_start =
 271 {
 272         self.candrown = 1; // this is turned off by some monsters like zombies
 273         // delay drop to floor to make sure all doors have been spawned
 274         // spread think times so they don't all happen at same time
 275         self.nextthink = time + random()*0.5 + 0.3;
 276         self.think = walkmonster_start_go;
 277         total_monsters = total_monsters + 1;
 278         self.bot_attack = TRUE;
 279         self.frags = 2; // actually just used to get havocbots to attack it...
 280         self.bleedfunc = genericbleedfunc;
 281         self.ismonster = TRUE;
 282
 283         monster_setalpha (0);
 284 }
 285
 286
 287
 288 void() flymonster_start_go =
 289 {
 290         self.takedamage = DAMAGE_AIM;
 291
 292         self.ideal_yaw = self.angles * '0 1 0';
 293         if (!self.yaw_speed)
 294                 self.yaw_speed = 10;
 295         self.view_ofs = '0 0 25';
 296         self.use = monster_use;
 297
 298         self.flags = self.flags | FL_FLY;
 299         self.flags = self.flags | FL_MONSTER;
 300
 301         if (!walkmove(0,0))
 302         {
 303                 dprint("flymonster in wall at: ");
 304                 dprint(vtos(self.origin));
 305                 dprint("\n");
 306                 monsterinwall();
 307         }
 308
 309         //self.cantrigger = TRUE;
 310
 311         if (monsterwander)
 312                 self.spawnflags = self.spawnflags | MONSTER_WANDER;
 313
 314         if (self.target)
 315         {
 316                 self.goalentity = self.movetarget = find(world, targetname, self.target);
 317                 if (!self.movetarget)
 318                 {
 319                         dprint("Monster can't find target at ");
 320                         dprint(vtos(self.origin));
 321                         dprint("\n");
 322                 }
 323                 // this used to be an objerror
 324                 if (self.movetarget.classname == "path_corner")
 325                         self.th_walk ();
 326                 else
 327                 {
 328                         if ((self.spawnflags & MONSTER_WANDER) && (!self.monsterawaitingteleport) && (self.spawnflags & 3) == 0 && (world.model != "maps/e1m7.bsp"))
 329                         {
 330                                 monster_spawnwanderpath();
 331                                 self.ideal_yaw = vectoyaw(self.goalentity.origin - self.origin);
 332                                 self.th_walk ();
 333                         }
 334                         else
 335                         {
 336                                 self.pausetime = 99999999;
 337                                 self.th_stand ();
 338                         }
 339                 }
 340         }
 341         else
 342         {
 343                 if ((self.spawnflags & MONSTER_WANDER) && (!self.monsterawaitingteleport) && (self.spawnflags & 3) == 0 && (world.model != "maps/e1m7.bsp"))
 344                 {
 345                         monster_spawnwanderpath();
 346                         self.ideal_yaw = vectoyaw(self.goalentity.origin - self.origin);
 347                         self.th_walk ();
 348                 }
 349                 else
 350                 {
 351                         self.pausetime = 99999999;
 352                         self.th_stand ();
 353                 }
 354         }
 355         self.iscreature = TRUE;
 356         self.damagedbycontents = TRUE;
 357
 358         force_retouch = 2; // mainly to detect teleports
 359
 360         monster_appearsetup();
 361 }
 362
 363 void() flymonster_start =
 364 {
 365         self.candrown = 1;
 366         // spread think times so they don't all happen at same time
 367         self.nextthink = time + random()*0.5 + 0.1;
 368         self.think = flymonster_start_go;
 369         total_monsters = total_monsters + 1;
 370         self.bot_attack = TRUE;
 371         self.frags = 2; // actually just used to get havocbots to attack it...
 372         self.bleedfunc = genericbleedfunc;
 373         self.ismonster = TRUE;
 374
 375         monster_setalpha (0);
 376 }
 377
 378
 379 void() swimmonster_start_go =
 380 {
 381         if (deathmatch)
 382         {
 383                 remove(self);
 384                 return;
 385         }
 386
 387         //self.cantrigger = TRUE;
 388
 389         self.takedamage = DAMAGE_AIM;
 390
 391         self.ideal_yaw = self.angles * '0 1 0';
 392         if (!self.yaw_speed)
 393                 self.yaw_speed = 10;
 394         self.view_ofs = '0 0 10';
 395         self.use = monster_use;
 396
 397         self.flags = self.flags | FL_SWIM;
 398         self.flags = self.flags | FL_MONSTER;
 399
 400         if (monsterwander)
 401                 self.spawnflags = self.spawnflags | MONSTER_WANDER;
 402
 403         if (self.target)
 404         {
 405                 self.goalentity = self.movetarget = find(world, targetname, self.target);
 406                 if (!self.movetarget)
 407                 {
 408                         dprint("Monster can't find target at ");
 409                         dprint(vtos(self.origin));
 410                         dprint("\n");
 411                 }
 412                 // this used to be an objerror
 413                 if (self.movetarget.classname == "path_corner")
 414                         self.th_walk ();
 415                 else
 416                 {
 417                         if ((self.spawnflags & MONSTER_WANDER) && (!self.monsterawaitingteleport) && (self.spawnflags & 3) == 0 && (world.model != "maps/e1m7.bsp"))
 418                         {
 419                                 monster_spawnwanderpath();
 420                                 self.ideal_yaw = vectoyaw(self.goalentity.origin - self.origin);
 421                                 self.th_walk ();
 422                         }
 423                         else
 424                         {
 425                                 self.pausetime = 99999999;
 426                                 self.th_stand ();
 427                         }
 428                 }
 429         }
 430         else
 431         {
 432                 if ((self.spawnflags & MONSTER_WANDER) && (!self.monsterawaitingteleport) && (self.spawnflags & 3) == 0 && (world.model != "maps/e1m7.bsp"))
 433                 {
 434                         monster_spawnwanderpath();
 435                         self.ideal_yaw = vectoyaw(self.goalentity.origin - self.origin);
 436                         self.th_walk ();
 437                 }
 438                 else
 439                 {
 440                         self.pausetime = 99999999;
 441                         self.th_stand ();
 442                 }
 443         }
 444         self.iscreature = TRUE;
 445         self.damagedbycontents = TRUE;
 446
 447         force_retouch = 2; // mainly to detect teleports
 448
 449         monster_appearsetup();
 450 }
 451
 452 void() swimmonster_start =
 453 {
 454         // spread think times so they don't all happen at same time
 455         self.candrown = 0;
 456         self.nextthink = time + random()*0.5 + 0.1;
 457         self.think = swimmonster_start_go;
 458         total_monsters = total_monsters + 1;
 459         self.bot_attack = TRUE;
 460         self.frags = 2; // actually just used to get havocbots to attack it...
 461         self.bleedfunc = genericbleedfunc;
 462         self.ismonster = TRUE;
 463
 464         monster_setalpha(0);
 465 }
 466
 467 void(vector org, float bodydamage, float armordamage, vector force, float damgtype) genericbleedfunc =
 468 {
 469         vector v;
 470         v = '0 0 0' - force * 0.05;
 471         if (armordamage > 0)
 472                 te_spark(org, v, armordamage * 3);
 473         if (bodydamage > 0)
 474                 te_blood(org, v, bodydamage);
 475 }