Merge branch 'terencehill/bot_waypoints'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / bot / default / havocbot / havocbot.qc
1 #include "havocbot.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include "../cvars.qh"
6
7 #include "../aim.qh"
8 #include "../bot.qh"
9 #include "../navigation.qh"
10 #include "../scripting.qh"
11 #include "../waypoints.qh"
12
13 #include <common/constants.qh>
14 #include <common/impulses/all.qh>
15 #include <common/net_linked.qh>
16 #include <common/physics/player.qh>
17 #include <common/state.qh>
18 #include <common/items/_mod.qh>
19 #include <common/wepent.qh>
20
21 #include <common/mapobjects/func/ladder.qh>
22 #include <common/mapobjects/teleporters.qh>
23 #include <common/mapobjects/trigger/jumppads.qh>
24
25 #include <lib/warpzone/common.qh>
26
27 .float speed;
28
29 void havocbot_ai(entity this)
30 {
31         if(this.draggedby)
32                 return;
33
34         if(bot_execute_commands(this))
35                 return;
36
37         if (bot_strategytoken == this && !bot_strategytoken_taken)
38         {
39                 if(this.havocbot_blockhead)
40                 {
41                         this.havocbot_blockhead = false;
42                 }
43                 else
44                 {
45                         if (!this.jumppadcount && !STAT(FROZEN, this))
46                                 this.havocbot_role(this); // little too far down the rabbit hole
47                 }
48
49                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
50                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
51                 if(!this.goalcurrent)
52                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
53                 {
54                         // Look for the closest waypoint out of water
55                         entity newgoal = NULL;
56                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
57                         {
58                                 if(it.origin.z < this.origin.z)
59                                         continue;
60
61                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
62                                         continue;
63
64                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
65                                         continue;
66
67                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
68
69                                 if(trace_fraction < 1)
70                                         continue;
71
72                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
73                                         newgoal = it;
74                         });
75
76                         if(newgoal)
77                         {
78                         //      te_wizspike(newgoal.origin);
79                                 navigation_pushroute(this, newgoal);
80                         }
81                 }
82
83                 // token has been used this frame
84                 bot_strategytoken_taken = true;
85         }
86
87         if(IS_DEAD(this) || STAT(FROZEN, this))
88         {
89                 if (this.goalcurrent)
90                         navigation_clearroute(this);
91                 return;
92         }
93
94         havocbot_chooseenemy(this);
95
96         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
97         {
98                 .entity weaponentity = weaponentities[slot];
99                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
100                 if(this.(weaponentity).bot_chooseweapontime < time)
101                 {
102                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
103                         havocbot_chooseweapon(this, weaponentity);
104                 }
105         }
106         havocbot_aim(this);
107         lag_update(this);
108
109         this.bot_aimdir_executed = false;
110
111         if (this.bot_aimtarg)
112         {
113                 this.aistatus |= AI_STATUS_ATTACKING;
114                 this.aistatus &= ~AI_STATUS_ROAMING;
115
116                 if(STAT(WEAPONS, this))
117                 {
118                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
119                         {
120                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
121                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
122                         }
123                         else
124                         {
125                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
126                                 {
127                                         .entity weaponentity = weaponentities[slot];
128                                         Weapon w = this.(weaponentity).m_weapon;
129                                         if(w == WEP_Null && slot != 0)
130                                                 continue;
131                                         w.wr_aim(w, this, weaponentity);
132                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
133                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
134                                 }
135                         }
136                 }
137                 else
138                 {
139                         if(IS_PLAYER(this.bot_aimtarg))
140                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
141                 }
142         }
143         else if (this.goalcurrent)
144         {
145                 this.aistatus |= AI_STATUS_ROAMING;
146                 this.aistatus &= ~AI_STATUS_ATTACKING;
147         }
148
149         havocbot_movetogoal(this);
150         if (!this.bot_aimdir_executed && this.goalcurrent)
151         {
152                 // Heading
153                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
154                 dir -= this.origin + this.view_ofs;
155                 dir.z = 0;
156                 bot_aimdir(this, dir, -1);
157         }
158
159         // if the bot is not attacking, consider reloading weapons
160         if (!(this.aistatus & AI_STATUS_ATTACKING))
161         {
162                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
163                 {
164                         .entity weaponentity = weaponentities[slot];
165
166                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
167                                 continue;
168
169                         // we are currently holding a weapon that's not fully loaded, reload it
170                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
171                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
172                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
173
174                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
175                         // the code above executes next frame, starting the reloading then
176                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
177                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
178                         {
179                                 FOREACH(Weapons, it != WEP_Null, {
180                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
181                                         {
182                                                 this.(weaponentity).m_switchweapon = it;
183                                                 break;
184                                         }
185                                 });
186                         }
187                 }
188         }
189 }
190
191 void havocbot_keyboard_movement(entity this, vector destorg)
192 {
193         vector keyboard;
194
195         if (time > this.havocbot_keyboardtime)
196         {
197                 float sk = skill + this.bot_moveskill;
198                 this.havocbot_keyboardtime =
199                         max(
200                                 this.havocbot_keyboardtime
201                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
202                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
203                         , time);
204                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
205
206                 float trigger = autocvar_bot_ai_keyboard_threshold;
207                 float trigger1 = -trigger;
208
209                 // categorize forward movement
210                 // at skill < 1.5 only forward
211                 // at skill < 2.5 only individual directions
212                 // at skill < 4.5 only individual directions, and forward diagonals
213                 // at skill >= 4.5, all cases allowed
214                 if (keyboard.x > trigger)
215                 {
216                         keyboard.x = 1;
217                         if (sk < 2.5)
218                                 keyboard.y = 0;
219                 }
220                 else if (keyboard.x < trigger1 && sk > 1.5)
221                 {
222                         keyboard.x = -1;
223                         if (sk < 4.5)
224                                 keyboard.y = 0;
225                 }
226                 else
227                 {
228                         keyboard.x = 0;
229                         if (sk < 1.5)
230                                 keyboard.y = 0;
231                 }
232                 if (sk < 4.5)
233                         keyboard.z = 0;
234
235                 if (keyboard.y > trigger)
236                         keyboard.y = 1;
237                 else if (keyboard.y < trigger1)
238                         keyboard.y = -1;
239                 else
240                         keyboard.y = 0;
241
242                 if (keyboard.z > trigger)
243                         keyboard.z = 1;
244                 else if (keyboard.z < trigger1)
245                         keyboard.z = -1;
246                 else
247                         keyboard.z = 0;
248
249                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
250                 if (this.havocbot_ducktime > time)
251                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
252         }
253
254         keyboard = this.havocbot_keyboard;
255         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
256         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
257         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
258 }
259
260 void havocbot_bunnyhop(entity this, vector dir)
261 {
262         float bunnyhopdistance;
263         vector deviation;
264         float maxspeed;
265
266         // Don't jump when attacking
267         if(this.aistatus & AI_STATUS_ATTACKING)
268                 return;
269
270         if(IS_PLAYER(this.goalcurrent))
271                 return;
272
273         maxspeed = autocvar_sv_maxspeed;
274
275         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
276                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
277         {
278                 this.aistatus &= ~AI_STATUS_RUNNING;
279                 PHYS_INPUT_BUTTON_JUMP(this) = false;
280                 this.bot_canruntogoal = 0;
281                 this.bot_timelastseengoal = 0;
282                 return;
283         }
284
285         if(this.waterlevel > WATERLEVEL_WETFEET)
286         {
287                 this.aistatus &= ~AI_STATUS_RUNNING;
288                 return;
289         }
290
291         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
292         {
293                 this.bot_canruntogoal = 0;
294                 this.bot_timelastseengoal = 0;
295         }
296
297         vector gco = get_closer_dest(this.goalcurrent, this.origin);
298         bunnyhopdistance = vlen(this.origin - gco);
299
300         // Run only to visible goals
301         if(IS_ONGROUND(this))
302         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
303         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
304         {
305                         this.bot_lastseengoal = this.goalcurrent;
306
307                         // seen it before
308                         if(this.bot_timelastseengoal)
309                         {
310                                 // for a period of time
311                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
312                                 {
313                                         float checkdistance;
314                                         checkdistance = true;
315
316                                         // don't run if it is too close
317                                         if(this.bot_canruntogoal==0)
318                                         {
319                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
320                                                         this.bot_canruntogoal = 1;
321                                                 else
322                                                         this.bot_canruntogoal = -1;
323                                         }
324
325                                         if(this.bot_canruntogoal != 1)
326                                                 return;
327
328                                         if(this.aistatus & AI_STATUS_ROAMING)
329                                         if(this.goalcurrent.classname=="waypoint")
330                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
331                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
332                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
333                                         {
334                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
335                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
336                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
337                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
338
339                                                 if(fabs(deviation.y) < 20)
340                                                 if(bunnyhopdistance < vlen(this.origin - gno))
341                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
342                                                 {
343                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
344                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
345                                                         {
346                                                                 checkdistance = false;
347                                                         }
348                                                 }
349                                         }
350
351                                         if(checkdistance)
352                                         {
353                                                 this.aistatus &= ~AI_STATUS_RUNNING;
354                                                 // increase stop distance in case the goal is on a slope or a lower platform
355                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
356                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
357                                         }
358                                         else
359                                         {
360                                                 this.aistatus |= AI_STATUS_RUNNING;
361                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
362                                         }
363                                 }
364                         }
365                         else
366                         {
367                                 this.bot_timelastseengoal = time;
368                         }
369         }
370         else
371         {
372                 this.bot_timelastseengoal = 0;
373         }
374
375 #if 0
376         // Release jump button
377         if(!cvar("sv_pogostick"))
378         if((IS_ONGROUND(this)) == 0)
379         {
380                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
381                         PHYS_INPUT_BUTTON_JUMP(this) = false;
382
383                 // Strafe
384                 if(this.aistatus & AI_STATUS_RUNNING)
385                 if(vlen(this.velocity)>maxspeed)
386                 {
387                         deviation = vectoangles(dir) - vectoangles(this.velocity);
388                         while (deviation.y < -180) deviation.y = deviation.y + 360;
389                         while (deviation.y > 180) deviation.y = deviation.y - 360;
390
391                         if(fabs(deviation.y)>10)
392                                 CS(this).movement_x = 0;
393
394                         if(deviation.y>10)
395                                 CS(this).movement_y = maxspeed * -1;
396                         else if(deviation.y<10)
397                                 CS(this).movement_y = maxspeed;
398
399                 }
400         }
401 #endif
402 }
403
404 // return true when bot isn't getting closer to the current goal
405 bool havocbot_checkgoaldistance(entity this, vector gco)
406 {
407         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
408         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
409         float distance_time = this.goalcurrent_distance_time;
410         if(distance_time < 0)
411                 distance_time = -distance_time;
412         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
413         {
414                 if(!distance_time)
415                         this.goalcurrent_distance_time = time;
416                 else if (time - distance_time > 0.5)
417                         return true;
418         }
419         else
420         {
421                 // reduce it a little bit so it works even with very small approaches to the goal
422                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
423                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
424                 this.goalcurrent_distance_time = 0;
425         }
426         return false;
427 }
428
429 entity havocbot_select_an_item_of_group(entity this, int gr)
430 {
431         entity selected = NULL;
432         float selected_dist2 = 0;
433         // select farthest item of this group from bot's position
434         IL_EACH(g_items, it.item_group == gr && it.solid,
435         {
436                 float dist2 = vlen2(this.origin - it.origin);
437                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
438                 {
439                         selected = it;
440                         selected_dist2 = vlen2(this.origin - selected.origin);
441                 }
442         });
443
444         if (!selected)
445                 return NULL;
446
447         set_tracewalk_dest(selected, this.origin, false);
448         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
449                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
450         {
451                 return NULL;
452         }
453
454         return selected;
455 }
456
457 void havocbot_movetogoal(entity this)
458 {
459         vector diff;
460         vector dir;
461         vector flatdir;
462         vector evadeobstacle;
463         vector evadelava;
464         float dodge_enemy_factor = 1;
465         float maxspeed;
466         //float dist;
467         vector dodge;
468         //if (this.goalentity)
469         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
470         CS(this).movement = '0 0 0';
471         maxspeed = autocvar_sv_maxspeed;
472
473         PHYS_INPUT_BUTTON_JETPACK(this) = false;
474         // Jetpack navigation
475         if(this.navigation_jetpack_goal)
476         if(this.goalcurrent==this.navigation_jetpack_goal)
477         if(GetResourceAmount(this, RESOURCE_FUEL))
478         {
479                 if(autocvar_bot_debug_goalstack)
480                 {
481                         debuggoalstack(this);
482                         te_wizspike(this.navigation_jetpack_point);
483                 }
484
485                 // Take off
486                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
487                 {
488                         // Brake almost completely so it can get a good direction
489                         if(vdist(this.velocity, >, 10))
490                                 return;
491                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
492                 }
493
494                 makevectors(this.v_angle.y * '0 1 0');
495                 dir = normalize(this.navigation_jetpack_point - this.origin);
496
497                 // Landing
498                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
499                 {
500                         // Calculate brake distance in xy
501                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
502                         float vel2 = vlen2(vec2(this.velocity));
503                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
504                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
505                         if(d < db || d < 500)
506                         {
507                                 // Brake
508                                 if (vel2 > (maxspeed * 0.3) ** 2)
509                                 {
510                                         CS(this).movement_x = dir * v_forward * -maxspeed;
511                                         return;
512                                 }
513                                 // Switch to normal mode
514                                 this.navigation_jetpack_goal = NULL;
515                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
516                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
517                                 return;
518                         }
519                 }
520                 else if(checkpvs(this.origin,this.goalcurrent))
521                 {
522                         // If I can see the goal switch to landing code
523                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
524                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
525                         return;
526                 }
527
528                 // Flying
529                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
530                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
531                 {
532                         CS(this).movement_x = dir * v_forward * maxspeed;
533                         CS(this).movement_y = dir * v_right * maxspeed;
534                 }
535                 return;
536         }
537
538         // Handling of jump pads
539         if(this.jumppadcount)
540         {
541                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
542                 {
543                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
544                         if(navigation_poptouchedgoals(this))
545                                 return;
546                 }
547                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
548                 {
549                         // If got stuck on the jump pad try to reach the farthest visible waypoint
550                         // but with some randomness so it can try out different paths
551                         if(!this.goalcurrent)
552                         {
553                                 entity newgoal = NULL;
554                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
555                                 {
556                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
557                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
558                                                 continue;
559
560                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
561
562                                         if(trace_fraction < 1)
563                                                 continue;
564
565                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
566                                                 newgoal = it;
567                                 });
568
569                                 if(newgoal)
570                                 {
571                                         this.ignoregoal = this.goalcurrent;
572                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
573                                         navigation_clearroute(this);
574                                         navigation_routetogoal(this, newgoal, this.origin);
575                                         if(autocvar_bot_debug_goalstack)
576                                                 debuggoalstack(this);
577                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
578                                 }
579                         }
580                         else
581                         {
582                                 if (this.goalcurrent.bot_pickup)
583                                 {
584                                         entity jumppad_wp = this.goalcurrent_prev;
585                                         navigation_poptouchedgoals(this);
586                                         if(!this.goalcurrent && jumppad_wp.wp00)
587                                         {
588                                                 // head to the jumppad destination once bot reaches the goal item
589                                                 navigation_pushroute(this, jumppad_wp.wp00);
590                                         }
591                                 }
592                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
593                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
594                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
595                                 else if(havocbot_checkgoaldistance(this, gco))
596                                 {
597                                         navigation_clearroute(this);
598                                         navigation_goalrating_timeout_force(this);
599                                 }
600                                 else
601                                         return;
602                         }
603                 }
604                 else
605                 {
606                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
607                         {
608                                 vector velxy = this.velocity; velxy_z = 0;
609                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
610                                 {
611                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
612                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
613                                 }
614                                 return;
615                         }
616
617                         // Don't chase players while using a jump pad
618                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
619                                 return;
620                 }
621         }
622         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
623                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
624
625         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
626         if (skill > 6 && !(IS_ONGROUND(this)))
627         {
628                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
629                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
630                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
631
632                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
633                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
634                 if(this.items & IT_JETPACK)
635                 {
636                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
637                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
638                         {
639                                 if(this.velocity.z<0)
640                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
641                         }
642                         else
643                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
644
645                         // If there is no goal try to move forward
646
647                         if(this.goalcurrent==NULL)
648                                 dir = v_forward;
649                         else
650                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
651
652                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
653                         float xyspeed = xyvelocity * dir;
654
655                         if(xyspeed < (maxspeed / 2))
656                         {
657                                 makevectors(this.v_angle.y * '0 1 0');
658                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
659                                 if(trace_fraction==1)
660                                 {
661                                         CS(this).movement_x = dir * v_forward * maxspeed;
662                                         CS(this).movement_y = dir * v_right * maxspeed;
663                                         if (skill < 10)
664                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
665                                 }
666                         }
667
668                         this.havocbot_blockhead = true;
669
670                         return;
671                 }
672                 else if(!this.jumppadcount && !this.goalcurrent.wphardwired
673                         && GetResourceAmount(this, RESOURCE_HEALTH) + GetResourceAmount(this, RESOURCE_ARMOR) > ROCKETJUMP_DAMAGE())
674                 {
675                         if(this.velocity.z < 0)
676                         {
677                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
678                                 {
679                                         .entity weaponentity = weaponentities[slot];
680
681                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
682                                                 continue;
683
684                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
685                                         {
686                                                 CS(this).movement_x = maxspeed;
687
688                                                 if(this.rocketjumptime)
689                                                 {
690                                                         if(time > this.rocketjumptime)
691                                                         {
692                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
693                                                                 this.rocketjumptime = 0;
694                                                         }
695                                                         return;
696                                                 }
697
698                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
699                                                 this.v_angle_x = 90;
700                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
701                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
702                                                 return;
703                                         }
704                                 }
705                         }
706                 }
707                 else
708                 {
709                         // If there is no goal try to move forward
710                         if(this.goalcurrent==NULL)
711                                 CS(this).movement_x = maxspeed;
712                 }
713         }
714
715         // If we are under water with no goals, swim up
716         if(this.waterlevel && !this.goalcurrent)
717         {
718                 dir = '0 0 0';
719                 if(this.waterlevel>WATERLEVEL_SWIMMING)
720                         dir.z = 1;
721                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
722                         PHYS_INPUT_BUTTON_JUMP(this) = true;
723                 else
724                         PHYS_INPUT_BUTTON_JUMP(this) = false;
725                 makevectors(this.v_angle.y * '0 1 0');
726                 vector v = dir * maxspeed;
727                 CS(this).movement.x = v * v_forward;
728                 CS(this).movement.y = v * v_right;
729                 CS(this).movement.z = v * v_up;
730         }
731
732         // if there is nowhere to go, exit
733         if (this.goalcurrent == NULL)
734                 return;
735
736
737         bool locked_goal = false;
738         if((this.goalentity && wasfreed(this.goalentity))
739                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
740         {
741                 navigation_clearroute(this);
742                 navigation_goalrating_timeout_force(this);
743                 return;
744         }
745         else if(this.goalentity.tag_entity)
746         {
747                 navigation_goalrating_timeout_expire(this, 2);
748         }
749         else if(this.goalentity.bot_pickup)
750         {
751                 if(this.goalentity.bot_pickup_respawning)
752                 {
753                         if(this.goalentity.solid) // item respawned
754                                 this.goalentity.bot_pickup_respawning = false;
755                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
756                         {
757                                 if(checkpvs(this.origin, this.goalentity))
758                                 {
759                                         this.goalentity.bot_pickup_respawning = false;
760                                         navigation_goalrating_timeout_expire(this, random());
761                                 }
762                                 locked_goal = true; // wait for item to respawn
763                         }
764                         else if(this.goalentity == this.goalcurrent)
765                                 locked_goal = true; // wait for item to respawn
766                 }
767                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
768                 {
769                         if(checkpvs(this.origin, this.goalentity))
770                         {
771                                 navigation_goalrating_timeout_expire(this, random());
772                         }
773                 }
774         }
775         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
776                 locked_goal = true;
777
778         if (navigation_shortenpath(this))
779         {
780                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
781                         && navigation_goalrating_timeout_can_be_anticipated(this))
782                 {
783                         navigation_goalrating_timeout_force(this);
784                 }
785         }
786
787         bool goalcurrent_can_be_removed = false;
788         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
789         {
790                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
791                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
792                 {
793                         goalcurrent_can_be_removed = true;
794                         // don't remove if not visible
795                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
796                         {
797                                 navigation_goalrating_timeout_force(this);
798                                 return;
799                         }
800                 }
801                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
802                 {
803                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
804                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
805                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
806                         {
807                                 navigation_goalrating_timeout_force(this);
808                                 return;
809                         }
810                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
811                 }
812         }
813
814         if(!locked_goal)
815         {
816                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
817                 // in this case path finding can start directly from a waypoint instead of
818                 // looking for all the reachable waypoints up to a certain distance
819                 if (navigation_poptouchedgoals(this))
820                 {
821                         if (this.goalcurrent)
822                         {
823                                 if (goalcurrent_can_be_removed)
824                                 {
825                                         // remove even if not visible
826                                         navigation_goalrating_timeout_force(this);
827                                         return;
828                                 }
829                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
830                                         navigation_goalrating_timeout_force(this);
831                         }
832                         else
833                         {
834                                 entity old_goal = this.goalcurrent_prev;
835                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
836                                 {
837                                         // Avoid multiple costly calls of path finding code that selects one of the closest
838                                         // item of the group by telling the bot to head directly to the farthest item.
839                                         // Next time we let the bot select a goal as usual which can be another item
840                                         // of this group (the closest one) and so on
841                                         this.item_group = old_goal.item_group;
842                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
843                                         if (new_goal)
844                                                 navigation_pushroute(this, new_goal);
845                                 }
846                         }
847                 }
848         }
849
850         // if ran out of goals try to use an alternative goal or get a new strategy asap
851         if(this.goalcurrent == NULL)
852         {
853                 navigation_goalrating_timeout_force(this);
854                 return;
855         }
856
857
858         if(autocvar_bot_debug_goalstack)
859                 debuggoalstack(this);
860
861         bool bunnyhop_forbidden = false;
862         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
863         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
864         {
865                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
866                 destorg = this.goalcurrent.origin;
867         }
868         else if (this.goalcurrent.wpisbox)
869         {
870                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
871                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
872                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
873                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
874                 {
875                         bunnyhop_forbidden = true;
876                         destorg = this.goalcurrent.origin;
877                         if(destorg.z > this.origin.z)
878                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
879                 }
880         }
881
882         diff = destorg - this.origin;
883
884         if (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10))
885         {
886                 // stop if the locked goal has been reached
887                 destorg = this.origin;
888                 diff = dir = '0 0 0';
889         }
890         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
891         {
892                 if (vdist(diff, <, 80))
893                 {
894                         // stop if too close to target player (even if frozen)
895                         destorg = this.origin;
896                         diff = dir = '0 0 0';
897                 }
898                 else
899                 {
900                         // move destorg out of target players, otherwise bot will consider them
901                         // an obstacle that needs to be jumped (especially if frozen)
902                         dir = normalize(diff);
903                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
904                         diff = destorg - this.origin;
905                 }
906         }
907         else
908                 dir = normalize(diff);
909         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
910
911         //if (this.bot_dodgevector_time < time)
912         {
913                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
914                 //this.bot_dodgevector_jumpbutton = 1;
915                 evadeobstacle = '0 0 0';
916                 evadelava = '0 0 0';
917
918                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
919                 makevectors(this.v_angle.y * '0 1 0');
920                 if (this.waterlevel > WATERLEVEL_WETFEET)
921                 {
922                         if (this.waterlevel > WATERLEVEL_SWIMMING)
923                         {
924                                 if(!this.goalcurrent)
925                                         this.aistatus |= AI_STATUS_OUT_WATER;
926                                 else if(destorg.z > this.origin.z)
927                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
928                         }
929                         else
930                         {
931                                 dir = flatdir;
932                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
933                                         (this.aistatus & AI_STATUS_OUT_WATER))
934                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
935                                 else
936                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
937                         }
938                 }
939                 else
940                 {
941                         float s;
942                         vector offset;
943                         if(this.aistatus & AI_STATUS_OUT_WATER)
944                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
945
946                         // jump if going toward an obstacle that doesn't look like stairs we
947                         // can walk up directly
948                         vector deviation = '0 0 0';
949                         float current_speed = vlen(vec2(this.velocity));
950                         if (current_speed < maxspeed * 0.2)
951                                 current_speed = maxspeed * 0.2;
952                         else
953                         {
954                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
955                                 while (deviation.y < -180) deviation.y += 360;
956                                 while (deviation.y > 180) deviation.y -= 360;
957                         }
958                         float turning = false;
959                         vector flat_diff = vec2(diff);
960                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
961                         vector actual_destorg = this.origin + offset;
962                         if (!this.goalstack01 || this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER))
963                         {
964                                 if (vlen2(flat_diff) < vlen2(offset))
965                                 {
966                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
967                                         {
968                                                 // oblique warpzones need a jump otherwise bots gets stuck
969                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
970                                         }
971                                         else
972                                         {
973                                                 actual_destorg.x = destorg.x;
974                                                 actual_destorg.y = destorg.y;
975                                         }
976                                 }
977                         }
978                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
979                         {
980                                 actual_destorg.x = destorg.x;
981                                 actual_destorg.y = destorg.y;
982                         }
983                         else if (vlen2(flat_diff) < vlen2(offset))
984                         {
985                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
986                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
987                                 float dist = vlen(vec2(this.origin + offset - destorg));
988                                 // if current and next goal are close to each other make sure
989                                 // actual_destorg isn't set beyond next_goal_org
990                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
991                                         actual_destorg = next_goal_org;
992                                 else
993                                         actual_destorg = vec2(destorg) + dist * next_dir;
994                                 actual_destorg.z = this.origin.z;
995                                 turning = true;
996                         }
997
998                         LABEL(jump_check);
999                         dir = flatdir = normalize(actual_destorg - this.origin);
1000
1001                         if (turning || fabs(deviation.y) < 50) // don't even try to jump if deviation is too high
1002                         {
1003                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1004                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1005                                 {
1006                                         s = trace_fraction;
1007                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1008                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1009                                         {
1010                                                 // found an obstacle
1011                                                 if (turning && fabs(deviation.y) > 5)
1012                                                 {
1013                                                         // check if the obstacle is still there without turning
1014                                                         actual_destorg = destorg;
1015                                                         turning = false;
1016                                                         this.bot_tracewalk_time = time + 0.25;
1017                                                         goto jump_check;
1018                                                 }
1019                                                 s = trace_fraction;
1020                                                 // don't artificially reduce max jump height in real-time
1021                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1022                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1023                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1024                                                 if (trace_fraction > s)
1025                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1026                                                 else
1027                                                 {
1028                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1029                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1030                                                         if (trace_fraction > s)
1031                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1032                                                 }
1033                                         }
1034                                 }
1035                         }
1036
1037                         // if bot for some reason doesn't get close to the current goal find another one
1038                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1039                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1040                         if(havocbot_checkgoaldistance(this, destorg))
1041                         {
1042                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1043                                 {
1044                                         navigation_clearroute(this);
1045                                         navigation_goalrating_timeout_force(this);
1046                                         return;
1047                                 }
1048
1049                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1050                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1051                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1052                                 {
1053                                         navigation_clearroute(this);
1054                                         navigation_goalrating_timeout_force(this);
1055                                         return;
1056                                 }
1057
1058                                 // give bot only another chance to prevent bot getting stuck
1059                                 // in case it thinks it can walk but actually can't
1060                                 this.goalcurrent_distance_z = FLOAT_MAX;
1061                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1062                                 this.goalcurrent_distance_time = -time; // mark second try
1063                         }
1064
1065                         // Check for water/slime/lava and dangerous edges
1066                         // (only when the bot is on the ground or jumping intentionally)
1067
1068                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
1069                         vector dst_ahead = this.origin + this.view_ofs + offset;
1070                         vector dst_down = dst_ahead - '0 0 3000';
1071                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1072
1073                         bool unreachable = false;
1074                         s = CONTENT_SOLID;
1075                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
1076                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1077                         {
1078                                 // Look downwards
1079                                 traceline(dst_ahead , dst_down, true, NULL);
1080                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1081                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
1082                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1083                                 {
1084                                         s = pointcontents(trace_endpos + '0 0 1');
1085                                         if (s != CONTENT_SOLID)
1086                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1087                                                 evadelava = normalize(this.velocity) * -1;
1088                                         else if (s == CONTENT_SKY)
1089                                                 evadeobstacle = normalize(this.velocity) * -1;
1090                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1091                                         {
1092                                                 // the traceline check isn't enough but is good as optimization,
1093                                                 // when not true (most of the time) this tracebox call is avoided
1094                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1095                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1096                                                 {
1097                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1098                                                         {
1099                                                                 // the goal is probably on an upper platform, assume bot can't get there
1100                                                                 unreachable = true;
1101                                                         }
1102                                                         else
1103                                                                 evadelava = normalize(this.velocity) * -1;
1104                                                 }
1105                                         }
1106                                 }
1107                         }
1108
1109                         dir = flatdir;
1110                         evadeobstacle.z = 0;
1111                         evadelava.z = 0;
1112                         makevectors(this.v_angle.y * '0 1 0');
1113
1114                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1115                         {
1116                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1117                                 if(IS_PLAYER(this.goalcurrent))
1118                                         unreachable = true;
1119                         }
1120
1121                         // slow down if bot is in the air and goal is under it
1122                         if (!this.goalcurrent.wphardwired
1123                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1124                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1125                         {
1126                                 // tracebox wouldn't work when bot is still on the ledge
1127                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1128                                 if (this.origin.z - trace_endpos.z > 120)
1129                                         evadeobstacle = normalize(this.velocity) * -1;
1130                         }
1131
1132                         if(unreachable)
1133                         {
1134                                 navigation_clearroute(this);
1135                                 navigation_goalrating_timeout_force(this);
1136                                 this.ignoregoal = this.goalcurrent;
1137                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1138                         }
1139                 }
1140
1141                 dodge = havocbot_dodge(this);
1142                 if (dodge)
1143                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1144                 dodge += evadeobstacle + evadelava;
1145                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1146                 if (this.enemy)
1147                 {
1148                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1149                         if (IS_PLAYER(trace_ent))
1150                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1151                 }
1152         //      this.bot_dodgevector = dir;
1153         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1154         }
1155
1156         float ladder_zdir = 0;
1157         if(time < this.ladder_time)
1158         {
1159                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1160                 {
1161                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1162                                 ladder_zdir = 1;
1163                 }
1164                 else
1165                 {
1166                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1167                                 ladder_zdir = -1;
1168                 }
1169                 if (ladder_zdir)
1170                 {
1171                         if (vdist(flatdir, <, 15))
1172                                 dir = ladder_zdir * '0 0 1';
1173                         else
1174                         {
1175                                 dir.z = ladder_zdir * 1.3;
1176                                 dir = normalize(dir);
1177                         }
1178                 }
1179         }
1180
1181         if (this.goalcurrent.wpisbox
1182                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1183         {
1184                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1185                 // head to teleport origin
1186                 dir = (this.goalcurrent.origin - this.origin);
1187                 dir.z = 0;
1188                 dir = normalize(dir);
1189         }
1190
1191         if (!this.bot_aimdir_executed)
1192                 bot_aimdir(this, dir, -1);
1193
1194         if (!ladder_zdir)
1195         {
1196                 dir *= dodge_enemy_factor;
1197                 dir = normalize(dir + dodge);
1198         }
1199
1200         //dir = this.bot_dodgevector;
1201         //if (this.bot_dodgevector_jumpbutton)
1202         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1203         CS(this).movement_x = dir * v_forward * maxspeed;
1204         CS(this).movement_y = dir * v_right * maxspeed;
1205         CS(this).movement_z = dir * v_up * maxspeed;
1206
1207         // Emulate keyboard interface
1208         if (skill < 10)
1209                 havocbot_keyboard_movement(this, destorg);
1210
1211         // Bunnyhop!
1212         //if(this.aistatus & AI_STATUS_ROAMING)
1213         if(!bunnyhop_forbidden && this.goalcurrent)
1214         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1215                 havocbot_bunnyhop(this, dir);
1216
1217         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1218         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1219         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1220 }
1221
1222 entity havocbot_gettarget(entity this, bool secondary)
1223 {
1224         entity best = NULL;
1225         vector eye = CENTER_OR_VIEWOFS(this);
1226         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1227         {
1228                 vector v = CENTER_OR_VIEWOFS(it);
1229                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1230                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1231                 if(bot_shouldattack(this, it))
1232                 {
1233                         traceline(eye, v, true, this);
1234                         if (trace_ent == it || trace_fraction >= 1)
1235                                 best = it;
1236                 }
1237         });
1238
1239         return best;
1240 }
1241
1242 void havocbot_chooseenemy(entity this)
1243 {
1244         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1245         {
1246                 this.enemy = NULL;
1247                 return;
1248         }
1249         if (this.enemy)
1250         {
1251                 if (!bot_shouldattack(this, this.enemy))
1252                 {
1253                         // enemy died or something, find a new target
1254                         this.enemy = NULL;
1255                         this.havocbot_chooseenemy_finished = time;
1256                 }
1257                 else if (this.havocbot_stickenemy)
1258                 {
1259                         // tracking last chosen enemy
1260                         // if enemy is visible
1261                         // and not really really far away
1262                         // and we're not severely injured
1263                         // then keep tracking for a half second into the future
1264                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1265                         if (trace_ent == this.enemy || trace_fraction == 1)
1266                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1267                         if (GetResourceAmount(this, RESOURCE_HEALTH) > 30)
1268                         {
1269                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1270                                 this.havocbot_chooseenemy_finished = time + 0.5;
1271                                 return;
1272                         }
1273                         // enemy isn't visible, or is far away, or we're injured severely
1274                         // so stop preferring this enemy
1275                         // (it will still take a half second until a new one is chosen)
1276                         this.havocbot_stickenemy = 0;
1277                 }
1278         }
1279         if (time < this.havocbot_chooseenemy_finished)
1280                 return;
1281         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1282         vector eye = this.origin + this.view_ofs;
1283         entity best = NULL;
1284         float bestrating = 100000000;
1285
1286         // Backup hit flags
1287         int hf = this.dphitcontentsmask;
1288
1289         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1290
1291         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1292
1293         bool scan_transparent = false;
1294         bool scan_secondary_targets = false;
1295         bool have_secondary_targets = false;
1296         while(true)
1297         {
1298                 scan_secondary_targets = false;
1299 LABEL(scan_targets)
1300                 IL_EACH(g_bot_targets, it.bot_attack,
1301                 {
1302                         if(!scan_secondary_targets)
1303                         {
1304                                 if(it.classname == "misc_breakablemodel")
1305                                 {
1306                                         have_secondary_targets = true;
1307                                         continue;
1308                                 }
1309                         }
1310                         else if(it.classname != "misc_breakablemodel")
1311                                 continue;
1312
1313                         vector v = (it.absmin + it.absmax) * 0.5;
1314                         float rating = vlen2(v - eye);
1315                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1316                         if (bestrating > rating)
1317                         if (bot_shouldattack(this, it))
1318                         {
1319                                 traceline(eye, v, true, this);
1320                                 if (trace_ent == it || trace_fraction >= 1)
1321                                 {
1322                                         best = it;
1323                                         bestrating = rating;
1324                                 }
1325                         }
1326                 });
1327
1328                 if(!best && have_secondary_targets && !scan_secondary_targets)
1329                 {
1330                         scan_secondary_targets = true;
1331                         // restart the loop
1332                         bestrating = 100000000;
1333                         goto scan_targets;
1334                 }
1335
1336                 // I want to do a second scan if no enemy was found or I don't have weapons
1337                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1338                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1339                         break;
1340                 if(scan_transparent)
1341                         break;
1342
1343                 // Set flags to see through transparent objects
1344                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1345
1346                 scan_transparent = true;
1347         }
1348
1349         // Restore hit flags
1350         this.dphitcontentsmask = hf;
1351
1352         this.enemy = best;
1353         this.havocbot_stickenemy = true;
1354         if(best && best.classname == "misc_breakablemodel")
1355                 this.havocbot_stickenemy = false;
1356 }
1357
1358 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1359 {
1360         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1361         // so skip this for them, or they'll never get to reload their weapons at all.
1362         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1363         if(skill < 5)
1364                 return false;
1365
1366         // if this weapon is scheduled for reloading, don't switch to it during combat
1367         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1368         {
1369                 FOREACH(Weapons, it != WEP_Null, {
1370                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1371                                 return true; // other weapon available
1372                 });
1373         }
1374
1375         return false;
1376 }
1377
1378 void havocbot_chooseweapon(entity this, .entity weaponentity)
1379 {
1380         int i;
1381
1382         // ;)
1383         if(g_weaponarena_weapons == WEPSET(TUBA))
1384         {
1385                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1386                 return;
1387         }
1388
1389         // TODO: clean this up by moving it to weapon code
1390         if(this.enemy==NULL)
1391         {
1392                 // If no weapon was chosen get the first available weapon
1393                 if(this.(weaponentity).m_weapon==WEP_Null)
1394                 FOREACH(Weapons, it != WEP_Null, {
1395                         if(client_hasweapon(this, it, weaponentity, true, false))
1396                         {
1397                                 this.(weaponentity).m_switchweapon = it;
1398                                 return;
1399                         }
1400                 });
1401                 return;
1402         }
1403
1404         // Do not change weapon during the next second after a combo
1405         float f = time - this.lastcombotime;
1406         if(f < 1)
1407                 return;
1408
1409         float w;
1410         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1411
1412         // Should it do a weapon combo?
1413         float af, ct, combo_time, combo;
1414
1415         af = ATTACK_FINISHED(this, weaponentity);
1416         ct = autocvar_bot_ai_weapon_combo_threshold;
1417
1418         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1419         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1420         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1421
1422         combo = false;
1423
1424         if(autocvar_bot_ai_weapon_combo)
1425         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1426         if(af > combo_time)
1427         {
1428                 combo = true;
1429                 this.lastcombotime = time;
1430         }
1431
1432         distance *= (2 ** this.bot_rangepreference);
1433
1434         // Custom weapon list based on distance to the enemy
1435         if(bot_custom_weapon){
1436
1437                 // Choose weapons for far distance
1438                 if ( distance > bot_distance_far ) {
1439                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1440                                 w = bot_weapons_far[i];
1441                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1442                                 {
1443                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1444                                                 continue;
1445                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1446                                         return;
1447                                 }
1448                         }
1449                 }
1450
1451                 // Choose weapons for mid distance
1452                 if ( distance > bot_distance_close) {
1453                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1454                                 w = bot_weapons_mid[i];
1455                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1456                                 {
1457                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1458                                                 continue;
1459                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1460                                         return;
1461                                 }
1462                         }
1463                 }
1464
1465                 // Choose weapons for close distance
1466                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1467                         w = bot_weapons_close[i];
1468                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1469                         {
1470                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1471                                         continue;
1472                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1473                                 return;
1474                         }
1475                 }
1476         }
1477 }
1478
1479 void havocbot_aim(entity this)
1480 {
1481         if (time < this.nextaim)
1482                 return;
1483         this.nextaim = time + 0.1;
1484         vector myvel = this.velocity;
1485         if (!this.waterlevel)
1486                 myvel.z = 0;
1487         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1488         else if (this.enemy)
1489         {
1490                 vector enemyvel = this.enemy.velocity;
1491                 if (!this.enemy.waterlevel)
1492                         enemyvel.z = 0;
1493                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1494         }
1495         else
1496                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1497 }
1498
1499 bool havocbot_moveto_refresh_route(entity this)
1500 {
1501         // Refresh path to goal if necessary
1502         entity wp;
1503         wp = this.havocbot_personal_waypoint;
1504         navigation_goalrating_start(this);
1505         navigation_routerating(this, wp, 10000, 10000);
1506         navigation_goalrating_end(this);
1507         return (this.goalentity != NULL);
1508 }
1509
1510 float havocbot_moveto(entity this, vector pos)
1511 {
1512         entity wp;
1513
1514         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1515         {
1516                 // Step 4: Move to waypoint
1517                 if(this.havocbot_personal_waypoint==NULL)
1518                 {
1519                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1520                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1521                         return CMD_STATUS_ERROR;
1522                 }
1523
1524                 if (!bot_strategytoken_taken)
1525                 if(this.havocbot_personal_waypoint_searchtime<time)
1526                 {
1527                         bot_strategytoken_taken = true;
1528                         if(havocbot_moveto_refresh_route(this))
1529                         {
1530                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1531                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1532                                 this.havocbot_personal_waypoint_failcounter = 0;
1533                         }
1534                         else
1535                         {
1536                                 this.havocbot_personal_waypoint_failcounter += 1;
1537                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1538                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1539                                 {
1540                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1541                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1542                                         delete(this.havocbot_personal_waypoint);
1543                                         return CMD_STATUS_ERROR;
1544                                 }
1545                                 else
1546                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1547                         }
1548                 }
1549
1550                 if(autocvar_bot_debug_goalstack)
1551                         debuggoalstack(this);
1552
1553
1554                 // Go!
1555                 havocbot_movetogoal(this);
1556
1557                 if (!this.bot_aimdir_executed && this.goalcurrent)
1558                 {
1559                         // Heading
1560                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1561                         dir -= this.origin + this.view_ofs;
1562                         dir.z = 0;
1563                         bot_aimdir(this, dir, -1);
1564                 }
1565
1566                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1567                 {
1568                         // Step 5: Waypoint reached
1569                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1570                         delete(this.havocbot_personal_waypoint);
1571                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1572                         return CMD_STATUS_FINISHED;
1573                 }
1574
1575                 return CMD_STATUS_EXECUTING;
1576         }
1577
1578         // Step 2: Linking waypoint
1579         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1580         {
1581                 // Wait until it is linked
1582                 if(!this.havocbot_personal_waypoint.wplinked)
1583                 {
1584                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1585                         return CMD_STATUS_EXECUTING;
1586                 }
1587
1588                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1589                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1590                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1591
1592                 // Step 3: Route to waypoint
1593                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1594
1595                 return CMD_STATUS_EXECUTING;
1596         }
1597
1598         // Step 1: Spawning waypoint
1599         wp = waypoint_spawnpersonal(this, pos);
1600         if(wp==NULL)
1601         {
1602                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1603                 return CMD_STATUS_ERROR;
1604         }
1605
1606         this.havocbot_personal_waypoint = wp;
1607         this.havocbot_personal_waypoint_failcounter = 0;
1608         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1609
1610         // if pos is inside a teleport, then let's mark it as teleport waypoint
1611         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1612         {
1613                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1614                 this.lastteleporttime = 0;
1615         });
1616
1617 /*
1618         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1619                 print("routing to a teleporter\n");
1620         else
1621                 print("routing to a non-teleporter\n");
1622 */
1623
1624         return CMD_STATUS_EXECUTING;
1625 }
1626
1627 float havocbot_resetgoal(entity this)
1628 {
1629         navigation_clearroute(this);
1630         return CMD_STATUS_FINISHED;
1631 }
1632
1633 void havocbot_setupbot(entity this)
1634 {
1635         this.bot_ai = havocbot_ai;
1636         this.cmd_moveto = havocbot_moveto;
1637         this.cmd_resetgoal = havocbot_resetgoal;
1638
1639         // NOTE: bot is not player yet
1640         havocbot_chooserole(this);
1641 }
1642
1643 vector havocbot_dodge(entity this)
1644 {
1645         // LordHavoc: disabled because this is too expensive
1646         return '0 0 0';
1647 #if 0
1648         entity head;
1649         vector dodge, v, n;
1650         float danger, bestdanger, vl, d;
1651         dodge = '0 0 0';
1652         bestdanger = -20;
1653         // check for dangerous objects near bot or approaching bot
1654         head = findchainfloat(bot_dodge, true);
1655         while(head)
1656         {
1657                 if (head.owner != this)
1658                 {
1659                         vl = vlen(head.velocity);
1660                         if (vl > autocvar_sv_maxspeed * 0.3)
1661                         {
1662                                 n = normalize(head.velocity);
1663                                 v = this.origin - head.origin;
1664                                 d = v * n;
1665                                 if (d > (0 - head.bot_dodgerating))
1666                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1667                                 {
1668                                         // calculate direction and distance from the flight path, by removing the forward axis
1669                                         v = v - (n * (v * n));
1670                                         danger = head.bot_dodgerating - vlen(v);
1671                                         if (bestdanger < danger)
1672                                         {
1673                                                 bestdanger = danger;
1674                                                 // dodge to the side of the object
1675                                                 dodge = normalize(v);
1676                                         }
1677                                 }
1678                         }
1679                         else
1680                         {
1681                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1682                                 if (bestdanger < danger)
1683                                 {
1684                                         bestdanger = danger;
1685                                         dodge = normalize(this.origin - head.origin);
1686                                 }
1687                         }
1688                 }
1689                 head = head.chain;
1690         }
1691         return dodge;
1692 #endif
1693 }