qcsrc/server/bot/default/aim.qc

   1 #include "aim.qh"
   2
   3 #include <server/defs.qh>
   4
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8
   9 #include <common/physics/player.qh>
  10 #include <common/state.qh>
  11
  12 #include "../../weapons/weaponsystem.qh"
  13
  14 #include "../../mutators/_mod.qh"
  15
  16 // traces multiple trajectories to find one that will impact the target
  17 // 'end' vector is the place it aims for,
  18 // returns true only if it hit targ (don't target non-solid entities)
  19
  20 float findtrajectorywithleading(vector org, vector m1, vector m2, entity targ, float shotspeed, float shotspeedupward, float maxtime, float shotdelay, entity ignore)
  21 {
  22         float c, savesolid, shottime;
  23         vector dir, end, v, o;
  24         if (shotspeed < 1)
  25                 return false; // could cause division by zero if calculated
  26         if (targ.solid < SOLID_BBOX) // SOLID_NOT and SOLID_TRIGGER
  27                 return false; // could never hit it
  28         if (!tracetossent)
  29                 tracetossent = new(tracetossent);
  30         tracetossent.owner = ignore;
  31         setsize(tracetossent, m1, m2);
  32         savesolid = targ.solid;
  33         targ.solid = SOLID_NOT;
  34         o = (targ.absmin + targ.absmax) * 0.5;
  35         shottime = ((vlen(o - org) / shotspeed) + shotdelay);
  36         v = targ.velocity * shottime + o;
  37         tracebox(o, targ.mins, targ.maxs, v, false, targ);
  38         v = trace_endpos;
  39         end = v + (targ.mins + targ.maxs) * 0.5;
  40         if ((vlen(end - org) / shotspeed + 0.2) > maxtime)
  41         {
  42                 // out of range
  43                 targ.solid = savesolid;
  44                 return false;
  45         }
  46
  47         if (!tracetossfaketarget)
  48                 tracetossfaketarget = new(tracetossfaketarget);
  49         tracetossfaketarget.solid = savesolid;
  50         set_movetype(tracetossfaketarget, targ.move_movetype);
  51         _setmodel(tracetossfaketarget, targ.model); // no low precision
  52         tracetossfaketarget.model = targ.model;
  53         tracetossfaketarget.modelindex = targ.modelindex;
  54         setsize(tracetossfaketarget, targ.mins, targ.maxs);
  55         setorigin(tracetossfaketarget, v);
  56
  57         c = 0;
  58         dir = normalize(end - org);
  59         while (c < 10) // 10 traces
  60         {
  61                 setorigin(tracetossent, org); // reset
  62                 tracetossent.velocity = findtrajectory_velocity = normalize(dir) * shotspeed + shotspeedupward * '0 0 1';
  63                 tracetoss(tracetossent, ignore); // love builtin functions...
  64                 if (trace_ent == tracetossfaketarget) // done
  65                 {
  66                         targ.solid = savesolid;
  67
  68                         // make it disappear
  69                         tracetossfaketarget.solid = SOLID_NOT;
  70                         set_movetype(tracetossfaketarget, MOVETYPE_NONE);
  71                         tracetossfaketarget.model = "";
  72                         tracetossfaketarget.modelindex = 0;
  73                         // relink to remove it from physics considerations
  74                         setorigin(tracetossfaketarget, v);
  75
  76                         return true;
  77                 }
  78                 dir.z = dir.z + 0.1; // aim up a little more
  79                 c = c + 1;
  80         }
  81         targ.solid = savesolid;
  82
  83         // make it disappear
  84         tracetossfaketarget.solid = SOLID_NOT;
  85         set_movetype(tracetossfaketarget, MOVETYPE_NONE);
  86         tracetossfaketarget.model = "";
  87         tracetossfaketarget.modelindex = 0;
  88         // relink to remove it from physics considerations
  89         setorigin(tracetossfaketarget, v);
  90
  91         // leave a valid one even if it won't reach
  92         findtrajectory_velocity = normalize(end - org) * shotspeed + shotspeedupward * '0 0 1';
  93         return false;
  94 }
  95
  96 void lag_update(entity this)
  97 {
  98         if (this.lag1_time) if (time > this.lag1_time) {this.lag_func(this, this.lag1_time, this.lag1_float1, this.lag1_float2, this.lag1_entity1, this.lag1_vec1, this.lag1_vec2, this.lag1_vec3, this.lag1_vec4);this.lag1_time = 0;}
  99         if (this.lag2_time) if (time > this.lag2_time) {this.lag_func(this, this.lag2_time, this.lag2_float1, this.lag2_float2, this.lag2_entity1, this.lag2_vec1, this.lag2_vec2, this.lag2_vec3, this.lag2_vec4);this.lag2_time = 0;}
 100         if (this.lag3_time) if (time > this.lag3_time) {this.lag_func(this, this.lag3_time, this.lag3_float1, this.lag3_float2, this.lag3_entity1, this.lag3_vec1, this.lag3_vec2, this.lag3_vec3, this.lag3_vec4);this.lag3_time = 0;}
 101         if (this.lag4_time) if (time > this.lag4_time) {this.lag_func(this, this.lag4_time, this.lag4_float1, this.lag4_float2, this.lag4_entity1, this.lag4_vec1, this.lag4_vec2, this.lag4_vec3, this.lag4_vec4);this.lag4_time = 0;}
 102         if (this.lag5_time) if (time > this.lag5_time) {this.lag_func(this, this.lag5_time, this.lag5_float1, this.lag5_float2, this.lag5_entity1, this.lag5_vec1, this.lag5_vec2, this.lag5_vec3, this.lag5_vec4);this.lag5_time = 0;}
 103 }
 104
 105 float lag_additem(entity this, float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
 106 {
 107         if (this.lag1_time == 0) {this.lag1_time = t;this.lag1_float1 = f1;this.lag1_float2 = f2;this.lag1_entity1 = e1;this.lag1_vec1 = v1;this.lag1_vec2 = v2;this.lag1_vec3 = v3;this.lag1_vec4 = v4;return true;}
 108         if (this.lag2_time == 0) {this.lag2_time = t;this.lag2_float1 = f1;this.lag2_float2 = f2;this.lag2_entity1 = e1;this.lag2_vec1 = v1;this.lag2_vec2 = v2;this.lag2_vec3 = v3;this.lag2_vec4 = v4;return true;}
 109         if (this.lag3_time == 0) {this.lag3_time = t;this.lag3_float1 = f1;this.lag3_float2 = f2;this.lag3_entity1 = e1;this.lag3_vec1 = v1;this.lag3_vec2 = v2;this.lag3_vec3 = v3;this.lag3_vec4 = v4;return true;}
 110         if (this.lag4_time == 0) {this.lag4_time = t;this.lag4_float1 = f1;this.lag4_float2 = f2;this.lag4_entity1 = e1;this.lag4_vec1 = v1;this.lag4_vec2 = v2;this.lag4_vec3 = v3;this.lag4_vec4 = v4;return true;}
 111         if (this.lag5_time == 0) {this.lag5_time = t;this.lag5_float1 = f1;this.lag5_float2 = f2;this.lag5_entity1 = e1;this.lag5_vec1 = v1;this.lag5_vec2 = v2;this.lag5_vec3 = v3;this.lag5_vec4 = v4;return true;}
 112         // no room for it (what is the best thing to do here??)
 113         return false;
 114 }
 115
 116 bool bot_shouldattack(entity this, entity targ)
 117 {
 118         if (targ.team == this.team)
 119         {
 120                 if (targ == this)
 121                         return false;
 122                 if (teamplay)
 123                 if (targ.team != 0)
 124                         return false;
 125         }
 126
 127         if(STAT(FROZEN, targ))
 128                 return false;
 129
 130         if(teamplay)
 131         {
 132                 if(targ.team==0)
 133                         return false;
 134         }
 135         else if (autocvar_bot_ignore_bots && IS_BOT_CLIENT(targ))
 136                 return false;
 137
 138         if (!targ.takedamage)
 139                 return false;
 140         if (IS_DEAD(targ))
 141                 return false;
 142         if (PHYS_INPUT_BUTTON_CHAT(targ) && !autocvar_bot_typefrag)
 143                 return false;
 144         if(targ.flags & FL_NOTARGET)
 145                 return false;
 146
 147         if(MUTATOR_CALLHOOK(BotShouldAttack, this, targ))
 148                 return false;
 149
 150         return true;
 151 }
 152
 153 void bot_lagfunc(entity this, float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
 154 {
 155         if(this.flags & FL_INWATER)
 156         {
 157                 this.bot_aimtarg = NULL;
 158                 return;
 159         }
 160         this.bot_aimtarg = e1;
 161         this.bot_aimlatency = CS(this).ping; // FIXME?  Shouldn't this be in the lag item?
 162         //this.bot_aimorigin = v1;
 163         //this.bot_aimvelocity = v2;
 164         this.bot_aimtargorigin = v3;
 165         this.bot_aimtargvelocity = v4;
 166         if(skill <= 0)
 167                 this.bot_canfire = (random() < 0.8);
 168         else if(skill <= 1)
 169                 this.bot_canfire = (random() < 0.9);
 170         else if(skill <= 2)
 171                 this.bot_canfire = (random() < 0.95);
 172         else
 173                 this.bot_canfire = 1;
 174 }
 175
 176 void bot_aimdir(entity this, vector v, float maxfiredeviation)
 177 {
 178         float dist, delta_t, blend;
 179         vector desiredang, diffang;
 180
 181         //dprint("aim ", this.netname, ": old:", vtos(this.v_angle));
 182         // make sure v_angle is sane first
 183         this.v_angle_y = this.v_angle.y - floor(this.v_angle.y / 360) * 360;
 184         this.v_angle_z = 0;
 185
 186         // invalid aim dir (can happen when bot overlaps target)
 187         if(!v) return;
 188
 189         // get the desired angles to aim at
 190         //dprint(" at:", vtos(v));
 191         v = normalize(v);
 192         //te_lightning2(NULL, this.origin + this.view_ofs, this.origin + this.view_ofs + v * 200);
 193         if (time >= this.bot_badaimtime)
 194         {
 195                 this.bot_badaimtime = max(this.bot_badaimtime + 0.3, time);
 196                 this.bot_badaimoffset = randomvec() * bound(0, 5 - 0.5 * (skill+this.bot_offsetskill), 5) * autocvar_bot_ai_aimskill_offset;
 197         }
 198         desiredang = vectoangles(v) + this.bot_badaimoffset;
 199         //dprint(" desired:", vtos(desiredang));
 200         if (desiredang.x >= 180)
 201                 desiredang.x = desiredang.x - 360;
 202         desiredang.x = bound(-90, 0 - desiredang.x, 90);
 203         desiredang.z = this.v_angle.z;
 204         //dprint(" / ", vtos(desiredang));
 205
 206         //// pain throws off aim
 207         //if (this.bot_painintensity)
 208         //{
 209         //      // shake from pain
 210         //      desiredang = desiredang + randomvec() * this.bot_painintensity * 0.2;
 211         //}
 212
 213         // calculate turn angles
 214         diffang = (desiredang - this.bot_olddesiredang);
 215         // wrap yaw turn
 216         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 217         if (diffang.y >= 180)
 218                 diffang.y = diffang.y - 360;
 219         this.bot_olddesiredang = desiredang;
 220         //dprint(" diff:", vtos(diffang));
 221
 222         delta_t = time-this.bot_prevaimtime;
 223         this.bot_prevaimtime = time;
 224         // Here we will try to anticipate the comming aiming direction
 225         this.bot_1st_order_aimfilter= this.bot_1st_order_aimfilter
 226                 + (diffang * (1 / delta_t)    - this.bot_1st_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_1st,1);
 227         this.bot_2nd_order_aimfilter= this.bot_2nd_order_aimfilter
 228                 + (this.bot_1st_order_aimfilter - this.bot_2nd_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_2nd,1);
 229         this.bot_3th_order_aimfilter= this.bot_3th_order_aimfilter
 230                 + (this.bot_2nd_order_aimfilter - this.bot_3th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_3th,1);
 231         this.bot_4th_order_aimfilter= this.bot_4th_order_aimfilter
 232                 + (this.bot_3th_order_aimfilter - this.bot_4th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_4th,1);
 233         this.bot_5th_order_aimfilter= this.bot_5th_order_aimfilter
 234                 + (this.bot_4th_order_aimfilter - this.bot_5th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_5th,1);
 235
 236         //blend = (bound(0,skill,10)*0.1)*((1-bound(0,skill,10)*0.05) ** 2.5)*5.656854249; //Plot formule before changing !
 237         blend = bound(0,skill+this.bot_aimskill,10)*0.1;
 238         desiredang = desiredang + blend *
 239         (
 240                   this.bot_1st_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_1st
 241                 + this.bot_2nd_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_2nd
 242                 + this.bot_3th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_3th
 243                 + this.bot_4th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_4th
 244                 + this.bot_5th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_5th
 245         );
 246
 247         // calculate turn angles
 248         diffang = desiredang - this.bot_mouseaim;
 249         // wrap yaw turn
 250         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 251         if (diffang.y >= 180)
 252                 diffang.y = diffang.y - 360;
 253         //dprint(" diff:", vtos(diffang));
 254
 255         if (time >= this.bot_aimthinktime)
 256         {
 257                 this.bot_aimthinktime = max(this.bot_aimthinktime + 0.5 - 0.05*(skill+this.bot_thinkskill), time);
 258                 this.bot_mouseaim = this.bot_mouseaim + diffang * (1-random()*0.1*bound(1,10-(skill+this.bot_thinkskill),10));
 259         }
 260
 261         //this.v_angle = this.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
 262
 263         diffang = this.bot_mouseaim - desiredang;
 264         // wrap yaw turn
 265         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 266         if (diffang.y >= 180)
 267                 diffang.y = diffang.y - 360;
 268         desiredang = desiredang + diffang * bound(0,autocvar_bot_ai_aimskill_think,1);
 269
 270         // calculate turn angles
 271         diffang = desiredang - this.v_angle;
 272         // wrap yaw turn
 273         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 274         if (diffang.y >= 180)
 275                 diffang.y = diffang.y - 360;
 276         //dprint(" diff:", vtos(diffang));
 277
 278         // jitter tracking
 279         dist = vlen(diffang);
 280         //diffang = diffang + randomvec() * (dist * 0.05 * (3.5 - bound(0, skill, 3)));
 281
 282         // turn
 283         float r, fixedrate, blendrate;
 284         fixedrate = autocvar_bot_ai_aimskill_fixedrate / bound(1,dist,1000);
 285         blendrate = autocvar_bot_ai_aimskill_blendrate;
 286         r = max(fixedrate, blendrate);
 287         //this.v_angle = this.v_angle + diffang * bound(frametime, r * frametime * (2+skill*skill*0.05-random()*0.05*(10-skill)), 1);
 288         this.v_angle = this.v_angle + diffang * bound(delta_t, r * delta_t * (2 + ((skill + this.bot_mouseskill) ** 3) * 0.005 - random()), 1);
 289         this.v_angle = this.v_angle * bound(0,autocvar_bot_ai_aimskill_mouse,1) + desiredang * bound(0,(1-autocvar_bot_ai_aimskill_mouse),1);
 290         //this.v_angle = this.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
 291         //this.v_angle = this.v_angle + diffang * (1/ blendrate);
 292         this.v_angle_z = 0;
 293         this.v_angle_y = this.v_angle.y - floor(this.v_angle.y / 360) * 360;
 294         //dprint(" turn:", vtos(this.v_angle));
 295
 296         makevectors(this.v_angle);
 297         shotorg = this.origin + this.view_ofs;
 298         shotdir = v_forward;
 299
 300         //dprint(" dir:", vtos(v_forward));
 301         //te_lightning2(NULL, shotorg, shotorg + shotdir * 100);
 302
 303         // calculate turn angles again
 304         //diffang = desiredang - this.v_angle;
 305         //diffang_y = diffang_y - floor(diffang_y / 360) * 360;
 306         //if (diffang_y >= 180)
 307         //      diffang_y = diffang_y - 360;
 308
 309         //dprint("e ", vtos(diffang), " < ", ftos(maxfiredeviation), "\n");
 310
 311         // decide whether to fire this time
 312         if (v * shotdir >= cos(maxfiredeviation * DEG2RAD))
 313         if(vdist(trace_endpos-shotorg, <, 500 + 500 * bound(0, skill + this.bot_aggresskill, 10)) || random()*random()>bound(0,(skill+this.bot_aggresskill)*0.05,1))
 314                 this.bot_firetimer = time + bound(0.1, 0.5-(skill+this.bot_aggresskill)*0.05, 0.5);
 315         //traceline(shotorg,shotorg+shotdir*1000,false,NULL);
 316         //dprint(ftos(maxfiredeviation),"\n");
 317         //dprint(" diff:", vtos(diffang), "\n");
 318
 319         //return this.bot_canfire && (time < this.bot_firetimer);
 320 }
 321
 322 vector bot_shotlead(vector targorigin, vector targvelocity, float shotspeed, float shotdelay)
 323 {
 324         // Try to add code here that predicts gravity effect here, no clue HOW to though ... well not yet atleast...
 325         return targorigin + targvelocity * (shotdelay + vlen(targorigin - shotorg) / shotspeed);
 326 }
 327
 328 bool bot_aim(entity this, .entity weaponentity, float shotspeed, float shotspeedupward, float maxshottime, bool applygravity)
 329 {
 330         float r, hf, distanceratio;
 331         vector v;
 332         /*
 333         eprint(this);
 334         dprint("bot_aim(", ftos(shotspeed));
 335         dprint(", ", ftos(shotspeedupward));
 336         dprint(", ", ftos(maxshottime));
 337         dprint(", ", ftos(applygravity));
 338         dprint(");\n");
 339         */
 340
 341         hf = this.dphitcontentsmask;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 343
 344         shotspeed *= W_WeaponSpeedFactor(this);
 345         shotspeedupward *= W_WeaponSpeedFactor(this);
 346         if (!shotspeed)
 347         {
 348                 LOG_TRACE("bot_aim: WARNING: weapon ", this.(weaponentity).m_weapon.m_name, " shotspeed is zero!");
 349                 shotspeed = 1000000;
 350         }
 351         if (!maxshottime)
 352         {
 353                 LOG_TRACE("bot_aim: WARNING: weapon ", this.(weaponentity).m_weapon.m_name, " maxshottime is zero!");
 354                 maxshottime = 1;
 355         }
 356         makevectors(this.v_angle);
 357         shotorg = this.origin + this.view_ofs;
 358         shotdir = v_forward;
 359         v = bot_shotlead(this.bot_aimtargorigin, this.bot_aimtargvelocity, shotspeed, this.bot_aimlatency);
 360         distanceratio = sqrt(bound(0,skill,10000))*0.3*(vlen(v-shotorg)-100)/autocvar_bot_ai_aimskill_firetolerance_distdegrees;
 361         distanceratio = bound(0,distanceratio,1);
 362         r =  (autocvar_bot_ai_aimskill_firetolerance_maxdegrees-autocvar_bot_ai_aimskill_firetolerance_mindegrees)
 363                 * (1-distanceratio) + autocvar_bot_ai_aimskill_firetolerance_mindegrees;
 364         if (applygravity && this.bot_aimtarg)
 365         {
 366                 if (!findtrajectorywithleading(shotorg, '0 0 0', '0 0 0', this.bot_aimtarg, shotspeed, shotspeedupward, maxshottime, 0, this))
 367                 {
 368                         this.dphitcontentsmask = hf;
 369                         return false;
 370                 }
 371
 372                 bot_aimdir(this, findtrajectory_velocity - shotspeedupward * '0 0 1', r);
 373         }
 374         else
 375         {
 376                 bot_aimdir(this, v - shotorg, r);
 377                 //dprint("AIM: ");dprint(vtos(this.bot_aimtargorigin));dprint(" + ");dprint(vtos(this.bot_aimtargvelocity));dprint(" * ");dprint(ftos(this.bot_aimlatency + vlen(this.bot_aimtargorigin - shotorg) / shotspeed));dprint(" = ");dprint(vtos(v));dprint(" : aimdir = ");dprint(vtos(normalize(v - shotorg)));dprint(" : ");dprint(vtos(shotdir));dprint("\n");
 378                 //traceline(shotorg, shotorg + shotdir * 10000, false, this);
 379                 //if (trace_ent.takedamage)
 380                 //if (trace_fraction < 1)
 381                 //if (!bot_shouldattack(this, trace_ent))
 382                 //      return false;
 383                 traceline(shotorg, this.bot_aimtargorigin, false, this);
 384                 if (trace_fraction < 1)
 385                 if (trace_ent != this.enemy)
 386                 if (!bot_shouldattack(this, trace_ent))
 387                 {
 388                         this.dphitcontentsmask = hf;
 389                         return false;
 390                 }
 391         }
 392
 393         //if (r > maxshottime * shotspeed)
 394         //      return false;
 395         this.dphitcontentsmask = hf;
 396         return true;
 397 }