qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/mapinfo.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/physics/player.qh>
   7 #include <common/stats.qh>
   8 #include <common/teams.qh>
   9 #include <common/util.qh>
  10 #include <common/weapons/_all.qh>
  11 #include <lib/csqcmodel/sv_model.qh>
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14 #include <server/antilag.qh>
  15 #include <server/bot/default/aim.qh>
  16 #include <server/bot/default/cvars.qh>
  17 #include <server/bot/default/havocbot/havocbot.qh>
  18 #include <server/bot/default/havocbot/scripting.qh>
  19 #include <server/bot/default/navigation.qh>
  20 #include <server/bot/default/scripting.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/client.qh>
  24 #include <server/damage.qh>
  25 #include <server/items/items.qh>
  26 #include <server/mutators/_mod.qh>
  27 #include <server/race.qh>
  28 #include <server/scores_rules.qh>
  29 #include <server/teamplay.qh>
  30 #include <server/weapons/accuracy.qh>
  31 #include <server/weapons/selection.qh>
  32 #include <server/world.qh>
  33
  34 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  35
  36 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  37 void bot_setclientfields(entity this)
  38 {
  39         CS_CVAR(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  40         CS_CVAR(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  41 }
  42
  43 entity bot_spawn()
  44 {
  45         entity bot = spawnclient();
  46         if (bot)
  47         {
  48                 setItemGroupCount();
  49                 currentbots = currentbots + 1;
  50                 bot_setnameandstuff(bot);
  51                 ClientConnect(bot);
  52                 bot_setclientfields(bot);
  53                 PutClientInServer(bot);
  54         }
  55         return bot;
  56 }
  57
  58 void bot_think(entity this)
  59 {
  60         if (this.bot_nextthink > time)
  61                 return;
  62
  63         this.flags &= ~FL_GODMODE;
  64         if(autocvar_bot_god)
  65                 this.flags |= FL_GODMODE;
  66
  67         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  68
  69         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  70         {
  71                 if (IS_PLAYER(this))
  72                 {
  73                         .entity weaponentity = weaponentities[0];
  74                         if(this.(weaponentity).m_weapon == WEP_Null)
  75                                 W_NextWeapon(this, 0, weaponentity);
  76                 }
  77                 CS(this).movement = '0 0 0';
  78                 this.bot_nextthink = time + 0.5;
  79                 return;
  80         }
  81
  82         if (this.fixangle)
  83         {
  84                 this.v_angle = this.angles;
  85                 this.v_angle_z = 0;
  86                 this.fixangle = false;
  87         }
  88
  89         this.dmg_take = 0;
  90         this.dmg_save = 0;
  91         this.dmg_inflictor = NULL;
  92
  93         // calculate an aiming latency based on the skill setting
  94         // (simulated network latency + naturally delayed reflexes)
  95         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  96         // minimum ping 20+10 random
  97         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
  98         // skill 10 = ping 0.2 (adrenaline)
  99         // skill 0 = ping 0.7 (slightly drunk)
 100
 101         // clear buttons
 102         PHYS_INPUT_BUTTON_ATCK(this) = false;
 103         // keep jump button pressed for a short while, useful with ramp jumps
 104         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
 105         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 106         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 107         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 108         PHYS_INPUT_BUTTON_HOOK(this) = false;
 109         PHYS_INPUT_BUTTON_INFO(this) = false;
 110         PHYS_INPUT_BUTTON_DRAG(this) = false;
 111         PHYS_INPUT_BUTTON_CHAT(this) = false;
 112         PHYS_INPUT_BUTTON_USE(this) = false;
 113
 114         if (time < game_starttime)
 115         {
 116                 // block the bot during the countdown to game start
 117                 CS(this).movement = '0 0 0';
 118                 this.bot_nextthink = game_starttime;
 119                 return;
 120         }
 121
 122         // if dead, just wait until we can respawn
 123         if (IS_DEAD(this) || IS_OBSERVER(this))
 124         {
 125                 if (bot_waypoint_queue_owner == this)
 126                         bot_waypoint_queue_owner = NULL;
 127                 this.aistatus = 0;
 128                 CS(this).movement = '0 0 0';
 129                 if (IS_OBSERVER(this))
 130                         return;
 131                 if (IS_DEAD(this))
 132                 {
 133                         if (!navigation_goalrating_timeout(this))
 134                                 navigation_goalrating_timeout_force(this);
 135                         // jump must not be pressed for at least one frame in order for
 136                         // PlayerThink to detect the key down event
 137                         if (this.deadflag == DEAD_DYING)
 138                                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 139                         else if (this.deadflag == DEAD_DEAD)
 140                                 PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 141                 }
 142         }
 143         else if(this.aistatus & AI_STATUS_STUCK)
 144                 navigation_unstuck(this);
 145
 146         // now call the current bot AI (havocbot for example)
 147         this.bot_ai(this);
 148 }
 149
 150 void bot_setnameandstuff(entity this)
 151 {
 152         string readfile, s;
 153         int file, tokens, prio;
 154
 155         file = fopen(autocvar_bot_config_file, FILE_READ);
 156
 157         if(file < 0)
 158         {
 159                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 160                 readfile = "";
 161         }
 162         else
 163         {
 164                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 165                 TeamBalance_GetTeamCounts(balance, NULL);
 166                 int smallest_team = -1;
 167                 int smallest_count = -1;
 168                 if (teamplay)
 169                 {
 170                         for (int i = 1; i <= AvailableTeams(); ++i)
 171                         {
 172                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 173                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 174                                 // since it keeps a spot for the real player in the desired team
 175                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 176                                 if (smallest_count < 0 || count < smallest_count)
 177                                 {
 178                                         smallest_team = i;
 179                                         smallest_count = count;
 180                                 }
 181                         }
 182                 }
 183                 TeamBalance_Destroy(balance);
 184                 RandomSelection_Init();
 185                 while((readfile = fgets(file)))
 186                 {
 187                         if(substring(readfile, 0, 2) == "//")
 188                                 continue;
 189                         if(substring(readfile, 0, 1) == "#")
 190                                 continue;
 191                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 192                         // will create 1 empty token because there's no separator (bug?)
 193                         if (readfile == "")
 194                                 continue;
 195                         tokens = tokenizebyseparator(readfile, "\t");
 196                         if(tokens == 0)
 197                                 continue;
 198                         s = argv(0);
 199                         prio = 0;
 200                         bool conflict = false;
 201                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 202                                 if (s == it.cleanname)
 203                                 {
 204                                         conflict = true;
 205                                         break;
 206                                 }
 207                         });
 208                         if (!conflict)
 209                                 prio += 1;
 210                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 211                         {
 212                                 int forced_team = stof(argv(5));
 213                                 if (!Team_IsValidIndex(forced_team))
 214                                         forced_team = 0;
 215                                 if (!forced_team || forced_team == smallest_team)
 216                                         prio += 2;
 217                         }
 218                         RandomSelection_AddString(readfile, 1, prio);
 219                 }
 220                 readfile = RandomSelection_chosen_string;
 221                 fclose(file);
 222         }
 223
 224         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 225
 226         tokens = tokenizebyseparator(readfile, "\t");
 227         if(argv(0) != "") bot_name = argv(0);
 228         else bot_name = "Bot";
 229
 230         if(argv(1) != "") bot_model = argv(1);
 231         else bot_model = "";
 232
 233         if(argv(2) != "") bot_skin = argv(2);
 234         else bot_skin = "0";
 235
 236         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 237         else bot_shirt = ftos(floor(random() * 15));
 238
 239         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 240         else bot_pants = ftos(floor(random() * 15));
 241
 242         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 243                 this.bot_forced_team = stof(argv(5));
 244         else
 245                 this.bot_forced_team = 0;
 246
 247         prio = 6;
 248
 249         #define READSKILL(f, w, r) MACRO_BEGIN \
 250                 if(argv(prio) != "") \
 251                         this.f = stof(argv(prio)) * w; \
 252                 else \
 253                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 254                 prio++; \
 255         MACRO_END
 256         //print(bot_name, ": ping=", argv(9), "\n");
 257
 258         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 259         READSKILL(bot_moveskill, 2, 0); // move skill
 260         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 261
 262         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 263
 264         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 265         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 266         READSKILL(bot_rangepreference, 1, 0); // read skill
 267
 268         READSKILL(bot_aimskill, 2, 0); // aim skill
 269         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 270         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 271
 272         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 273         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 274
 275         if (file >= 0 && argv(prio) != "")
 276                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 277
 278         this.bot_config_loaded = true;
 279
 280         // this is really only a default, TeamBalance_JoinBestTeam is called later
 281         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 282         this.bot_preferredcolors = this.clientcolors;
 283
 284         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
 285         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
 286         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
 287
 288         if (name == "")
 289         {
 290                 name = ftos(etof(this));
 291                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 292         }
 293         else
 294         {
 295                 // number bots with identical names
 296                 int j = 0;
 297                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 298                         if(it.cleanname == name)
 299                                 ++j;
 300                 });
 301                 if (j)
 302                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 303                 else
 304                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 305         }
 306         this.cleanname = strzone(name);
 307
 308         // pick the model and skin
 309         if(substring(bot_model, -4, 1) != ".")
 310                 bot_model = strcat(bot_model, ".iqm");
 311         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 312         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 313 }
 314
 315 void bot_custom_weapon_priority_setup()
 316 {
 317         static string bot_priority_far_prev;
 318         static string bot_priority_mid_prev;
 319         static string bot_priority_close_prev;
 320         static string bot_priority_distances_prev;
 321         float tokens, i, w;
 322
 323         bot_custom_weapon = false;
 324
 325         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 326                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 327                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 328                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 329         )
 330                 return;
 331
 332         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 333         {
 334                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 335                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 336
 337                 if (tokens!=2)
 338                         return;
 339
 340                 bot_distance_far = stof(argv(0));
 341                 bot_distance_close = stof(argv(1));
 342
 343                 if(bot_distance_far < bot_distance_close){
 344                         bot_distance_far = stof(argv(1));
 345                         bot_distance_close = stof(argv(0));
 346                 }
 347         }
 348
 349         int c;
 350
 351         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 352                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 353                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 354                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 355                         bot_weapons_##dist[0] = -1; \
 356                         c = 0; \
 357                         for(i = 0; i < tokens && c < REGISTRY_COUNT(Weapons); ++i) { \
 358                                 w = stof(argv(i)); \
 359                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 360                                         bot_weapons_##dist[c] = w; \
 361                                         ++c; \
 362                                 } \
 363                         } \
 364                         if (c < REGISTRY_COUNT(Weapons)) \
 365                                 bot_weapons_##dist[c] = -1; \
 366                 } \
 367         MACRO_END
 368
 369         PARSE_WEAPON_PRIORITIES(far);
 370         PARSE_WEAPON_PRIORITIES(mid);
 371         PARSE_WEAPON_PRIORITIES(close);
 372
 373         bot_custom_weapon = true;
 374 }
 375
 376 void bot_endgame()
 377 {
 378         bot_relinkplayerlist();
 379         entity e = bot_list;
 380         while (e)
 381         {
 382                 setcolor(e, e.bot_preferredcolors);
 383                 e = e.nextbot;
 384         }
 385         // if dynamic waypoints are ever implemented, save them here
 386 }
 387
 388 void bot_relinkplayerlist()
 389 {
 390         player_count = 0;
 391         currentbots = 0;
 392         bot_list = NULL;
 393
 394         entity prevbot = NULL;
 395         FOREACH_CLIENT(true,
 396         {
 397                 ++player_count;
 398
 399                 if(IS_BOT_CLIENT(it))
 400                 {
 401                         if (!IS_OBSERVER(it) && !bot_ispaused(it))
 402                         {
 403                                 if(prevbot)
 404                                         prevbot.nextbot = it;
 405                                 else
 406                                         bot_list = it;
 407                                 prevbot = it;
 408                         }
 409                         ++currentbots;
 410                 }
 411         });
 412         if(prevbot)
 413                 prevbot.nextbot = NULL;
 414         bot_strategytoken = bot_list;
 415         bot_strategytoken_taken = true;
 416 }
 417
 418 void bot_clientdisconnect(entity this)
 419 {
 420         if (!IS_BOT_CLIENT(this))
 421                 return;
 422         bot_clearqueue(this);
 423         strfree(this.cleanname);
 424         strfree(this.netname_freeme);
 425         strfree(this.playermodel_freeme);
 426         strfree(this.playerskin_freeme);
 427         if(this.bot_cmd_current)
 428                 delete(this.bot_cmd_current);
 429         if(bot_waypoint_queue_owner == this)
 430                 bot_waypoint_queue_owner = NULL;
 431 }
 432
 433 void bot_clientconnect(entity this)
 434 {
 435         if (!IS_BOT_CLIENT(this)) return;
 436         this.bot_preferredcolors = this.clientcolors;
 437         this.bot_nextthink = time - random();
 438         this.lag_func = bot_lagfunc;
 439         this.isbot = true;
 440         this.createdtime = this.bot_nextthink;
 441
 442         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 443         {
 444                 bot_setnameandstuff(this);
 445                 bot_setclientfields(this);
 446         }
 447
 448         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 449         {
 450                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 451         }
 452         else
 453         {
 454                 this.bot_forced_team = 0;
 455                 TeamBalance_JoinBestTeam(this);
 456         }
 457
 458         havocbot_setupbot(this);
 459 }
 460
 461 void bot_removefromlargestteam()
 462 {
 463         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 464         TeamBalance_GetTeamCounts(balance, NULL);
 465
 466         entity best = NULL;
 467         float besttime = 0;
 468         int bestcount = 0;
 469
 470         int bcount = 0;
 471         FOREACH_CLIENT(it.isbot,
 472         {
 473                 ++bcount;
 474
 475                 if(!best)
 476                 {
 477                         best = it;
 478                         besttime = it.createdtime;
 479                 }
 480
 481                 int thiscount = 0;
 482
 483                 if (Team_IsValidTeam(it.team))
 484                 {
 485                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 486                                 Team_TeamToIndex(it.team));
 487                 }
 488
 489                 if(thiscount > bestcount)
 490                 {
 491                         bestcount = thiscount;
 492                         besttime = it.createdtime;
 493                         best = it;
 494                 }
 495                 else if(thiscount == bestcount && besttime < it.createdtime)
 496                 {
 497                         besttime = it.createdtime;
 498                         best = it;
 499                 }
 500         });
 501         TeamBalance_Destroy(balance);
 502         if(!bcount)
 503                 return; // no bots to remove
 504         currentbots = currentbots - 1;
 505         dropclient(best);
 506 }
 507
 508 void bot_removenewest()
 509 {
 510         if(teamplay)
 511         {
 512                 bot_removefromlargestteam();
 513                 return;
 514         }
 515
 516         float besttime = 0;
 517         entity best = NULL;
 518         int bcount = 0;
 519
 520         FOREACH_CLIENT(it.isbot,
 521         {
 522                 ++bcount;
 523
 524                 if(!best)
 525                 {
 526                         best = it;
 527                         besttime = it.createdtime;
 528                 }
 529
 530                 if(besttime < it.createdtime)
 531                 {
 532                         besttime = it.createdtime;
 533                         best = it;
 534                 }
 535         });
 536
 537         if(!bcount)
 538                 return; // no bots to remove
 539
 540         currentbots = currentbots - 1;
 541         dropclient(best);
 542 }
 543
 544 void autoskill(float factor)
 545 {
 546         int bestbot = -1;
 547         int bestplayer = -1;
 548         FOREACH_CLIENT(IS_PLAYER(it), {
 549                 if(IS_REAL_CLIENT(it))
 550                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 551                 else
 552                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 553         });
 554
 555         string msg = strcat("autoskill: best player got ", ftos(bestplayer), ", ""best bot got ", ftos(bestbot), "; ");
 556         if(bestbot < 0 || bestplayer < 0)
 557         {
 558                 msg = strcat(msg, "not doing anything");
 559                 // don't return, let it reset all counters below
 560         }
 561         else if(bestbot <= bestplayer * factor - 2)
 562         {
 563                 if(autocvar_skill < 17)
 564                 {
 565                         msg = strcat(msg, "2 frags difference, increasing skill");
 566                         cvar_set("skill", ftos(autocvar_skill + 1));
 567                         bprint("^2BOT SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 568                 }
 569         }
 570         else if(bestbot >= bestplayer * factor + 2)
 571         {
 572                 if(autocvar_skill > 0)
 573                 {
 574                         msg = strcat(msg, "2 frags difference, decreasing skill");
 575                         cvar_set("skill", ftos(autocvar_skill - 1));
 576                         bprint("^1BOT SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 577                 }
 578         }
 579         else
 580         {
 581                 msg = strcat(msg, "not doing anything");
 582                 return;
 583                 // don't reset counters, wait for them to accumulate
 584         }
 585         LOG_DEBUG(msg);
 586
 587         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 588 }
 589
 590 void bot_calculate_stepheightvec()
 591 {
 592         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 593         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 594         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 595         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 596 }
 597
 598 bool bot_fixcount(bool multiple_per_frame)
 599 {
 600         int activerealplayers = 0;
 601         int realplayers = 0;
 602         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 603                 activerealplayers = M_ARGV(0, int);
 604                 realplayers = M_ARGV(1, int);
 605         } else {
 606                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 607                         if(IS_PLAYER(it))
 608                                 ++activerealplayers;
 609                         ++realplayers;
 610                 });
 611         }
 612
 613         int bots;
 614         // But don't remove bots immediately on level change, as the real players
 615         // usually haven't rejoined yet
 616         bots_would_leave = false;
 617         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 618                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 619         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 620         {
 621                 int minplayers = max(0, floor(autocvar_minplayers));
 622                 if (teamplay)
 623                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 624                 int minbots = max(0, floor(autocvar_bot_number));
 625
 626                 // add bots to reach minplayers if needed
 627                 bots = max(minbots, minplayers - activerealplayers);
 628                 // cap bots to the max players allowed by the server
 629                 int player_limit = GetPlayerLimit();
 630                 if(player_limit)
 631                         bots = min(bots, max(player_limit - activerealplayers, 0));
 632                 bots = min(bots, maxclients - realplayers);
 633
 634                 if(bots > minbots)
 635                         bots_would_leave = true;
 636         }
 637         else
 638         {
 639                 // if there are no players, remove bots
 640                 bots = 0;
 641         }
 642
 643         // only add one bot per frame to avoid utter chaos
 644         if(time > botframe_nextthink)
 645         {
 646                 while (currentbots < bots)
 647                 {
 648                         if (bot_spawn() == NULL)
 649                         {
 650                                 bprint("Can not add bot, server full.\n");
 651                                 return false;
 652                         }
 653                         if (!multiple_per_frame)
 654                         {
 655                                 break;
 656                         }
 657                 }
 658                 while (currentbots > bots && bots >= 0)
 659                         bot_removenewest();
 660         }
 661
 662         return true;
 663 }
 664
 665 void bot_serverframe()
 666 {
 667         if (intermission_running && currentbots > 0)
 668         {
 669                 // after the end of the match all bots stay unless all human players disconnect
 670                 int realplayers = 0;
 671                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 672                 if (!realplayers)
 673                 {
 674                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 675                         currentbots = 0;
 676                 }
 677                 return;
 678         }
 679
 680         if (game_stopped)
 681                 return;
 682
 683         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 684         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 685         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 686         // either intentionally or automatically (sv_spectate 0)
 687         if (time < 2.5)
 688         {
 689                 currentbots = -1;
 690                 return;
 691         }
 692
 693         if (currentbots == -1)
 694         {
 695                 // count bots already in the server from the previous match
 696                 currentbots = 0;
 697                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 698         }
 699
 700         if(autocvar_skill != skill)
 701         {
 702                 float wpcost_update = false;
 703                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 704                         wpcost_update = true;
 705                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 706                         wpcost_update = true;
 707
 708                 skill = autocvar_skill;
 709                 if (wpcost_update)
 710                         waypoint_updatecost_foralllinks();
 711         }
 712
 713         bot_calculate_stepheightvec();
 714         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 715
 716         if(time > autoskill_nextthink)
 717         {
 718                 float a;
 719                 a = autocvar_skill_auto;
 720                 if(a)
 721                         autoskill(a);
 722                 autoskill_nextthink = time + 5;
 723         }
 724
 725         if(time > botframe_nextthink)
 726         {
 727                 if(!bot_fixcount(false))
 728                         botframe_nextthink = time + 10;
 729         }
 730
 731         if(botframe_spawnedwaypoints)
 732         {
 733                 if(autocvar_waypoint_benchmark)
 734                         localcmd("quit\n");
 735         }
 736
 737         if (currentbots > 0 || waypointeditor_enabled || autocvar_g_waypointeditor_auto)
 738         if (botframe_spawnedwaypoints)
 739         {
 740                 if(botframe_cachedwaypointlinks)
 741                 {
 742                         if(!botframe_loadedforcedlinks)
 743                                 waypoint_load_hardwiredlinks();
 744                 }
 745                 else
 746                 {
 747                         // TODO: Make this check cleaner
 748                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 749                         {
 750                                 waypoint_save_links();
 751                                 break;
 752                         });
 753                 }
 754         }
 755         else
 756         {
 757                 botframe_spawnedwaypoints = true;
 758                 waypoint_loadall();
 759                 waypoint_load_links();
 760         }
 761
 762         if (bot_list)
 763         {
 764                 // cycle the goal token from one bot to the next each frame
 765                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 766                 //  frame, which causes choppy framerates)
 767                 if (bot_strategytoken_taken)
 768                 {
 769                         // give goal token to the first bot without goals; if all bots don't have
 770                         // any goal (or are dead/frozen) simply give it to the next one
 771                         bot_strategytoken_taken = false;
 772                         entity bot_strategytoken_save = bot_strategytoken;
 773                         while (true)
 774                         {
 775                                 if (bot_strategytoken)
 776                                         bot_strategytoken = bot_strategytoken.nextbot;
 777                                 if (!bot_strategytoken)
 778                                         bot_strategytoken = bot_list;
 779
 780                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 781                                         && !bot_strategytoken.goalcurrent)
 782                                         break;
 783
 784                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 785                                         break;
 786                                 if (bot_strategytoken == bot_strategytoken_save)
 787                                         bot_strategytoken_save = NULL; // looped through all the bots
 788                         }
 789                 }
 790
 791                 if (botframe_nextdangertime < time)
 792                 {
 793                         float interval;
 794                         interval = autocvar_bot_ai_dangerdetectioninterval;
 795                         if (botframe_nextdangertime < time - interval * 1.5)
 796                                 botframe_nextdangertime = time;
 797                         botframe_nextdangertime = botframe_nextdangertime + interval;
 798                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 799                 }
 800         }
 801
 802         if (waypointeditor_enabled)
 803                 botframe_showwaypointlinks();
 804
 805         if (autocvar_g_waypointeditor_auto)
 806                 botframe_autowaypoints();
 807
 808         if (currentbots > 0)
 809                 bot_custom_weapon_priority_setup();
 810 }