qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include "../../mutators/_mod.qh"
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  45 void bot_setclientfields(entity this)
  46 {
  47         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  48         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  49 }
  50
  51 entity bot_spawn()
  52 {
  53         entity bot = spawnclient();
  54         if (bot)
  55         {
  56                 setItemGroupCount();
  57                 currentbots = currentbots + 1;
  58                 bot_setnameandstuff(bot);
  59                 ClientConnect(bot);
  60                 bot_setclientfields(bot);
  61                 PutClientInServer(bot);
  62         }
  63         return bot;
  64 }
  65
  66 void bot_think(entity this)
  67 {
  68         if (this.bot_nextthink > time)
  69                 return;
  70
  71         this.flags &= ~FL_GODMODE;
  72         if(autocvar_bot_god)
  73                 this.flags |= FL_GODMODE;
  74
  75         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  76
  77         //if (this.bot_painintensity > 0)
  78         //      this.bot_painintensity = this.bot_painintensity - (skill + 1) * 40 * frametime;
  79
  80         //this.bot_painintensity = this.bot_painintensity + this.bot_oldhealth - this.health;
  81         //this.bot_painintensity = bound(0, this.bot_painintensity, 100);
  82
  83         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  84         {
  85                 CS(this).movement = '0 0 0';
  86                 this.bot_nextthink = time + 0.5;
  87                 return;
  88         }
  89
  90         if (this.fixangle)
  91         {
  92                 this.v_angle = this.angles;
  93                 this.v_angle_z = 0;
  94                 this.fixangle = false;
  95         }
  96
  97         this.dmg_take = 0;
  98         this.dmg_save = 0;
  99         this.dmg_inflictor = NULL;
 100
 101         // calculate an aiming latency based on the skill setting
 102         // (simulated network latency + naturally delayed reflexes)
 103         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 104         // minimum ping 20+10 random
 105         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 106         // skill 10 = ping 0.2 (adrenaline)
 107         // skill 0 = ping 0.7 (slightly drunk)
 108
 109         // clear buttons
 110         PHYS_INPUT_BUTTON_ATCK(this) = false;
 111         PHYS_INPUT_BUTTON_JUMP(this) = false;
 112         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 113         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 114         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 115         PHYS_INPUT_BUTTON_HOOK(this) = false;
 116         PHYS_INPUT_BUTTON_INFO(this) = false;
 117         PHYS_INPUT_BUTTON_DRAG(this) = false;
 118         PHYS_INPUT_BUTTON_CHAT(this) = false;
 119         PHYS_INPUT_BUTTON_USE(this) = false;
 120
 121         if (time < game_starttime)
 122         {
 123                 // block the bot during the countdown to game start
 124                 CS(this).movement = '0 0 0';
 125                 this.bot_nextthink = game_starttime;
 126                 return;
 127         }
 128
 129         // if dead, just wait until we can respawn
 130         if (IS_DEAD(this))
 131         {
 132                 CS(this).movement = '0 0 0';
 133                 if (this.deadflag == DEAD_DEAD)
 134                 {
 135                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 136                         navigation_goalrating_timeout_force(this);
 137                 }
 138         }
 139         else if(this.aistatus & AI_STATUS_STUCK)
 140                 navigation_unstuck(this);
 141
 142         // now call the current bot AI (havocbot for example)
 143         this.bot_ai(this);
 144 }
 145
 146 void bot_setnameandstuff(entity this)
 147 {
 148         string readfile, s;
 149         float file, tokens, prio;
 150
 151         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 152         string name, prefix, suffix;
 153
 154         if(autocvar_g_campaign)
 155         {
 156                 prefix = "";
 157                 suffix = "";
 158         }
 159         else
 160         {
 161                 prefix = autocvar_bot_prefix;
 162                 suffix = autocvar_bot_suffix;
 163         }
 164
 165         file = fopen(autocvar_bot_config_file, FILE_READ);
 166
 167         if(file < 0)
 168         {
 169                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 170                 readfile = "";
 171         }
 172         else
 173         {
 174                 RandomSelection_Init();
 175                 while((readfile = fgets(file)))
 176                 {
 177                         if(substring(readfile, 0, 2) == "//")
 178                                 continue;
 179                         if(substring(readfile, 0, 1) == "#")
 180                                 continue;
 181                         tokens = tokenizebyseparator(readfile, "\t");
 182                         if(tokens == 0)
 183                                 continue;
 184                         s = argv(0);
 185                         prio = 1;
 186                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 187                                 if(s == it.cleanname)
 188                                 {
 189                                         prio = 0;
 190                                         break;
 191                                 }
 192                         });
 193                         RandomSelection_AddString(readfile, 1, prio);
 194                 }
 195                 readfile = RandomSelection_chosen_string;
 196                 fclose(file);
 197         }
 198
 199         tokens = tokenizebyseparator(readfile, "\t");
 200         if(argv(0) != "") bot_name = argv(0);
 201         else bot_name = "Bot";
 202
 203         if(argv(1) != "") bot_model = argv(1);
 204         else bot_model = "";
 205
 206         if(argv(2) != "") bot_skin = argv(2);
 207         else bot_skin = "0";
 208
 209         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 210         else bot_shirt = ftos(floor(random() * 15));
 211
 212         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 213         else bot_pants = ftos(floor(random() * 15));
 214
 215         this.bot_forced_team = stof(argv(5));
 216
 217         prio = 6;
 218
 219         #define READSKILL(f, w, r) MACRO_BEGIN { \
 220                 if(argv(prio) != "") \
 221                         this.f = stof(argv(prio)) * w; \
 222                 else \
 223                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 224                 prio++; \
 225         } MACRO_END
 226         //print(bot_name, ": ping=", argv(9), "\n");
 227
 228         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 229         READSKILL(bot_moveskill, 2, 0); // move skill
 230         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 231
 232         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 233
 234         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 235         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 236         READSKILL(bot_rangepreference, 1, 0); // read skill
 237
 238         READSKILL(bot_aimskill, 2, 0); // aim skill
 239         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 240         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 241
 242         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 243         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 244
 245         this.bot_config_loaded = true;
 246
 247         // this is really only a default, JoinBestTeam is called later
 248         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 249         this.bot_preferredcolors = this.clientcolors;
 250
 251         // pick the name
 252         if (autocvar_bot_usemodelnames)
 253                 name = bot_model;
 254         else
 255                 name = bot_name;
 256
 257         // number bots with identical names
 258         int j = 0;
 259         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 260                 if(it.cleanname == name)
 261                         ++j;
 262         });
 263         if (j)
 264                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 265         else
 266                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 267
 268         this.cleanname = strzone(name);
 269
 270         // pick the model and skin
 271         if(substring(bot_model, -4, 1) != ".")
 272                 bot_model = strcat(bot_model, ".iqm");
 273         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 274         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 275 }
 276
 277 void bot_custom_weapon_priority_setup()
 278 {
 279         float tokens, i, w;
 280
 281         bot_custom_weapon = false;
 282
 283         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 284                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 285                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 286                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 287         )
 288                 return;
 289
 290         // Parse distances
 291         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 292
 293         if (tokens!=2)
 294                 return;
 295
 296         bot_distance_far = stof(argv(0));
 297         bot_distance_close = stof(argv(1));
 298
 299         if(bot_distance_far < bot_distance_close){
 300                 bot_distance_far = stof(argv(1));
 301                 bot_distance_close = stof(argv(0));
 302         }
 303
 304         // Initialize list of weapons
 305         bot_weapons_far[0] = -1;
 306         bot_weapons_mid[0] = -1;
 307         bot_weapons_close[0] = -1;
 308
 309         // Parse far distance weapon priorities
 310         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 311
 312         int c = 0;
 313         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 314                 w = stof(argv(i));
 315                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 316                         bot_weapons_far[c] = w;
 317                         ++c;
 318                 }
 319         }
 320         if(c < Weapons_COUNT)
 321                 bot_weapons_far[c] = -1;
 322
 323         // Parse mid distance weapon priorities
 324         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 325
 326         c = 0;
 327         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 328                 w = stof(argv(i));
 329                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 330                         bot_weapons_mid[c] = w;
 331                         ++c;
 332                 }
 333         }
 334         if(c < Weapons_COUNT)
 335                 bot_weapons_mid[c] = -1;
 336
 337         // Parse close distance weapon priorities
 338         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 339
 340         c = 0;
 341         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 342                 w = stof(argv(i));
 343                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 344                         bot_weapons_close[c] = w;
 345                         ++c;
 346                 }
 347         }
 348         if(c < Weapons_COUNT)
 349                 bot_weapons_close[c] = -1;
 350
 351         bot_custom_weapon = true;
 352 }
 353
 354 void bot_endgame()
 355 {
 356         bot_relinkplayerlist();
 357         entity e = bot_list;
 358         while (e)
 359         {
 360                 setcolor(e, e.bot_preferredcolors);
 361                 e = e.nextbot;
 362         }
 363         // if dynamic waypoints are ever implemented, save them here
 364 }
 365
 366 void bot_relinkplayerlist()
 367 {
 368         player_count = 0;
 369         currentbots = 0;
 370         bot_list = NULL;
 371
 372         entity prevbot = NULL;
 373         FOREACH_CLIENT(true,
 374         {
 375                 ++player_count;
 376
 377                 if(IS_BOT_CLIENT(it))
 378                 {
 379                         if(prevbot)
 380                                 prevbot.nextbot = it;
 381                         else
 382                                 bot_list = it;
 383                         prevbot = it;
 384                         ++currentbots;
 385                 }
 386         });
 387         if(prevbot)
 388                 prevbot.nextbot = NULL;
 389         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 390         bot_strategytoken = bot_list;
 391         bot_strategytoken_taken = true;
 392 }
 393
 394 void bot_clientdisconnect(entity this)
 395 {
 396         if (!IS_BOT_CLIENT(this))
 397                 return;
 398         bot_clearqueue(this);
 399         strfree(this.cleanname);
 400         strfree(this.netname_freeme);
 401         strfree(this.playermodel_freeme);
 402         strfree(this.playerskin_freeme);
 403         if(this.bot_cmd_current)
 404                 delete(this.bot_cmd_current);
 405         if(bot_waypoint_queue_owner == this)
 406                 bot_waypoint_queue_owner = NULL;
 407 }
 408
 409 void bot_clientconnect(entity this)
 410 {
 411         if (!IS_BOT_CLIENT(this)) return;
 412         this.bot_preferredcolors = this.clientcolors;
 413         this.bot_nextthink = time - random();
 414         this.lag_func = bot_lagfunc;
 415         this.isbot = true;
 416         this.createdtime = this.bot_nextthink;
 417
 418         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 419         {
 420                 bot_setnameandstuff(this);
 421                 bot_setclientfields(this);
 422         }
 423
 424         if(this.bot_forced_team==1)
 425                 this.team = NUM_TEAM_1;
 426         else if(this.bot_forced_team==2)
 427                 this.team = NUM_TEAM_2;
 428         else if(this.bot_forced_team==3)
 429                 this.team = NUM_TEAM_3;
 430         else if(this.bot_forced_team==4)
 431                 this.team = NUM_TEAM_4;
 432         else
 433                 JoinBestTeam(this, true);
 434
 435         havocbot_setupbot(this);
 436 }
 437
 438 void bot_removefromlargestteam()
 439 {
 440         CheckAllowedTeams(NULL);
 441         GetTeamCounts(NULL);
 442
 443         entity best = NULL;
 444         float besttime = 0;
 445         int bestcount = 0;
 446
 447         int bcount = 0;
 448         FOREACH_CLIENT(it.isbot,
 449         {
 450                 ++bcount;
 451
 452                 if(!best)
 453                 {
 454                         best = it;
 455                         besttime = it.createdtime;
 456                 }
 457
 458                 int thiscount = 0;
 459
 460                 switch(it.team)
 461                 {
 462                         case NUM_TEAM_1: thiscount = c1; break;
 463                         case NUM_TEAM_2: thiscount = c2; break;
 464                         case NUM_TEAM_3: thiscount = c3; break;
 465                         case NUM_TEAM_4: thiscount = c4; break;
 466                 }
 467
 468                 if(thiscount > bestcount)
 469                 {
 470                         bestcount = thiscount;
 471                         besttime = it.createdtime;
 472                         best = it;
 473                 }
 474                 else if(thiscount == bestcount && besttime < it.createdtime)
 475                 {
 476                         besttime = it.createdtime;
 477                         best = it;
 478                 }
 479         });
 480         if(!bcount)
 481                 return; // no bots to remove
 482         currentbots = currentbots - 1;
 483         dropclient(best);
 484 }
 485
 486 void bot_removenewest()
 487 {
 488         if(teamplay)
 489         {
 490                 bot_removefromlargestteam();
 491                 return;
 492         }
 493
 494         float besttime = 0;
 495         entity best = NULL;
 496         int bcount = 0;
 497
 498         FOREACH_CLIENT(it.isbot,
 499         {
 500                 ++bcount;
 501
 502                 if(!best)
 503                 {
 504                         best = it;
 505                         besttime = it.createdtime;
 506                 }
 507
 508                 if(besttime < it.createdtime)
 509                 {
 510                         besttime = it.createdtime;
 511                         best = it;
 512                 }
 513         });
 514
 515         if(!bcount)
 516                 return; // no bots to remove
 517
 518         currentbots = currentbots - 1;
 519         dropclient(best);
 520 }
 521
 522 void autoskill(float factor)
 523 {
 524         float bestbot;
 525         float bestplayer;
 526
 527         bestbot = -1;
 528         bestplayer = -1;
 529         FOREACH_CLIENT(IS_PLAYER(it), {
 530                 if(IS_REAL_CLIENT(it))
 531                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 532                 else
 533                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 534         });
 535
 536         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 537         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 538         if(bestbot < 0 || bestplayer < 0)
 539         {
 540                 LOG_DEBUG("not doing anything");
 541                 // don't return, let it reset all counters below
 542         }
 543         else if(bestbot <= bestplayer * factor - 2)
 544         {
 545                 if(autocvar_skill < 17)
 546                 {
 547                         LOG_DEBUG("2 frags difference, increasing skill");
 548                         cvar_set("skill", ftos(autocvar_skill + 1));
 549                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 550                 }
 551         }
 552         else if(bestbot >= bestplayer * factor + 2)
 553         {
 554                 if(autocvar_skill > 0)
 555                 {
 556                         LOG_DEBUG("2 frags difference, decreasing skill");
 557                         cvar_set("skill", ftos(autocvar_skill - 1));
 558                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 559                 }
 560         }
 561         else
 562         {
 563                 LOG_DEBUG("not doing anything");
 564                 return;
 565                 // don't reset counters, wait for them to accumulate
 566         }
 567
 568         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 569 }
 570
 571 void bot_calculate_stepheightvec()
 572 {
 573         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 574         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 575         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 576 }
 577
 578 float bot_fixcount()
 579 {
 580         int activerealplayers = 0;
 581         int realplayers = 0;
 582         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 583                 activerealplayers = M_ARGV(0, int);
 584                 realplayers = M_ARGV(1, int);
 585         } else {
 586                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 587                         if(IS_PLAYER(it))
 588                                 ++activerealplayers;
 589                         ++realplayers;
 590                 });
 591         }
 592
 593         int bots;
 594         // add/remove bots if needed to make sure there are at least
 595         // minplayers+bot_number, or remove all bots if no one is playing
 596         // But don't remove bots immediately on level change, as the real players
 597         // usually haven't rejoined yet
 598         bots_would_leave = false;
 599         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 600                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 601         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 602         {
 603                 float realminplayers, minplayers;
 604                 realminplayers = autocvar_minplayers;
 605                 minplayers = max(0, floor(realminplayers));
 606
 607                 float realminbots, minbots;
 608                 realminbots = autocvar_bot_number;
 609                 minbots = max(0, floor(realminbots));
 610
 611                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
 612                 if(bots > minbots)
 613                         bots_would_leave = true;
 614         }
 615         else
 616         {
 617                 // if there are no players, remove bots
 618                 bots = 0;
 619         }
 620
 621         // only add one bot per frame to avoid utter chaos
 622         if(time > botframe_nextthink)
 623         {
 624                 if (currentbots < bots)
 625                 {
 626                         if (bot_spawn() == NULL)
 627                         {
 628                                 bprint("Can not add bot, server full.\n");
 629                                 return false;
 630                         }
 631                 }
 632                 while (currentbots > bots)
 633                         bot_removenewest();
 634         }
 635
 636         return true;
 637 }
 638
 639 void bot_remove_from_bot_list(entity this)
 640 {
 641         entity e = bot_list;
 642         entity prev_bot = NULL;
 643         while (e)
 644         {
 645                 if(e == this)
 646                 {
 647                         if(!prev_bot)
 648                                 bot_list = this.nextbot;
 649                         else
 650                                 prev_bot.nextbot = this.nextbot;
 651                         if(bot_strategytoken == this)
 652                         {
 653                                 bot_strategytoken = this.nextbot;
 654                                 bot_strategytoken_taken = true;
 655                         }
 656                         this.nextbot = NULL;
 657                         break;
 658                 }
 659                 prev_bot = e;
 660                 e = e.nextbot;
 661         }
 662 }
 663
 664 void bot_clear(entity this)
 665 {
 666         bot_remove_from_bot_list(this);
 667         if(bot_waypoint_queue_owner == this)
 668                 bot_waypoint_queue_owner = NULL;
 669         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 670 }
 671
 672 void bot_serverframe()
 673 {
 674         if (intermission_running && currentbots > 0)
 675         {
 676                 // after the end of the match all bots stay unless all human players disconnect
 677                 int realplayers = 0;
 678                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 679                 if (!realplayers)
 680                 {
 681                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 682                         currentbots = 0;
 683                 }
 684                 return;
 685         }
 686
 687         if (game_stopped)
 688                 return;
 689
 690         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 691         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 692         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 693         // either intentionally or automatically (sv_spectate 0)
 694         if (time < 2.5)
 695         {
 696                 currentbots = -1;
 697                 return;
 698         }
 699
 700         if (currentbots == -1)
 701         {
 702                 // count bots already in the server from the previous match
 703                 currentbots = 0;
 704                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 705         }
 706
 707         if(autocvar_skill != skill)
 708         {
 709                 float wpcost_update = false;
 710                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 711                         wpcost_update = true;
 712                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 713                         wpcost_update = true;
 714
 715                 skill = autocvar_skill;
 716                 if (wpcost_update)
 717                         waypoint_updatecost_foralllinks();
 718         }
 719
 720         bot_calculate_stepheightvec();
 721         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 722
 723         if(time > autoskill_nextthink)
 724         {
 725                 float a;
 726                 a = autocvar_skill_auto;
 727                 if(a)
 728                         autoskill(a);
 729                 autoskill_nextthink = time + 5;
 730         }
 731
 732         if(time > botframe_nextthink)
 733         {
 734                 if(!bot_fixcount())
 735                         botframe_nextthink = time + 10;
 736         }
 737
 738         if(botframe_spawnedwaypoints)
 739         {
 740                 if(autocvar_waypoint_benchmark)
 741                         localcmd("quit\n");
 742         }
 743
 744         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 745         if (botframe_spawnedwaypoints)
 746         {
 747                 if(botframe_cachedwaypointlinks)
 748                 {
 749                         if(!botframe_loadedforcedlinks)
 750                                 waypoint_load_links_hardwired();
 751                 }
 752                 else
 753                 {
 754                         // TODO: Make this check cleaner
 755                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 756                         {
 757                                 waypoint_save_links();
 758                                 break;
 759                         });
 760                 }
 761         }
 762         else
 763         {
 764                 botframe_spawnedwaypoints = true;
 765                 waypoint_loadall();
 766                 waypoint_load_links();
 767         }
 768
 769         if (bot_list)
 770         {
 771                 // cycle the goal token from one bot to the next each frame
 772                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 773                 //  frame, which causes choppy framerates)
 774                 if (bot_strategytoken_taken)
 775                 {
 776                         // give goal token to the first bot without goals; if all bots don't have
 777                         // any goal (or are dead/frozen) simply give it to the next one
 778                         bot_strategytoken_taken = false;
 779                         entity bot_strategytoken_save = bot_strategytoken;
 780                         while (true)
 781                         {
 782                                 if (bot_strategytoken)
 783                                         bot_strategytoken = bot_strategytoken.nextbot;
 784                                 if (!bot_strategytoken)
 785                                         bot_strategytoken = bot_list;
 786
 787                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 788                                         && !bot_strategytoken.goalcurrent)
 789                                         break;
 790
 791                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 792                                         break;
 793                                 if (bot_strategytoken == bot_strategytoken_save)
 794                                         bot_strategytoken_save = NULL; // looped through all the bots
 795                         }
 796                 }
 797
 798                 if (botframe_nextdangertime < time)
 799                 {
 800                         float interval;
 801                         interval = autocvar_bot_ai_dangerdetectioninterval;
 802                         if (botframe_nextdangertime < time - interval * 1.5)
 803                                 botframe_nextdangertime = time;
 804                         botframe_nextdangertime = botframe_nextdangertime + interval;
 805                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 806                 }
 807         }
 808
 809         if (autocvar_g_waypointeditor)
 810                 botframe_showwaypointlinks();
 811
 812         if (autocvar_g_waypointeditor_auto)
 813                 botframe_autowaypoints();
 814
 815         if(time > bot_cvar_nextthink)
 816         {
 817                 if(currentbots>0)
 818                         bot_custom_weapon_priority_setup();
 819                 bot_cvar_nextthink = time + 5;
 820         }
 821 }