Don't respawn frozen non-players when touching the void
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / bot / default / havocbot / havocbot.qc
1 #include "havocbot.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include "../cvars.qh"
6
7 #include "../aim.qh"
8 #include "../bot.qh"
9 #include "../navigation.qh"
10 #include "../scripting.qh"
11 #include "../waypoints.qh"
12
13 #include <common/constants.qh>
14 #include <common/impulses/all.qh>
15 #include <common/net_linked.qh>
16 #include <common/physics/player.qh>
17 #include <common/state.qh>
18 #include <common/items/_mod.qh>
19 #include <common/wepent.qh>
20
21 #include <common/mapobjects/func/ladder.qh>
22 #include <common/mapobjects/teleporters.qh>
23 #include <common/mapobjects/trigger/jumppads.qh>
24
25 #include <lib/warpzone/common.qh>
26
27 .float speed;
28
29 void havocbot_ai(entity this)
30 {
31         if(this.draggedby)
32                 return;
33
34         if(bot_execute_commands(this))
35                 return;
36
37         if (bot_strategytoken == this && !bot_strategytoken_taken)
38         {
39                 if(this.havocbot_blockhead)
40                 {
41                         this.havocbot_blockhead = false;
42                 }
43                 else
44                 {
45                         if (!this.jumppadcount && !STAT(FROZEN, this))
46                                 this.havocbot_role(this); // little too far down the rabbit hole
47                 }
48
49                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
50                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
51                 if(!this.goalcurrent)
52                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
53                 {
54                         // Look for the closest waypoint out of water
55                         entity newgoal = NULL;
56                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
57                         {
58                                 if(it.origin.z < this.origin.z)
59                                         continue;
60
61                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
62                                         continue;
63
64                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
65                                         continue;
66
67                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
68
69                                 if(trace_fraction < 1)
70                                         continue;
71
72                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
73                                         newgoal = it;
74                         });
75
76                         if(newgoal)
77                         {
78                         //      te_wizspike(newgoal.origin);
79                                 navigation_pushroute(this, newgoal);
80                         }
81                 }
82
83                 // token has been used this frame
84                 bot_strategytoken_taken = true;
85         }
86
87         if(IS_DEAD(this) || STAT(FROZEN, this))
88         {
89                 if (this.goalcurrent)
90                         navigation_clearroute(this);
91                 return;
92         }
93
94         havocbot_chooseenemy(this);
95
96         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
97         {
98                 .entity weaponentity = weaponentities[slot];
99                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
100                 if(this.(weaponentity).bot_chooseweapontime < time)
101                 {
102                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
103                         havocbot_chooseweapon(this, weaponentity);
104                 }
105         }
106         havocbot_aim(this);
107         lag_update(this);
108
109         this.bot_aimdir_executed = false;
110
111         if (this.bot_aimtarg)
112         {
113                 this.aistatus |= AI_STATUS_ATTACKING;
114                 this.aistatus &= ~AI_STATUS_ROAMING;
115
116                 if(STAT(WEAPONS, this))
117                 {
118                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
119                         {
120                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
121                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
122                         }
123                         else
124                         {
125                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
126                                 {
127                                         .entity weaponentity = weaponentities[slot];
128                                         Weapon w = this.(weaponentity).m_weapon;
129                                         if(w == WEP_Null && slot != 0)
130                                                 continue;
131                                         w.wr_aim(w, this, weaponentity);
132                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
133                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
134                                 }
135                         }
136                 }
137                 else
138                 {
139                         if(IS_PLAYER(this.bot_aimtarg))
140                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
141                 }
142         }
143         else if (this.goalcurrent)
144         {
145                 this.aistatus |= AI_STATUS_ROAMING;
146                 this.aistatus &= ~AI_STATUS_ATTACKING;
147         }
148
149         havocbot_movetogoal(this);
150         if (!this.bot_aimdir_executed && this.goalcurrent)
151         {
152                 // Heading
153                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
154                 dir -= this.origin + this.view_ofs;
155                 dir.z = 0;
156                 bot_aimdir(this, dir, -1);
157         }
158
159         // if the bot is not attacking, consider reloading weapons
160         if (!(this.aistatus & AI_STATUS_ATTACKING))
161         {
162                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
163                 {
164                         .entity weaponentity = weaponentities[slot];
165
166                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
167                                 continue;
168
169                         // we are currently holding a weapon that's not fully loaded, reload it
170                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
171                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
172                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
173
174                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
175                         // the code above executes next frame, starting the reloading then
176                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
177                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
178                         {
179                                 FOREACH(Weapons, it != WEP_Null, {
180                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
181                                         {
182                                                 this.(weaponentity).m_switchweapon = it;
183                                                 break;
184                                         }
185                                 });
186                         }
187                 }
188         }
189 }
190
191 void havocbot_keyboard_movement(entity this, vector destorg)
192 {
193         vector keyboard;
194
195         if (time > this.havocbot_keyboardtime)
196         {
197                 float sk = skill + this.bot_moveskill;
198                 this.havocbot_keyboardtime =
199                         max(
200                                 this.havocbot_keyboardtime
201                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
202                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
203                         , time);
204                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
205
206                 float trigger = autocvar_bot_ai_keyboard_threshold;
207                 float trigger1 = -trigger;
208
209                 // categorize forward movement
210                 // at skill < 1.5 only forward
211                 // at skill < 2.5 only individual directions
212                 // at skill < 4.5 only individual directions, and forward diagonals
213                 // at skill >= 4.5, all cases allowed
214                 if (keyboard.x > trigger)
215                 {
216                         keyboard.x = 1;
217                         if (sk < 2.5)
218                                 keyboard.y = 0;
219                 }
220                 else if (keyboard.x < trigger1 && sk > 1.5)
221                 {
222                         keyboard.x = -1;
223                         if (sk < 4.5)
224                                 keyboard.y = 0;
225                 }
226                 else
227                 {
228                         keyboard.x = 0;
229                         if (sk < 1.5)
230                                 keyboard.y = 0;
231                 }
232                 if (sk < 4.5)
233                         keyboard.z = 0;
234
235                 if (keyboard.y > trigger)
236                         keyboard.y = 1;
237                 else if (keyboard.y < trigger1)
238                         keyboard.y = -1;
239                 else
240                         keyboard.y = 0;
241
242                 if (keyboard.z > trigger)
243                         keyboard.z = 1;
244                 else if (keyboard.z < trigger1)
245                         keyboard.z = -1;
246                 else
247                         keyboard.z = 0;
248
249                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
250                 if (this.havocbot_ducktime > time)
251                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
252         }
253
254         keyboard = this.havocbot_keyboard;
255         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
256         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
257         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
258 }
259
260 void havocbot_bunnyhop(entity this, vector dir)
261 {
262         float bunnyhopdistance;
263         vector deviation;
264         float maxspeed;
265
266         // Don't jump when attacking
267         if(this.aistatus & AI_STATUS_ATTACKING)
268                 return;
269
270         if(IS_PLAYER(this.goalcurrent))
271                 return;
272
273         maxspeed = autocvar_sv_maxspeed;
274
275         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
276                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
277         {
278                 this.aistatus &= ~AI_STATUS_RUNNING;
279                 PHYS_INPUT_BUTTON_JUMP(this) = false;
280                 this.bot_canruntogoal = 0;
281                 this.bot_timelastseengoal = 0;
282                 return;
283         }
284
285         if(this.waterlevel > WATERLEVEL_WETFEET)
286         {
287                 this.aistatus &= ~AI_STATUS_RUNNING;
288                 return;
289         }
290
291         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
292         {
293                 this.bot_canruntogoal = 0;
294                 this.bot_timelastseengoal = 0;
295         }
296
297         vector gco = get_closer_dest(this.goalcurrent, this.origin);
298         bunnyhopdistance = vlen(this.origin - gco);
299
300         // Run only to visible goals
301         if(IS_ONGROUND(this))
302         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
303         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
304         {
305                         this.bot_lastseengoal = this.goalcurrent;
306
307                         // seen it before
308                         if(this.bot_timelastseengoal)
309                         {
310                                 // for a period of time
311                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
312                                 {
313                                         float checkdistance;
314                                         checkdistance = true;
315
316                                         // don't run if it is too close
317                                         if(this.bot_canruntogoal==0)
318                                         {
319                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
320                                                         this.bot_canruntogoal = 1;
321                                                 else
322                                                         this.bot_canruntogoal = -1;
323                                         }
324
325                                         if(this.bot_canruntogoal != 1)
326                                                 return;
327
328                                         if(this.aistatus & AI_STATUS_ROAMING)
329                                         if(this.goalcurrent.classname=="waypoint")
330                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
331                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
332                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
333                                         {
334                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
335                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
336                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
337                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
338
339                                                 if(fabs(deviation.y) < 20)
340                                                 if(bunnyhopdistance < vlen(this.origin - gno))
341                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
342                                                 {
343                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
344                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
345                                                         {
346                                                                 checkdistance = false;
347                                                         }
348                                                 }
349                                         }
350
351                                         if(checkdistance)
352                                         {
353                                                 this.aistatus &= ~AI_STATUS_RUNNING;
354                                                 // increase stop distance in case the goal is on a slope or a lower platform
355                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
356                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
357                                         }
358                                         else
359                                         {
360                                                 this.aistatus |= AI_STATUS_RUNNING;
361                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
362                                         }
363                                 }
364                         }
365                         else
366                         {
367                                 this.bot_timelastseengoal = time;
368                         }
369         }
370         else
371         {
372                 this.bot_timelastseengoal = 0;
373         }
374
375 #if 0
376         // Release jump button
377         if(!cvar("sv_pogostick"))
378         if((IS_ONGROUND(this)) == 0)
379         {
380                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
381                         PHYS_INPUT_BUTTON_JUMP(this) = false;
382
383                 // Strafe
384                 if(this.aistatus & AI_STATUS_RUNNING)
385                 if(vlen(this.velocity)>maxspeed)
386                 {
387                         deviation = vectoangles(dir) - vectoangles(this.velocity);
388                         while (deviation.y < -180) deviation.y = deviation.y + 360;
389                         while (deviation.y > 180) deviation.y = deviation.y - 360;
390
391                         if(fabs(deviation.y)>10)
392                                 CS(this).movement_x = 0;
393
394                         if(deviation.y>10)
395                                 CS(this).movement_y = maxspeed * -1;
396                         else if(deviation.y<10)
397                                 CS(this).movement_y = maxspeed;
398
399                 }
400         }
401 #endif
402 }
403
404 // return true when bot isn't getting closer to the current goal
405 bool havocbot_checkgoaldistance(entity this, vector gco)
406 {
407         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
408         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
409         float distance_time = this.goalcurrent_distance_time;
410         if(distance_time < 0)
411                 distance_time = -distance_time;
412         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
413         {
414                 if(!distance_time)
415                         this.goalcurrent_distance_time = time;
416                 else if (time - distance_time > 0.5)
417                         return true;
418         }
419         else
420         {
421                 // reduce it a little bit so it works even with very small approaches to the goal
422                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
423                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
424                 this.goalcurrent_distance_time = 0;
425         }
426         return false;
427 }
428
429 entity havocbot_select_an_item_of_group(entity this, int gr)
430 {
431         entity selected = NULL;
432         float selected_dist2 = 0;
433         // select farthest item of this group from bot's position
434         IL_EACH(g_items, it.item_group == gr && it.solid,
435         {
436                 float dist2 = vlen2(this.origin - it.origin);
437                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
438                 {
439                         selected = it;
440                         selected_dist2 = vlen2(this.origin - selected.origin);
441                 }
442         });
443
444         if (!selected)
445                 return NULL;
446
447         set_tracewalk_dest(selected, this.origin, false);
448         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
449                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
450         {
451                 return NULL;
452         }
453
454         return selected;
455 }
456
457 void havocbot_movetogoal(entity this)
458 {
459         vector diff;
460         vector dir;
461         vector flatdir;
462         vector evadeobstacle;
463         vector evadelava;
464         float dodge_enemy_factor = 1;
465         float maxspeed;
466         //float dist;
467         vector dodge;
468         //if (this.goalentity)
469         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
470         CS(this).movement = '0 0 0';
471         maxspeed = autocvar_sv_maxspeed;
472
473         PHYS_INPUT_BUTTON_JETPACK(this) = false;
474         // Jetpack navigation
475         if(this.navigation_jetpack_goal)
476         if(this.goalcurrent==this.navigation_jetpack_goal)
477         if(GetResourceAmount(this, RESOURCE_FUEL))
478         {
479                 if(autocvar_bot_debug_goalstack)
480                 {
481                         debuggoalstack(this);
482                         te_wizspike(this.navigation_jetpack_point);
483                 }
484
485                 // Take off
486                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
487                 {
488                         // Brake almost completely so it can get a good direction
489                         if(vdist(this.velocity, >, 10))
490                                 return;
491                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
492                 }
493
494                 makevectors(this.v_angle.y * '0 1 0');
495                 dir = normalize(this.navigation_jetpack_point - this.origin);
496
497                 // Landing
498                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
499                 {
500                         // Calculate brake distance in xy
501                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
502                         float vel2 = vlen2(vec2(this.velocity));
503                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
504                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
505                         if(d < db || d < 500)
506                         {
507                                 // Brake
508                                 if (vel2 > (maxspeed * 0.3) ** 2)
509                                 {
510                                         CS(this).movement_x = dir * v_forward * -maxspeed;
511                                         return;
512                                 }
513                                 // Switch to normal mode
514                                 this.navigation_jetpack_goal = NULL;
515                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
516                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
517                                 return;
518                         }
519                 }
520                 else if(checkpvs(this.origin,this.goalcurrent))
521                 {
522                         // If I can see the goal switch to landing code
523                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
524                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
525                         return;
526                 }
527
528                 // Flying
529                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
530                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
531                 {
532                         CS(this).movement_x = dir * v_forward * maxspeed;
533                         CS(this).movement_y = dir * v_right * maxspeed;
534                 }
535                 return;
536         }
537
538         // Handling of jump pads
539         if(this.jumppadcount)
540         {
541                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
542                 {
543                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
544                         if(navigation_poptouchedgoals(this))
545                                 return;
546                 }
547                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
548                 {
549                         // If got stuck on the jump pad try to reach the farthest visible waypoint
550                         // but with some randomness so it can try out different paths
551                         if(!this.goalcurrent)
552                         {
553                                 entity newgoal = NULL;
554                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
555                                 {
556                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
557                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
558                                                 continue;
559
560                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
561
562                                         if(trace_fraction < 1)
563                                                 continue;
564
565                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
566                                                 newgoal = it;
567                                 });
568
569                                 if(newgoal)
570                                 {
571                                         this.ignoregoal = this.goalcurrent;
572                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
573                                         navigation_clearroute(this);
574                                         navigation_routetogoal(this, newgoal, this.origin);
575                                         if(autocvar_bot_debug_goalstack)
576                                                 debuggoalstack(this);
577                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
578                                 }
579                         }
580                         else
581                         {
582                                 if (this.goalcurrent.bot_pickup)
583                                 {
584                                         entity jumppad_wp = this.goalcurrent_prev;
585                                         navigation_poptouchedgoals(this);
586                                         if(!this.goalcurrent && jumppad_wp.wp00)
587                                         {
588                                                 // head to the jumppad destination once bot reaches the goal item
589                                                 navigation_pushroute(this, jumppad_wp.wp00);
590                                         }
591                                 }
592                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
593                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
594                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
595                                 else if(havocbot_checkgoaldistance(this, gco))
596                                 {
597                                         navigation_clearroute(this);
598                                         navigation_goalrating_timeout_force(this);
599                                 }
600                                 else
601                                         return;
602                         }
603                 }
604                 else
605                 {
606                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
607                         {
608                                 vector velxy = this.velocity; velxy_z = 0;
609                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
610                                 {
611                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
612                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
613                                 }
614                                 return;
615                         }
616
617                         // Don't chase players while using a jump pad
618                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
619                                 return;
620                 }
621         }
622         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
623                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
624
625         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
626         if (skill > 6 && !(IS_ONGROUND(this)))
627         {
628                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
629                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
630                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
631
632                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
633                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
634                 if(this.items & IT_JETPACK)
635                 {
636                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
637                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
638                         {
639                                 if(this.velocity.z<0)
640                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
641                         }
642                         else
643                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
644
645                         // If there is no goal try to move forward
646
647                         if(this.goalcurrent==NULL)
648                                 dir = v_forward;
649                         else
650                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
651
652                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
653                         float xyspeed = xyvelocity * dir;
654
655                         if(xyspeed < (maxspeed / 2))
656                         {
657                                 makevectors(this.v_angle.y * '0 1 0');
658                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
659                                 if(trace_fraction==1)
660                                 {
661                                         CS(this).movement_x = dir * v_forward * maxspeed;
662                                         CS(this).movement_y = dir * v_right * maxspeed;
663                                         if (skill < 10)
664                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
665                                 }
666                         }
667
668                         this.havocbot_blockhead = true;
669
670                         return;
671                 }
672                 else if(!this.jumppadcount && !this.goalcurrent.wphardwired
673                         && GetResourceAmount(this, RESOURCE_HEALTH) + GetResourceAmount(this, RESOURCE_ARMOR) > ROCKETJUMP_DAMAGE())
674                 {
675                         if(this.velocity.z < 0)
676                         {
677                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
678                                 {
679                                         .entity weaponentity = weaponentities[slot];
680
681                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
682                                                 continue;
683
684                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
685                                         {
686                                                 CS(this).movement_x = maxspeed;
687
688                                                 if(this.rocketjumptime)
689                                                 {
690                                                         if(time > this.rocketjumptime)
691                                                         {
692                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
693                                                                 this.rocketjumptime = 0;
694                                                         }
695                                                         return;
696                                                 }
697
698                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
699                                                 this.v_angle_x = 90;
700                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
701                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
702                                                 return;
703                                         }
704                                 }
705                         }
706                 }
707                 else
708                 {
709                         // If there is no goal try to move forward
710                         if(this.goalcurrent==NULL)
711                                 CS(this).movement_x = maxspeed;
712                 }
713         }
714
715         // If we are under water with no goals, swim up
716         if(this.waterlevel && !this.goalcurrent)
717         {
718                 dir = '0 0 0';
719                 if(this.waterlevel>WATERLEVEL_SWIMMING)
720                         dir.z = 1;
721                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
722                         PHYS_INPUT_BUTTON_JUMP(this) = true;
723                 else
724                         PHYS_INPUT_BUTTON_JUMP(this) = false;
725                 makevectors(this.v_angle.y * '0 1 0');
726                 vector v = dir * maxspeed;
727                 CS(this).movement.x = v * v_forward;
728                 CS(this).movement.y = v * v_right;
729                 CS(this).movement.z = v * v_up;
730         }
731
732         // if there is nowhere to go, exit
733         if (this.goalcurrent == NULL)
734                 return;
735
736
737         bool locked_goal = false;
738         if((this.goalentity && wasfreed(this.goalentity))
739                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
740         {
741                 navigation_clearroute(this);
742                 navigation_goalrating_timeout_force(this);
743                 return;
744         }
745         else if(this.goalentity.tag_entity)
746         {
747                 navigation_goalrating_timeout_expire(this, 2);
748         }
749         else if(this.goalentity.bot_pickup)
750         {
751                 if(this.goalentity.bot_pickup_respawning)
752                 {
753                         if(this.goalentity.solid) // item respawned
754                                 this.goalentity.bot_pickup_respawning = false;
755                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
756                         {
757                                 if(checkpvs(this.origin, this.goalentity))
758                                 {
759                                         this.goalentity.bot_pickup_respawning = false;
760                                         navigation_goalrating_timeout_expire(this, random());
761                                 }
762                                 locked_goal = true; // wait for item to respawn
763                         }
764                         else if(this.goalentity == this.goalcurrent)
765                                 locked_goal = true; // wait for item to respawn
766                 }
767                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
768                 {
769                         if(checkpvs(this.origin, this.goalentity))
770                         {
771                                 navigation_goalrating_timeout_expire(this, random());
772                         }
773                 }
774         }
775         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
776                 locked_goal = true;
777
778         if (navigation_shortenpath(this))
779         {
780                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
781                         && navigation_goalrating_timeout_can_be_anticipated(this))
782                         navigation_goalrating_timeout_force(this);
783         }
784
785         bool goalcurrent_can_be_removed = false;
786         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
787         {
788                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
789                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
790                 {
791                         goalcurrent_can_be_removed = true;
792                         // don't remove if not visible
793                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
794                         {
795                                 navigation_goalrating_timeout_force(this);
796                                 return;
797                         }
798                 }
799                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
800                 {
801                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
802                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
803                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
804                         {
805                                 navigation_goalrating_timeout_force(this);
806                                 return;
807                         }
808                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
809                 }
810         }
811
812         if(!locked_goal)
813         {
814                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
815                 // in this case path finding can start directly from a waypoint instead of
816                 // looking for all the reachable waypoints up to a certain distance
817                 if (navigation_poptouchedgoals(this))
818                 {
819                         if (this.goalcurrent)
820                         {
821                                 if (goalcurrent_can_be_removed)
822                                 {
823                                         // remove even if not visible
824                                         navigation_goalrating_timeout_force(this);
825                                         return;
826                                 }
827                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
828                                         navigation_goalrating_timeout_force(this);
829                         }
830                         else
831                         {
832                                 entity old_goal = this.goalcurrent_prev;
833                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
834                                 {
835                                         // Avoid multiple costly calls of path finding code that selects one of the closest
836                                         // item of the group by telling the bot to head directly to the farthest item.
837                                         // Next time we let the bot select a goal as usual which can be another item
838                                         // of this group (the closest one) and so on
839                                         this.item_group = old_goal.item_group;
840                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
841                                         if (new_goal)
842                                                 navigation_pushroute(this, new_goal);
843                                 }
844                         }
845                 }
846         }
847
848         // if ran out of goals try to use an alternative goal or get a new strategy asap
849         if(this.goalcurrent == NULL)
850         {
851                 navigation_goalrating_timeout_force(this);
852                 return;
853         }
854
855
856         if(autocvar_bot_debug_goalstack)
857                 debuggoalstack(this);
858
859         bool bunnyhop_forbidden = false;
860         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
861         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
862         {
863                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
864                 destorg = this.goalcurrent.origin;
865         }
866         else if (this.goalcurrent.wpisbox)
867         {
868                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
869                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
870                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
871                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
872                 {
873                         bunnyhop_forbidden = true;
874                         destorg = this.goalcurrent.origin;
875                         if(destorg.z > this.origin.z)
876                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
877                 }
878         }
879
880         diff = destorg - this.origin;
881
882         if (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10))
883         {
884                 // stop if the locked goal has been reached
885                 destorg = this.origin;
886                 diff = dir = '0 0 0';
887         }
888         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
889         {
890                 if (vdist(diff, <, 80))
891                 {
892                         // stop if too close to target player (even if frozen)
893                         destorg = this.origin;
894                         diff = dir = '0 0 0';
895                 }
896                 else
897                 {
898                         // move destorg out of target players, otherwise bot will consider them
899                         // an obstacle that needs to be jumped (especially if frozen)
900                         dir = normalize(diff);
901                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
902                         diff = destorg - this.origin;
903                 }
904         }
905         else
906                 dir = normalize(diff);
907         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
908
909         //if (this.bot_dodgevector_time < time)
910         {
911                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
912                 //this.bot_dodgevector_jumpbutton = 1;
913                 evadeobstacle = '0 0 0';
914                 evadelava = '0 0 0';
915
916                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
917                 makevectors(this.v_angle.y * '0 1 0');
918                 if (this.waterlevel > WATERLEVEL_WETFEET)
919                 {
920                         if (this.waterlevel > WATERLEVEL_SWIMMING)
921                         {
922                                 if(!this.goalcurrent)
923                                         this.aistatus |= AI_STATUS_OUT_WATER;
924                                 else if(destorg.z > this.origin.z)
925                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
926                         }
927                         else
928                         {
929                                 dir = flatdir;
930                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
931                                         (this.aistatus & AI_STATUS_OUT_WATER))
932                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
933                                 else
934                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
935                         }
936                 }
937                 else
938                 {
939                         float s;
940                         vector offset;
941                         if(this.aistatus & AI_STATUS_OUT_WATER)
942                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
943
944                         // jump if going toward an obstacle that doesn't look like stairs we
945                         // can walk up directly
946                         vector deviation = '0 0 0';
947                         float current_speed = vlen(vec2(this.velocity));
948                         if (current_speed < maxspeed * 0.2)
949                                 current_speed = maxspeed * 0.2;
950                         else
951                         {
952                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
953                                 while (deviation.y < -180) deviation.y += 360;
954                                 while (deviation.y > 180) deviation.y -= 360;
955                         }
956                         float turning = false;
957                         vector flat_diff = vec2(diff);
958                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
959                         vector actual_destorg = this.origin + offset;
960                         if (!this.goalstack01 || this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER))
961                         {
962                                 if (vlen2(flat_diff) < vlen2(offset))
963                                 {
964                                         actual_destorg.x = destorg.x;
965                                         actual_destorg.y = destorg.y;
966                                 }
967                         }
968                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
969                         {
970                                 actual_destorg.x = destorg.x;
971                                 actual_destorg.y = destorg.y;
972                         }
973                         else if (vlen2(flat_diff) < vlen2(offset))
974                         {
975                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
976                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
977                                 float dist = vlen(vec2(this.origin + offset - destorg));
978                                 // if current and next goal are close to each other make sure
979                                 // actual_destorg isn't set beyond next_goal_org
980                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
981                                         actual_destorg = next_goal_org;
982                                 else
983                                         actual_destorg = vec2(destorg) + dist * next_dir;
984                                 actual_destorg.z = this.origin.z;
985                                 turning = true;
986                         }
987
988                         LABEL(jump_check);
989                         dir = flatdir = normalize(actual_destorg - this.origin);
990
991                         if (turning || fabs(deviation.y) < 50) // don't even try to jump if deviation is too high
992                         {
993                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
994                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
995                                 {
996                                         s = trace_fraction;
997                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
998                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
999                                         {
1000                                                 // found an obstacle
1001                                                 if (turning && fabs(deviation.y) > 5)
1002                                                 {
1003                                                         // check if the obstacle is still there without turning
1004                                                         actual_destorg = destorg;
1005                                                         turning = false;
1006                                                         this.bot_tracewalk_time = time + 0.25;
1007                                                         goto jump_check;
1008                                                 }
1009                                                 s = trace_fraction;
1010                                                 // don't artificially reduce max jump height in real-time
1011                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1012                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1013                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1014                                                 if (trace_fraction > s)
1015                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1016                                                 else
1017                                                 {
1018                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1019                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1020                                                         if (trace_fraction > s)
1021                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1022                                                 }
1023                                         }
1024                                 }
1025                         }
1026
1027                         // if bot for some reason doesn't get close to the current goal find another one
1028                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1029                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1030                         if(havocbot_checkgoaldistance(this, destorg))
1031                         {
1032                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1033                                 {
1034                                         navigation_clearroute(this);
1035                                         navigation_goalrating_timeout_force(this);
1036                                         return;
1037                                 }
1038
1039                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1040                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1041                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1042                                 {
1043                                         navigation_clearroute(this);
1044                                         navigation_goalrating_timeout_force(this);
1045                                         return;
1046                                 }
1047
1048                                 // give bot only another chance to prevent bot getting stuck
1049                                 // in case it thinks it can walk but actually can't
1050                                 this.goalcurrent_distance_z = FLOAT_MAX;
1051                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1052                                 this.goalcurrent_distance_time = -time; // mark second try
1053                         }
1054
1055                         // Check for water/slime/lava and dangerous edges
1056                         // (only when the bot is on the ground or jumping intentionally)
1057
1058                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
1059                         vector dst_ahead = this.origin + this.view_ofs + offset;
1060                         vector dst_down = dst_ahead - '0 0 3000';
1061                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1062
1063                         bool unreachable = false;
1064                         s = CONTENT_SOLID;
1065                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
1066                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1067                         {
1068                                 // Look downwards
1069                                 traceline(dst_ahead , dst_down, true, NULL);
1070                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1071                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
1072                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1073                                 {
1074                                         s = pointcontents(trace_endpos + '0 0 1');
1075                                         if (s != CONTENT_SOLID)
1076                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1077                                                 evadelava = normalize(this.velocity) * -1;
1078                                         else if (s == CONTENT_SKY)
1079                                                 evadeobstacle = normalize(this.velocity) * -1;
1080                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1081                                         {
1082                                                 // the traceline check isn't enough but is good as optimization,
1083                                                 // when not true (most of the time) this tracebox call is avoided
1084                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1085                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1086                                                 {
1087                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1088                                                         {
1089                                                                 // the goal is probably on an upper platform, assume bot can't get there
1090                                                                 unreachable = true;
1091                                                         }
1092                                                         else
1093                                                                 evadelava = normalize(this.velocity) * -1;
1094                                                 }
1095                                         }
1096                                 }
1097                         }
1098
1099                         dir = flatdir;
1100                         evadeobstacle.z = 0;
1101                         evadelava.z = 0;
1102                         makevectors(this.v_angle.y * '0 1 0');
1103
1104                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1105                         {
1106                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1107                                 if(IS_PLAYER(this.goalcurrent))
1108                                         unreachable = true;
1109                         }
1110
1111                         // slow down if bot is in the air and goal is under it
1112                         if (!this.goalcurrent.wphardwired
1113                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1114                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1115                         {
1116                                 // tracebox wouldn't work when bot is still on the ledge
1117                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1118                                 if (this.origin.z - trace_endpos.z > 120)
1119                                         evadeobstacle = normalize(this.velocity) * -1;
1120                         }
1121
1122                         if(unreachable)
1123                         {
1124                                 navigation_clearroute(this);
1125                                 navigation_goalrating_timeout_force(this);
1126                                 this.ignoregoal = this.goalcurrent;
1127                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1128                         }
1129                 }
1130
1131                 dodge = havocbot_dodge(this);
1132                 if (dodge)
1133                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1134                 dodge += evadeobstacle + evadelava;
1135                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1136                 if (this.enemy)
1137                 {
1138                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1139                         if (IS_PLAYER(trace_ent))
1140                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1141                 }
1142         //      this.bot_dodgevector = dir;
1143         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1144         }
1145
1146         float ladder_zdir = 0;
1147         if(time < this.ladder_time)
1148         {
1149                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1150                 {
1151                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1152                                 ladder_zdir = 1;
1153                 }
1154                 else
1155                 {
1156                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1157                                 ladder_zdir = -1;
1158                 }
1159                 if (ladder_zdir)
1160                 {
1161                         if (vdist(flatdir, <, 15))
1162                                 dir = ladder_zdir * '0 0 1';
1163                         else
1164                         {
1165                                 dir.z = ladder_zdir * 1.3;
1166                                 dir = normalize(dir);
1167                         }
1168                 }
1169         }
1170
1171         if (this.goalcurrent.wpisbox
1172                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1173         {
1174                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1175                 // head to teleport origin
1176                 dir = (this.goalcurrent.origin - this.origin);
1177                 dir.z = 0;
1178                 dir = normalize(dir);
1179         }
1180
1181         if (!this.bot_aimdir_executed)
1182                 bot_aimdir(this, dir, -1);
1183
1184         if (!ladder_zdir)
1185         {
1186                 dir *= dodge_enemy_factor;
1187                 dir = normalize(dir + dodge);
1188         }
1189
1190         //dir = this.bot_dodgevector;
1191         //if (this.bot_dodgevector_jumpbutton)
1192         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1193         CS(this).movement_x = dir * v_forward * maxspeed;
1194         CS(this).movement_y = dir * v_right * maxspeed;
1195         CS(this).movement_z = dir * v_up * maxspeed;
1196
1197         // Emulate keyboard interface
1198         if (skill < 10)
1199                 havocbot_keyboard_movement(this, destorg);
1200
1201         // Bunnyhop!
1202         //if(this.aistatus & AI_STATUS_ROAMING)
1203         if(!bunnyhop_forbidden && this.goalcurrent)
1204         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1205                 havocbot_bunnyhop(this, dir);
1206
1207         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1208         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1209         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1210 }
1211
1212 entity havocbot_gettarget(entity this, bool secondary)
1213 {
1214         entity best = NULL;
1215         vector eye = CENTER_OR_VIEWOFS(this);
1216         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1217         {
1218                 vector v = CENTER_OR_VIEWOFS(it);
1219                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1220                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1221                 if(bot_shouldattack(this, it))
1222                 {
1223                         traceline(eye, v, true, this);
1224                         if (trace_ent == it || trace_fraction >= 1)
1225                                 best = it;
1226                 }
1227         });
1228
1229         return best;
1230 }
1231
1232 void havocbot_chooseenemy(entity this)
1233 {
1234         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1235         {
1236                 this.enemy = NULL;
1237                 return;
1238         }
1239         if (this.enemy)
1240         {
1241                 if (!bot_shouldattack(this, this.enemy))
1242                 {
1243                         // enemy died or something, find a new target
1244                         this.enemy = NULL;
1245                         this.havocbot_chooseenemy_finished = time;
1246                 }
1247                 else if (this.havocbot_stickenemy)
1248                 {
1249                         // tracking last chosen enemy
1250                         // if enemy is visible
1251                         // and not really really far away
1252                         // and we're not severely injured
1253                         // then keep tracking for a half second into the future
1254                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1255                         if (trace_ent == this.enemy || trace_fraction == 1)
1256                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1257                         if (GetResourceAmount(this, RESOURCE_HEALTH) > 30)
1258                         {
1259                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1260                                 this.havocbot_chooseenemy_finished = time + 0.5;
1261                                 return;
1262                         }
1263                         // enemy isn't visible, or is far away, or we're injured severely
1264                         // so stop preferring this enemy
1265                         // (it will still take a half second until a new one is chosen)
1266                         this.havocbot_stickenemy = 0;
1267                 }
1268         }
1269         if (time < this.havocbot_chooseenemy_finished)
1270                 return;
1271         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1272         vector eye = this.origin + this.view_ofs;
1273         entity best = NULL;
1274         float bestrating = 100000000;
1275
1276         // Backup hit flags
1277         int hf = this.dphitcontentsmask;
1278
1279         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1280
1281         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1282
1283         bool scan_transparent = false;
1284         bool scan_secondary_targets = false;
1285         bool have_secondary_targets = false;
1286         while(true)
1287         {
1288                 scan_secondary_targets = false;
1289 LABEL(scan_targets)
1290                 IL_EACH(g_bot_targets, it.bot_attack,
1291                 {
1292                         if(!scan_secondary_targets)
1293                         {
1294                                 if(it.classname == "misc_breakablemodel")
1295                                 {
1296                                         have_secondary_targets = true;
1297                                         continue;
1298                                 }
1299                         }
1300                         else if(it.classname != "misc_breakablemodel")
1301                                 continue;
1302
1303                         vector v = (it.absmin + it.absmax) * 0.5;
1304                         float rating = vlen2(v - eye);
1305                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1306                         if (bestrating > rating)
1307                         if (bot_shouldattack(this, it))
1308                         {
1309                                 traceline(eye, v, true, this);
1310                                 if (trace_ent == it || trace_fraction >= 1)
1311                                 {
1312                                         best = it;
1313                                         bestrating = rating;
1314                                 }
1315                         }
1316                 });
1317
1318                 if(!best && have_secondary_targets && !scan_secondary_targets)
1319                 {
1320                         scan_secondary_targets = true;
1321                         // restart the loop
1322                         bestrating = 100000000;
1323                         goto scan_targets;
1324                 }
1325
1326                 // I want to do a second scan if no enemy was found or I don't have weapons
1327                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1328                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1329                         break;
1330                 if(scan_transparent)
1331                         break;
1332
1333                 // Set flags to see through transparent objects
1334                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1335
1336                 scan_transparent = true;
1337         }
1338
1339         // Restore hit flags
1340         this.dphitcontentsmask = hf;
1341
1342         this.enemy = best;
1343         this.havocbot_stickenemy = true;
1344         if(best && best.classname == "misc_breakablemodel")
1345                 this.havocbot_stickenemy = false;
1346 }
1347
1348 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1349 {
1350         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1351         // so skip this for them, or they'll never get to reload their weapons at all.
1352         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1353         if(skill < 5)
1354                 return false;
1355
1356         // if this weapon is scheduled for reloading, don't switch to it during combat
1357         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1358         {
1359                 FOREACH(Weapons, it != WEP_Null, {
1360                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1361                                 return true; // other weapon available
1362                 });
1363         }
1364
1365         return false;
1366 }
1367
1368 void havocbot_chooseweapon(entity this, .entity weaponentity)
1369 {
1370         int i;
1371
1372         // ;)
1373         if(g_weaponarena_weapons == WEPSET(TUBA))
1374         {
1375                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1376                 return;
1377         }
1378
1379         // TODO: clean this up by moving it to weapon code
1380         if(this.enemy==NULL)
1381         {
1382                 // If no weapon was chosen get the first available weapon
1383                 if(this.(weaponentity).m_weapon==WEP_Null)
1384                 FOREACH(Weapons, it != WEP_Null, {
1385                         if(client_hasweapon(this, it, weaponentity, true, false))
1386                         {
1387                                 this.(weaponentity).m_switchweapon = it;
1388                                 return;
1389                         }
1390                 });
1391                 return;
1392         }
1393
1394         // Do not change weapon during the next second after a combo
1395         float f = time - this.lastcombotime;
1396         if(f < 1)
1397                 return;
1398
1399         float w;
1400         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1401
1402         // Should it do a weapon combo?
1403         float af, ct, combo_time, combo;
1404
1405         af = ATTACK_FINISHED(this, weaponentity);
1406         ct = autocvar_bot_ai_weapon_combo_threshold;
1407
1408         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1409         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1410         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1411
1412         combo = false;
1413
1414         if(autocvar_bot_ai_weapon_combo)
1415         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1416         if(af > combo_time)
1417         {
1418                 combo = true;
1419                 this.lastcombotime = time;
1420         }
1421
1422         distance *= (2 ** this.bot_rangepreference);
1423
1424         // Custom weapon list based on distance to the enemy
1425         if(bot_custom_weapon){
1426
1427                 // Choose weapons for far distance
1428                 if ( distance > bot_distance_far ) {
1429                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1430                                 w = bot_weapons_far[i];
1431                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1432                                 {
1433                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1434                                                 continue;
1435                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1436                                         return;
1437                                 }
1438                         }
1439                 }
1440
1441                 // Choose weapons for mid distance
1442                 if ( distance > bot_distance_close) {
1443                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1444                                 w = bot_weapons_mid[i];
1445                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1446                                 {
1447                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1448                                                 continue;
1449                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1450                                         return;
1451                                 }
1452                         }
1453                 }
1454
1455                 // Choose weapons for close distance
1456                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1457                         w = bot_weapons_close[i];
1458                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1459                         {
1460                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1461                                         continue;
1462                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1463                                 return;
1464                         }
1465                 }
1466         }
1467 }
1468
1469 void havocbot_aim(entity this)
1470 {
1471         if (time < this.nextaim)
1472                 return;
1473         this.nextaim = time + 0.1;
1474         vector myvel = this.velocity;
1475         if (!this.waterlevel)
1476                 myvel.z = 0;
1477         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1478         else if (this.enemy)
1479         {
1480                 vector enemyvel = this.enemy.velocity;
1481                 if (!this.enemy.waterlevel)
1482                         enemyvel.z = 0;
1483                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1484         }
1485         else
1486                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1487 }
1488
1489 bool havocbot_moveto_refresh_route(entity this)
1490 {
1491         // Refresh path to goal if necessary
1492         entity wp;
1493         wp = this.havocbot_personal_waypoint;
1494         navigation_goalrating_start(this);
1495         navigation_routerating(this, wp, 10000, 10000);
1496         navigation_goalrating_end(this);
1497         return (this.goalentity != NULL);
1498 }
1499
1500 float havocbot_moveto(entity this, vector pos)
1501 {
1502         entity wp;
1503
1504         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1505         {
1506                 // Step 4: Move to waypoint
1507                 if(this.havocbot_personal_waypoint==NULL)
1508                 {
1509                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1510                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1511                         return CMD_STATUS_ERROR;
1512                 }
1513
1514                 if (!bot_strategytoken_taken)
1515                 if(this.havocbot_personal_waypoint_searchtime<time)
1516                 {
1517                         bot_strategytoken_taken = true;
1518                         if(havocbot_moveto_refresh_route(this))
1519                         {
1520                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1521                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1522                                 this.havocbot_personal_waypoint_failcounter = 0;
1523                         }
1524                         else
1525                         {
1526                                 this.havocbot_personal_waypoint_failcounter += 1;
1527                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1528                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1529                                 {
1530                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1531                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1532                                         delete(this.havocbot_personal_waypoint);
1533                                         return CMD_STATUS_ERROR;
1534                                 }
1535                                 else
1536                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1537                         }
1538                 }
1539
1540                 if(autocvar_bot_debug_goalstack)
1541                         debuggoalstack(this);
1542
1543
1544                 // Go!
1545                 havocbot_movetogoal(this);
1546
1547                 if (!this.bot_aimdir_executed && this.goalcurrent)
1548                 {
1549                         // Heading
1550                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1551                         dir -= this.origin + this.view_ofs;
1552                         dir.z = 0;
1553                         bot_aimdir(this, dir, -1);
1554                 }
1555
1556                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1557                 {
1558                         // Step 5: Waypoint reached
1559                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1560                         delete(this.havocbot_personal_waypoint);
1561                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1562                         return CMD_STATUS_FINISHED;
1563                 }
1564
1565                 return CMD_STATUS_EXECUTING;
1566         }
1567
1568         // Step 2: Linking waypoint
1569         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1570         {
1571                 // Wait until it is linked
1572                 if(!this.havocbot_personal_waypoint.wplinked)
1573                 {
1574                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1575                         return CMD_STATUS_EXECUTING;
1576                 }
1577
1578                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1579                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1580                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1581
1582                 // Step 3: Route to waypoint
1583                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1584
1585                 return CMD_STATUS_EXECUTING;
1586         }
1587
1588         // Step 1: Spawning waypoint
1589         wp = waypoint_spawnpersonal(this, pos);
1590         if(wp==NULL)
1591         {
1592                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1593                 return CMD_STATUS_ERROR;
1594         }
1595
1596         this.havocbot_personal_waypoint = wp;
1597         this.havocbot_personal_waypoint_failcounter = 0;
1598         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1599
1600         // if pos is inside a teleport, then let's mark it as teleport waypoint
1601         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1602         {
1603                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1604                 this.lastteleporttime = 0;
1605         });
1606
1607 /*
1608         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1609                 print("routing to a teleporter\n");
1610         else
1611                 print("routing to a non-teleporter\n");
1612 */
1613
1614         return CMD_STATUS_EXECUTING;
1615 }
1616
1617 float havocbot_resetgoal(entity this)
1618 {
1619         navigation_clearroute(this);
1620         return CMD_STATUS_FINISHED;
1621 }
1622
1623 void havocbot_setupbot(entity this)
1624 {
1625         this.bot_ai = havocbot_ai;
1626         this.cmd_moveto = havocbot_moveto;
1627         this.cmd_resetgoal = havocbot_resetgoal;
1628
1629         // NOTE: bot is not player yet
1630         havocbot_chooserole(this);
1631 }
1632
1633 vector havocbot_dodge(entity this)
1634 {
1635         // LordHavoc: disabled because this is too expensive
1636         return '0 0 0';
1637 #if 0
1638         entity head;
1639         vector dodge, v, n;
1640         float danger, bestdanger, vl, d;
1641         dodge = '0 0 0';
1642         bestdanger = -20;
1643         // check for dangerous objects near bot or approaching bot
1644         head = findchainfloat(bot_dodge, true);
1645         while(head)
1646         {
1647                 if (head.owner != this)
1648                 {
1649                         vl = vlen(head.velocity);
1650                         if (vl > autocvar_sv_maxspeed * 0.3)
1651                         {
1652                                 n = normalize(head.velocity);
1653                                 v = this.origin - head.origin;
1654                                 d = v * n;
1655                                 if (d > (0 - head.bot_dodgerating))
1656                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1657                                 {
1658                                         // calculate direction and distance from the flight path, by removing the forward axis
1659                                         v = v - (n * (v * n));
1660                                         danger = head.bot_dodgerating - vlen(v);
1661                                         if (bestdanger < danger)
1662                                         {
1663                                                 bestdanger = danger;
1664                                                 // dodge to the side of the object
1665                                                 dodge = normalize(v);
1666                                         }
1667                                 }
1668                         }
1669                         else
1670                         {
1671                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1672                                 if (bestdanger < danger)
1673                                 {
1674                                         bestdanger = danger;
1675                                         dodge = normalize(this.origin - head.origin);
1676                                 }
1677                         }
1678                 }
1679                 head = head.chain;
1680         }
1681         return dodge;
1682 #endif
1683 }