qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include <server/mutators/_mod.qh>
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  45
  46 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  47 void bot_setclientfields(entity this)
  48 {
  49         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  50         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  51 }
  52
  53 entity bot_spawn()
  54 {
  55         entity bot = spawnclient();
  56         if (bot)
  57         {
  58                 setItemGroupCount();
  59                 currentbots = currentbots + 1;
  60                 bot_setnameandstuff(bot);
  61                 ClientConnect(bot);
  62                 bot_setclientfields(bot);
  63                 PutClientInServer(bot);
  64         }
  65         return bot;
  66 }
  67
  68 void bot_think(entity this)
  69 {
  70         if (this.bot_nextthink > time)
  71                 return;
  72
  73         this.flags &= ~FL_GODMODE;
  74         if(autocvar_bot_god)
  75                 this.flags |= FL_GODMODE;
  76
  77         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  78
  79         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  80         {
  81                 CS(this).movement = '0 0 0';
  82                 this.bot_nextthink = time + 0.5;
  83                 return;
  84         }
  85
  86         if (this.fixangle)
  87         {
  88                 this.v_angle = this.angles;
  89                 this.v_angle_z = 0;
  90                 this.fixangle = false;
  91         }
  92
  93         this.dmg_take = 0;
  94         this.dmg_save = 0;
  95         this.dmg_inflictor = NULL;
  96
  97         // calculate an aiming latency based on the skill setting
  98         // (simulated network latency + naturally delayed reflexes)
  99         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 100         // minimum ping 20+10 random
 101         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 102         // skill 10 = ping 0.2 (adrenaline)
 103         // skill 0 = ping 0.7 (slightly drunk)
 104
 105         // clear buttons
 106         PHYS_INPUT_BUTTON_ATCK(this) = false;
 107         PHYS_INPUT_BUTTON_JUMP(this) = false;
 108         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 109         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 110         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 111         PHYS_INPUT_BUTTON_HOOK(this) = false;
 112         PHYS_INPUT_BUTTON_INFO(this) = false;
 113         PHYS_INPUT_BUTTON_DRAG(this) = false;
 114         PHYS_INPUT_BUTTON_CHAT(this) = false;
 115         PHYS_INPUT_BUTTON_USE(this) = false;
 116
 117         if (time < game_starttime)
 118         {
 119                 // block the bot during the countdown to game start
 120                 CS(this).movement = '0 0 0';
 121                 this.bot_nextthink = game_starttime;
 122                 return;
 123         }
 124
 125         // if dead, just wait until we can respawn
 126         if (IS_DEAD(this))
 127         {
 128                 if (bot_waypoint_queue_owner == this)
 129                         bot_waypoint_queue_owner = NULL;
 130                 this.aistatus = 0;
 131                 CS(this).movement = '0 0 0';
 132                 if (this.deadflag == DEAD_DEAD)
 133                 {
 134                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 135                         navigation_goalrating_timeout_force(this);
 136                 }
 137         }
 138         else if(this.aistatus & AI_STATUS_STUCK)
 139                 navigation_unstuck(this);
 140
 141         // now call the current bot AI (havocbot for example)
 142         this.bot_ai(this);
 143 }
 144
 145 void bot_setnameandstuff(entity this)
 146 {
 147         string readfile, s;
 148         float file, tokens, prio;
 149
 150         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 151         string name, prefix, suffix;
 152
 153         if(autocvar_g_campaign)
 154         {
 155                 prefix = "";
 156                 suffix = "";
 157         }
 158         else
 159         {
 160                 prefix = autocvar_bot_prefix;
 161                 suffix = autocvar_bot_suffix;
 162         }
 163
 164         file = fopen(autocvar_bot_config_file, FILE_READ);
 165
 166         if(file < 0)
 167         {
 168                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 169                 readfile = "";
 170         }
 171         else
 172         {
 173                 RandomSelection_Init();
 174                 while((readfile = fgets(file)))
 175                 {
 176                         if(substring(readfile, 0, 2) == "//")
 177                                 continue;
 178                         if(substring(readfile, 0, 1) == "#")
 179                                 continue;
 180                         tokens = tokenizebyseparator(readfile, "\t");
 181                         if(tokens == 0)
 182                                 continue;
 183                         s = argv(0);
 184                         prio = 1;
 185                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 186                                 if(s == it.cleanname)
 187                                 {
 188                                         prio = 0;
 189                                         break;
 190                                 }
 191                         });
 192                         RandomSelection_AddString(readfile, 1, prio);
 193                 }
 194                 readfile = RandomSelection_chosen_string;
 195                 fclose(file);
 196         }
 197
 198         tokens = tokenizebyseparator(readfile, "\t");
 199         if(argv(0) != "") bot_name = argv(0);
 200         else bot_name = "Bot";
 201
 202         if(argv(1) != "") bot_model = argv(1);
 203         else bot_model = "";
 204
 205         if(argv(2) != "") bot_skin = argv(2);
 206         else bot_skin = "0";
 207
 208         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 209         else bot_shirt = ftos(floor(random() * 15));
 210
 211         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 212         else bot_pants = ftos(floor(random() * 15));
 213
 214         this.bot_forced_team = stof(argv(5));
 215
 216         prio = 6;
 217
 218         #define READSKILL(f, w, r) MACRO_BEGIN \
 219                 if(argv(prio) != "") \
 220                         this.f = stof(argv(prio)) * w; \
 221                 else \
 222                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 223                 prio++; \
 224         MACRO_END
 225         //print(bot_name, ": ping=", argv(9), "\n");
 226
 227         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 228         READSKILL(bot_moveskill, 2, 0); // move skill
 229         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 230
 231         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 232
 233         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 234         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 235         READSKILL(bot_rangepreference, 1, 0); // read skill
 236
 237         READSKILL(bot_aimskill, 2, 0); // aim skill
 238         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 239         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 240
 241         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 242         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 243
 244         if (file >= 0 && argv(prio) != "")
 245                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 246
 247         this.bot_config_loaded = true;
 248
 249         // this is really only a default, TeamBalance_JoinBestTeam is called later
 250         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 251         this.bot_preferredcolors = this.clientcolors;
 252
 253         // pick the name
 254         if (autocvar_bot_usemodelnames)
 255                 name = bot_model;
 256         else
 257                 name = bot_name;
 258
 259         // number bots with identical names
 260         if (name == "")
 261         {
 262                 name = ftos(etof(this));
 263                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 264         }
 265         else
 266         {
 267                 int j = 0;
 268                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 269                         if(it.cleanname == name)
 270                                 ++j;
 271                 });
 272                 if (j)
 273                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 274                 else
 275                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 276         }
 277         this.cleanname = strzone(name);
 278
 279         // pick the model and skin
 280         if(substring(bot_model, -4, 1) != ".")
 281                 bot_model = strcat(bot_model, ".iqm");
 282         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 283         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 284 }
 285
 286 void bot_custom_weapon_priority_setup()
 287 {
 288         float tokens, i, w;
 289
 290         bot_custom_weapon = false;
 291
 292         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 293                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 294                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 295                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 296         )
 297                 return;
 298
 299         // Parse distances
 300         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 301
 302         if (tokens!=2)
 303                 return;
 304
 305         bot_distance_far = stof(argv(0));
 306         bot_distance_close = stof(argv(1));
 307
 308         if(bot_distance_far < bot_distance_close){
 309                 bot_distance_far = stof(argv(1));
 310                 bot_distance_close = stof(argv(0));
 311         }
 312
 313         // Initialize list of weapons
 314         bot_weapons_far[0] = -1;
 315         bot_weapons_mid[0] = -1;
 316         bot_weapons_close[0] = -1;
 317
 318         // Parse far distance weapon priorities
 319         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 320
 321         int c = 0;
 322         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 323                 w = stof(argv(i));
 324                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 325                         bot_weapons_far[c] = w;
 326                         ++c;
 327                 }
 328         }
 329         if(c < Weapons_COUNT)
 330                 bot_weapons_far[c] = -1;
 331
 332         // Parse mid distance weapon priorities
 333         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 334
 335         c = 0;
 336         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 337                 w = stof(argv(i));
 338                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 339                         bot_weapons_mid[c] = w;
 340                         ++c;
 341                 }
 342         }
 343         if(c < Weapons_COUNT)
 344                 bot_weapons_mid[c] = -1;
 345
 346         // Parse close distance weapon priorities
 347         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 348
 349         c = 0;
 350         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 351                 w = stof(argv(i));
 352                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 353                         bot_weapons_close[c] = w;
 354                         ++c;
 355                 }
 356         }
 357         if(c < Weapons_COUNT)
 358                 bot_weapons_close[c] = -1;
 359
 360         bot_custom_weapon = true;
 361 }
 362
 363 void bot_endgame()
 364 {
 365         bot_relinkplayerlist();
 366         entity e = bot_list;
 367         while (e)
 368         {
 369                 setcolor(e, e.bot_preferredcolors);
 370                 e = e.nextbot;
 371         }
 372         // if dynamic waypoints are ever implemented, save them here
 373 }
 374
 375 void bot_relinkplayerlist()
 376 {
 377         player_count = 0;
 378         currentbots = 0;
 379         bot_list = NULL;
 380
 381         entity prevbot = NULL;
 382         FOREACH_CLIENT(true,
 383         {
 384                 ++player_count;
 385
 386                 if(IS_BOT_CLIENT(it))
 387                 {
 388                         if(prevbot)
 389                                 prevbot.nextbot = it;
 390                         else
 391                                 bot_list = it;
 392                         prevbot = it;
 393                         ++currentbots;
 394                 }
 395         });
 396         if(prevbot)
 397                 prevbot.nextbot = NULL;
 398         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 399         bot_strategytoken = bot_list;
 400         bot_strategytoken_taken = true;
 401 }
 402
 403 void bot_clientdisconnect(entity this)
 404 {
 405         if (!IS_BOT_CLIENT(this))
 406                 return;
 407         bot_clearqueue(this);
 408         strfree(this.cleanname);
 409         strfree(this.netname_freeme);
 410         strfree(this.playermodel_freeme);
 411         strfree(this.playerskin_freeme);
 412         if(this.bot_cmd_current)
 413                 delete(this.bot_cmd_current);
 414         if(bot_waypoint_queue_owner == this)
 415                 bot_waypoint_queue_owner = NULL;
 416 }
 417
 418 void bot_clientconnect(entity this)
 419 {
 420         if (!IS_BOT_CLIENT(this)) return;
 421         this.bot_preferredcolors = this.clientcolors;
 422         this.bot_nextthink = time - random();
 423         this.lag_func = bot_lagfunc;
 424         this.isbot = true;
 425         this.createdtime = this.bot_nextthink;
 426
 427         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 428         {
 429                 bot_setnameandstuff(this);
 430                 bot_setclientfields(this);
 431         }
 432
 433         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 434         {
 435                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 436         }
 437         else
 438         {
 439                 this.bot_forced_team = 0;
 440                 TeamBalance_JoinBestTeam(this);
 441         }
 442
 443         havocbot_setupbot(this);
 444 }
 445
 446 void bot_removefromlargestteam()
 447 {
 448         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 449         TeamBalance_GetTeamCounts(balance, NULL);
 450
 451         entity best = NULL;
 452         float besttime = 0;
 453         int bestcount = 0;
 454
 455         int bcount = 0;
 456         FOREACH_CLIENT(it.isbot,
 457         {
 458                 ++bcount;
 459
 460                 if(!best)
 461                 {
 462                         best = it;
 463                         besttime = it.createdtime;
 464                 }
 465
 466                 int thiscount = 0;
 467
 468                 if (Team_IsValidTeam(it.team))
 469                 {
 470                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 471                                 Team_TeamToIndex(it.team));
 472                 }
 473
 474                 if(thiscount > bestcount)
 475                 {
 476                         bestcount = thiscount;
 477                         besttime = it.createdtime;
 478                         best = it;
 479                 }
 480                 else if(thiscount == bestcount && besttime < it.createdtime)
 481                 {
 482                         besttime = it.createdtime;
 483                         best = it;
 484                 }
 485         });
 486         TeamBalance_Destroy(balance);
 487         if(!bcount)
 488                 return; // no bots to remove
 489         currentbots = currentbots - 1;
 490         dropclient(best);
 491 }
 492
 493 void bot_removenewest()
 494 {
 495         if(teamplay)
 496         {
 497                 bot_removefromlargestteam();
 498                 return;
 499         }
 500
 501         float besttime = 0;
 502         entity best = NULL;
 503         int bcount = 0;
 504
 505         FOREACH_CLIENT(it.isbot,
 506         {
 507                 ++bcount;
 508
 509                 if(!best)
 510                 {
 511                         best = it;
 512                         besttime = it.createdtime;
 513                 }
 514
 515                 if(besttime < it.createdtime)
 516                 {
 517                         besttime = it.createdtime;
 518                         best = it;
 519                 }
 520         });
 521
 522         if(!bcount)
 523                 return; // no bots to remove
 524
 525         currentbots = currentbots - 1;
 526         dropclient(best);
 527 }
 528
 529 void autoskill(float factor)
 530 {
 531         float bestbot;
 532         float bestplayer;
 533
 534         bestbot = -1;
 535         bestplayer = -1;
 536         FOREACH_CLIENT(IS_PLAYER(it), {
 537                 if(IS_REAL_CLIENT(it))
 538                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 539                 else
 540                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 541         });
 542
 543         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 544         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 545         if(bestbot < 0 || bestplayer < 0)
 546         {
 547                 LOG_DEBUG("not doing anything");
 548                 // don't return, let it reset all counters below
 549         }
 550         else if(bestbot <= bestplayer * factor - 2)
 551         {
 552                 if(autocvar_skill < 17)
 553                 {
 554                         LOG_DEBUG("2 frags difference, increasing skill");
 555                         cvar_set("skill", ftos(autocvar_skill + 1));
 556                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 557                 }
 558         }
 559         else if(bestbot >= bestplayer * factor + 2)
 560         {
 561                 if(autocvar_skill > 0)
 562                 {
 563                         LOG_DEBUG("2 frags difference, decreasing skill");
 564                         cvar_set("skill", ftos(autocvar_skill - 1));
 565                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 566                 }
 567         }
 568         else
 569         {
 570                 LOG_DEBUG("not doing anything");
 571                 return;
 572                 // don't reset counters, wait for them to accumulate
 573         }
 574
 575         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 576 }
 577
 578 void bot_calculate_stepheightvec()
 579 {
 580         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 581         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 582         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 583         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 584 }
 585
 586 bool bot_fixcount()
 587 {
 588         int activerealplayers = 0;
 589         int realplayers = 0;
 590         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 591                 activerealplayers = M_ARGV(0, int);
 592                 realplayers = M_ARGV(1, int);
 593         } else {
 594                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 595                         if(IS_PLAYER(it))
 596                                 ++activerealplayers;
 597                         ++realplayers;
 598                 });
 599         }
 600
 601         int bots;
 602         // But don't remove bots immediately on level change, as the real players
 603         // usually haven't rejoined yet
 604         bots_would_leave = false;
 605         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 606                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 607         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 608         {
 609                 int minplayers = max(0, floor(autocvar_minplayers));
 610                 if (teamplay)
 611                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 612                 int minbots = max(0, floor(autocvar_bot_number));
 613
 614                 // add bots to reach minplayers if needed
 615                 bots = max(minbots, minplayers - activerealplayers);
 616                 // cap bots to the max players allowed by the server
 617                 int player_limit = GetPlayerLimit();
 618                 if(player_limit)
 619                         bots = min(bots, max(player_limit - activerealplayers, 0));
 620                 bots = min(bots, maxclients - realplayers);
 621
 622                 if(bots > minbots)
 623                         bots_would_leave = true;
 624         }
 625         else
 626         {
 627                 // if there are no players, remove bots
 628                 bots = 0;
 629         }
 630
 631         // only add one bot per frame to avoid utter chaos
 632         if(time > botframe_nextthink)
 633         {
 634                 if (currentbots < bots)
 635                 {
 636                         if (bot_spawn() == NULL)
 637                         {
 638                                 bprint("Can not add bot, server full.\n");
 639                                 return false;
 640                         }
 641                 }
 642                 while (currentbots > bots && bots >= 0)
 643                         bot_removenewest();
 644         }
 645
 646         return true;
 647 }
 648
 649 void bot_remove_from_bot_list(entity this)
 650 {
 651         entity e = bot_list;
 652         entity prev_bot = NULL;
 653         while (e)
 654         {
 655                 if(e == this)
 656                 {
 657                         if(!prev_bot)
 658                                 bot_list = this.nextbot;
 659                         else
 660                                 prev_bot.nextbot = this.nextbot;
 661                         if(bot_strategytoken == this)
 662                         {
 663                                 bot_strategytoken = this.nextbot;
 664                                 bot_strategytoken_taken = true;
 665                         }
 666                         this.nextbot = NULL;
 667                         break;
 668                 }
 669                 prev_bot = e;
 670                 e = e.nextbot;
 671         }
 672 }
 673
 674 void bot_clear(entity this)
 675 {
 676         bot_remove_from_bot_list(this);
 677         if(bot_waypoint_queue_owner == this)
 678                 bot_waypoint_queue_owner = NULL;
 679         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 680 }
 681
 682 void bot_serverframe()
 683 {
 684         if (intermission_running && currentbots > 0)
 685         {
 686                 // after the end of the match all bots stay unless all human players disconnect
 687                 int realplayers = 0;
 688                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 689                 if (!realplayers)
 690                 {
 691                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 692                         currentbots = 0;
 693                 }
 694                 return;
 695         }
 696
 697         if (game_stopped)
 698                 return;
 699
 700         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 701         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 702         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 703         // either intentionally or automatically (sv_spectate 0)
 704         if (time < 2.5)
 705         {
 706                 currentbots = -1;
 707                 return;
 708         }
 709
 710         if (currentbots == -1)
 711         {
 712                 // count bots already in the server from the previous match
 713                 currentbots = 0;
 714                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 715         }
 716
 717         if(autocvar_skill != skill)
 718         {
 719                 float wpcost_update = false;
 720                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 721                         wpcost_update = true;
 722                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 723                         wpcost_update = true;
 724
 725                 skill = autocvar_skill;
 726                 if (wpcost_update)
 727                         waypoint_updatecost_foralllinks();
 728         }
 729
 730         bot_calculate_stepheightvec();
 731         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 732
 733         if(time > autoskill_nextthink)
 734         {
 735                 float a;
 736                 a = autocvar_skill_auto;
 737                 if(a)
 738                         autoskill(a);
 739                 autoskill_nextthink = time + 5;
 740         }
 741
 742         if(time > botframe_nextthink)
 743         {
 744                 if(!bot_fixcount())
 745                         botframe_nextthink = time + 10;
 746         }
 747
 748         if(botframe_spawnedwaypoints)
 749         {
 750                 if(autocvar_waypoint_benchmark)
 751                         localcmd("quit\n");
 752         }
 753
 754         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 755         if (botframe_spawnedwaypoints)
 756         {
 757                 if(botframe_cachedwaypointlinks)
 758                 {
 759                         if(!botframe_loadedforcedlinks)
 760                                 waypoint_load_hardwiredlinks();
 761                 }
 762                 else
 763                 {
 764                         // TODO: Make this check cleaner
 765                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 766                         {
 767                                 waypoint_save_links();
 768                                 break;
 769                         });
 770                 }
 771         }
 772         else
 773         {
 774                 botframe_spawnedwaypoints = true;
 775                 waypoint_loadall();
 776                 waypoint_load_links();
 777         }
 778
 779         if (bot_list)
 780         {
 781                 // cycle the goal token from one bot to the next each frame
 782                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 783                 //  frame, which causes choppy framerates)
 784                 if (bot_strategytoken_taken)
 785                 {
 786                         // give goal token to the first bot without goals; if all bots don't have
 787                         // any goal (or are dead/frozen) simply give it to the next one
 788                         bot_strategytoken_taken = false;
 789                         entity bot_strategytoken_save = bot_strategytoken;
 790                         while (true)
 791                         {
 792                                 if (bot_strategytoken)
 793                                         bot_strategytoken = bot_strategytoken.nextbot;
 794                                 if (!bot_strategytoken)
 795                                         bot_strategytoken = bot_list;
 796
 797                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 798                                         && !bot_strategytoken.goalcurrent)
 799                                         break;
 800
 801                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 802                                         break;
 803                                 if (bot_strategytoken == bot_strategytoken_save)
 804                                         bot_strategytoken_save = NULL; // looped through all the bots
 805                         }
 806                 }
 807
 808                 if (botframe_nextdangertime < time)
 809                 {
 810                         float interval;
 811                         interval = autocvar_bot_ai_dangerdetectioninterval;
 812                         if (botframe_nextdangertime < time - interval * 1.5)
 813                                 botframe_nextdangertime = time;
 814                         botframe_nextdangertime = botframe_nextdangertime + interval;
 815                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 816                 }
 817         }
 818
 819         if (autocvar_g_waypointeditor)
 820                 botframe_showwaypointlinks();
 821
 822         if (autocvar_g_waypointeditor_auto)
 823                 botframe_autowaypoints();
 824
 825         if(time > bot_cvar_nextthink)
 826         {
 827                 if(currentbots>0)
 828                         bot_custom_weapon_priority_setup();
 829                 bot_cvar_nextthink = time + 5;
 830         }
 831 }